QB64.org Forum

Active Forums => Programs => Topic started by: Dav on December 25, 2020, 10:03:06 pm

Title: Bouncing Balls over a Plasma sky
Post by: Dav on December 25, 2020, 10:03:06 pm

Playing around with some old source code, trying to turn it into something more interesting.  Here are bouncing balls combined with a plasma background.  Runs kind of slow on my PC, but maybe not on yours... 

- Dav

Code: QB64: [Select]

1. 'Balls&Plasma.bas
2.  
3. SCREEN _NEWIMAGE(700, 700, 32)
4.  
5. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
6. _PRINTMODE _KEEPBACKGROUND
7.  
8. balls = 50: size = 40: speed = 10
9.  
10. DIM BallX(balls), BallY(balls)
11. DIM BallXdir(balls), BallYdir(balls)
12. DIM BallSpeed(balls), BallSize(balls)
13.  
14. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
15.  
16. 'Generate random ball data
17. FOR B = 1 TO balls
18.     BallX(B) = RND * w: BallY(B) = RND * h
19.     BallSpeed(B) = RND * speed + 1
20.     BallSize(B) = 40 + (RND * 50)
21. NEXT
22.  
23. DO
24.     CLS
25.     'compute ball movement
26.     FOR t = 1 TO balls
27.         IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 0
28.         IF BallX(t) < BallSize(t) THEN BallXdir(t) = 1
29.         IF BallXdir(t) THEN BallX(t) = BallX(t) + BallSpeed(t) ELSE BallX(t) = BallX(t) - BallSpeed(t)
30.         IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 0
31.         IF BallY(t) < BallSize(t) THEN BallYdir(t) = 1
32.         IF BallYdir(t) THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
33.     NEXT
34.     'draw plasma
35.     t = TIMER
36.     FOR x = 0 TO w
37.         FOR y = 0 TO h STEP 2
38.             r = SIN(1.1 * t) * h2 - y + h2
39.             g = SIN(.9 * t) * w2 - x + w2
40.             B = SIN(x / w2 + t + y / h2) * r
41.             PSET (x, y), _RGB(r, g, B)
42.         NEXT
43.         t = t + .01
44.     NEXT
45.     'draw balls
46.     FOR i = 1 TO balls
47.         ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
48.         _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
49.     NEXT
50.     _DISPLAY: _LIMIT 60
51. LOOP
52.  
53.  
54. SUB ball (BallX, BallY, size, r, g, b)
55.     FOR s = 1 TO size STEP .5
56.         CIRCLE (BallX, BallY), s, _RGB(r, g, b)
57.         r = r - 1: g = g - 1: b = b - 1
58.     NEXT
59. END SUB
60.  

Title: Re: Bouncing Balls over a Plasma sky
Post by: TempodiBasic on December 26, 2020, 12:56:13 pm

Cool!
On my i3 Toshiba with HDD runs very well, maybe on another faster machine we need a _limit in the loop.

Title: Re: Bouncing Balls over a Plasma sky
Post by: NOVARSEG on December 26, 2020, 08:05:08 pm

  Tried to get a realistic collision between balls. Not that easy.  Calculated the distance between balls.

The code will print out the distance and will delay 1 second when there is a collision.

Code: QB64: [Select]

1. 'Balls&Plasma.bas
2.  
3. SCREEN _NEWIMAGE(700, 700, 32)
4.  
5. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
6. _PRINTMODE _KEEPBACKGROUND
7.  
8. balls = 2: size = 40: speed = 10
9.  
10. DIM BallX(balls), BallY(balls)
11. DIM BallXdir(balls), BallYdir(balls)
12. DIM BallSpeed(balls), BallSize(balls)
13.  
14. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
15.  
16. 'Generate random ball data
17. FOR B = 1 TO balls
18.     BallX(B) = RND * w: BallY(B) = RND * h
19.     BallSpeed(B) = RND * speed + 1
20.     BallSize(B) = 40 '+ (RND * 50)
21. NEXT
22.  
23. DO
24.     CLS
25.     'compute ball movement
26.     FOR t = 1 TO balls
27.  
28.  
29.         d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5
30.         PRINT d%
31.  
32.         'IF d% <= 80 THEN _DELAY 1
33.  
34.  
35.         IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 1
36.         IF BallX(t) < BallSize(t) THEN BallXdir(t) = 0
37.  
38.         IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 1
39.         IF BallY(t) < BallSize(t) THEN BallYdir(t) = 0
40.  
41.         IF BallXdir(t) = 0 THEN BallX(t) = BallX(t) + BallSpeed(t)
42.         IF BallXdir(t) = 1 THEN BallX(t) = BallX(t) - BallSpeed(t)
43.  
44.         IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t)
45.         IF BallYdir(t) = 1 THEN BallY(t) = BallY(t) - BallSpeed(t)
46.  
47.  
48.  
49.         ' IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
50.     NEXT
51.     'draw plasma
52.     t = TIMER
53.     FOR x = 0 TO w
54.         FOR y = 0 TO h STEP 2
55.             r = SIN(1.1 * t) * h2 - y + h2
56.             g = SIN(.9 * t) * w2 - x + w2
57.             B = SIN(x / w2 + t + y / h2) * r
58.             PSET (x, y), _RGB(r, g, B)
59.         NEXT
60.         t = t + .01
61.     NEXT
62.     'draw balls
63.     FOR i = 1 TO balls
64.         ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
65.         _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
66.     NEXT
67.     _DISPLAY: _LIMIT 60
68.     IF d% <= 80 THEN _DELAY 1
69. LOOP
70.  
71.  
72. SUB ball (BallX, BallY, size, r, g, b)
73.     FOR s = 1 TO size STEP .5
74.         CIRCLE (BallX, BallY), s, _RGB(r, g, b)
75.         r = r - 1: g = g - 1: b = b - 1
76.     NEXT
77. END SUB
78.  

Title: Re: Bouncing Balls over a Plasma sky
Post by: Dav on December 26, 2020, 08:50:57 pm

@TempodiBasic :  Thanks for trying it out!

