Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Dav on January 23, 2021, 01:41:52 pm

Title: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 23, 2021, 01:41:52 pm
I'm working on a simple file selection box SUB which uses SHELL "dir" calls to get filenames and directory info.  Wanting to make to code compatible with linux and macs, I was wondering what changes if any in the SHELL call I would need to make it work on those OS.  Or would a SHELL "dir" call not work at all on them?  I only can test on Windows right now, not sure about SHELLIng on linux or Mac.  Thanks....

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: odin on January 23, 2021, 01:46:33 pm
Here's how it's done by the IDE, works on all platforms:

Code: QB64: [Select]
  1. FUNCTION idezfilelist$ (path$, method, mask$) 'method0=*.bas, method1=*.*, method2=custom mask
  2.     DIM sep AS STRING * 1
  3.     sep = CHR$(0)
  4.  
  5.     IF os$ = "WIN" THEN
  6.         OPEN ".\internal\temp\files.txt" FOR OUTPUT AS #150: CLOSE #150
  7.         IF method = 0 THEN SHELL _HIDE "dir /b /ON /A-D " + QuotedFilename$(path$) + "\*.bas >.\internal\temp\files.txt"
  8.         IF method = 1 THEN SHELL _HIDE "dir /b /ON /A-D " + QuotedFilename$(path$) + "\*.* >.\internal\temp\files.txt"
  9.         IF method = 2 THEN SHELL _HIDE "dir /b /ON /A-D " + QuotedFilename$(path$) + "\" + QuotedFilename$(mask$) + " >.\internal\temp\files.txt"
  10.         filelist$ = ""
  11.         OPEN ".\internal\temp\files.txt" FOR INPUT AS #150
  12.         DO UNTIL EOF(150)
  13.             LINE INPUT #150, a$
  14.             IF LEN(a$) THEN 'skip blank entries
  15.                 IF filelist$ = "" THEN filelist$ = a$ ELSE filelist$ = filelist$ + sep + a$
  16.             END IF
  17.         LOOP
  18.         CLOSE #150
  19.         idezfilelist$ = filelist$
  20.         EXIT FUNCTION
  21.     END IF
  22.  
  23.     IF os$ = "LNX" THEN
  24.         filelist$ = ""
  25.         IF method = 0 THEN
  26.             FOR i = 1 TO 2
  27.                 OPEN "./internal/temp/files.txt" FOR OUTPUT AS #150: CLOSE #150
  28.                 IF i = 1 THEN SHELL _HIDE "find " + QuotedFilename$(path$) + " -maxdepth 1 -type f -name " + CHR$(34) + "*.bas" + CHR$(34) + " | sort >./internal/temp/files.txt"
  29.                 IF i = 2 THEN SHELL _HIDE "find " + QuotedFilename$(path$) + " -maxdepth 1 -type f -name " + CHR$(34) + "*.BAS" + CHR$(34) + " | sort >./internal/temp/files.txt"
  30.                 GOSUB AddToList
  31.             NEXT
  32.         ELSEIF method = 1 THEN
  33.             SHELL _HIDE "find " + QuotedFilename$(path$) + " -maxdepth 1 -type f -name " + CHR$(34) + "*" + CHR$(34) + " | sort >./internal/temp/files.txt"
  34.             GOSUB AddToList
  35.         ELSEIF method = 2 THEN
  36.             SHELL _HIDE "find " + QuotedFilename$(path$) + " -maxdepth 1 -type f -name " + CHR$(34) + mask$ + CHR$(34) + " | sort >./internal/temp/files.txt"
  37.             GOSUB AddToList
  38.         END IF
  39.         idezfilelist$ = filelist$
  40.         EXIT FUNCTION
  41.  
  42.         AddToList:
  43.         OPEN "./internal/temp/files.txt" FOR INPUT AS #150
  44.         DO UNTIL EOF(150)
  45.             LINE INPUT #150, a$
  46.             IF LEN(a$) = 0 THEN EXIT DO
  47.             FOR x = LEN(a$) TO 1 STEP -1
  48.                 a2$ = MID$(a$, x, 1)
  49.                 IF a2$ = "/" THEN
  50.                     a$ = RIGHT$(a$, LEN(a$) - x)
  51.                     EXIT FOR
  52.                 END IF
  53.             NEXT
  54.             IF filelist$ = "" THEN filelist$ = a$ ELSE filelist$ = filelist$ + sep + a$
  55.         LOOP
  56.         CLOSE #150
  57.         RETURN
  58.     END IF
  59.  
  61.  
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 23, 2021, 01:50:42 pm
Thanks, odin!

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 23, 2021, 02:00:16 pm
That's a time saver, Dav. I could have told you Linux uses the exact same dir command, but that the switches and output format are different than Windows. It's neat to see the QB64 conversions needed to convert that information, which I take means that a SHELL in QB64 will produce the same output format, I would hope, when doing something like SHELL _HIDE "dir *.*>tmp.tmp

So provided the Windows tmp,tmp file appeared in the same format for file names, dates, and file size, and had the same headers, etc. you could rely on one open and read method to extract and parse the info correctly for both platforms. In other words, more is needed than the Windows /b (bare) switch for date and file size info.

As for Mac, it is stated to be POSIX compliant, so I would hope it can be handled the same as Windows for directory output.

Maybe you could make a simple snippet for Fell, who I believe has a Mac and Linux system, and ask him to post the output. If your Windows results match his Linux and Apple results, your golden. That may not even be necessary, but I'd take fact over theory, everyday. (Sorry Bill!).

Pete
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on January 23, 2021, 02:32:29 pm
There is another cross platform approach that will give you a Directory's List array and a File's list array for a given folder or directory, it happens to be current Best Answer in this thread:
https://www.qb64.org/forum/index.php?topic=1511.msg122368#msg122368

Looks like you will have to parse out the files' string returned by odin's function.

 
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SMcNeill on January 23, 2021, 02:59:22 pm
Quote from: bplus on January 23, 2021, 02:32:29 pm
There is another cross platform approach that will give you a Directory's List array and a File's list array for a given folder or directory, it happens to be current Best Answer in this thread:
https://www.qb64.org/forum/index.php?topic=1511.msg122368#msg122368

Looks like you will have to parse out the files' string returned by odin's function.

You might want to attach direntry.h to that post, so folks can find it and download it.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on January 23, 2021, 03:46:09 pm
Quote from: SMcNeill on January 23, 2021, 02:59:22 pm
You might want to attach direntry.h to that post, so folks can find it and download it.

OK
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 23, 2021, 04:23:01 pm
Thanks for the link, @bplus.  I think I glanced at that once before, but had my interest elsewhere at the time and forgot about it.  Very glad to see it again.  Looks like it's what I'm after.

Here's what I had started working on, was going to add directory info and navigating, and allow a graphics version too.

- Dav

