QB64.org Forum

Active Forums => Programs => Topic started by: NOVARSEG on January 06, 2021, 12:49:24 am

Title: Is there a way to copy data from windows and paste into a running program?
Post by: NOVARSEG on January 06, 2021, 12:49:24 am

Is it possible  to copy a number from the internet and paste it into a program that is asking for data?

Example.  Copy a number from windows calculator with CTRL C and paste it into a program that is asking for input data with CTRL - V

Title: Re: Is there a way to copy data from windows and paste into a running program?
Post by: Pete on January 06, 2021, 01:45:02 am

Look up _CLIPBOARD$ in the QB64 Wiki. Simply put, use Ctrl + C to copy and _CLIPBOARD$ will contain that data. To paste it, you need to write some code similar to this...

Code: QB64: [Select]

1. DO
2. _LIMIT 30
3. b$ = INKEY$
4.     IF LEN(b$) THEN
5.         SELECT CASE b$
6.              CASE CHR$(22) ' Paste
7.              PRINT _CLIPBOARD$
8.         END SELECT
9.     END IF
10. LOOP UNTIL b$ = CHR$(27) ' Esc key.

Pete

Title: Re: Is there a way to copy data from windows and paste into a running program?
Post by: SMcNeill on January 06, 2021, 02:33:25 am

Change your program's INPUT routine to my ExtendedInput version.

Code: QB64: [Select]

1. _CONTROLCHR OFF
2. PRINT "Enter some information (CTRL-V works fine for insert): ";
3. ExtendedInput information$
4. PRINT
5. PRINT "You entered: "; information$
6.  
7. SUB ExtendedInput (out$)
8.     PCOPY 0, 1
9.     A = _AUTODISPLAY: X = POS(0): Y = CSRLIN
10.     CP = 0: OldCP = 0 'Cursor Position
11.     _KEYCLEAR
12.     DO
13.         PCOPY 1, 0
14.         IF _KEYDOWN(100307) OR _KEYDOWN(100308) THEN AltDown = -1 ELSE AltDown = 0
15.         k = _KEYHIT
16.         IF AltDown THEN
17.             SELECT CASE k 'ignore all keypresses except ALT-number presses
18.                 CASE 48 TO 57: AltWasDown = -1: alt$ = alt$ + CHR$(k)
19.             END SELECT
20.         ELSE
21.             SELECT CASE k 'without alt, add any keypresses to our input
22.                 CASE 8
23.                     oldin$ = in$
24.                     IF CP > 0 THEN OldCP = CP: CP = CP - 1
25.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2) 'backspace to erase input
26.                 CASE 9
27.                     oldin$ = in$
28.                     in$ = LEFT$(in$, CP) + SPACE$(4) + MID$(in$, CP + 1) 'four spaces for any TAB entered
29.                     OldCP = CP
30.                     CP = CP + 4
31.                 CASE 32 TO 128
32.                     IF _KEYDOWN(100305) OR _KEYDOWN(100306) THEN
33.                         IF k = 118 OR k = 86 THEN
34.                             oldin$ = in$
35.                             in$ = LEFT$(in$, CP) + _CLIPBOARD$ + MID$(in$, CP + 1) 'ctrl-v paste
36.                             'CTRL-V leaves cursor in position before the paste, without moving it after.
37.                             'Feel free to modify that behavior here, if you want it to move to after the paste.
38.                             'CP = CP + LEN(_CLIPBOARD$)
39.                         END IF
40.                         IF k = 122 OR k = 90 THEN SWAP in$, oldin$: SWAP OldCP, CP 'ctrl-z undo
41.                     ELSE
42.                         oldin$ = in$
43.                         in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
44.                         OldCP = CP
45.                         CP = CP + 1
46.                     END IF
47.                 CASE 18176 'Home
48.                     CP = 0
49.                 CASE 20224 'End
50.                     CP = LEN(in$)
51.                 CASE 21248 'Delete
52.                     oldin$ = in$
53.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2)
54.                 CASE 19200 'Left
55.                     CP = CP - 1
56.                     IF CP < 0 THEN CP = 0
57.                 CASE 19712 'Right
58.                     CP = CP + 1
59.                     IF CP > LEN(in$) THEN CP = LEN(in$)
60.             END SELECT
61.         END IF
62.         alt$ = RIGHT$(alt$, 3)
63.         IF AltWasDown = -1 AND AltDown = 0 THEN
64.             v = VAL(alt$)
65.             IF v >= 0 AND v <= 255 THEN in$ = in$ + CHR$(v)
66.             alt$ = "": AltWasDown = 0
67.         END IF
68.         blink = (blink + 1) MOD 30
69.         LOCATE Y, X
70.         PRINT LEFT$(in$, CP);
71.         IF blink \ 15 THEN PRINT " "; ELSE PRINT "_";
72.         PRINT MID$(in$, CP + 1)
73.  
74.         _DISPLAY
75.         _LIMIT 30
76.     LOOP UNTIL k = 13
77.  
78.     PCOPY 1, 0
79.     LOCATE Y, X: PRINT in$
80.     out$ = in$
81.     IF A THEN _AUTODISPLAY
82. END SUB
83.  

Title: Re: Is there a way to copy data from windows and paste into a running program?
Post by: NOVARSEG on January 06, 2021, 02:52:54 am

Thanks
looking at the code now.

Also it would be nice to take data from a running program and paste it into windows

Title: Re: Is there a way to copy data from windows and paste into a running program?
Post by: GTC on January 06, 2021, 09:35:52 am

As an aside to this, the output of Windows CMD commands can be piped to the clipboard, for instance:

SHELL "CMD/C DIR | CLIP"

Text Only | Text with Attachments