@NOVARSEG : That's pretty good.  I may have to borrow that method for something.  Thanks for trying the code out.

I tried to make a little game out of this, clicking away the balls in order, starting at ball 1.  Not perfect as I'm reading squares of mouse x/y input data, and the balls are in circles.  Messy code here warning, but it's a start at least.  I tweaked the plasma code to made it smoother on my slow laptop.

- Dav

Code: QB64: [Select]

1. 'ClickAwayBalls.bas
2. 'by Dav, DEC/2020
3.  
4. 'Click on balls in order, starting at 1 untill all gone.
5.  
6.  
7. SCREEN _NEWIMAGE(700, 700, 32)
8.  
9. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
10. _PRINTMODE _KEEPBACKGROUND
11.  
12. balls = 15: size = 40: speed = 10
13.  
14. DIM BallX(balls), BallY(balls)
15. DIM BallXdir(balls), BallYdir(balls)
16. DIM BallSpeed(balls), BallSize(balls)
17. DIM BallShow(balls)
18.  
19. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
20.  
21. 'Generate random ball data
22. FOR B = 1 TO balls
23.     BallX(B) = RND * w: BallY(B) = RND * h
24.     BallSpeed(B) = RND * speed + 1
25.     BallSize(B) = 40 + (RND * 50)
26.     BallShow(B) = 1
27. NEXT
28.  
29. curball = 1
30.  
31. DO
32.     CLS
33.     'compute ball movement
34.     FOR t = 1 TO balls
35.         IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 0
36.         IF BallX(t) < BallSize(t) THEN BallXdir(t) = 1
37.         IF BallXdir(t) THEN BallX(t) = BallX(t) + BallSpeed(t) ELSE BallX(t) = BallX(t) - BallSpeed(t)
38.         IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 0
39.         IF BallY(t) < BallSize(t) THEN BallYdir(t) = 1
40.         IF BallYdir(t) THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
41.     NEXT
42.     'draw background
43.     t = TIMER
44.     FOR x = 0 TO w
45.         FOR y = 0 TO h
46.             r = SIN(1.1 * t) * h2 - y + h2
47.             PSET (x, y), _RGB(r, r - y, -r)
48.         NEXT
49.         t = t + .01
50.         GOSUB GetMouseClick
51.     NEXT
52.  
53.     IF gameover = 1 THEN
54.         PLAY "o2l16cegagfefgabgc3l4"
55.         END
56.     END IF
57.  
58.     'draw balls
59.     FOR i = 1 TO balls
60.         IF BallShow(i) = 1 THEN
61.             ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
62.             _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
63.         END IF
64.     NEXT
65.  
66.     LOCATE 1, 1: PRINT "Click ball.."; curball;
67.     _DISPLAY: _LIMIT 60
68.  
69.     'If click on only one ball (no overlayed ones) remove it
70.     IF found = 1 THEN
71.         IF firstball = curball THEN
72.             'erase ball
73.             ball BallX(firstball), BallY(firstball), BallSize(firstball), 255, 200, 200
74.             BallShow(firstball) = 0
75.             PLAY "mbl32o2ceg"
76.             _DISPLAY: _DELAY .05
77.             curball = curball + 1
78.             found = 0
79.         ELSE
80.             found = found + 1
81.             lastfound = firstball
82.         END IF
83.     END IF
84.  
85.     'If clicked over several balls, highlight the top most one
86.     IF found > 1 THEN
87.         'BallShow(lastfound) = 0
88.         ball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
89.         _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
90.         _DISPLAY: PLAY "mbl32o2bo3fo2b"
91.         found = 0
92.         _DELAY .1
93.     END IF
94.  
95.     'check if all calls clicked away
96.     anyleft = 0
97.     FOR c = 1 TO balls
98.         IF BallShow(c) = 1 THEN anyleft = anyleft + 1
99.     NEXT
100.     IF anyleft = 0 THEN
101.         gameover = 1
102.     END IF
103.  
104. LOOP
105.  
106. END
107.  
108. '==============
109. GetMouseClick:
110. '==============
111.  
112. mi = _MOUSEINPUT
113. IF _MOUSEBUTTON(1) = 0 THEN done = 0
114. IF _MOUSEBUTTON(1) AND done = 0 THEN
115.     mx = _MOUSEX: my = _MOUSEY
116.     found = 0
117.     FOR m = 1 TO balls
118.         IF BallShow(m) = 1 THEN
119.             IF mx > (BallX(m) - BallSize(m)) AND mx < (BallX(m) + BallSize(m)) THEN
120.                 IF my > (BallY(m) - BallSize(m)) AND my < (BallY(m) + BallSize(m)) THEN
121.                     IF found = 0 THEN firstball = m
122.                     found = found + 1
123.                     IF found > 1 THEN
124.                         lastfound = m
125.                     END IF
126.                 END IF
127.             END IF
128.         END IF
129.     NEXT
130.     done = 1
131. END IF
132.  
133. RETURN
134.  
135.  
136. SUB ball (BallX, BallY, size, r, g, b)
137.     FOR s = 1 TO size STEP .4
138.         CIRCLE (BallX, BallY), s, _RGB(r, g, b)
139.         r = r - 1: g = g - 1: b = b - 1
140.     NEXT
141. END SUB
142.  

Title: Re: Bouncing Balls over a Plasma sky
Post by: NOVARSEG on December 26, 2020, 10:23:33 pm

Having trouble with PRINT

   

Quote

d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5

    LOCATE 10, 10: PRINT d%

    IF d% <= 80 THEN _DELAY 1

So run the code and find that 80 or less than 80 is never printed to the screen when the balls FIRST collide.

Code: QB64: [Select]