Code: QB64: [Select]
  1.  
  2. a$ = FileSelect$(5, 10, 15, 55, "*.*")
  3.  
  4. IF a$ <> "" THEN
  5.     PRINT "You selected: "; a$
  7.  
  9.  
  10.  
  11. FUNCTION FileSelect$ (y, x, y2, x2, Filespec$)
  12.  
  13.     '=== save original place of cursor
  14.     origy = CSRLIN: origx = POS(1)
  15.  
  16.     '=== Save whole screen
  17.     DIM scr1 AS _MEM, scr2 AS _MEM
  18.     scr1 = _MEMIMAGE(0): scr2 = _MEMNEW(scr1.SIZE)
  19.     _MEMCOPY scr1, scr1.OFFSET, scr1.SIZE TO scr2, scr2.OFFSET
  20.  
  21.     SHELL _HIDE "DIR " + Filespec$ + " /b > $_TeMP_FILE_LIST"
  22.  
  23.     'get list...
  24.     REDIM FileNames$(5000) 'space for 5000 filenames
  25.  
  26.     FF = FREEFILE
  27.     OPEN "$_TeMP_FILE_LIST" FOR INPUT AS #FF
  28.     LineCount = 0
  29.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
  30.         LINE INPUT #FF, rl$
  31.         'skip the temp file...
  32.         IF rl$ <> "$_TeMP_FILE_LIST" THEN
  33.             FileNames$(LineCount) = rl$
  34.             LineCount = LineCount + 1
  35.         END IF
  36.     WEND
  37.     CLOSE #FF
  38.  
  39.     KILL "$_TeMP_FILE_LIST"
  40.  
  41.     'draw a box
  42.     COLOR _RGB(100, 100, 255)
  43.     FOR l = 0 TO y2 + 1
  44.         LOCATE y + l, x: PRINT STRING$(x2 + 4, CHR$(219));
  45.     NEXT
  46.  
  47.     DO
  48.  
  49.         FOR l = 0 TO (y2 - 1)
  50.             LOCATE (y + 1) + l, (x + 2)
  51.             IF l + top = Selection THEN
  52.                 COLOR _RGB(0, 0, 0), _RGB(255, 255, 255) 'selected line
  53.             ELSE
  54.                 COLOR _RGB(255, 255, 255), _RGB(0, 0, 0) 'regular
  55.             END IF
  56.             PRINT LEFT$(FileNames$(top + l) + STRING$(x2, " "), x2);
  57.         NEXT
  58.  
  59.         k$ = INKEY$
  60.         SELECT CASE k$
  61.             CASE IS = CHR$(0) + CHR$(72) 'Up arrow
  62.                 IF Selection > 0 THEN Selection = Selection - 1
  63.                 IF Selection < top THEN top = Selection
  64.             CASE IS = CHR$(0) + CHR$(80) 'Down Arrow
  65.                 IF Selection < (LineCount - 1) THEN Selection = Selection + 1
  66.                 IF Selection > (top + (y2 - 2)) THEN top = Selection - y2 + 1
  67.             CASE IS = CHR$(0) + CHR$(73) 'Page up
  68.                 top = top - y2
  69.                 Selection = Selection - y2
  70.                 IF top < 0 THEN top = 0
  71.                 IF Selection < 0 THEN Selection = 0
  72.             CASE IS = CHR$(0) + CHR$(81) 'Page Down
  73.                 top = top + y2
  74.                 Selection = Selection + y2
  75.                 IF top >= LineCount - y2 THEN top = LineCount - y2
  76.                 IF top < 0 THEN top = 0
  77.                 IF Selection >= LineCount THEN Selection = LineCount - 1
  78.             CASE IS = CHR$(0) + CHR$(71) 'Home
  79.                 top = 0: Selection = 0
  80.             CASE IS = CHR$(0) + CHR$(79) 'End
  81.                 Selection = LineCount - 1
  82.                 top = Selection - y2 + 1
  83.                 IF top < 0 THEN top = 0
  84.             CASE IS = CHR$(27) ' ESC cancels
  85.                 FileSelect$ = ""
  86.                 EXIT DO
  87.             CASE IS = CHR$(13) 'Enter
  88.                 FileSelect$ = RTRIM$(FileNames$(Selection))
  89.                 EXIT DO
  90.         END SELECT
  91.     LOOP
  92.  
  93.     _KEYCLEAR
  94.  
  95.     '=== Restore the whole screen
  96.     _MEMCOPY scr2, scr2.OFFSET, scr2.SIZE TO scr1, scr1.OFFSET
  97.     _MEMFREE scr1: _MEMFREE scr2
  98.  
  99.     '=== restore original y,x
  100.     LOCATE origy, origx
  101.  
  103.  
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on January 23, 2021, 04:32:45 pm
Yeah, I like the fileSpec$ aspect of both odin's and Dav's.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 23, 2021, 04:48:07 pm
Been there, done that, but at some point I'm going to have to add a directory tree to my routine, too. I like to use BINARY instead of INPUT in all my files operations. If you  want to include date an time, let me know; otherwise /b is a nice command line switch to get just the file names. I use it a lot but for files, I like to see when they were created.

Pete
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 23, 2021, 06:24:48 pm
Yeah, I want to show the file info too eventually.  I have API routines to do all that, but was aiming for a cross compatible way.  And seeing how you use SHELL _HIDE often to your advantage kind of motivated me with it.

I planned to get Directories first  (SHELL dir /d), then another call for files, combine both to the Filenames$ array.  Selecting directory name will change to that directory.  Maybe put a ".." selection at the top of the list to go up one directory.  Was thinking that combining SHELL with QB64's builtin directory commands could handle all that, and work on all platforms.

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 23, 2021, 06:43:58 pm
I'm thinking along the same lines. something like this...

..
[Directory-1]
[Directory-2]
[Directory-3]
Filename1.txt
Filename2.text
Filename3.txt

etc.

Fairly easy to do by making a DIR only call, followed a files only call. add the .., directories, and the files. I track the entry numbers, so all I'll need to know is the entry number that changes from a directory to a file.

In windows there re several options to organize the output. Date of creation, alphabetically, etc. It's a time saver, but in days past I made functions to convert to army time, and sort dates, names, etc. For a list of all switches, visit the easy.dos.com site.

Fun stuff,

Pete
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 23, 2021, 06:52:20 pm
Yes, it's fun to me trying to find workarounds.   I was thinking of just adding the [ ] to the dir names when saving them in the array, and then just strip the [ ] out before using the names to change directories. 

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 23, 2021, 07:05:03 pm
What I would like, beyond what we are discussing, is a root navigation option. I'm not sure if I'll do that as a second popup, like a right click, or make some sort of flip screen. It's just a whole lot faster to move around to the folders you want to access that way. Of course another option is a dir input line, where you can click somewhere within that line, and it shortens to where you clicked and then displays that directory to the screen like:

c:\QB64\myprograms\

So click anywhere on qb64, and it shortens the url to: c:\qb64, and then opens that directory.

That lateral scrolling routine would make that method quite possible, still, it isn't as fast as with all the opens that Explorer has to offer.

Pete
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 25, 2021, 04:15:09 pm
Here's what I got so far, thanks @Pete for dir command help.  Seems to work ok for me this way. 

Right now it's just for Windows still.  I might make directories a slightly different color.

You can navigate directories, just press enter to enter them.  Enter on filename to select it.

- Dav

