Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on December 17, 2020, 09:17:37 am

Title: MBS (Mouse Button Status)
Post by: SMcNeill on December 17, 2020, 09:17:37 am
Code: QB64: [Select]
  1. _TITLE "MBS (Mouse Button Status) by Steve" ' 12-17-2020
  2.  
  4.     CLS
  5.     held$ = ""
  6.     result = MBS
  7.     left = left - (result AND 8) \ 8
  8.     right = right - (result AND 16) \ 16
  9.     middle = middle - (result AND 32) \ 32
  10.     IF result AND 64 THEN held$ = "Left held"
  11.     IF result AND 128 THEN held$ = "Right held"
  12.     IF result AND 256 THEN held$ = "Middle held"
  13.     IF result AND 512 THEN scroll = scroll + 1
  14.     IF result AND 1024 THEN scroll = scroll - 1
  15.  
  16.     PRINT "MouseX: "; _MOUSEX
  17.     PRINT "MouseY: "; _MOUSEY
  18.     PRINT "Left down     : "; result AND 1
  19.     PRINT "Right down     : "; result AND 2
  20.     PRINT "Middle down     : "; result AND 4
  21.     PRINT "Left pressed  : "; left
  22.     PRINT "Right pressed : "; right
  23.     PRINT "Middle pressed: "; middle
  24.     PRINT "Mouse Wheel Scrolled: "; scroll
  25.     PRINT
  26.     PRINT "Last held event started at X/Y :"; Mouse_StartX, Mouse_StartY
  27.     PRINT "Last held event ended at X/Y   :"; Mouse_EndX, Mouse_EndY
  28.     PRINT held$
  29.     _LIMIT 60
  31.  
  32.  
  33. FUNCTION MBS% 'Mouse Button Status
  34.     STATIC StartTimer AS _FLOAT
  35.     STATIC ButtonDown AS INTEGER
  36.     STATIC ClickCount AS INTEGER
  37.     CONST ClickLimit## = 0.2 'Less than 1/4th of a second to down, up a key to count as a CLICK.
  38.     '                          Down longer counts as a HOLD event.
  39.     SHARED Mouse_StartX, Mouse_StartY, Mouse_EndX, Mouse_EndY
  40.     WHILE _MOUSEINPUT 'Remark out this block, if mouse main input/clear is going to be handled manually in main program.
  41.         SELECT CASE SGN(_MOUSEWHEEL)
  42.             CASE 1: MBS = MBS OR 512
  43.             CASE -1: MBS = MBS OR 1024
  44.         END SELECT
  45.     WEND
  46.  
  47.  
  48.     IF _MOUSEBUTTON(1) THEN MBS = MBS OR 1
  49.     IF _MOUSEBUTTON(2) THEN MBS = MBS OR 2
  50.     IF _MOUSEBUTTON(3) THEN MBS = MBS OR 4
  51.  
  52.  
  53.     IF StartTimer = 0 THEN
  54.         IF _MOUSEBUTTON(1) THEN 'If a button is pressed, start the timer to see what it does (click or hold)
  55.             ButtonDown = 1: StartTimer = TIMER(0.01)
  56.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
  57.         ELSEIF _MOUSEBUTTON(2) THEN
  58.             ButtonDown = 2: StartTimer = TIMER(0.01)
  59.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
  60.         ELSEIF _MOUSEBUTTON(3) THEN
  61.             ButtonDown = 3: StartTimer = TIMER(0.01)
  62.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
  63.         END IF
  64.     ELSE
  65.         BD = ButtonDown MOD 3
  66.         IF BD = 0 THEN BD = 3
  67.         IF TIMER(0.01) - StartTimer <= ClickLimit THEN 'Button was down, then up, within time limit.  It's a click
  68.             IF _MOUSEBUTTON(BD) = 0 THEN MBS = 4 * 2 ^ ButtonDown: ButtonDown = 0: StartTimer = 0
  69.         ELSE
  70.             IF _MOUSEBUTTON(BD) = 0 THEN 'hold event has now ended
  71.                 MBS = 0: ButtonDown = 0: StartTimer = 0
  72.                 Mouse_EndX = _MOUSEX: Mouse_EndY = _MOUSEY
  73.             ELSE 'We've now started the hold event
  74.                 MBS = MBS OR 32 * 2 ^ ButtonDown
  75.             END IF
  76.         END IF
  77.     END IF
  79.  

I had one of these somewhere before, but I'll be danged if I can find it, so I rolled another one...

A simple routine to check the mouse buttons and to give us information on up/down, click, and hold statuses, as well as hold start/stop positions.   Results are all stored in a single binary integer, and basically break down to:

1 -- left down
2 -- right down
4 -- middle down
8 -- left clicked
16 -- right clicked
32 -- middle clicked
64 -- left held
128 -- right held
256 -- middle held
512 -- scroll down
1024 -- scroll up

Starting X/Y and Ending X/Y positions are available in the shared Mouse_ variables. 

Note, HOLD and CLICK events are independent of each other.  We don't register a free click with each hold event.  Windows tends to count first down events as clicks, so all hold events start with a click event and then transition into a hold event.  I didn't need that for my purposes, so this will either give you a hold event OR a click event; not both. 
Title: Re: MBS (Mouse Button Status)
Post by: bplus on December 17, 2020, 01:29:58 pm
This is interesting, I be looking for one mouse and keypress handler for multiple list boxes when I get around to my own File Explorer now that we've got the listing of Folders and Files working in Windows and Linux (thanks to Johnno's report and it must work someway otherwise QB64 couldn't do it). Scrolling or mousewheel is a must, Mouse and Keypress probably key to setting up an events sort of app.
Title: Re: MBS (Mouse Button Status)
Post by: Richard Frost on December 18, 2020, 08:22:44 pm
That makes about a dozen files in my QB64 directory that start with the word "steve" - high
quality stuff for immediate use or that I'm sure to need, someday.  I've probably got much
more of his code, but only had the sense to start naming things after the source late in my
downloading.  If I could go without a cigarette for 12 hours, I'd fly to Oz and eat his brain.
Bet it's mega tasty.
Title: Re: MBS (Mouse Button Status)
Post by: SMcNeill on December 18, 2020, 08:58:36 pm
Chocolate caramel flavored!
Title: Re: MBS (Mouse Button Status)
Post by: OldMoses on December 19, 2020, 07:19:47 pm
All outstanding, and I definitely need to study the "last held event" start and end part, that looks highly useful for rubber band box type stuff.
Title: Re: MBS (Mouse Button Status)
Post by: NOVARSEG on December 19, 2020, 10:38:10 pm
Now it is easy to see how the mouse works.

Code works perfect.  Good diagnostic to see if mouse is working etc.

Text Only | Text with Attachments