1. 'Balls&Plasma.bas
2.  
3. SCREEN _NEWIMAGE(700, 700, 32)
4.  
5. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
6. '_PRINTMODE _KEEPBACKGROUND
7.  
8. balls = 2: size = 40: speed = 10
9.  
10. DIM BallX(balls), BallY(balls)
11. DIM BallXdir(balls), BallYdir(balls)
12. DIM BallSpeed(balls), BallSize(balls)
13.  
14. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
15.  
16. 'Generate random ball data
17. FOR B = 1 TO balls
18.     BallX(B) = RND * w: BallY(B) = RND * h
19.     BallSpeed(B) = RND * speed + 1
20.     BallSize(B) = 40 '+ (RND * 50)
21. NEXT
22.  
23. DO
24.     CLS
25.  
26.  
27.  
28.     'compute ball movement
29.     FOR t = 1 TO balls
30.  
31.         LL:
32.         IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 1
33.         IF BallX(t) < BallSize(t) THEN BallXdir(t) = 0
34.  
35.         IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 1
36.         IF BallY(t) < BallSize(t) THEN BallYdir(t) = 0
37.  
38.         IF BallXdir(t) = 0 THEN BallX(t) = BallX(t) + BallSpeed(t)
39.         IF BallXdir(t) = 1 THEN BallX(t) = BallX(t) - BallSpeed(t)
40.  
41.         IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t)
42.         IF BallYdir(t) = 1 THEN BallY(t) = BallY(t) - BallSpeed(t)
43.  
44.  
45.     NEXT
46.  
47.  
48.  
49.     'draw plasma
50.     ' t = TIMER
51.     ' FOR x = 0 TO w
52.     ' FOR y = 0 TO h STEP 2
53.     ' r = SIN(1.1 * t) * h2 - y + h2
54.     ' g = SIN(.9 * t) * w2 - x + w2
55.     ' B = SIN(x / w2 + t + y / h2) * r
56.     ' PSET (x, y), _RGB(r, g, B)
57.     ' NEXT
58.     ' t = t + .01
59.     ' NEXT
60.     'draw balls
61.  
62.  
63.  
64.  
65.     FOR i = 1 TO balls
66.         ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
67.         _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
68.     NEXT
69.  
70.  
71.     d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5
72.  
73.     LOCATE 10, 10: PRINT d%
74.  
75.     IF d% <= 80 THEN _DELAY 1
76.  
77.  
78.     _DISPLAY: _LIMIT 60
79.  
80.  
81. LOOP
82.  
83.  
84. SUB ball (BallX, BallY, size, r, g, b)
85.     FOR s = 1 TO size STEP .5
86.         CIRCLE (BallX, BallY), s, _RGB(r, g, b)
87.         r = r - 1: g = g - 1: b = b - 1
88.     NEXT
89. END SUB

Title: Re: Bouncing Balls over a Plasma sky
Post by: bplus on December 26, 2020, 10:44:35 pm

 

Quote

Having trouble with PRINT

No you are having trouble with _DISPLAY!

When you use that, you have to say _DISPLAY every where you want to see PRINT immediately.

You can turn off _DISPLAY with _AUTODISPLAY or just say _DISPLAY again after the PRINT.

@Dav  LINE with BF might be alittle bit faster than PSET according to @SMcNeill.

Title: Re: Bouncing Balls over a Plasma sky
Post by: NOVARSEG on December 26, 2020, 11:11:14 pm

bplus you are right .  I put a _DISPLAY right after the PRINT and it works.

Title: Re: Bouncing Balls over a Plasma sky
Post by: NOVARSEG on December 26, 2020, 11:35:49 pm

Got the code tp print distance and relative direction.

Code: QB64: [Select]

1. 'Balls&Plasma.bas
2.  
3. SCREEN _NEWIMAGE(700, 700, 32)
4.  
5. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
6. '_PRINTMODE _KEEPBACKGROUND
7.  
8. balls = 2: size = 40: speed = 1
9.  
10. DIM BallX(balls), BallY(balls)
11. DIM BallXdir(balls), BallYdir(balls)
12. DIM BallSpeed(balls), BallSize(balls)
13.  
14. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
15.  
16. 'Generate random ball data
17. FOR B = 1 TO balls
18.     BallX(B) = RND * w: BallY(B) = RND * h
19.     BallSpeed(B) = RND * speed + 1
20.     BallSize(B) = 40 '+ (RND * 50)
21. NEXT
22.  
23. DO
24.     CLS
25.  
26.  
27.     'compute ball movement
28.     FOR t = 1 TO balls
29.  
30.         LL:
31.         IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 1
32.         IF BallX(t) < BallSize(t) THEN BallXdir(t) = 0
33.  
34.         IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 1
35.         IF BallY(t) < BallSize(t) THEN BallYdir(t) = 0
36.  
37.         IF BallXdir(t) = 0 THEN BallX(t) = BallX(t) + BallSpeed(t)
38.         IF BallXdir(t) = 1 THEN BallX(t) = BallX(t) - BallSpeed(t)
39.  
40.         IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t)
41.         IF BallYdir(t) = 1 THEN BallY(t) = BallY(t) - BallSpeed(t)
42.  
43.  
44.     NEXT
45.  
46.  
47.  
48.     'draw plasma
49.     ' t = TIMER
50.     ' FOR x = 0 TO w
51.     ' FOR y = 0 TO h STEP 2
52.     ' r = SIN(1.1 * t) * h2 - y + h2
53.     ' g = SIN(.9 * t) * w2 - x + w2
54.     ' B = SIN(x / w2 + t + y / h2) * r
55.     ' PSET (x, y), _RGB(r, g, B)
56.     ' NEXT
57.     ' t = t + .01
58.     ' NEXT
59.     'draw balls
60.  
61.  
62.  
63.  
64.     FOR i = 1 TO balls
65.         ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
66.         _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
67.     NEXT
68.  
69.     d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5
70.  
71.  
72.     LOCATE 10, 10: PRINT "Distance"
73.     LOCATE 11, 10: PRINT d%
74.     LOCATE 12, 10: PRINT
75.     LOCATE 13, 10: PRINT "Relative"
76.     LOCATE 14, 10: PRINT "Direction"
77.     LOCATE 15, 10: PRINT (BallX(1) - BallX(2)) / (BallY(1) - BallY(2))
78.  
79.     _DISPLAY
80.     IF d% <= 80 THEN _DELAY 1
81.  
82.     _DISPLAY
83.     _LIMIT 60
84.  
85.  
86. LOOP
87.  
88.  
89. SUB ball (BallX, BallY, size, r, g, b)
90.     FOR s = 1 TO size STEP .5
91.         CIRCLE (BallX, BallY), s, _RGB(r, g, b)
92.         r = r - 1: g = g - 1: b = b - 1
93.     NEXT
94. END SUB