Code: QB64: [Select]
  1.  
  2. a$ = FileSelect$(5, 10, 15, 55, "*.*")
  3.  
  4. IF a$ <> "" THEN
  5.     PRINT "You selected: "; a$
  7.  
  9.  
  10.  
  11. FUNCTION FileSelect$ (y, x, y2, x2, Filespec$)
  12.  
  13.     '=== save original place of cursor
  14.     origy = CSRLIN: origx = POS(1)
  15.  
  16.     '=== Save whole screen
  17.     DIM scr1 AS _MEM, scr2 AS _MEM
  18.     scr1 = _MEMIMAGE(0): scr2 = _MEMNEW(scr1.SIZE)
  19.     _MEMCOPY scr1, scr1.OFFSET, scr1.SIZE TO scr2, scr2.OFFSET
  20.  
  21.     loadagain:
  22.     top = 0
  23.     selection = 0
  24.  
  25.     SHELL _HIDE "DIR /b /A:D > $_TeMP_FILE_LIST"
  26.  
  27.     'get list...
  28.     REDIM FileNames$(5000) 'space for 5000 filenames
  29.  
  30.     FileNames$(0) = ".."
  31.  
  32.     FF = FREEFILE
  33.     OPEN "$_TeMP_FILE_LIST" FOR INPUT AS #FF
  34.  
  35.     LineCount = 1
  36.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
  37.         LINE INPUT #FF, rl$
  38.         FileNames$(LineCount) = "[" + rl$ + "]"
  39.         LineCount = LineCount + 1
  40.     WEND
  41.     CLOSE #FF
  42.  
  43.     KILL "$_TeMP_FILE_LIST"
  44.  
  45.     SHELL _HIDE "DIR /b /A:-D " + Filespec$ + " > $_TeMP_FILE_LIST"
  46.  
  47.     FF = FREEFILE
  48.     OPEN "$_TeMP_FILE_LIST" FOR INPUT AS #FF
  49.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
  50.         LINE INPUT #FF, rl$
  51.         'skip the temp file...
  52.         IF rl$ <> "$_TeMP_FILE_LIST" THEN
  53.             FileNames$(LineCount) = rl$
  54.             LineCount = LineCount + 1
  55.         END IF
  56.     WEND
  57.     CLOSE #FF
  58.  
  59.     KILL "$_TeMP_FILE_LIST"
  60.  
  61.     'draw a box
  62.     COLOR _RGB(100, 100, 255)
  63.     FOR l = 0 TO y2 + 1
  64.         LOCATE y + l, x: PRINT STRING$(x2 + 4, CHR$(219));
  65.     NEXT
  66.  
  67.     DO
  68.  
  69.         FOR l = 0 TO (y2 - 1)
  70.             LOCATE (y + 1) + l, (x + 2)
  71.             IF l + top = selection THEN
  72.                 COLOR _RGB(0, 0, 0), _RGB(255, 255, 255) 'selected line
  73.             ELSE
  74.                 COLOR _RGB(255, 255, 255), _RGB(0, 0, 0) 'regular
  75.             END IF
  76.             PRINT LEFT$(FileNames$(top + l) + STRING$(x2, " "), x2);
  77.         NEXT
  78.  
  79.         k$ = INKEY$
  80.         SELECT CASE k$
  81.             CASE IS = CHR$(0) + CHR$(72) 'Up arrow
  82.                 IF selection > 0 THEN selection = selection - 1
  83.                 IF selection < top THEN top = selection
  84.             CASE IS = CHR$(0) + CHR$(80) 'Down Arrow
  85.                 IF selection < (LineCount - 1) THEN selection = selection + 1
  86.                 IF selection > (top + (y2 - 2)) THEN top = selection - y2 + 1
  87.             CASE IS = CHR$(0) + CHR$(73) 'Page up
  88.                 top = top - y2
  89.                 selection = selection - y2
  90.                 IF top < 0 THEN top = 0
  91.                 IF selection < 0 THEN selection = 0
  92.             CASE IS = CHR$(0) + CHR$(81) 'Page Down
  93.                 top = top + y2
  94.                 selection = selection + y2
  95.                 IF top >= LineCount - y2 THEN top = LineCount - y2
  96.                 IF top < 0 THEN top = 0
  97.                 IF selection >= LineCount THEN selection = LineCount - 1
  98.             CASE IS = CHR$(0) + CHR$(71) 'Home
  99.                 top = 0: selection = 0
  100.             CASE IS = CHR$(0) + CHR$(79) 'End
  101.                 selection = LineCount - 1
  102.                 top = selection - y2 + 1
  103.                 IF top < 0 THEN top = 0
  104.             CASE IS = CHR$(27) ' ESC cancels
  105.                 FileSelect$ = ""
  106.                 EXIT DO
  107.             CASE IS = CHR$(13) 'Enter
  108.                 'go up one dir
  109.                 IF RTRIM$(FileNames$(selection)) = ".." THEN
  110.                     cd$ = _CWD$
  111.                     cd$ = LEFT$(cd$, _INSTRREV(cd$, "\"))
  112.                     CHDIR cd$
  113.                     ERASE FileNames$
  114.                     GOTO loadagain
  115.                 END IF
  116.                 'see if directory
  117.                 test$ = RTRIM$(FileNames$(selection))
  118.                 IF LEFT$(test$, 1) = "[" THEN
  119.                     test$ = MID$(test$, 2, LEN(test$) - 2)
  120.                     CHDIR test$
  121.                     ERASE FileNames$
  122.                     GOTO loadagain
  123.                 ELSE
  124.                     IF RIGHT$(_CWD$, 1) = "\" THEN
  125.                         c$ = _CWD$
  126.                     ELSE
  127.                         c$ = _CWD$ + "\"
  128.                     END IF
  129.                     FileSelect$ = c$ + RTRIM$(FileNames$(selection))
  130.                     EXIT DO
  131.                 END IF
  132.         END SELECT
  133.     LOOP
  134.  
  135.     _KEYCLEAR
  136.  
  137.     '=== Restore the whole screen
  138.     _MEMCOPY scr2, scr2.OFFSET, scr2.SIZE TO scr1, scr1.OFFSET
  139.     _MEMFREE scr1: _MEMFREE scr2
  140.  
  141.     '=== restore original y,x
  142.     LOCATE origy, origx
  143.  
  145.  
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 25, 2021, 09:41:17 pm
Although Steve has provided me a better file select solution, I wanted to go ahead and finish up the SHELL version, so I added the Linux find command if linux OS is detected.   If one of you kind linux people could test this and see if this works for you I'd appreciate it.  Thanks.  I used to have QB64 on linux mint pen drive, but lost it...

Also, this function changes the foreground and background COLOR attributes.  I'd like to restore those upon exiting.  Is there a way to do that?  I'm trying _DEFAULTCOLOR, but it seems to only save foreground (text).  The background color stays changed. (fixed...)

- Dav

Code: QB64: [Select]
  1.  
  2. a$ = FileSelect$(5, 10, 15, 55, "*.*")
  3.  
  4. IF a$ <> "" THEN
  5.     PRINT "You selected: "; a$
  7.  
  9.  
  10.  
  11. FUNCTION FileSelect$ (y, x, y2, x2, Filespec$)
  12.  
  13.     '=== save original place of cursor
  14.     origy = CSRLIN: origx = POS(1)
  15.  
  16.     '=== save colors
  17.     fg& = _DEFAULTCOLOR
  18.     bg& = _BACKGROUNDCOLOR
  19.  
  20.     '=== Save whole screen
  21.     DIM scr1 AS _MEM, scr2 AS _MEM
  22.     scr1 = _MEMIMAGE(0): scr2 = _MEMNEW(scr1.SIZE)
  23.     _MEMCOPY scr1, scr1.OFFSET, scr1.SIZE TO scr2, scr2.OFFSET
  24.  
  25.     loadagain:
  26.  
  27.     top = 0
  28.     selection = 0
  29.  
  30.     IF INSTR(_OS$, "LINUX") THEN
  31.         SHELL _HIDE "find . -type d > $_TeMP_FILE_LIST"
  32.     ELSE
  33.         SHELL _HIDE "dir /b /A:D > $_TeMP_FILE_LIST"
  34.     END IF
  35.  
  36.     'get list...
  37.     REDIM FileNames$(5000) 'space for 5000 filenames
  38.  
  39.     FileNames$(0) = ".."
  40.  
  41.     FF = FREEFILE
  42.     OPEN "$_TeMP_FILE_LIST" FOR INPUT AS #FF
  43.  
  44.     LineCount = 1
  45.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
  46.         LINE INPUT #FF, rl$
  47.         FileNames$(LineCount) = "[" + rl$ + "]"
  48.         LineCount = LineCount + 1
  49.     WEND
  50.     CLOSE #FF
  51.  
  52.     KILL "$_TeMP_FILE_LIST"
  53.  
  54.     IF INSTR(_OS$, "LINUX") THEN
  55.         SHELL _HIDE "find . -type f " + CHR$(34) + Filespec$ + CHR$(34) + " > $_TeMP_FILE_LIST"
  56.     ELSE
  57.         SHELL _HIDE "dir /b /A:-D " + Filespec$ + " > $_TeMP_FILE_LIST"
  58.     END IF
  59.  
  60.     FF = FREEFILE
  61.     OPEN "$_TeMP_FILE_LIST" FOR INPUT AS #FF
  62.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
  63.         LINE INPUT #FF, rl$
  64.         'skip the temp file...
  65.         IF rl$ <> "$_TeMP_FILE_LIST" THEN
  66.             FileNames$(LineCount) = rl$
  67.             LineCount = LineCount + 1
  68.         END IF
  69.     WEND
  70.     CLOSE #FF
  71.  
  72.     KILL "$_TeMP_FILE_LIST"
  73.  
  74.     'draw a box
  75.     COLOR _RGB(100, 100, 255)
  76.     FOR l = 0 TO y2 + 1
  77.         LOCATE y + l, x: PRINT STRING$(x2 + 4, CHR$(219));
  78.     NEXT
  79.  
  80.     DO
  81.  
  82.         FOR l = 0 TO (y2 - 1)
  83.             LOCATE (y + 1) + l, (x + 2)
  84.             IF l + top = selection THEN
  85.                 COLOR _RGB(0, 0, 0), _RGB(255, 255, 255) 'selected line
  86.             ELSE
  87.                 COLOR _RGB(255, 255, 255), _RGB(0, 0, 0) 'regular
  88.             END IF
  89.             PRINT LEFT$(FileNames$(top + l) + STRING$(x2, " "), x2);
  90.         NEXT
  91.  
  92.         k$ = INKEY$
  93.         SELECT CASE k$
  94.             CASE IS = CHR$(0) + CHR$(72) 'Up arrow
  95.                 IF selection > 0 THEN selection = selection - 1
  96.                 IF selection < top THEN top = selection
  97.             CASE IS = CHR$(0) + CHR$(80) 'Down Arrow
  98.                 IF selection < (LineCount - 1) THEN selection = selection + 1
  99.                 IF selection > (top + (y2 - 2)) THEN top = selection - y2 + 1
  100.             CASE IS = CHR$(0) + CHR$(73) 'Page up
  101.                 top = top - y2
  102.                 selection = selection - y2
  103.                 IF top < 0 THEN top = 0
  104.                 IF selection < 0 THEN selection = 0
  105.             CASE IS = CHR$(0) + CHR$(81) 'Page Down
  106.                 top = top + y2
  107.                 selection = selection + y2
  108.                 IF top >= LineCount - y2 THEN top = LineCount - y2
  109.                 IF top < 0 THEN top = 0
  110.                 IF selection >= LineCount THEN selection = LineCount - 1
  111.             CASE IS = CHR$(0) + CHR$(71) 'Home
  112.                 top = 0: selection = 0
  113.             CASE IS = CHR$(0) + CHR$(79) 'End
  114.                 selection = LineCount - 1
  115.                 top = selection - y2 + 1
  116.                 IF top < 0 THEN top = 0
  117.             CASE IS = CHR$(27) ' ESC cancels
  118.                 FileSelect$ = ""
  119.                 EXIT DO
  120.             CASE IS = CHR$(13) 'Enter
  121.                 'go up one dir
  122.                 IF RTRIM$(FileNames$(selection)) = ".." THEN
  123.                     cd$ = _CWD$
  124.                     cd$ = LEFT$(cd$, _INSTRREV(cd$, "\"))
  125.                     CHDIR cd$
  126.                     ERASE FileNames$
  127.                     GOTO loadagain
  128.                 END IF
  129.                 'see if directory
  130.                 test$ = RTRIM$(FileNames$(selection))
  131.                 IF LEFT$(test$, 1) = "[" THEN
  132.                     test$ = MID$(test$, 2, LEN(test$) - 2)
  133.                     CHDIR test$
  134.                     ERASE FileNames$
  135.                     GOTO loadagain
  136.                 ELSE
  137.                     IF RIGHT$(_CWD$, 1) = "\" THEN
  138.                         c$ = _CWD$
  139.                     ELSE
  140.                         c$ = _CWD$ + "\"
  141.                     END IF
  142.                     FileSelect$ = c$ + RTRIM$(FileNames$(selection))
  143.                     EXIT DO
  144.                 END IF
  145.         END SELECT
  146.     LOOP
  147.  
  148.     _KEYCLEAR
  149.  
  150.     '=== Restore the whole screen
  151.     _MEMCOPY scr2, scr2.OFFSET, scr2.SIZE TO scr1, scr1.OFFSET
  152.     _MEMFREE scr1: _MEMFREE scr2
  153.  
  154.     '=== restore original y,x
  155.     LOCATE origy, origx
  156.  
  157.     COLOR fg&, bg&
  158.  
  160.  
  161.  
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: FellippeHeitor on January 25, 2021, 09:43:21 pm
There's _DEFAULTCOLOR for the foreground and _BACKGROUNDCOLOR for the bg. Links to wiki:

Code: QB64: [Select]

Save their values before you change COLOR, then restore when the procedure ends.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 25, 2021, 09:45:39 pm
Ah... I missed that one.  Thanks, @FellippeHeitor.

EDIT: I fixed the code.  Restores color as should..

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 25, 2021, 09:56:48 pm
Hold on Dav...

Code: QB64: [Select]
  1. COLOR 14, 4
  2. PRINT "SCREEN ZERO HERO!"
  4. ' Now lets save this original color...
  5. LOCATE 1, 1
  6. a = SCREEN(1, 1, 1)
  7. ' Now change color
  8. COLOR 7, 0
  9. LOCATE 3, 1
  10. PRINT "Back to white on black..."
  12. ' Now lets get back to our original color...
  13.  
  14. COLOR a MOD 16, a \ 16
  15. LOCATE 5, 1
  16. PRINT "That's how it's done, old school!"
  18.  

Hey, I just got my dir stuff completed over at QBF, too. I have to smooth a few things out, but it completes the directory searching just fine.

Pete
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on January 25, 2021, 10:07:31 pm
Hmm,well that seems to work, @Pete.  But I'm not sure how...I must have missed old school class that day!

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 25, 2021, 10:21:19 pm
SCREEN has a third parameter that reads the color attribute of the screen. The trick is knowing how to put that value back into the COLOR statement, which is foreground equals the number mod 16 and the background is the number integer division 16.

I'll have to give Steve's stuff a try out tomorrow, and have a peek at yours after you post it.

Pete

Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: FellippeHeitor on January 25, 2021, 10:22:02 pm
Or just keep the _DEFAULTCOLOR and _BACKGROUNDCOLOR approach for all screen modes, 0 included. SCREEN won't work if nothing's been printed though, too.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 25, 2021, 10:54:13 pm
Fell missed day 2 of Old School...

Code: QB64: [Select]
  1. SCREEN 0, 0, 0, 0
  2. ' PRINT "SCREEN ZERO HERO!"
  3. SCREEN 0, 0, 1, 0
  5. COLOR 14, 4
  6. PRINT " ";
  7. ' Now lets save this original color...
  8. LOCATE 1, 1
  9. a = SCREEN(1, 1, 1)
  10. SCREEN 0, 0, 0, 0
  11. ' Now change color
  12. COLOR 7, 0
  13. LOCATE 3, 1
  14. PRINT "Back to white on black..."
  16. ' Now lets get back to our original color...
  17.  
  18. COLOR a MOD 16, a \ 16
  19. LOCATE 5, 1
  20. PRINT "That's how it's done, old school!"
  22.  

Of course you can just print a blank space to a part of the screen not in use, and read it. Flipping to a separate hidden page is a bit overkill.

Pete
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: FellippeHeitor on January 25, 2021, 11:34:26 pm
@Dav Also, you're saving the last COLOR parameters the user of your library had set - in this case the last COLOR parameters you had set yourself before calling the sub. No way to do that with the SCREEN trick, as you have to pick a location to read the color from.

@Pete ❤️
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Pete on January 26, 2021, 11:32:15 am
Quote from: FellippeHeitor on January 25, 2021, 11:34:26 pm
@Dav Also, you're saving the last COLOR parameters the user of your library had set - in this case the last COLOR parameters you had set yourself before calling the sub. No way to do that with the SCREEN trick, as you have to pick a location to read the color from.

@Pete ❤️

There's always a way. If there wasn't, we woudn't have QB64 in the first place. It's just a question of the level of complexity needed in the chewing gum and bailing wire operations. I've gone as far as memory mapping, in a graphics gui thing I put together. This was before _MEMBLOCK came out and made my approach obsolete.

It's always a trade off. Better keywords create easier coding, but take away from solution based thinking on a lower level. One can only hope that coders will be freed up to use those solution skills for higher purposes.

Personally, I wanted this _DEFAULTCOLOR and _BACKGROUNDCOLOR stuff in QuickBASIC. I never could understand why the last color set couldn't be retrieved from memory. In Atari, that was accomplished with PEEK/POKE. Also, speaking of AtariBASIC, we could easily change the 8x8 pixels of any character, into a custom character. That feature made it super easy to underline words. I suppose if I want to do that with QB64, I'd have to go the way of unicode characters. That's probably something I'll be looking into in the near future. Fingers crossed it will include SCREEN 0, the only screen mode anyone should ever need.

Pete
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on February 05, 2021, 05:38:33 pm
Even though I'll be using direntry.h in the future, I went ahead and finished off this SHELL "dir" file box routine.  By doing so, I found out something worth noting about using KILL.   I was having a problem deleting the temp file using KILL in certain directories, such as "Documents and Settings".  The program would error report the file doesn't exist and halt, even though the file did exist.  Looks like KILL can't be used on files in restricted directories, it won't see them.  So I decided to use SHELL "del" to delete the temp file instead and it won't error out.  The file won't delete that way either under that directory, but the program will continue and not stop.

Here is what I ended up with.  Shows current directory at top now, and the ".." doesn't show when at the root.  Directories are different colors.  I hope I'm doing the right call under linux to delete the temp file.  For Mac, I have no idea...

Edit:  I guess the best thing to do is always use _FILEEXISTS before using KILL, all the time.

- Dav

Code: QB64: [Select]
  1. '==============
  2. 'FILESELECT.BAS
  3. '==============
  4. 'Simple file selector box. Coded by Dav, FEB/2021
  5. '(with the kind help of the QB64.org forum gurus)
  6.  
  7. 'Navigate through directories and select a file.
  8. 'Use arrows, page up/down, home, end to scroll list.
  9. 'Press enter to select highlighted file or enter the dir.
  10.  
  11. 'things to do: auto center box on screen, and ditch x/y input?
  12. '              ...will need to adjust box size based on file/dir chr length
  13. '              Add user defined colors instead...?
  14.  
  15.  
  16. SCREEN _NEWIMAGE(600, 600, 32)
  17.  
  18. CLS , _RGB(32, 32, 32)
  19.  
  20. '=== draw stuff
  21. FOR x = 1 TO 600 STEP 3
  22.     FOR y = 1 TO 600 STEP 3
  23.         PSET (x, y), _RGB(RND * 255, RND * 255, RND * 255)
  24.     NEXT
  26.  
  27. a$ = FileSelect$(5, 10, 15, 55, "*.*")
  28.  
  29. IF a$ <> "" THEN
  30.     PRINT "You selected: "; a$
  32.  
  34.  
  35.  
  36. FUNCTION FileSelect$ (y, x, y2, x2, Filespec$)
  37.  
  38.     '=== save original place of cursor
  39.     origy = CSRLIN: origx = POS(1)
  40.  
  41.     '=== save colors
  42.     fg& = _DEFAULTCOLOR
  43.     bg& = _BACKGROUNDCOLOR
  44.  
  45.     '=== Save whole screen
  46.     DIM scr1 AS _MEM, scr2 AS _MEM
  47.     scr1 = _MEMIMAGE(0): scr2 = _MEMNEW(scr1.SIZE)
  48.     _MEMCOPY scr1, scr1.OFFSET, scr1.SIZE TO scr2, scr2.OFFSET
  49.  
  50.     loadagain:
  51.  
  52.     top = 0
  53.     selection = 0
  54.  
  55.     IF INSTR(_OS$, "LINUX") THEN
  56.         SHELL _HIDE "find . -type d > $_TeMP_FILE_LIST"
  57.     ELSE
  58.         SHELL _HIDE "dir /b /A:D > $_TeMP_FILE_LIST"
  59.     END IF
  60.  
  61.     'get list...
  62.     REDIM FileNames$(5000) 'space for 5000 filenames
  63.  
  64.     'only show the ".." if not at root dir
  65.     IF LEN(_CWD$) <> 3 THEN
  66.         FileNames$(0) = ".."
  67.         LineCount = 1
  68.     ELSE
  69.         LineCount = 0
  70.     END IF
  71.  
  72.     FF = FREEFILE
  73.     OPEN "$_TeMP_FILE_LIST" FOR INPUT AS #FF
  74.  
  75.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
  76.         LINE INPUT #FF, rl$
  77.         FileNames$(LineCount) = "[" + rl$ + "]"
  78.         LineCount = LineCount + 1
  79.     WEND
  80.     CLOSE #FF
  81.  
  82.     'KILL "$_TeMP_FILE_LIST"
  83.     IF INSTR(_OS$, "LINUX") THEN
  84.         SHELL _HIDE "rm $_TeMP_FILE_LIST"
  85.         SHELL _HIDE "find . -type f " + CHR$(34) + Filespec$ + CHR$(34) + " > $_TeMP_FILE_LIST"
  86.     ELSE
  87.         SHELL _HIDE "del $_TeMP_FILE_LIST"
  88.         SHELL _HIDE "dir /b /A:-D " + Filespec$ + " > $_TeMP_FILE_LIST"
  89.     END IF
  90.  
  91.     FF = FREEFILE
  92.     OPEN "$_TeMP_FILE_LIST" FOR INPUT AS #FF
  93.     WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
  94.         LINE INPUT #FF, rl$
  95.         'skip the temp file...
  96.         IF rl$ <> "$_TeMP_FILE_LIST" THEN
  97.             FileNames$(LineCount) = rl$
  98.             LineCount = LineCount + 1
  99.         END IF
  100.     WEND
  101.     CLOSE #FF
  102.  
  103.     'KILL "$_TeMP_FILE_LIST"
  104.     IF INSTR(_OS$, "LINUX") THEN
  105.         SHELL _HIDE "rm $_TeMP_FILE_LIST"
  106.     ELSE
  107.         SHELL _HIDE "del $_TeMP_FILE_LIST"
  108.     END IF
  109.  
  110.  
  111.     'draw a box
  112.     COLOR _RGB(100, 100, 255)
  113.     FOR l = 0 TO y2 + 1
  114.         LOCATE y + l, x: PRINT STRING$(x2 + 4, CHR$(219));
  115.     NEXT
  116.  
  117.     'show current working dir
  118.     COLOR _RGB(255, 255, 255), _RGB(100, 100, 255)
  119.     CurDir$ = _CWD$
  120.     'Shorten it is too long, for display purposes
  121.     IF LEN(CurDir$) > x2 - x THEN
  122.         CurDir$ = MID$(CurDir$, 1, x2 - x - 3) + "..."
  123.     END IF
  124.     LOCATE y, x + 2: PRINT CurDir$;
  125.  
  126.     DO
  127.  
  128.         FOR l = 0 TO (y2 - 1)
  129.             LOCATE (y + 1) + l, (x + 2)
  130.             IF l + top = selection THEN
  131.                 COLOR _RGB(0, 0, 64), _RGB(255, 255, 255) 'selected line
  132.             ELSE
  133.  
  134.                 COLOR _RGB(255, 255, 255), _RGB(0, 0, 64) 'regular
  135.  
  136.                 'directories get a different color...
  137.                 IF MID$(FileNames$(top + l), 1, 1) = "[" THEN
  138.                     COLOR _RGB(255, 255, 0), _RGB(0, 0, 64)
  139.                 END IF
  140.             END IF
  141.             PRINT LEFT$(FileNames$(top + l) + STRING$(x2, " "), x2);
  142.         NEXT
  143.  
  144.         k$ = INKEY$
  145.         SELECT CASE k$
  146.             CASE IS = CHR$(0) + CHR$(72) 'Up arrow
  147.                 IF selection > 0 THEN selection = selection - 1
  148.                 IF selection < top THEN top = selection
  149.             CASE IS = CHR$(0) + CHR$(80) 'Down Arrow
  150.                 IF selection < (LineCount - 1) THEN selection = selection + 1
  151.                 IF selection > (top + (y2 - 2)) THEN top = selection - y2 + 1
  152.             CASE IS = CHR$(0) + CHR$(73) 'Page up
  153.                 top = top - y2
  154.                 selection = selection - y2
  155.                 IF top < 0 THEN top = 0
  156.                 IF selection < 0 THEN selection = 0
  157.             CASE IS = CHR$(0) + CHR$(81) 'Page Down
  158.                 top = top + y2
  159.                 selection = selection + y2
  160.                 IF top >= LineCount - y2 THEN top = LineCount - y2
  161.                 IF top < 0 THEN top = 0
  162.                 IF selection >= LineCount THEN selection = LineCount - 1
  163.             CASE IS = CHR$(0) + CHR$(71) 'Home
  164.                 top = 0: selection = 0
  165.             CASE IS = CHR$(0) + CHR$(79) 'End
  166.                 selection = LineCount - 1
  167.                 top = selection - y2 + 1
  168.                 IF top < 0 THEN top = 0
  169.             CASE IS = CHR$(27) ' ESC cancels
  170.                 FileSelect$ = ""
  171.                 EXIT DO
  172.             CASE IS = CHR$(13) 'Enter
  173.                 'go up one dir
  174.                 IF RTRIM$(FileNames$(selection)) = ".." THEN
  175.                     cd$ = _CWD$
  176.                     cd$ = LEFT$(cd$, _INSTRREV(cd$, "\"))
  177.                     CHDIR cd$
  178.                     ERASE FileNames$
  179.                     GOTO loadagain
  180.                 END IF
  181.                 'see if directory
  182.                 test$ = RTRIM$(FileNames$(selection))
  183.                 IF LEFT$(test$, 1) = "[" THEN
  184.                     test$ = MID$(test$, 2, LEN(test$) - 2)
  185.                     CHDIR test$
  186.                     ERASE FileNames$
  187.                     GOTO loadagain
  188.                 ELSE
  189.                     IF RIGHT$(_CWD$, 1) = "\" THEN
  190.                         C$ = _CWD$
  191.                     ELSE
  192.                         C$ = _CWD$ + "\"
  193.                     END IF
  194.                     FileSelect$ = C$ + RTRIM$(FileNames$(selection))
  195.                     EXIT DO
  196.                 END IF
  197.         END SELECT
  198.     LOOP
  199.  
  200.     _KEYCLEAR
  201.  
  202.     '=== Restore the whole screen
  203.     _MEMCOPY scr2, scr2.OFFSET, scr2.SIZE TO scr1, scr1.OFFSET
  204.     _MEMFREE scr1: _MEMFREE scr2
  205.  
  206.     '=== restore original y,x
  207.     LOCATE origy, origx
  208.  
  209.     COLOR fg&, bg&
  210.  
  212.  

Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 05, 2021, 10:07:30 pm
Steve advised me one time to use one filename stored under Windows temp folder from environment variable.

Just write over that file, no need to kill, kill, kill unless you just like saying that to Windows.

I like your one box method everything in one window, Tiny Navigator is going to be rid of that pesky need to press f to select from files listing. Simple solutions often the best!
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on February 05, 2021, 10:51:04 pm
That's a good thought, @bplus.  I'm not sure in Linux has a environment temp setting though, but perhaps I can do the one temp file in the programs _STARTDIR$ directory instead, that would bypass writing temp files in every directory browsed and writing any to restricted directories too.  Thanks for the idea. 

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 05, 2021, 10:57:12 pm
Quote from: Dav on February 05, 2021, 10:51:04 pm
That's a good thought, @bplus.  I'm not sure in Linux has a environment temp setting though, but perhaps I can do the one temp file in the programs _STARTDIR$ directory instead, that would bypass writing temp files in every directory browsed and writing any to restricted directories too.  Thanks for the idea. 

- Dav

Well I thought when you were going to go for cross platform, you'd use the direntry.h method.

I know you wrote that somewhere, were you just teas'n me?  ;-))
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on February 05, 2021, 11:02:57 pm
I'll be using direntry, but I wanted to get this method figured out.  One of my quirks I guess, can't let things go very easy while they're still gnawing on me.

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 05, 2021, 11:08:57 pm
Quote from: Dav on February 05, 2021, 11:02:57 pm
I'll be using direntry, but I wanted to get this method figured out.  One of my quirks I guess, can't let things go very easy while they're still gnawing on me.

- Dav

Yeah, I know that.

But I'm saying don't worry what Linux does about temp files, you would be switching to the other method by then I would think.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 05, 2021, 11:10:58 pm
Might I suggest using pipecom to get rid of using temp files? There will be a speed increase and will work on all platforms still
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 05, 2021, 11:16:19 pm
Oh man I just remembered an advantage with temp files, you can get all kinds of details about the files too and might be easier to do pathed-file-spec.

@SpriggsySpriggs  I have that pipecom code of yours, offhand I don't remember if it can do all the details like a Command prompt Dir with all the switches can do. What do you say?

Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 05, 2021, 11:19:43 pm
@bplus It will do any command. It simply returns console output. Anything you want. It can replace any SHELL. Its main advantage is speed and immediate filling of a variable rather than writing to a file, opening it, reading it, closing it, deleting it.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 05, 2021, 11:22:28 pm
Well I will check it out again, do you happen to have a link?
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 05, 2021, 11:25:43 pm
@bplus Click my link in my signature for my API Collection, click the GitHub link on that page and then navigate to the Cross Platform folder. It's in there.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 06, 2021, 12:39:03 am
@Dav  have you seen Doppler's method?

Code: QB64: [Select]
  2.  
  3. Shell "dir /b *.* | clip"
  5.  
  7.  
  8.  

0 temp files!!!
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 06, 2021, 12:42:40 am
OK @SpriggsySpriggs

I found this that requires much less digging:
https://www.qb64.org/forum/index.php?topic=3167.msg124332#msg124332

Code: QB64: [Select]
  1. _Title "Dir replacement " ' >>>>>>>>>>>>>> needs pipecom.h in QB64 folder
  2. 'spriggsySpriggs ref:  https://www.qb64.org/forum/index.php?topic=3167.msg124332#msg124332
  3.  
  4. ' the following is the pipecom.h file without comments
  5.  
  6. 'const char* pipecom (char* cmd){
  7. 'string data;
  8. 'FILE * stream;
  9. 'const int max_buffer = 256;
  10. 'char buffer[max_buffer];
  11.  
  12. '    stream = popen(cmd, "r");
  13. '    if (stream) {
  14. '        while (!feof(stream)) {
  15. '            if (fgets(buffer, max_buffer, stream) != NULL) {
  16. '                data.append(buffer);
  17. '            }
  18. '        }
  19. '        pclose(stream);
  20. '    }
  21. '    //
  22. '    //cout << data;
  23. '    const char* dataout;
  24. '    dataout = strdup(data.c_str());
  25. '    return dataout;
  26. '}
  27.  
  28.  
  29.  
  30. Declare Library "pipecom"
  31.     Function pipecom$ (cmd As String)
  33.  
  35.  
  36. ' NOTE: these slants work \    these do not /
  37. 'F = pipecom("dir C:/*.*") ' Linux needs other switches
  38. F = pipecom("dir /b *.BAS") 'if you need just the filenames and not the rest of the output
  39.  
  41.  
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on February 06, 2021, 09:52:02 am
Oh cool. I see I had that pipcom downloaded already, forgot about it.  Nice one.

Really slick trick, doppler's method.

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 06, 2021, 10:18:44 am
@Dav the main thing though is that using clip slows down shell execution by quite a bit. At that point you should use temp files because that's quicker than clip.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: Dav on February 06, 2021, 11:42:06 am
Yes, good point. @SpriggsySpriggs.

- Dav
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 06, 2021, 01:27:11 pm
Can't be that great a difference reading/writing files to disk is slower than access to Clips stored in RAM, I would think.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 06, 2021, 01:29:38 pm
@bplus I'm talking about using clip. When you pipe to clip it takes a lot longer than just writing to a file. The clipboard itself isn't slow. It's the usage of clip that is.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 06, 2021, 01:39:25 pm
Are you saying you can't get access to clip data faster than you can get access file data?
Is clip data written to temp files on disk by OS, that would be an explanation about access being slower for clip but seems not very smart coding. Send Steve over and show them how to use memory ;-))


Quote
It's the usage of clip that is.
The usage of the data is up to us in our QB64 code.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 06, 2021, 01:54:19 pm
Oh it's probably the SHELL that's slower than pipecom.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 06, 2021, 02:02:33 pm
Quote from: bplus on February 06, 2021, 01:39:25 pm
Are you saying you can't get access to clip data faster than you can get access file data?
Is clip data written to temp files on disk by OS, that would be an explanation about access being slower for clip but seems not very smart coding.

@bplus You aren't understanding what I am saying. "clip" is a command in command prompt. The action of piping "dir" or whatever into "clip" is what takes extra time because now you are calling two commands rather than one. The clipboard itself is fine. What you are doing in "dir | clip" is telling it to run "dir" and then send everything from "dir" into the command "clip" which THEN fills the clipboard. That's slow. That command is running TWO executables. "clip" is reading the stdout handle of "dir" and then writing to the clipboard. When you write straight to a file you aren't having to worry about running a second executable. That time spent is saved. WinAPI has functions for making temp files out in a temp directory and they work great.

Quote from: bplus on February 06, 2021, 01:54:19 pm
Oh it's probably the SHELL that's slower than pipecom.

I've been saying that SHELL is slower than pipecom for months now. But it isn't JUST the SHELL that's slower here. The "clip" command makes it way slower than pipecom and even slower than using files. Use temp files instead of "clip".
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 06, 2021, 04:30:31 pm
OK working with what pipecom returns people should know it is Chr$(10) delimited string should they want to split the string into an array.

Also it appears an empty string$ = "" is on the end, don't know if that is from pipecom probably or the split I am using?
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 06, 2021, 04:34:34 pm
Probably the split you are using. Before in the past I've had to do UBOUND(array)-1. And they can always look at the C++ code to see how it is delimited. I opted for Linux style which is CHR$(10) rather than Windows style which is CHR$(13) + CHR$(10).

Which split are you using? I've had issues before with splitting strings because of the algorithms that are out there. I haven't found one I really like just yet.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 06, 2021, 05:09:02 pm
Quote from: SpriggsySpriggs on February 06, 2021, 04:34:34 pm
Probably the split you are using. Before in the past I've had to do UBOUND(array)-1. And they can always look at the C++ code to see how it is delimited. I opted for Linux style which is CHR$(10) rather than Windows style which is CHR$(13) + CHR$(10).

Which split are you using? I've had issues before with splitting strings because of the algorithms that are out there. I haven't found one I really like just yet.

Quote
I opted for Linux style which is CHR$(10) rather than Windows style which is CHR$(13) + CHR$(10).
Oh is this built into the .h file? I approve! not that it matters :)
I consider the 2 byte delimiter the old DOS way and Chr$(10) the newer way, only 1 byte is more efficient.

Quote
Before in the past I've had to do UBOUND(array)-1
Don't you think this indicates an empty string on the end, I am wondering about a Chr$(0) on the end since C likes to do that. Anyway there is something useless at that Ubound.

Split1000 found here:
https://www.qb64.org/forum/index.php?topic=1607.msg108201#msg108201
I am getting perfect counts in my tests of a simple array displayer and my arrays coming out of Split have some empty string character at Ubound of array. Maybe if I trimmed the returned string from pipecom? maybe I should just check that next, before the splitting. ;-))

It handles 0 and 1 base ReDim 'd arrays (dynamic that you can change the size of) it probably could handle an exotic
Code: QB64: [Select]
  1. ReDim(-5 to -5) as string
but I have enough things to test and play with.

I will show you the code when I am done messing with it. I am really interested in the ideal way to do files and folders cross platform. But I suspect ideal depends on the application as usual. So my app is get a filename or pathname from anywhere on hard drive. After that selecting multiple files from different folders for some operation like copy to SD drive maybe for my backups.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: SpriggsySpriggs on February 06, 2021, 05:13:24 pm
Quote from: bplus on February 06, 2021, 05:09:02 pm
Don't you think this indicates an empty string on the end, I am wondering about a Chr$(0) on the end since C likes to do that. Anyway there is something useless at that Ubound.

I take it back.... I remember that sometimes (depending on the command) you might have an extra CHR$(10). You can use LEFT$ or MID$ and just take it off.
Title: Re: Question about using SHELL "dir" on non windows OS.
Post by: bplus on February 07, 2021, 02:02:35 am
Yes at the end of the string returned by pipecom is a delimiter, to be ignored.

I got a crude browser working using pipecom to get a dir listing to navigate with:
Code: QB64: [Select]
  2. _Title "Compare Pipecom to SHELL methods of file data access" 'b+ 2021-02-6
  3. Screen _NewImage(1024, 400, 32)
  4. _Delay .25
  6.  
  7. Declare Library "pipecom"
  8.     Function pipecom$ (cmd As String)
  10.  
  11. 'Dim F As String                 'tests with command line dir calls
  12. ' NOTE: these slants work \    these do not /
  13. 'F = pipecom("dir " + Chr$(34) + "C:\users\marka\desktop\QB64 work\000 work QB64" + Chr$(34) + " /b /A:D") ' Linux needs other switches
  14. 'F = pipecom("dir /b *.BAS") 'if you need just the filenames and not the rest of the output
  15. 'F = pipecom("dir /b /A:D") ' /b = bare list /A:D directories only
  16. 'F = pipecom("dir /n /o:gend") ' long list files on right? well <dir> for dirs and files  ahhhh!
  17.  
  18. ReDim As String choice
  19. While _KeyDown(27) = 0 'until escape
  20.     choice = GetFileName$
  21.     If choice <> "" Then Print: Print "You selected " + choice Else Print: Print "You canceled"
  22.     Print: Print "          press any for another test, escape to quit..."
  23.     Sleep
  25.  
  26. Function GetFileName$ ()
  27.     Dim As String d, s, dr
  28.     Getfolder:
  29.     d = pipecom("dir /n /o:gend") '/n files on right (40) /o = order g for group dirs first, e extension, name, date
  30.     d = Left$(d, Len(d) - 1) ' always ends with delimiter
  31.     ReDim dir$(1 To 1)
  32.     Split d, Chr$(10), dir$()
  33.     s$ = GetArrayItem$(dir$())
  34.     Cls
  35.     If InStr(s$, "<DIR>") Then 'isolate name
  36.         dr$ = _Trim$(Mid$(s$, InStr(s$, "<DIR>") + 6))
  37.         ChDir dr$
  38.         GoTo Getfolder
  39.     ElseIf InStr(s$, "AM") Or InStr(s$, "PM") Then
  40.         GetFileName$ = _Trim$(Mid$(s$, 40))
  41.     End If
  43.  
  44. Sub Split (SplitMeString As String, delim As String, loadMeArray() As String)
  45.     Dim curpos As Long, arrpos As Long, LD As Long, dpos As Long 'fix use the Lbound the array already has
  46.     curpos = 1: arrpos = LBound(loadMeArray): LD = Len(delim)
  47.     dpos = InStr(curpos, SplitMeString, delim)
  48.     Do Until dpos = 0
  49.         loadMeArray(arrpos) = Mid$(SplitMeString, curpos, dpos - curpos)
  50.         arrpos = arrpos + 1
  51.         If arrpos > UBound(loadMeArray) Then ReDim _Preserve loadMeArray(LBound(loadMeArray) To UBound(loadMeArray) + 1000) As String
  52.         curpos = dpos + LD
  53.         dpos = InStr(curpos, SplitMeString, delim)
  54.     Loop
  55.     loadMeArray(arrpos) = Mid$(SplitMeString, curpos)
  56.     ReDim _Preserve loadMeArray(LBound(loadMeArray) To arrpos) As String 'get the ubound correct
  58.  
  59. Function GetArrayItem$ (arr() As String)
  60.     Dim As Long lb, ub, top, i, row, prevrow, n, ad, r
  61.     Dim iNum$, k$
  62.     lb = LBound(arr): ub = UBound(arr): ad = _AutoDisplay
  63.     If ub - lb + 1 < 21 Then top = ub Else top = lb + 19
  64.     Do
  65.         Cls
  66.         Print "       Scroll, Enter number choice, delete to Clear number, or escape to Cancel"
  67.         If ub - lb + 1 > 20 Then
  68.             While _MouseInput
  69.                 row = row + _MouseWheel
  70.                 If row < lb Then row = lb 'prevent under scrolling
  71.                 If row > ub - 19 Then row = ub - 19 'prevent over scrolling
  72.                 If prevrow <> row Then 'look for a change in row value
  73.                     prevrow = row 'store previous row valu
  74.                 End If
  75.             Wend
  76.             r = 2
  77.             For n = row To row + 19
  78.                 Locate r, 1: Print "#"; _Trim$(Str$(n)); ": "; " "; arr(n)
  79.                 r = r + 1
  80.             Next
  81.         Else
  82.             For i = lb To top
  83.                 Print i; " "; arr(i)
  84.             Next
  85.         End If
  86.         Locate 23, 1: Print iNum$
  87.         k$ = InKey$
  88.         If InStr("0123456789", k$) Then
  89.             iNum$ = iNum$ + k$
  90.         ElseIf iNum$ = "" And k$ = "-" Then
  91.             iNum$ = "-"
  92.         ElseIf k$ = Chr$(8) Then
  93.             If Len(iNum$) Then iNum$ = Left$(iNum$, Len(iNum$) - 1)
  94.         ElseIf Len(k$) = 2 And Right$(k$, 1) = Chr$(83) Then
  95.             iNum$ = ""
  96.         ElseIf k$ = Chr$(13) And Len(iNum$) Then
  97.             If Val(iNum$) >= lb And Val(iNum$) <= ub Then GetArrayItem$ = arr(Val(iNum$)): Exit Do Else iNum$ = ""
  98.         ElseIf k$ = Chr$(27) Then
  99.             Exit Function
  100.         End If
  101.         _Display
  102.         _Limit 30
  103.     Loop
  104.     If ad Then _AutoDisplay ' reverse changes
  105.     _KeyClear
  107.  
Text Only | Text with Attachments