QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: SMcNeill on December 27, 2020, 09:46:35 am

Title: Here's a puzzler
Post by: SMcNeill on December 27, 2020, 09:46:35 am

So here's a really simple concept, that I'm ending up having a heckuva time with:  Instead of drawing a box of X thickness around an area, draw 4 triangular tabs at the edges instead.

So instead of:


**************************************
**************************************
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**                                  **
**************************************
**************************************


We'd see something like:



******                         *******
******                         *******
**                                  **
**                                  **






***                                ***
****                              ****
** **                            ** **
**  **                          **  **
*******                        *******
*******                        *******



Now, ASCII art is too big of a PITA for me to sit and draw all 4 "tabs" in the above illustration, but I think the bottom half showcases the general idea.

Draw a triangle at each corner of a rectangle, and fix it so you can adjust to whatever variable width thickness you want for that triangle.

For a box, the concept is really simple:

FOR i = 0 to line_thickness
    LINE(x+i, y+ i)-STEP(wide - 2*i, high - 2*i), desired_color, B
NEXT

But for a set of 4 triangles??   My poor mind has been going crazy trying to sort out the math! 

So far, here's what I have (which does 3 of my 4 sides already:)

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. $COLOR:32
3. x = 1
4. y = 1
5.  
6. FOR i = 0 TO 5
7.     'top left
8.     x1 = x * 1280 / 7 + i: y1 = y * 90 + TopOffset + i
9.     x2 = x1 + 20 - i: y2 = y1
10.     x3 = x1: y3 = y1 + 20 - i
11.     Triangle x1, y1, x2, y2, x3, y3
12.     'top right
13.     x4 = (x + 1) * 1280 / 7 + 3 - i: y4 = y1
14.     x5 = x4 - 20 + i: y5 = y4
15.     x6 = x4: y6 = y4 + 20 - i
16.     Triangle x4, y4, x5, y5, x6, y6
17.     'bottom left
18.     x7 = x * 1280 / 7 + i: y7 = (y + 1) * 90 + TopOffset + 3 - i
19.     x8 = x7: y8 = y7 - 20 + i
20.     x9 = x7 + 20 - i: y9 = y7
21.     Triangle x7, y7, x8, y8, x9, y9
22. NEXT
23.  
24. SUB Triangle (x1, y1, x2, y2, x3, y3)
25.     LINE (x1, y1)-(x2, y2), Red
26.     LINE -(x3, y3), Red
27.     LINE -(x1, y1), Red
28. END SUB
29.  

Only four more cups of coffee and another three handfuls of hair, and I'll be finished!  :P

Anyone got a very simple little routine to do something like this that I can borrow (*cough*  *cough* *steal shamelessly*) in case I ever want to do something like this again in the future? 

The code above showcases the concept a lot better than my poor skills at ASCII art ever could. ;)

Title: Re: Here's a puzzler
Post by: SMcNeill on December 27, 2020, 09:58:00 am

And here's the whole thing working now:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. $COLOR:32
3. x = 1
4. y = 1
5.  
6. FOR i = 0 TO 5
7.     'top left
8.     x1 = x * 1280 / 7 + i: y1 = y * 90 + TopOffset + i
9.     x2 = x1 + 20 - i: y2 = y1
10.     x3 = x1: y3 = y1 + 20 - i
11.     Triangle x1, y1, x2, y2, x3, y3
12.     'top right
13.     x4 = (x + 1) * 1280 / 7 + 3 - i: y4 = y1
14.     x5 = x4 - 20 + i: y5 = y4
15.     x6 = x4: y6 = y4 + 20 - i
16.     Triangle x4, y4, x5, y5, x6, y6
17.     'bottom left
18.     x7 = x * 1280 / 7 + i: y7 = (y + 1) * 90 + TopOffset + 3 - i
19.     x8 = x7: y8 = y7 - 20 + i
20.     x9 = x7 + 20 - i: y9 = y7 '- 20 - i
21.     Triangle x7, y7, x8, y8, x9, y9
22.     'bottom right
23.     x10 = x4: y10 = y7
24.     x11 = x10 - 20 + i: y11 = y10
25.     x12 = x10: y12 = y11 - 20 + i
26.     Triangle x10, y10, x11, y11, x12, y12
27.  
28. NEXT
29.  
30. SUB Triangle (x1, y1, x2, y2, x3, y3)
31.     LINE (x1, y1)-(x2, y2), Red
32.     LINE -(x3, y3), Red
33.     LINE -(x1, y1), Red
34. END SUB

Change the x/y values, and you can see how our little tabs move around the screen for us.  Now, all I need is 57.5 bottles of rootbeer to dunk my head in to get my poor brain to stop smoldering.  :P

(You can also change the FOR i limit to change the thickness of the lines on the tabs, if you want to.)

Title: Re: Here's a puzzler
Post by: bplus on December 27, 2020, 12:03:06 pm