Title: Re: Bouncing Balls over a Plasma sky
Post by: Dav on December 27, 2020, 09:49:36 am

Thanks, @bplus.  I played around with that and put LINE in this new version. 

Gave the game a little challenge now.  Added a game timer, click them all in 20 seconds.   speed increases as you go.  Clicking the wrong ball restarts game.  I lowered _LIMIT as @TempodiBasic suggested.  Hope it doesn't run too fast now.  Have a ball...

- Dav

Code: QB64: [Select]

1. 'ClickAwayBalls.bas v1.1
2. 'new: speed increases, added timer, clicking bad choice restarts.
3. 'by Dav, DEC/2020
4.  
5. 'Click on balls in order, starting at 1 untill all gone,
6. 'before the timer runs out.  Clicking wrong number restarts.
7.  
8.  
9. SCREEN _NEWIMAGE(700, 700, 32)
10.  
11. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
12. _PRINTMODE _KEEPBACKGROUND
13.  
14. balls = 15: size = 40: speed = 3
15.  
16. DIM BallX(balls), BallY(balls)
17. DIM BallXdir(balls), BallYdir(balls)
18. DIM BallSpeed(balls), BallSize(balls)
19. DIM BallShow(balls)
20.  
21. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
22.  
23. restart:
24.  
25. 'Generate random ball data
26. FOR B = 1 TO balls
27.     BallX(B) = RND * w: BallY(B) = RND * h
28.     BallSpeed(B) = RND * speed + 1
29.     BallSize(B) = 40 + (RND * 50)
30.     BallShow(B) = 1
31. NEXT
32.  
33. curball = 1
34.  
35. gametime = TIMER
36.  
37. timelimit = 20
38.  
39. DO
40.     CLS
41.     'compute ball movement
42.     FOR t = 1 TO balls
43.         IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 0
44.         IF BallX(t) < BallSize(t) THEN BallXdir(t) = 1
45.         IF BallXdir(t) THEN BallX(t) = BallX(t) + BallSpeed(t) ELSE BallX(t) = BallX(t) - BallSpeed(t)
46.         IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 0
47.         IF BallY(t) < BallSize(t) THEN BallYdir(t) = 1
48.         IF BallYdir(t) THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
49.     NEXT
50.     'draw background
51.     t = TIMER
52.     FOR x = 0 TO w
53.         FOR y = 0 TO h
54.             r = SIN(1.1 * t) * h2 - y + h2
55.             'PSET (x, y), _RGB(r, r - y, -r)
56.             LINE (x, y)-(x, y), _RGB(r, r - y, -r), BF
57.         NEXT
58.         t = t + .01
59.         GOSUB GetMouseClick
60.     NEXT
61.  
62.     IF gameover = 1 THEN
63.         PLAY "o2l16cegagfefgabgc3l4"
64.         SLEEP 3
65.         GOTO restart
66.     END IF
67.  
68.     'draw balls
69.     FOR i = 1 TO balls
70.         IF BallShow(i) = 1 THEN
71.             ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
72.             _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
73.         END IF
74.     NEXT
75.  
76.     LOCATE 1, 1: PRINT "Click ball.."; curball;
77.     LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
78.     _DISPLAY: _LIMIT 30
79.  
80.     'If click on one ball (no overlayed oned) remove it
81.     IF found = 1 THEN
82.         IF firstball = curball THEN
83.             'erase ball
84.             ball BallX(firstball), BallY(firstball), BallSize(firstball), 255, 200, 200
85.             BallShow(firstball) = 0
86.             PLAY "mbl32o2ceg"
87.             _DISPLAY: _DELAY .05
88.             curball = curball + 1
89.             found = 0
90.  
91.             'Increase spped of balls
92.             FOR s = 1 TO balls
93.                 BallSpeed(s) = BallSpeed(s) + 1
94.             NEXT
95.  
96.         ELSE
97.             found = found + 1
98.             lastfound = firstball
99.         END IF
100.     END IF
101.  
102.     'If click over several balls, remove top one
103.     IF found > 1 THEN
104.         'BallShow(lastfound) = 0
105.         ball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
106.         _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
107.         _DISPLAY: PLAY "mbl16o2fbfbl8f"
108.         found = 0
109.         _DELAY .5
110.         GOTO restart
111.     END IF
112.  
113.     'check if all clicked
114.     anyleft = 0
115.     FOR c = 1 TO balls
116.         IF BallShow(c) = 1 THEN anyleft = anyleft + 1
117.     NEXT
118.     IF anyleft = 0 THEN
119.         gameover = 1
120.     END IF
121.  
122.     IF TIMER - gametime > timelimit THEN
123.         PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
124.         SLEEP 3
125.         GOTO restart
126.     END IF
127.  
128. LOOP
129.  
130. END
131.  
132. '==============
133. GetMouseClick:
134. '==============
135.  
136. mi = _MOUSEINPUT
137. IF _MOUSEBUTTON(1) = 0 THEN done = 0
138. IF _MOUSEBUTTON(1) AND done = 0 THEN
139.     mx = _MOUSEX: my = _MOUSEY
140.     found = 0
141.     FOR m = 1 TO balls
142.         IF BallShow(m) = 1 THEN
143.             IF mx > (BallX(m) - BallSize(m)) AND mx < (BallX(m) + BallSize(m)) THEN
144.                 IF my > (BallY(m) - BallSize(m)) AND my < (BallY(m) + BallSize(m)) THEN
145.                     IF found = 0 THEN firstball = m
146.                     found = found + 1
147.                     IF found > 1 THEN
148.                         lastfound = m
149.                     END IF
150.                 END IF
151.             END IF
152.         END IF
153.     NEXT
154.     done = 1
155. END IF
156.  
157. RETURN
158.  
159.  
160. SUB ball (BallX, BallY, size, r, g, b)
161.     FOR s = 1 TO size STEP .4
162.         CIRCLE (BallX, BallY), s, _RGB(r, g, b)
163.         r = r - 1: g = g - 1: b = b - 1
164.     NEXT
165. END SUB
166.  

Title: Re: Bouncing Balls over a Plasma sky
Post by: bplus on December 27, 2020, 12:47:15 pm

I tried game and not enough variation of direction, a couple times the higher balls overlapped smaller the whole 20 secs

Title: Re: Bouncing Balls over a Plasma sky
Post by: FellippeHeitor on December 27, 2020, 12:57:04 pm

Fun game, Dav. I love the plasma effect, I think I'd seen this bit before in one of your previously shared pieces.

Title: Re: Bouncing Balls over a Plasma sky
Post by: Dav on December 27, 2020, 01:33:25 pm

@bplus. Yes, i agree. Happens to me too. I'll figure something out there. I wonder how I can get mouse x/y in a circle instead of a rectangle? I'm gonna think on it.

@FellippeHeitor, i think I did post that little plasma things before.

- Dav

Title: Re: Bouncing Balls over a Plasma sky
Post by: bplus on December 27, 2020, 02:35:33 pm

Some more variation in ball movement, center screen, more time, no so big balls but more colors can almost get them all heh heh..

Code: QB64: [Select]

1. 'ClickAwayBalls.bas v1.1
2. 'new: speed increases, added timer, clicking bad choice restarts.
3. 'by Dav, DEC/2020
4.  
5. 'Click on balls in order, starting at 1 untill all gone,
6. 'before the timer runs out.  Clicking wrong number restarts.
7.  
8. RANDOMIZE TIMER
9. SCREEN _NEWIMAGE(800, 600, 32)
10. _DELAY .25
11. _SCREENMOVE _MIDDLE
12.  
13. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
14. _PRINTMODE _KEEPBACKGROUND
15.  
16. balls = 15: size = 40: speed = 3
17.  
18. REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
19.  
20. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
21.  
22. restart:
23.  
24. 'Generate random ball data
25. FOR B = 1 TO balls
26.     BallSize(B) = 40 + (RND * 30)
27.     BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
28.     a = RND * _PI(2): Ballspeed = 7 + RND * 14
29.     BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
30.     BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
31. NEXT
32.  
33. curball = 1
34.  
35. gametime = TIMER
36.  
37. timelimit = 30
38.  
39. DO
40.     CLS
41.     'compute ball movement
42.     FOR t = 1 TO balls
43.         BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
44.         BallY(t) = BallY(t) + BallDy(t)
45.         IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
46.         IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
47.         IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
48.         IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
49.     NEXT
50.     'draw background
51.     t = TIMER
52.     FOR x = 0 TO w
53.         FOR y = 0 TO h
54.             r = SIN(1.1 * t) * h2 - y + h2
55.             'PSET (x, y), _RGB(r, r - y, -r)
56.             LINE (x, y)-(x, y), _RGB(r, r - y, -r), BF
57.         NEXT
58.         t = t + .01
59.         GOSUB GetMouseClick
60.     NEXT
61.  
62.     IF gameover = 1 THEN
63.         PLAY "o2l16cegagfefgabgc3l4"
64.         SLEEP 3
65.         GOTO restart
66.     END IF
67.  
68.     'draw balls
69.     FOR i = 1 TO balls
70.         IF BallShow(i) = 1 THEN
71.             drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
72.             _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
73.         END IF
74.     NEXT
75.  
76.     LOCATE 1, 1: PRINT "Click ball.."; curball;
77.     LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
78.     _DISPLAY: _LIMIT 30
79.  
80.     'If click on one ball (no overlayed oned) remove it
81.     IF found = 1 THEN
82.         IF firstball = curball THEN
83.             'erase ball
84.             drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
85.             BallShow(firstball) = 0
86.             PLAY "mbl32o2ceg"
87.             _DISPLAY: _DELAY .05
88.             curball = curball + 1
89.             found = 0
90.  
91.  
92.         ELSE
93.             found = found + 1
94.             lastfound = firstball
95.         END IF
96.     END IF
97.  
98.     ''If click over several balls, remove top one
99.     'IF found > 1 THEN
100.     '    'BallShow(lastfound) = 0
101.     '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
102.     '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
103.     '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
104.     '    found = 0
105.     '    _DELAY .5
106.     '    GOTO restart
107.     'END IF
108.  
109.     'check if all clicked
110.     anyleft = 0
111.     FOR c = 1 TO balls
112.         IF BallShow(c) = 1 THEN anyleft = anyleft + 1
113.     NEXT
114.     IF anyleft = 0 THEN
115.         gameover = 1
116.     END IF
117.  
118.     IF TIMER - gametime > timelimit THEN
119.         PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
120.         SLEEP 3
121.         GOTO restart
122.     END IF
123.  
124. LOOP
125.  
126. END
127.  
128. '==============
129. GetMouseClick:
130. '==============
131.  
132. mi = _MOUSEINPUT
133. IF _MOUSEBUTTON(1) = 0 THEN done = 0
134. IF _MOUSEBUTTON(1) AND done = 0 THEN
135.     mx = _MOUSEX: my = _MOUSEY
136.     found = 0
137.     FOR m = 1 TO balls
138.         IF BallShow(m) = 1 THEN
139.             IF mx > (BallX(m) - BallSize(m)) AND mx < (BallX(m) + BallSize(m)) THEN
140.                 IF my > (BallY(m) - BallSize(m)) AND my < (BallY(m) + BallSize(m)) THEN
141.                     IF found = 0 THEN firstball = m
142.                     found = found + 1
143.                     IF found > 1 THEN
144.                         lastfound = m
145.                     END IF
146.                 END IF
147.             END IF
148.         END IF
149.     NEXT
150.     done = 1
151. END IF
152.  
153. RETURN
154.  
155.  
156. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
157.     DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
158.     rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
159.     FOR rr = r TO 0 STEP -1
160.         f = 1 - rr / r
161.         fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
162.     NEXT
163. END SUB
164.  
165. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
166.     DIM Radius AS INTEGER, RadiusError AS INTEGER
167.     DIM X AS INTEGER, Y AS INTEGER
168.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
169.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
170.     LINE (CX - X, CY)-(CX + X, CY), C, BF
171.     WHILE X > Y
172.         RadiusError = RadiusError + Y * 2 + 1
173.         IF RadiusError >= 0 THEN
174.             IF X <> Y + 1 THEN
175.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
176.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
177.             END IF
178.             X = X - 1
179.             RadiusError = RadiusError - X * 2
180.         END IF
181.         Y = Y + 1
182.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
183.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
184.     WEND
185. END SUB
186.  
187.  