Here is 45 degree right triangles

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _DELAY .25
3. _SCREENMOVE _MIDDLE
4. tri4 100, 50, 200, 100, 25, &HFFFF0000
5.  
6. SUB tri4 (x, y, w, h, tSide, c AS _UNSIGNED LONG)
7.     ftri x, y, x + tSide, y, x, y + tSide, c
8.     ftri x + w, y, x + w - tSide, y, x + w, y + tSide, c
9.     ftri x + w, y + h, x + w - tSide, y + h, x + w, y + h - tSide, c
10.     ftri x, y + h, x + tSide, y + h, x, y + h - tSide, c
11. END SUB
12.  
13.  
14. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
15.     DIM D AS LONG
16.     STATIC a&
17.     D = _DEST
18.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
19.     _DEST a&
20.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
21.     PSET (0, 0), K
22.     _BLEND a& '<<<< new 2019-12-16 fix
23.     _DEST D
24.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
25. END SUB
26.  
27.  

Title: Re: Here's a puzzler
Post by: bplus on December 27, 2020, 02:53:12 pm

Here it is fancied up with triangles within triangles:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _DELAY .25
3. _SCREENMOVE _MIDDLE
4. tri4 100, 50, 200, 250, 50, &HFFFF0000
5. tri4 105, 55, 190, 240, 35, &HFFFFFF00
6. tri4 110, 60, 180, 230, 20, &HFF0000FF
7.  
8. SUB tri4 (x, y, w, h, tSide, c AS _UNSIGNED LONG)
9.     ftri x, y, x + tSide, y, x, y + tSide, c
10.     ftri x + w, y, x + w - tSide, y, x + w, y + tSide, c
11.     ftri x + w, y + h, x + w - tSide, y + h, x + w, y + h - tSide, c
12.     ftri x, y + h, x + tSide, y + h, x, y + h - tSide, c
13. END SUB
14.  
15.  
16. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
17.     DIM D AS LONG
18.     STATIC a&
19.     D = _DEST
20.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
21.     _DEST a&
22.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
23.     PSET (0, 0), K
24.     _BLEND a& '<<<< new 2019-12-16 fix
25.     _DEST D
26.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
27. END SUB
28.  

Title: Re: Here's a puzzler
Post by: bplus on December 27, 2020, 03:11:00 pm

Here 'tis 3D!

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _DELAY .25
3. _SCREENMOVE _MIDDLE
4. FOR i = 0 TO 15
5.     tri4 100 + i, 50 + i, 200 - 2 * i, 250 - 2 * i, 50 - 3 * i, _RGB32(0, i * 17, 0)
6. NEXT
7.  
8. SUB tri4 (x, y, w, h, tSide, c AS _UNSIGNED LONG)
9.     ftri x, y, x + tSide, y, x, y + tSide, c
10.     ftri x + w, y, x + w - tSide, y, x + w, y + tSide, c
11.     ftri x + w, y + h, x + w - tSide, y + h, x + w, y + h - tSide, c
12.     ftri x, y + h, x + tSide, y + h, x, y + h - tSide, c
13. END SUB
14.  
15.  
16. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
17.     DIM D AS LONG
18.     STATIC a&
19.     D = _DEST
20.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
21.     _DEST a&
22.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
23.     PSET (0, 0), K
24.     _BLEND a& '<<<< new 2019-12-16 fix
25.     _DEST D
26.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
27. END SUB
28.  
29.  
30.  

Title: Re: Here's a puzzler
Post by: Richard Frost on December 27, 2020, 11:29:14 pm

Some of my attempts looked like spiderwebs, but here are 3 ordinary flavors:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3. s = 100 '                                                  size of corners
4. DO
5.     FOR r = 1 TO 3 '                                       type of corner
6.         CLS
7.         FOR q = 0 TO s STEP 10
8.             RESTORE
9.             q2 = s - q
10.             FOR i = 1 TO 4 '                               4 corners
11.                 READ xo, yo, xd1, yd1, xd2, yd2, xi, yi
12.                 x0 = xo * (_WIDTH - 1) + xi * q / r
13.                 y0 = yo * (_HEIGHT - 1) + yi * q / r
14.                 LINE (x0, y0)-STEP(xd1 * q2, yd1 * q2)
15.                 LINE -(x0 + xd2 * q2, y0 + yd2 * q2)
16.                 LINE -(x0, y0)
17.                 _DELAY .01 '                               let human see what's happening
18.             NEXT i
19.         NEXT q
20.         WaitUntil! = TIMER + .5
21.         DO: _LIMIT 10
22.             IF LEN(INKEY$) THEN END
23.         LOOP UNTIL TIMER > WaitUntil!
24.     NEXT r
25. LOOP
26.  
27. DATA 0,0,0,1,1,0,1,1
28. DATA 1,0,-1,0,0,1,-1,1
29. DATA 1,1,-1,0,0,-1,-1,-1
30. DATA 0,1,0,-1,1,0,1,-1
31.  

Text Only | Text with Attachments