Quote

I wonder how I can get mouse x/y in a circle instead of a rectangle?

Do you mean is mouse x, y is a ball radius away from ball middle?
if sqr((mx - bx)^2 + (my-by)^2))<= br then 'ball clicked

Code: QB64: [Select]

1. 'ClickAwayBalls.bas v1.1
2. 'new: speed increases, added timer, clicking bad choice restarts.
3. 'by Dav, DEC/2020
4.  
5. 'Click on balls in order, starting at 1 untill all gone,
6. 'before the timer runs out.  Clicking wrong number restarts.
7.  
8. RANDOMIZE TIMER
9. SCREEN _NEWIMAGE(800, 600, 32)
10. _DELAY .25
11. _SCREENMOVE _MIDDLE
12.  
13. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
14. _PRINTMODE _KEEPBACKGROUND
15.  
16. balls = 15: size = 40: speed = 3
17.  
18. REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
19.  
20. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
21.  
22. restart:
23.  
24. 'Generate random ball data
25. FOR B = 1 TO balls
26.     BallSize(B) = 40 + (RND * 30)
27.     BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
28.     a = RND * _PI(2): Ballspeed = 7 + RND * 14
29.     BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
30.     BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
31. NEXT
32.  
33. curball = 1
34.  
35. gametime = TIMER
36.  
37. timelimit = 30
38.  
39. DO
40.     CLS
41.     'compute ball movement
42.     FOR t = 1 TO balls
43.         BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
44.         BallY(t) = BallY(t) + BallDy(t)
45.         IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
46.         IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
47.         IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
48.         IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
49.     NEXT
50.     'draw background
51.     t = TIMER
52.     FOR x = 0 TO w
53.         FOR y = 0 TO h
54.             r = SIN(1.1 * t) * h2 - y + h2
55.             'PSET (x, y), _RGB(r, r - y, -r)
56.             LINE (x, y)-(x, y), _RGB(r, r - y, -r), BF
57.         NEXT
58.         t = t + .01
59.         GOSUB GetMouseClick
60.     NEXT
61.  
62.     IF gameover = 1 THEN
63.         PLAY "o2l16cegagfefgabgc3l4"
64.         SLEEP 3
65.         GOTO restart
66.     END IF
67.  
68.     'draw balls
69.     FOR i = 1 TO balls
70.         IF BallShow(i) = 1 THEN
71.             drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
72.             _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
73.         END IF
74.     NEXT
75.  
76.     LOCATE 1, 1: PRINT "Click ball.."; curball;
77.     LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
78.     _DISPLAY: _LIMIT 30
79.  
80.     'If click on one ball (no overlayed oned) remove it
81.     IF found = 1 THEN
82.         IF firstball = curball THEN
83.             'erase ball
84.             drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
85.             BallShow(firstball) = 0
86.             PLAY "mbl32o2ceg"
87.             _DISPLAY: _DELAY .05
88.             curball = curball + 1
89.             found = 0
90.  
91.  
92.         ELSE
93.             found = found + 1
94.             lastfound = firstball
95.         END IF
96.     END IF
97.  
98.     ''If click over several balls, remove top one
99.     'IF found > 1 THEN
100.     '    'BallShow(lastfound) = 0
101.     '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
102.     '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
103.     '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
104.     '    found = 0
105.     '    _DELAY .5
106.     '    GOTO restart
107.     'END IF
108.  
109.     'check if all clicked
110.     anyleft = 0
111.     FOR c = 1 TO balls
112.         IF BallShow(c) = 1 THEN anyleft = anyleft + 1
113.     NEXT
114.     IF anyleft = 0 THEN
115.         gameover = 1
116.     END IF
117.  
118.     IF TIMER - gametime > timelimit THEN
119.         PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
120.         SLEEP 3
121.         GOTO restart
122.     END IF
123.  
124. LOOP
125.  
126. END
127.  
128. '==============
129. GetMouseClick:
130. '==============
131.  
132. mi = _MOUSEINPUT
133. IF _MOUSEBUTTON(1) = 0 THEN done = 0
134. IF _MOUSEBUTTON(1) AND done = 0 THEN
135.     mx = _MOUSEX: my = _MOUSEY
136.     found = 0
137.     FOR m = 1 TO balls
138.         IF BallShow(m) = 1 THEN
139.             IF SQR((mx - BallX(m)) ^ 2 + (my - BallY(m)) ^ 2) < BallSize(m) THEN
140.                 IF found = 0 THEN firstball = m
141.                 found = found + 1
142.                 IF found > 1 THEN
143.                     lastfound = m
144.                 END IF
145.             END IF
146.         END IF
147.     NEXT
148.     done = 1
149. END IF
150.  
151. RETURN
152.  
153.  
154. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
155.     DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
156.     rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
157.     FOR rr = r TO 0 STEP -1
158.         f = 1 - rr / r
159.         fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
160.     NEXT
161. END SUB
162.  
163. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
164.     DIM Radius AS INTEGER, RadiusError AS INTEGER
165.     DIM X AS INTEGER, Y AS INTEGER
166.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
167.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
168.     LINE (CX - X, CY)-(CX + X, CY), C, BF
169.     WHILE X > Y
170.         RadiusError = RadiusError + Y * 2 + 1
171.         IF RadiusError >= 0 THEN
172.             IF X <> Y + 1 THEN
173.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
174.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
175.             END IF
176.             X = X - 1
177.             RadiusError = RadiusError - X * 2
178.         END IF
179.         Y = Y + 1
180.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
181.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
182.     WEND
183. END SUB
184.  

Title: Re: Bouncing Balls over a Plasma sky
Post by: bplus on December 27, 2020, 02:59:22 pm

Here it is with less time spent drawing plasma

Code: QB64: [Select]

1. 'ClickAwayBalls.bas v1.1
2. 'new: speed increases, added timer, clicking bad choice restarts.
3. 'by Dav, DEC/2020
4.  
5. 'Click on balls in order, starting at 1 untill all gone,
6. 'before the timer runs out.  Clicking wrong number restarts.
7.  
8. RANDOMIZE TIMER
9. SCREEN _NEWIMAGE(800, 600, 32)
10. _DELAY .25
11. _SCREENMOVE _MIDDLE
12.  
13. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
14. _PRINTMODE _KEEPBACKGROUND
15.  
16. balls = 15: size = 40: speed = 3
17.  
18. REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
19.  
20. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
21.  
22. restart:
23.  
24. 'Generate random ball data
25. FOR B = 1 TO balls
26.     BallSize(B) = 40 + (RND * 30)
27.     BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
28.     a = RND * _PI(2): Ballspeed = 4 + RND * 8
29.     BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
30.     BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
31. NEXT
32.  
33. curball = 1
34.  
35. gametime = TIMER
36.  
37. timelimit = 30
38.  
39. DO
40.     CLS
41.     'compute ball movement
42.     FOR t = 1 TO balls
43.         BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
44.         BallY(t) = BallY(t) + BallDy(t)
45.         IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
46.         IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
47.         IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
48.         IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
49.     NEXT
50.     'draw background
51.     t = TIMER
52.     FOR x = 0 TO w STEP 4
53.         FOR y = 0 TO h STEP 4
54.             r = SIN(1.1 * t) * h2 - y + h2
55.             'PSET (x, y), _RGB(r, r - y, -r)
56.             LINE (x, y)-STEP(3, 3), _RGB(r, r - y, -r), BF
57.         NEXT
58.         t = t + .01
59.         GOSUB GetMouseClick
60.     NEXT
61.  
62.     IF gameover = 1 THEN
63.         PLAY "o2l16cegagfefgabgc3l4"
64.         SLEEP 3
65.         GOTO restart
66.     END IF
67.  
68.     'draw balls
69.     FOR i = 1 TO balls
70.         IF BallShow(i) = 1 THEN
71.             drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
72.             _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
73.         END IF
74.     NEXT
75.  
76.     LOCATE 1, 1: PRINT "Click ball.."; curball;
77.     LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
78.     _DISPLAY: _LIMIT 30
79.  
80.     'If click on one ball (no overlayed oned) remove it
81.     IF found = 1 THEN
82.         IF firstball = curball THEN
83.             'erase ball
84.             drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
85.             BallShow(firstball) = 0
86.             PLAY "mbl32o2ceg"
87.             _DISPLAY: _DELAY .05
88.             curball = curball + 1
89.             found = 0
90.  
91.  
92.         ELSE
93.             found = found + 1
94.             lastfound = firstball
95.         END IF
96.     END IF
97.  
98.     ''If click over several balls, remove top one
99.     'IF found > 1 THEN
100.     '    'BallShow(lastfound) = 0
101.     '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
102.     '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
103.     '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
104.     '    found = 0
105.     '    _DELAY .5
106.     '    GOTO restart
107.     'END IF
108.  
109.     'check if all clicked
110.     anyleft = 0
111.     FOR c = 1 TO balls
112.         IF BallShow(c) = 1 THEN anyleft = anyleft + 1
113.     NEXT
114.     IF anyleft = 0 THEN
115.         gameover = 1
116.     END IF
117.  
118.     IF TIMER - gametime > timelimit THEN
119.         PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
120.         SLEEP 3
121.         GOTO restart
122.     END IF
123.  
124. LOOP
125.  
126. END
127.  
128. '==============
129. GetMouseClick:
130. '==============
131.  
132. mi = _MOUSEINPUT
133. IF _MOUSEBUTTON(1) = 0 THEN done = 0
134. IF _MOUSEBUTTON(1) AND done = 0 THEN
135.     mx = _MOUSEX: my = _MOUSEY
136.     found = 0
137.     FOR m = 1 TO balls
138.         IF BallShow(m) = 1 THEN
139.             IF SQR((mx - BallX(m)) ^ 2 + (my - BallY(m)) ^ 2) < BallSize(m) THEN
140.                 IF found = 0 THEN firstball = m
141.                 found = found + 1
142.                 IF found > 1 THEN
143.                     lastfound = m
144.                 END IF
145.             END IF
146.         END IF
147.     NEXT
148.     done = 1
149. END IF
150.  
151. RETURN
152.  
153.  
154. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
155.     DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
156.     rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
157.     FOR rr = r TO 0 STEP -1
158.         f = 1 - rr / r
159.         fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
160.     NEXT
161. END SUB
162.  
163. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
164.     DIM Radius AS INTEGER, RadiusError AS INTEGER
165.     DIM X AS INTEGER, Y AS INTEGER
166.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
167.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
168.     LINE (CX - X, CY)-(CX + X, CY), C, BF
169.     WHILE X > Y
170.         RadiusError = RadiusError + Y * 2 + 1
171.         IF RadiusError >= 0 THEN
172.             IF X <> Y + 1 THEN
173.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
174.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
175.             END IF
176.             X = X - 1
177.             RadiusError = RadiusError - X * 2
178.         END IF
179.         Y = Y + 1
180.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
181.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
182.     WEND
183. END SUB
184.  
185.  

edit: guess have to slow down balls now!

Title: Re: Bouncing Balls over a Plasma sky
Post by: bplus on December 27, 2020, 03:21:42 pm

OK low numbered balls move slow, high numbered balls move fast, now you know what to look for besides number:

Code: QB64: [Select]

1. 'ClickAwayBalls.bas v1.1
2. 'new: speed increases, added timer, clicking bad choice restarts.
3. 'by Dav, DEC/2020
4.  
5. 'Click on balls in order, starting at 1 untill all gone,
6. 'before the timer runs out.  Clicking wrong number restarts.
7.  
8. RANDOMIZE TIMER
9. SCREEN _NEWIMAGE(800, 600, 32)
10. _DELAY .25
11. _SCREENMOVE _MIDDLE
12.  
13. f = _LOADFONT("cyberbit.ttf", 30): _FONT f
14. _PRINTMODE _KEEPBACKGROUND
15.  
16. balls = 15: size = 40: speed = 3
17.  
18. REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
19.  
20. w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
21.  
22. restart:
23.  
24. 'Generate random ball data
25. FOR B = 1 TO balls
26.     BallSize(B) = 40 + (RND * 30)
27.     BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
28.     a = RND * _PI(2): Ballspeed = 2 + B
29.     BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
30.     BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
31. NEXT
32.  
33. curball = 1
34.  
35. gametime = TIMER
36.  
37. timelimit = 30
38.  
39. DO
40.     CLS
41.     'compute ball movement
42.     FOR t = 1 TO balls
43.         BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
44.         BallY(t) = BallY(t) + BallDy(t)
45.         IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
46.         IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
47.         IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
48.         IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
49.     NEXT
50.     'draw background
51.     t = TIMER
52.     FOR x = 0 TO w STEP 4
53.         FOR y = 0 TO h STEP 4
54.             r = SIN(1.1 * t) * h2 - y + h2
55.             'PSET (x, y), _RGB(r, r - y, -r)
56.             LINE (x, y)-STEP(3, 3), _RGB(r, r - y, -r), BF
57.         NEXT
58.         t = t + .01
59.         GOSUB GetMouseClick
60.     NEXT
61.  
62.     IF gameover = 1 THEN
63.         PLAY "o2l16cegagfefgabgc3l4"
64.         SLEEP 3
65.         GOTO restart
66.     END IF
67.  
68.     'draw balls
69.     FOR i = 1 TO balls
70.         IF BallShow(i) = 1 THEN
71.             drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
72.             _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
73.         END IF
74.     NEXT
75.  
76.     LOCATE 1, 1: PRINT "Click ball.."; curball;
77.     LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
78.     _DISPLAY: _LIMIT 30
79.  
80.     'If click on one ball (no overlayed oned) remove it
81.     IF found = 1 THEN
82.         IF firstball = curball THEN
83.             'erase ball
84.             drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
85.             BallShow(firstball) = 0
86.             PLAY "mbl32o2ceg"
87.             _DISPLAY: _DELAY .05
88.             curball = curball + 1
89.             found = 0
90.  
91.  
92.         ELSE
93.             found = found + 1
94.             lastfound = firstball
95.         END IF
96.     END IF
97.  
98.     ''If click over several balls, remove top one
99.     'IF found > 1 THEN
100.     '    'BallShow(lastfound) = 0
101.     '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
102.     '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
103.     '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
104.     '    found = 0
105.     '    _DELAY .5
106.     '    GOTO restart
107.     'END IF
108.  
109.     'check if all clicked
110.     anyleft = 0
111.     FOR c = 1 TO balls
112.         IF BallShow(c) = 1 THEN anyleft = anyleft + 1
113.     NEXT
114.     IF anyleft = 0 THEN
115.         gameover = 1
116.     END IF
117.  
118.     IF TIMER - gametime > timelimit THEN
119.         PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
120.         SLEEP 3
121.         GOTO restart
122.     END IF
123.  
124. LOOP
125.  
126. END
127.  
128. '==============
129. GetMouseClick:
130. '==============
131.  
132. mi = _MOUSEINPUT
133. IF _MOUSEBUTTON(1) = 0 THEN done = 0
134. IF _MOUSEBUTTON(1) AND done = 0 THEN
135.     mx = _MOUSEX: my = _MOUSEY
136.     found = 0
137.     FOR m = 1 TO balls
138.         IF BallShow(m) = 1 THEN
139.             IF SQR((mx - BallX(m)) ^ 2 + (my - BallY(m)) ^ 2) < BallSize(m) THEN
140.                 IF found = 0 THEN firstball = m
141.                 found = found + 1
142.                 IF found > 1 THEN
143.                     lastfound = m
144.                 END IF
145.             END IF
146.         END IF
147.     NEXT
148.     done = 1
149. END IF
150.  
151. RETURN
152.  
153.  
154. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
155.     DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
156.     rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
157.     FOR rr = r TO 0 STEP -1
158.         f = 1 - rr / r
159.         fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
160.     NEXT
161. END SUB
162.  
163. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
164.     DIM Radius AS INTEGER, RadiusError AS INTEGER
165.     DIM X AS INTEGER, Y AS INTEGER
166.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
167.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
168.     LINE (CX - X, CY)-(CX + X, CY), C, BF
169.     WHILE X > Y
170.         RadiusError = RadiusError + Y * 2 + 1
171.         IF RadiusError >= 0 THEN
172.             IF X <> Y + 1 THEN
173.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
174.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
175.             END IF
176.             X = X - 1
177.             RadiusError = RadiusError - X * 2
178.         END IF
179.         Y = Y + 1
180.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
181.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
182.     WEND
183. END SUB
184.  
185.  
186.  

Title: Re: Bouncing Balls over a Plasma sky
Post by: Dav on December 27, 2020, 03:55:50 pm

Brilliant, @bplus.  Great speed tweak with the plasma.  Looks better too.

Yes, that's what I was meaning about getting a circle of mouse click instead of rectangular.  Thanks for you input and help! 

- Dav 

Title: Re: Bouncing Balls over a Plasma sky
Post by: bplus on December 27, 2020, 05:07:00 pm

Quote from: Dav on December 27, 2020, 03:55:50 pm

Brilliant, @bplus.  Great speed tweak with the plasma.  Looks better too.

Yes, that's what I was meaning about getting a circle of mouse click instead of rectangular.  Thanks for you input and help! 

- Dav 

Oh good! I was getting worried about too much changing. :)

Text Only | Text with Attachments