QB64.org Forum

Active Forums => Programs => Topic started by: NOVARSEG on December 17, 2020, 01:58:14 am

Title: Base 64 encoder / decoder
Post by: NOVARSEG on December 17, 2020, 01:58:14 am

Encodes  base 256  to base 64
Decodes base 64 to base 256

The code is more of an example of the math behind base to base conversions.

The earlier version had a bug  - now corrected.

Code: QB64: [Select]

1. 'BASE 64 encoder / decoder
2.  
3. 'prints the string to be encoded
4. 'prints the encoded base 64 string
5. 'prints the decoded base 64 string
6.  
7. DIM s AS DOUBLE
8. DIM os AS DOUBLE
9. DIM a AS INTEGER
10. DIM b AS INTEGER
11. DIM c AS INTEGER
12. DIM d AS INTEGER
13. DIM e AS STRING
14. DIM f AS STRING
15. DIM g AS STRING
16. DIM h AS STRING
17. DIM string1 AS STRING
18. DIM string2 AS STRING
19. _FULLSCREEN
20.  
21. string1 = "ASCII stands for American Standard Code for Information Interchange.."
22.  
23. PRINT "STRING1 "; string1
24. PRINT
25. FOR x% = 1 TO LEN(string1) STEP 3
26.     a = ASC(MID$(string1, x%, 1))
27.     b = ASC(MID$(string1, x% + 1, 1))
28.     c = ASC(MID$(string1, x% + 2, 1))
29.  
30.  
31.     s = a * 256 ^ 2 + b * 256 + c
32.  
33.  
34.     IF s >= 64 ^ 3 THEN
35.         i = INT(s / 64 ^ 3)
36.         s = s - i * 64 ^ 3
37.         e = CHR$(i + 48)
38.     END IF
39.  
40.     IF s >= 64 ^ 2 THEN
41.         i = INT(s / 64 ^ 2)
42.         s = s - i * 64 ^ 2
43.         f = CHR$(i + 48)
44.     END IF
45.  
46.     IF s >= 64 ^ 1 THEN
47.         i = INT(s / 64 ^ 1)
48.         s = s - i * 64 ^ 1
49.         g = CHR$(i + 48)
50.     END IF
51.  
52.     IF s >= 64 ^ 0 THEN
53.         i = INT(s / 64 ^ 0)
54.         s = s - i * 64 ^ 0
55.         h = CHR$(i + 48)
56.     END IF
57.  
58.  
59.     string2 = string2 + (e + f + g + h)
60. NEXT x%
61. PRINT "STRING2 "; string2
62. PRINT
63. string1 = ""
64. '********************
65. FOR x% = 1 TO LEN(string2) STEP 4
66.     a = ASC(MID$(string2, x%, 1)) - 48
67.     b = ASC(MID$(string2, x% + 1, 1)) - 48
68.     c = ASC(MID$(string2, x% + 2, 1)) - 48
69.     d = ASC(MID$(string2, x% + 3, 1)) - 48
70.  
71.  
72.     s = a * 64 ^ 3 + b * 64 ^ 2 + c * 64 + d
73.  
74.     IF s >= 256 ^ 2 THEN
75.         i = INT(s / 256 ^ 2)
76.         s = s - i * 256 ^ 2
77.         e = CHR$(i)
78.     END IF
79.  
80.     IF s >= 256 ^ 1 THEN
81.         i = INT(s / 256 ^ 1)
82.         s = s - i * 256 ^ 1
83.         f = CHR$(i)
84.     END IF
85.  
86.     IF s >= 256 ^ 0 THEN
87.         i = INT(s / 256 ^ 0)
88.         s = s - i * 256 ^ 0
89.         g = CHR$(i)
90.     END IF
91.  
92.     string1 = string1 + (e + f + g)
93.  
94. NEXT x%
95.  
96. PRINT "STRING1 "; string1
97.  
98.  
99. END
100.  

Title: Re: Base 64 encoder
Post by: bplus on December 17, 2020, 01:06:06 pm

What's the POINT?

Wouldn't numbers be more handy for processing?

ColorNumber~& = _RGB32(red, green, blue, alpha)

And the reverse, simple handy SUB for analyzing a color:

Code: QB64: [Select]

1. SUB cAnalysis (c AS _UNSIGNED LONG, outRed, outGrn, outBlu, outAlp)
2.     outRed = _RED32(c): outGrn = _GREEN32(c): outBlu = _BLUE32(c): outAlp = _ALPHA32(c)
3. END SUB
4.  

Demo test:

Code: QB64: [Select]

1. red = 50: green = 100: blue = 200: alpha = 100
2. ColorNumber~& = _RGBA32(red, green, blue, alpha)
3. PRINT red, green, blue, alpha, ColorNumber~&
4. cAnalysis ColorNumber~&, outR, outG, outB, outA
5. PRINT outR, outG, outB, outA
6.  
7.  
8. 'And the reverse, simple handy SUB for analyzing a color:
9.  
10. SUB cAnalysis (c AS _UNSIGNED LONG, outRed, outGrn, outBlu, outAlp)
11.     outRed = _RED32(c): outGrn = _GREEN32(c): outBlu = _BLUE32(c): outAlp = _ALPHA32(c)
12. END SUB
13.  

Convert red, green, blue, alpha to Binary, Hex, Oct....

Title: Re: Base 64 encoder
Post by: SMcNeill on December 17, 2020, 04:26:13 pm

Here's my Base-128 converter:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3. a$ = "  The Old Woman and the Wine-Jar" + CHR$(10)
4. a$ = a$ + "AN OLD WOMAN found an empty jar which had lately been full of prime old wine and which still retained the fragrant smell of its former contents.  She greedily placed it several times to her nose, and drawing it backwards and forwards said, 'O most delicious! How nice must the Wine itself have been, when it leaves behind in the very vessel which contained it so sweet a perfume!'" + CHR$(10)
5. a$ = a$ + "The memory of a good deed lives.     "
6.  
7. d$ = B256to128$(a$)
8. i$ = B128to256$(d$)
9. PRINT a$
10. PRINT "-----------------"
11. SLEEP
12. PRINT d$
13. PRINT "-----------------"
14. SLEEP
15. PRINT i$
16. PRINT "-----------------"
17. SLEEP
18. PRINT
19. PRINT
20. PRINT "Length of original:"; LEN(a$)
21. PRINT "Length of 128-bit DATA ready conversion:"; LEN(d$)
22. PRINT "Length of restored:"; LEN(i$)
23.  
24.  
25.  
26.  
27.  
28. FUNCTION B256to128$ (temp$)
29.     text$ = _DEFLATE$(temp$)
30.     l = 8 * LEN(text$)
31.     DIM A(1 TO l) AS _UNSIGNED _BIT, b AS _UNSIGNED _BYTE
32.     'convert the text to the 8 bit array
33.     FOR i = 1 TO LEN(text$)
34.         b = ASC(text$, i)
35.         p = (i - 1) * 8 + 1
36.         FOR j = 0 TO 7
37.             IF b AND (2 ^ j) THEN A(p + j) = 1 'ELSE A(p + j) = 0
38.         NEXT
39.     NEXT
40.     'convert the array to 7bit strings
41.     FOR i = 1 TO l STEP 7
42.         b = 0
43.         FOR j = 6 TO 0 STEP -1
44.             IF i + j < l THEN
45.                 IF A(i + j) THEN b = b + (2 ^ j)
46.             END IF
47.         NEXT
48.         b = b + 59
49.         t$ = t$ + CHR$(b)
50.  
51.     NEXT
52.     B256to128 = t$
53. END FUNCTION
54.  
55. FUNCTION B128to256$ (text$)
56.     l = 7 * LEN(text$)
57.     DIM A(1 TO l) AS _UNSIGNED _BIT, b AS _UNSIGNED _BYTE
58.     'convert the text to the 8 bit array
59.     FOR i = 1 TO LEN(text$)
60.         b = ASC(text$, i) - 59
61.         FOR j = 0 TO 6
62.             p = p + 1: IF p > l THEN EXIT FOR
63.             IF b AND (2 ^ j) THEN A(p) = 1 ELSE A(p) = 0
64.         NEXT
65.     NEXT
66.     'convert the array to 8bit strings
67.     p = 0
68.     FOR i = 1 TO l STEP 8
69.         b = 0
70.         FOR j = 0 TO 7
71.             p = p + 1
72.             IF p > l THEN EXIT FOR
73.             IF A(p) THEN b = b + (2 ^ j)
74.         NEXT
75.         t$ = t$ + CHR$(b)
76.     NEXT
77.     B128to256 = _INFLATE$(t$)
78. END FUNCTION

With this, I can take file assets such as images, sounds, or memblocks, and I can convert them down from BASE-256 characters to compressed BASE-128 characters, so that they'll paste into a DATA statement without any invalid characters causing problems.

For example, we can't have this in QB64:

DATA He said, "Foobar on your toolbar."

Those quotes and commas are problematic, as would a CHR$(0) or ":" be.  Not all 256 characters play nice with DATA statements, so I convert my data down to 128-bytes and place them into a program instead. 

Note: Routines above haven't been optimized for speed, so they may take a few seconds to convert and restore your data, in the case of large image or sound files.  I should honestly fix that sometime soon, but since I usually only use these routines for small assets (such as storing internal data for such things such as character information), it's never been too much of an issue for me.  Just be aware:  Large files can take a while to process with this method -- especially on an older, slower machine.

Title: Re: Base 64 encoder
Post by: NOVARSEG on December 17, 2020, 06:50:44 pm

with base 256 to base 64 conversion, it will  require 4 base 64 characters to encode 3 bytes.

with base 256 to base 128 conversion, it will require 4 base 128 characters to encode 3 bytes.

4 characters are required for both methods

base 256 to base 64 conversion is exactly efficient because 256^3 = 64^4

Any encoded characters like "," or quotes, can be mapped to other characters which is much easier since there are only 64 characters in the encoding set.

Title: Re: Base 64 encoder
Post by: SMcNeill on December 17, 2020, 07:48:21 pm

Quote from: NOVARSEG on December 17, 2020, 06:50:44 pm

with base 256 to base 64 conversion, it will  require 4 base 64 characters to encode 3 bytes.

with base 256 to base 128 conversion, it will require 4 base 128 characters to encode 3 bytes.

4 characters are required for both methods

base 256 to base 64 conversion is exactly efficient because 256^3 = 64^4

Any encoded characters like "," or quotes, can be mapped to other characters which is much easier since there are only 64 characters in the encoding set.

Base 64 lets you pack 6 bits of data per character.
Base 128 lets you pack 7 bits of data per character.

So 7 bytes of ASCII data is 56-BITS.

In base-64, you'll need 56/6 = 10 characters to hold your data.  (Round up, as you don't have fractional characters.)

In base-128, you'll need 56/7 = 8 characters to hold your data. 

It's simple to see how base-128 packs more data into 7-bits than base-64 can pack into 6-bits.

How often are you converting ONLY 3 bytes?  Why not convert a whole row of pixels at once?  Or the whole screen?  No need to do pixel by pixel, when you can do image by image.

Title: Re: Base 64 encoder / decoder
Post by: NOVARSEG on December 17, 2020, 10:00:41 pm

SMcNeill

Hi
In the previous example I'm processing 3 bytes at a time.

For longer strings say 21 bytes * 8 = 168 bits

base 64 encoding would require 28 characters

Putting the 21 bytes into 7 bit bytes would require  only 24 characters

So that is 14.2% smaller encoding for the 7 bit method.

***************
In a convertor that Dav posted the encoded data looks to be base 64. Here is a bit of code from his convertor.

   

Quote

A$ = A$ + "8d;ai7=B`OhkhbAWZm^?Fbe6f0W?h7feD]G466?ShkeZZW3K;QCaWihI9W;b"
    A$ = A$ + "m7>F^WijPf?n<[cniJbW=]JNo=`efa5IkHO:\:hK`cP[1WSWQlL;oH2edC1C"
    A$ = A$ + "RWe`X`^Ah<df0J?9fHHG>Uf:aCK9X=SfEH9oghnoIT6[dl==i<0]513JdFZF"
    A$ = A$ + "J[dL\g7hoVf;;GYSbeoo[Y#?aO#e;iaGn9YJgl`V>EKUKf^17RH4R69RI0a3"
    A$ = A$ + "H\V;AOG;C;FShWNlA?7?O^oJcanNNR=IRbe6ZEii?g0BFQ6TLg9jEnYO__Ul"
    A$ = A$ + "gn7mk:O_?ok;OQGlnb[Om;:_be?_l_jCoZbgi;nITk<aPfkdn?oI9;MJ?SaW"
    A$ = A$ + "Xo1n;K6coLUIm\CAVcDWZ\\i?OIQcIfR?;HnbbFlRlDlI9b9>jQTSOT38[Ni"
    A$ = A$ + ";FFa2V[\YE^2eN[E9Kc_EJfd6PZKJk:_Jo[OEbagF0VV2G<c;#]W>g4>Q5cK"
    A$ = A$ + "\IRo3Q]0Wa]=n<[CaC<g?VIK5U2lVS`XYiYm14eGQUh\KS2eOMjUH9n?1MGH"
    A$ = A$ + "38<#HB=DXfnH9I;iYJb8_3Yn1e=XnbPeGaTnN9Ge>WJb#]W9g<dg=EKLR?:k"
    A$ = A$ + "H;8fCJea:9aH\SSmAMdRC8JS=DJBaJJJZ;kd\j`lIHMiYf7Q=<dFNmh_jdRc"
    A$ = A$ + "N_7MED7ZV<CdhB`Thc`ZQiRo\QMbkEh?9>g3DGijcg`<o9ae0^XSS`faGC\M"

The encoded bytes range from ASC 48  "0"  to ASC 111 "o".  111 - 48  = 63 (64 characters). In that range, the comma and quotes are avoided.

However, the base 128 encoding packs in more data.

Title: Re: Base 64 encoder / decoder
Post by: SMcNeill on December 17, 2020, 10:13:41 pm

If you're curious, here's where Petr and I had a nice discussion over Base64 encoding/decoding: https://www.qb64.org/forum/index.php?topic=2017.msg112422#msg112422

Title: Re: Base 64 encoder / decoder
Post by: NOVARSEG on December 17, 2020, 11:06:14 pm

I just fixed major bugs in my code up top.  It works now.

I read the link you posted. 

 7 bytes = 8  (7 bit) bytes Ok I will try that.

Title: Re: Base 64 encoder / decoder
Post by: NOVARSEG on December 18, 2020, 01:01:25 am

Here is a  base 256 to base 128 encoder.
Does not decode yet.   Encodes 7 bytes at a time.

Code: QB64: [Select]

1.  'BASE 128 encoder
2.  
3. DIM b8, b7, b6, b5, b4, b3, b2, b1 AS INTEGER
4.  
5. DIM s8 AS STRING
6. DIM s7 AS STRING
7. DIM s6 AS STRING
8. DIM s5 AS STRING
9. DIM s4 AS STRING
10. DIM s3 AS STRING
11. DIM s2 AS STRING
12. DIM s1 AS STRING
13.  
14. DIM n AS INTEGER
15. DIM string1 AS STRING 'input string
16. DIM string2 AS STRING 'output string
17. '
18. string1 = "ASCII stands for American Standard Code for Information Interchange..."
19. PRINT LEN(string1) 'must be a multiple of 7
20.  
21. PRINT "STRING1 "; string1
22. PRINT
23.  
24. n = 45 'offset into ASCII table
25.  
26.  
27. FOR x% = 1 TO LEN(string1) STEP 7
28.     b7 = ASC(MID$(string1, x%, 1))
29.     b6 = ASC(MID$(string1, x% + 1, 1))
30.     b5 = ASC(MID$(string1, x% + 2, 1))
31.     b4 = ASC(MID$(string1, x% + 3, 1))
32.     b3 = ASC(MID$(string1, x% + 4, 1))
33.     b2 = ASC(MID$(string1, x% + 5, 1))
34.     b1 = ASC(MID$(string1, x% + 6, 1))
35.  
36.  
37.     IF b7 >= 128 THEN
38.         b8 = 64
39.         b7 = b7 - 128
40.     END IF
41.     s7 = CHR$(b7 + n)
42.  
43.     IF b6 >= 128 THEN
44.         b8 = b8 + 32
45.         b6 = b6 - 128
46.     END IF
47.     s6 = CHR$(b6 + n)
48.  
49.     IF b5 >= 128 THEN
50.         b8 = b8 + 16
51.         b5 = b5 - 128
52.     END IF
53.     s5 = CHR$(b5 + n)
54.  
55.     IF b4 >= 128 THEN
56.         b8 = b8 + 8
57.         b4 = b4 - 128
58.     END IF
59.     s4 = CHR$(b4 + n)
60.  
61.     IF b3 >= 128 THEN
62.         b8 = b8 + 4
63.         b3 = b3 - 128
64.     END IF
65.     s3 = CHR$(b3 + n)
66.  
67.     IF b2 >= 128 THEN
68.         b8 = b8 + 2
69.         b2 = b2 - 128
70.     END IF
71.     s2 = CHR$(b2 + n)
72.  
73.     IF b1 >= 128 THEN
74.         b8 = b8 + 1
75.         b1 = b1 - 128
76.     END IF
77.     s1 = CHR$(b1 + n)
78.  
79.     s8 = CHR$(b8+n)
80.    
81.     string2 = string2 + (s8 + s7 + s6 + s5 + s4 + s3 + s2 + s1)
82. NEXT x%
83.  
84.  
85. PRINT string2
86.  
87. END
88.  

Title: Re: Base 64 encoder / decoder
Post by: SpriggsySpriggs on December 18, 2020, 08:28:02 am

@NOVARSEG

My API collection has WinAPI code for encoding and decoding in Base 64. Feel free to check it out.

Title: Re: Base 64 encoder / decoder
Post by: SMcNeill on December 18, 2020, 09:53:50 am

Quote from: SpriggsySpriggs on December 18, 2020, 08:28:02 am

@NOVARSEG

My API collection has WinAPI code for encoding and decoding in Base 64. Feel free to check it out.

@SpriggsySpriggs -- I was looking at your encoder/decoder...  Are you certain you need to add a CHR$(0) to the code?

        encode = encode + CHR$(0)

This isn't a null-terminated C-function; you have to specify the length of the string for it to work properly.  As it is, you're adding characters to your conversion routines, as below:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. DIM encode AS STRING
4. PRINT "My name is Inigo Montoya", LEN("My name is Inigo Montoya")
5. encode = encodeBase64("My name is Inigo Montoya")
6.  
7. PRINT encode, LEN(encode)
8.  
9. DIM decode AS STRING
10. decode = decodeBase64(encode)
11.  
12. PRINT decode, LEN(decode)
13.  
14.  
15. $IF WIN THEN
16.     'DECLARE LIBRARY ".\pipecom"
17.     '    FUNCTION pipecom$ (cmd AS STRING)
18.     'END DECLARE
19.     'FUNCTION encodeBase64$ (encode AS STRING)
20.     '    DIM encoded AS STRING
21.     '    DIM encodefile AS INTEGER
22.     '    encodefile = FREEFILE
23.     '    OPEN "3nc0deb64" FOR OUTPUT AS #encodefile
24.     '    PRINT #encodefile, encode
25.     '    CLOSE #encodefile
26.     '    encoded = pipecom("certutil -encode 3nc0deb64 3nc0dedb64 && type 3nc0dedb64 && del 3nc0dedb64 && del 3nc0deb64")
27.     '    encoded = MID$(encoded, INSTR(encoded, "-----BEGIN CERTIFICATE-----") + LEN("-----BEGIN CERTIFICATE-----") + 1)
28.     '    encoded = MID$(encoded, 1, INSTR(encoded, "-----END CERTIFICATE-----") - 2)
29.     '    encodeBase64 = encoded
30.     'END FUNCTION
31.  
32.     'FUNCTION decodeBase64$ (decode AS STRING)
33.     '    DIM decoded AS STRING
34.     '    DIM decodefile AS INTEGER
35.     '    decodefile = FREEFILE
36.     '    OPEN "d3c0deb64" FOR OUTPUT AS #decodefile
37.     '    PRINT #decodefile, decode
38.     '    CLOSE #decodefile
39.     '    decoded = pipecom("certutil -decode d3c0deb64 d3c0dedb64 && type d3c0dedb64 && del d3c0deb64 && del d3c0dedb64")
40.     '    decoded = MID$(decoded, _INSTRREV(decoded, "successfully.") + 1 + LEN("successfully."))
41.     '    decoded = MID$(decoded, 1, LEN(decoded) - 1)
42.     '    decodeBase64 = decoded
43.     'END FUNCTION
44.  
45.     DECLARE DYNAMIC LIBRARY "Crypt32"
46.         FUNCTION CryptBinaryToString%% ALIAS CryptBinaryToStringA (BYVAL pbBinary AS _OFFSET, BYVAL cbBinary AS LONG, BYVAL dwFlags AS LONG, BYVAL pszString AS _OFFSET, BYVAL pcchString AS _OFFSET)
47.         FUNCTION CryptStringToBinary%% ALIAS CryptStringToBinaryA (BYVAL pszString AS _OFFSET, BYVAL cchString AS LONG, BYVAL dwFlags AS LONG, BYVAL pbBinary AS _OFFSET, BYVAL pcbBinary AS _OFFSET, BYVAL pdwSkip AS _OFFSET, BYVAL pdwFlags AS _OFFSET)
48.     END DECLARE
49.  
50.     FUNCTION encodeBase64$ (encode AS STRING)
51.         CONST CRYPT_STRING_NOCRLF = &H40000000
52.         CONST CRYPT_STRING_BASE64 = &H00000001
53.  
54.         DIM a AS _BYTE
55.         DIM lengthencode AS LONG
56.         DIM encoded AS STRING
57.         DIM lengthencoded AS LONG
58.  
59.         encode = encode + CHR$(0)
60.         lengthencode = LEN(encode)
61.  
62.         a = CryptBinaryToString(_OFFSET(encode), lengthencode, CRYPT_STRING_BASE64 OR CRYPT_STRING_NOCRLF, 0, _OFFSET(lengthencoded))
63.         'Calculate buffer length
64.         IF a <> 0 THEN
65.             encoded = SPACE$(lengthencoded)
66.         ELSE
67.             encodeBase64 = ""
68.             EXIT FUNCTION
69.         END IF
70.         a = CryptBinaryToString(_OFFSET(encode), lengthencode, CRYPT_STRING_BASE64 OR CRYPT_STRING_NOCRLF, _OFFSET(encoded), _OFFSET(lengthencoded))
71.         'Acual conversion
72.         IF a <> 0 THEN
73.             encodeBase64 = encoded
74.         ELSE
75.             encodeBase64 = ""
76.         END IF
77.     END FUNCTION
78.  
79.     FUNCTION decodeBase64$ (decode AS STRING)
80.         CONST CRYPT_STRING_BASE64_ANY = &H00000006
81.  
82.         DIM a AS _BYTE
83.         DIM lengthdecode AS LONG
84.         DIM decoded AS STRING
85.         DIM lengthdecoded AS LONG
86.  
87.         decode = decode + CHR$(0)
88.         lengthdecode = LEN(decode) - 1
89.         a = CryptStringToBinary(_OFFSET(decode), lengthdecode, CRYPT_STRING_BASE64_ANY, 0, _OFFSET(lengthdecoded), 0, 0)
90.         'Calculate buffer length
91.         IF a <> 0 THEN
92.             decoded = SPACE$(lengthdecoded)
93.         ELSE
94.             decodeBase64 = ""
95.             EXIT FUNCTION
96.         END IF
97.         a = CryptStringToBinary(_OFFSET(decode), lengthdecode, CRYPT_STRING_BASE64_ANY, _OFFSET(decoded), _OFFSET(lengthdecoded), 0, 0)
98.         'Actual conversion
99.         IF a <> 0 THEN
100.             decodeBase64 = decoded
101.         ELSE
102.             decodeBase64 = ""
103.         END IF
104.     END FUNCTION
105. $ELSE
106.     DECLARE LIBRARY "./pipecom"
107.     FUNCTION pipecom$ (cmd AS STRING)
108.     END DECLARE
109.  
110.     FUNCTION encodeBase64$ (encode AS STRING)
111.     DIM encoded AS STRING
112.     DIM encodefile AS INTEGER
113.     encodefile = FREEFILE
114.     OPEN "3nc0deb64" FOR OUTPUT AS #encodefile
115.     PRINT #encodefile, encode
116.     CLOSE #encodefile
117.     encoded = pipecom("base64 3nc0deb64")
118.     KILL "3nc0deb64"
119.     encodeBase64 = MID$(encoded, 1, LEN(encoded) - 1)
120.     END FUNCTION
121.  
122.     FUNCTION decodeBase64$ (decode AS STRING)
123.     DIM decoded AS STRING
124.     DIM decodefile AS INTEGER
125.     decodefile = FREEFILE
126.     OPEN "d3c0deb64" FOR OUTPUT AS #decodefile
127.     PRINT #decodefile, decode
128.     CLOSE #decodefile
129.     decoded = pipecom("base64 -d d3c0deb64")
130.     KILL "d3c0deb64"
131.     decodeBase64 = decoded
132.     END FUNCTION
133. $END IF

If you notice, you've tacked a stray CHR$(0) onto the end of the decoded results. 

Title: Re: Base 64 encoder / decoder
Post by: SpriggsySpriggs on December 18, 2020, 09:58:07 am

@SMcNeill

https://docs.microsoft.com/en-us/windows/win32/api/wincrypt/nf-wincrypt-cryptstringtobinarya (https://docs.microsoft.com/en-us/windows/win32/api/wincrypt/nf-wincrypt-cryptstringtobinarya)

What I should have done instead is make the length argument be zero or just not do a CHR$(0). I think there might have been issues and that's why I did that but feel free to comment that one line out.

Title: Re: Base 64 encoder / decoder
Post by: SpriggsySpriggs on December 18, 2020, 10:04:36 am

@SMcNeill

Yeah, I just got used to having to do null-terminated strings. I'll fix the code in the zip folder momentarily.

  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. $CONSOLE:ONLY
3. _DEST _CONSOLE
4. 'DIM encode AS STRING
5. 'encode = encodeBase64("My name is Inigo Montoya")
6. DIM encoded AS STRING
7. 'PRINT encode
8. DO
9.     LINE INPUT "Input Base64 String: ", encoded
10. LOOP UNTIL encoded <> ""
11. DIM decode AS STRING
12. decode = decodeBase64(encoded)
13.  
14. PRINT decode
15. SLEEP
16.  
17. $IF WIN THEN
18.     'DECLARE LIBRARY ".\pipecom"
19.     '    FUNCTION pipecom$ (cmd AS STRING)
20.     'END DECLARE
21.     'FUNCTION encodeBase64$ (encode AS STRING)
22.     '    DIM encoded AS STRING
23.     '    DIM encodefile AS INTEGER
24.     '    encodefile = FREEFILE
25.     '    OPEN "3nc0deb64" FOR OUTPUT AS #encodefile
26.     '    PRINT #encodefile, encode
27.     '    CLOSE #encodefile
28.     '    encoded = pipecom("certutil -encode 3nc0deb64 3nc0dedb64 && type 3nc0dedb64 && del 3nc0dedb64 && del 3nc0deb64")
29.     '    encoded = MID$(encoded, INSTR(encoded, "-----BEGIN CERTIFICATE-----") + LEN("-----BEGIN CERTIFICATE-----") + 1)
30.     '    encoded = MID$(encoded, 1, INSTR(encoded, "-----END CERTIFICATE-----") - 2)
31.     '    encodeBase64 = encoded
32.     'END FUNCTION
33.  
34.     'FUNCTION decodeBase64$ (decode AS STRING)
35.     '    DIM decoded AS STRING
36.     '    DIM decodefile AS INTEGER
37.     '    decodefile = FREEFILE
38.     '    OPEN "d3c0deb64" FOR OUTPUT AS #decodefile
39.     '    PRINT #decodefile, decode
40.     '    CLOSE #decodefile
41.     '    decoded = pipecom("certutil -decode d3c0deb64 d3c0dedb64 && type d3c0dedb64 && del d3c0deb64 && del d3c0dedb64")
42.     '    decoded = MID$(decoded, _INSTRREV(decoded, "successfully.") + 1 + LEN("successfully."))
43.     '    decoded = MID$(decoded, 1, LEN(decoded) - 1)
44.     '    decodeBase64 = decoded
45.     'END FUNCTION
46.  
47.     DECLARE DYNAMIC LIBRARY "Crypt32"
48.         FUNCTION CryptBinaryToString%% ALIAS CryptBinaryToStringA (BYVAL pbBinary AS _OFFSET, BYVAL cbBinary AS LONG, BYVAL dwFlags AS LONG, BYVAL pszString AS _OFFSET, BYVAL pcchString AS _OFFSET)
49.         FUNCTION CryptStringToBinary%% ALIAS CryptStringToBinaryA (BYVAL pszString AS _OFFSET, BYVAL cchString AS LONG, BYVAL dwFlags AS LONG, BYVAL pbBinary AS _OFFSET, BYVAL pcbBinary AS _OFFSET, BYVAL pdwSkip AS _OFFSET, BYVAL pdwFlags AS _OFFSET)
50.     END DECLARE
51.  
52.     FUNCTION encodeBase64$ (encode AS STRING)
53.         CONST CRYPT_STRING_NOCRLF = &H40000000
54.         CONST CRYPT_STRING_BASE64 = &H00000001
55.  
56.         DIM a AS _BYTE
57.         DIM lengthencode AS LONG
58.         DIM encoded AS STRING
59.         DIM lengthencoded AS LONG
60.  
61.         lengthencode = LEN(encode)
62.  
63.         a = CryptBinaryToString(_OFFSET(encode), lengthencode, CRYPT_STRING_BASE64 OR CRYPT_STRING_NOCRLF, 0, _OFFSET(lengthencoded))
64.         'Calculate buffer length
65.         IF a <> 0 THEN
66.             encoded = SPACE$(lengthencoded)
67.         ELSE
68.             encodeBase64 = ""
69.             EXIT FUNCTION
70.         END IF
71.         a = CryptBinaryToString(_OFFSET(encode), lengthencode, CRYPT_STRING_BASE64 OR CRYPT_STRING_NOCRLF, _OFFSET(encoded), _OFFSET(lengthencoded))
72.         'Acual conversion
73.         IF a <> 0 THEN
74.             encodeBase64 = encoded
75.         ELSE
76.             encodeBase64 = ""
77.         END IF
78.     END FUNCTION
79.  
80.     FUNCTION decodeBase64$ (decode AS STRING)
81.         CONST CRYPT_STRING_BASE64_ANY = &H00000006
82.  
83.         DIM a AS _BYTE
84.         DIM lengthdecode AS LONG
85.         DIM decoded AS STRING
86.         DIM lengthdecoded AS LONG
87.  
88.         lengthdecode = LEN(decode)
89.         a = CryptStringToBinary(_OFFSET(decode), lengthdecode, CRYPT_STRING_BASE64_ANY, 0, _OFFSET(lengthdecoded), 0, 0)
90.         'Calculate buffer length
91.         IF a <> 0 THEN
92.             decoded = SPACE$(lengthdecoded)
93.         ELSE
94.             decodeBase64 = ""
95.             EXIT FUNCTION
96.         END IF
97.         a = CryptStringToBinary(_OFFSET(decode), lengthdecode, CRYPT_STRING_BASE64_ANY, _OFFSET(decoded), _OFFSET(lengthdecoded), 0, 0)
98.         'Actual conversion
99.         IF a <> 0 THEN
100.             decodeBase64 = decoded
101.         ELSE
102.             decodeBase64 = ""
103.         END IF
104.     END FUNCTION
105. $ELSE
106.     DECLARE LIBRARY "./pipecom"
107.     FUNCTION pipecom$ (cmd AS STRING)
108.     END DECLARE
109.  
110.     FUNCTION encodeBase64$ (encode AS STRING)
111.     DIM encoded AS STRING
112.     DIM encodefile AS INTEGER
113.     encodefile = FREEFILE
114.     OPEN "3nc0deb64" FOR OUTPUT AS #encodefile
115.     PRINT #encodefile, encode
116.     CLOSE #encodefile
117.     encoded = pipecom("base64 3nc0deb64")
118.     KILL "3nc0deb64"
119.     encodeBase64 = MID$(encoded, 1, LEN(encoded) - 1)
120.     END FUNCTION
121.  
122.     FUNCTION decodeBase64$ (decode AS STRING)
123.     DIM decoded AS STRING
124.     DIM decodefile AS INTEGER
125.     decodefile = FREEFILE
126.     OPEN "d3c0deb64" FOR OUTPUT AS #decodefile
127.     PRINT #decodefile, decode
128.     CLOSE #decodefile
129.     decoded = pipecom("base64 -d d3c0deb64")
130.     KILL "d3c0deb64"
131.     decodeBase64 = decoded
132.     END FUNCTION
133. $END IF

Title: Re: Base 64 encoder / decoder
Post by: SMcNeill on December 18, 2020, 10:13:36 am

One more pointer, which might be of interest to you:  When passing pointers, you can just declare it without BYVAL.

Instead of:
  FUNCTION CryptBinaryToString%% ALIAS CryptBinaryToStringA (BYVAL pbBinary AS _OFFSET....

You can go with:
  FUNCTION CryptBinaryToString%% ALIAS CryptBinaryToStringA (pbBinary AS STRING....

Then when you call the function, instead of this:
a = CryptBinaryToString(_OFFSET(encode)....

It'd be:
a = CryptBinaryToString(encode....

---

It might be a trick to help simplify your libraries a bit, and cut down on some typing for you.  (Not just on strings, but all cases where pointers to something is required, rather than the actual data value itself.)

Not that what you're doing is wrong; I just thought you might not realize WHY that BYVAL is there, and what we do when it's not.  ;)

With BYVAL, we pass the value.
Without it, we pass the offset to whatever.

Title: Re: Base 64 encoder / decoder
Post by: SpriggsySpriggs on December 18, 2020, 10:21:31 am

@SMcNeill

Yeah, I know I can. I typically pass _OFFSETs unless it is more convenient for myself to just pass it as text rather than a variable (usually it isn't, due to the number of arguments, so I just write a wrapper that does all that B.S.). So instead of foo(_OFFSET(stringvalue$)) I would just do foo("this is my string"). I try to stay consistent with my code. Since I've done almost all of my code using _OFFSET rather than passing the string itself I just go ahead and keep using _OFFSETs unless absolutely necessary. I don't mind the extra typing. I passed this variable as a string for this particular function (different topic) because it didn't require a null character at the end and would be too much work for a 3 character string.

Code: QB64: [Select]

1. GetDiskFreeSpace("L:\", 0, 0, _OFFSET(totalFreeBytesOnDisk))

But yeah, I typically don't pass a string to a function without _OFFSET unless I pass it as plain text.

Title: Re: Base 64 encoder / decoder
Post by: Dav on December 18, 2020, 10:25:35 am

This thread has re-sparked my interest in binary to text encoders.  Always looking for something better than base64 to output code safe to post on forums.  Has anyone tried to implement base91 before? 

Edit: Nevermind-- looks like base91 is patented (https://patents.google.com/patent/US20030152220A1/en).

- Dav

Title: Re: Base 64 encoder / decoder
Post by: SMcNeill on December 18, 2020, 10:33:45 am

@Dav

You posted an encoding routine which you use, a while back, which:

Quote

The encoded bytes range from ASC 48  "0"  to ASC 111 "o".  111 - 48  = 63 (64 characters). In that range, the comma and quotes are avoided.

I had a similar method going for my stuff, but then I ran into an issue, which might affect your encoder as well:

58 is ":", which in QB64 is a command separator.

My solution was simply to change my code so that it started at 59 instead, and thus that problem is forever avoided and I don't have to enclose the output in quotes if I want to use it for something like DATA statements.  ;)

Title: Re: Base 64 encoder / decoder
Post by: Dav on December 18, 2020, 10:40:04 am

Thanks for the tip, @SMcNeill.  Yes, I would need to change that if my output wasn't in quotes.  One problem I did have to fix in my last few encoders here was using the @ symbol.  That was interfering with posted code because of the forums way of using @ to note members, so I had to swap it out with an unused character.

Edit: Thread about the @ problem here (https://www.qb64.org/forum/index.php?topic=2589.0).

- Dav

Title: Re: Base 64 encoder / decoder
Post by: SpriggsySpriggs on December 18, 2020, 11:54:06 am

Quote from: Dav on December 18, 2020, 10:40:04 am

One problem I did have to fix in my last few encoders here was using the @ symbol.  That was interfering with posted code because of the forums way of using @ to note members, so I had to swap it out with an unused character.

@Dav

I remember that! It feels like such a long time ago. Your code revolutionized includes for me.

By the way, how did you hide the URL and show just "here"? I haven't figured out how to do that. Never mind. Figured out how to do that (https://wiki.simplemachines.org/smf/Url)

Title: Re: Base 64 encoder / decoder
Post by: bplus on December 18, 2020, 12:31:33 pm

I found we were on this very same subject last year! Petr and AndyA were doing things.

I am wondering if all this data packing slows program loads?

Title: Re: Base 64 encoder / decoder
Post by: Petr on December 18, 2020, 01:05:07 pm

Quote

I am wondering if all this data packing slows program loads?

My version slows down, AndyA's version practically not at all. This is the difference between using the logical AND operator (AndyA version) and / or strings (my version).

Title: Re: Base 64 encoder / decoder
Post by: Dav on December 18, 2020, 01:19:13 pm

I haven't tested mine for speed, but I imagine it's slow as molasses. Not familiar with AndyA's version (I didn't hang around here too much last year) but I'll search for it.   Maybe these encoding schemes would make a good test in a benchmark program!

- Dav

Title: Re: Base 64 encoder / decoder
Post by: NOVARSEG on December 18, 2020, 04:43:02 pm

Here is base 256 to base 128 encoder / decoder


detected bug . . . .fixed

Code: QB64: [Select]

1. 'BASE 128 encoder  / decoder
2. 'input string is encoded then decoded
3.  
4. DIM b8, b7, b6, b5, b4, b3, b2, b1 AS INTEGER
5. DIM s8 AS STRING
6. DIM s7 AS STRING
7. DIM s6 AS STRING
8. DIM s5 AS STRING
9. DIM s4 AS STRING
10. DIM s3 AS STRING
11. DIM s2 AS STRING
12. DIM s1 AS STRING
13. DIM n AS INTEGER
14. DIM string1 AS STRING 'input string
15. DIM string2 AS STRING 'output string
16. _FULLSCREEN
17. string1 = "ASCII stands for American Standard Code for Information Interchange..." + CHR$(166) + CHR$(167) + CHR$(168) + CHR$(169) + CHR$(170) + CHR$(171) + CHR$(172)
18. 'string1 = "ASCII stands for American Standard Code for Information Interchange..."
19.  
20. 'string1 must be a multiple of 7 bytes
21.  
22. PRINT "string1"
23. PRINT string1
24. PRINT
25. PRINT
26. n = 45 'offset into ASCII table
27.  
28. 'Encode
29. FOR x% = 1 TO LEN(string1) STEP 7
30.     b7 = ASC(MID$(string1, x%, 1))
31.     b6 = ASC(MID$(string1, x% + 1, 1))
32.     b5 = ASC(MID$(string1, x% + 2, 1))
33.     b4 = ASC(MID$(string1, x% + 3, 1))
34.     b3 = ASC(MID$(string1, x% + 4, 1))
35.     b2 = ASC(MID$(string1, x% + 5, 1))
36.     b1 = ASC(MID$(string1, x% + 6, 1))
37.  
38.     IF b7 >= 128 THEN
39.         b7 = b7 - 128
40.         b8 = 64
41.     END IF
42.     s7 = CHR$(b7 + n)
43.  
44.     IF b6 >= 128 THEN
45.         b6 = b6 - 128
46.         b8 = b8 + 32
47.     END IF
48.     s6 = CHR$(b6 + n)
49.  
50.     IF b5 >= 128 THEN
51.         b5 = b5 - 128
52.         b8 = b8 + 16
53.     END IF
54.     s5 = CHR$(b5 + n)
55.  
56.     IF b4 >= 128 THEN
57.         b4 = b4 - 128
58.         b8 = b8 + 8
59.     END IF
60.     s4 = CHR$(b4 + n)
61.  
62.     IF b3 >= 128 THEN
63.         b3 = b3 - 128
64.         b8 = b8 + 4
65.     END IF
66.     s3 = CHR$(b3 + n)
67.  
68.     IF b2 >= 128 THEN
69.         b2 = b2 - 128
70.         b8 = b8 + 2
71.     END IF
72.     s2 = CHR$(b2 + n)
73.  
74.     IF b1 >= 128 THEN
75.         b1 = b1 - 128
76.         b8 = b8 + 1
77.     END IF
78.     s1 = CHR$(b1 + n)
79.  
80.     s8 = CHR$(b8 + n)
81.  
82.     string2 = string2 + (s8 + s7 + s6 + s5 + s4 + s3 + s2 + s1)
83.  
84. NEXT x%
85.  
86. string1 = ""
87.  
88. PRINT "string1 encoded"
89. PRINT string2
90. PRINT
91. PRINT
92.  
93.  
94. 'Decode
95. FOR x% = 1 TO LEN(string2) STEP 8
96.  
97.     b8 = ASC(MID$(string2, x%, 1)) - n
98.     b7 = ASC(MID$(string2, x% + 1, 1)) - n
99.     b6 = ASC(MID$(string2, x% + 2, 1)) - n
100.     b5 = ASC(MID$(string2, x% + 3, 1)) - n
101.     b4 = ASC(MID$(string2, x% + 4, 1)) - n
102.     b3 = ASC(MID$(string2, x% + 5, 1)) - n
103.     b2 = ASC(MID$(string2, x% + 6, 1)) - n
104.     b1 = ASC(MID$(string2, x% + 7, 1)) - n
105.  
106.     IF b8 >= 64 THEN
107.         b8 = b8 - 64
108.         b7 = b7 + 128
109.     END IF
110.     s7 = CHR$(b7)
111.  
112.     IF b8 >= 32 THEN
113.         b8 = b8 - 32
114.         b6 = b6 + 128
115.     END IF
116.     s6 = CHR$(b6)
117.  
118.     IF b8 >= 16 THEN
119.         b8 = b8 - 16
120.         b5 = b5 + 128
121.     END IF
122.     s5 = CHR$(b5)
123.  
124.     IF b8 >= 8 THEN
125.         b8 = b8 - 8
126.         b4 = b4 + 128
127.     END IF
128.     s4 = CHR$(b4)
129.  
130.     IF b8 >= 4 THEN
131.         b8 = b8 - 4
132.         b3 = b3 + 128
133.     END IF
134.     s3 = CHR$(b3)
135.  
136.     IF b8 >= 2 THEN
137.         b8 = b8 - 2
138.         b2 = b2 + 128
139.     END IF
140.     s2 = CHR$(b2)
141.  
142.     IF b8 >= 1 THEN
143.         b8 = b8 - 1
144.         b1 = b1 + 128
145.     END IF
146.     s1 = CHR$(b1)
147.  
148.     string1 = string1 + (s7 + s6 + s5 + s4 + s3 + s2 + s1)
149.  
150.  
151. NEXT x%
152.  
153. PRINT "decoded"
154. "
155. PRINT string1
156. PRINT
157. PRINT
158.  
159. END
160.  

Title: Re: Base 64 encoder / decoder
Post by: bplus on December 18, 2020, 06:47:51 pm

Quote

FOR x% = 1 TO LEN(string1) STEP 7
    b7 = ASC(MID$(string1, x%, 1))
    b6 = ASC(MID$(string1, x% + 1, 1))
    b5 = ASC(MID$(string1, x% + 2, 1))
    b4 = ASC(MID$(string1, x% + 3, 1))
    b3 = ASC(MID$(string1, x% + 4, 1))
    b2 = ASC(MID$(string1, x% + 5, 1))
    b1 = ASC(MID$(string1, x% + 6, 1))

Oh I think I see the error...

Anyway here is a tip:

Code: QB64: [Select]

1. s$ = "string"
2. FOR i = 1 TO LEN(s$)
3.     PRINT ASC(s$, i); "  =  "; ASC(MID$(s$, i, 1)) '   <<<<<<<<<<<<< tip
4. NEXT

Title: Re: Base 64 encoder / decoder
Post by: NOVARSEG on December 18, 2020, 07:35:59 pm

Thanks bplus

code updated

Code: QB64: [Select]

1. 'BASE 128 encoder  / decoder
2. 'input string is encoded then decoded
3.  
4. DIM b8, b7, b6, b5, b4, b3, b2, b1 AS INTEGER
5. DIM s8 AS STRING
6. DIM s7 AS STRING
7. DIM s6 AS STRING
8. DIM s5 AS STRING
9. DIM s4 AS STRING
10. DIM s3 AS STRING
11. DIM s2 AS STRING
12. DIM s1 AS STRING
13. DIM n AS INTEGER
14. DIM string1 AS STRING 'input string
15. DIM string2 AS STRING 'output string
16. _FULLSCREEN
17. string1 = "ASCII stands for American Standard Code for Information Interchange..." + CHR$(166) + CHR$(167) + CHR$(168) + CHR$(169) + CHR$(170) + CHR$(171) + CHR$(172)
18. 'string1 = "ASCII stands for American Standard Code for Information Interchange..."
19.  
20. 'string1 must be a multiple of 7 bytes
21.  
22. PRINT "string1"
23. PRINT string1
24. PRINT
25. PRINT
26. n = 45 'offset into ASCII table
27.  
28. 'Encode
29. FOR x% = 1 TO LEN(string1) STEP 7
30.  
31.     b7 = ASC(string1, x%)
32.     b6 = ASC(string1, x% + 1)
33.     b5 = ASC(string1, x% + 2)
34.     b4 = ASC(string1, x% + 3)
35.     b3 = ASC(string1, x% + 4)
36.     b2 = ASC(string1, x% + 5)
37.     b1 = ASC(string1, x% + 6)
38.  
39.     IF b7 >= 128 THEN
40.         b7 = b7 - 128
41.         b8 = 64
42.     END IF
43.     s7 = CHR$(b7 + n)
44.  
45.     IF b6 >= 128 THEN
46.         b6 = b6 - 128
47.         b8 = b8 + 32
48.     END IF
49.     s6 = CHR$(b6 + n)
50.  
51.     IF b5 >= 128 THEN
52.         b5 = b5 - 128
53.         b8 = b8 + 16
54.     END IF
55.     s5 = CHR$(b5 + n)
56.  
57.     IF b4 >= 128 THEN
58.         b4 = b4 - 128
59.         b8 = b8 + 8
60.     END IF
61.     s4 = CHR$(b4 + n)
62.  
63.     IF b3 >= 128 THEN
64.         b3 = b3 - 128
65.         b8 = b8 + 4
66.     END IF
67.     s3 = CHR$(b3 + n)
68.  
69.     IF b2 >= 128 THEN
70.         b2 = b2 - 128
71.         b8 = b8 + 2
72.     END IF
73.     s2 = CHR$(b2 + n)
74.  
75.     IF b1 >= 128 THEN
76.         b1 = b1 - 128
77.         b8 = b8 + 1
78.     END IF
79.     s1 = CHR$(b1 + n)
80.  
81.     s8 = CHR$(b8 + n)
82.  
83.     string2 = string2 + (s8 + s7 + s6 + s5 + s4 + s3 + s2 + s1)
84.  
85. NEXT x%
86.  
87. string1 = ""
88.  
89. PRINT "string1 encoded"
90. PRINT string2
91. PRINT
92. PRINT
93.  
94.  
95. 'Decode
96. FOR x% = 1 TO LEN(string2) STEP 8
97.  
98.     b8 = ASC(string2, x%) - n
99.     b7 = ASC(string2, x% + 1) - n
100.     b6 = ASC(string2, x% + 2) - n
101.     b5 = ASC(string2, x% + 3) - n
102.     b4 = ASC(string2, x% + 4) - n
103.     b3 = ASC(string2, x% + 5) - n
104.     b2 = ASC(string2, x% + 6) - n
105.     b1 = ASC(string2, x% + 7) - n
106.  
107.     IF b8 >= 64 THEN
108.         b8 = b8 - 64
109.         b7 = b7 + 128
110.     END IF
111.     s7 = CHR$(b7)
112.  
113.     IF b8 >= 32 THEN
114.         b8 = b8 - 32
115.         b6 = b6 + 128
116.     END IF
117.     s6 = CHR$(b6)
118.  
119.     IF b8 >= 16 THEN
120.         b8 = b8 - 16
121.         b5 = b5 + 128
122.     END IF
123.     s5 = CHR$(b5)
124.  
125.     IF b8 >= 8 THEN
126.         b8 = b8 - 8
127.         b4 = b4 + 128
128.     END IF
129.     s4 = CHR$(b4)
130.  
131.     IF b8 >= 4 THEN
132.         b8 = b8 - 4
133.         b3 = b3 + 128
134.     END IF
135.     s3 = CHR$(b3)
136.  
137.     IF b8 >= 2 THEN
138.         b8 = b8 - 2
139.         b2 = b2 + 128
140.     END IF
141.     s2 = CHR$(b2)
142.  
143.     IF b8 >= 1 THEN
144.         b8 = b8 - 1
145.         b1 = b1 + 128
146.     END IF
147.     s1 = CHR$(b1)
148.  
149.     string1 = string1 + (s7 + s6 + s5 + s4 + s3 + s2 + s1)
150.  
151.  
152. NEXT x%
153.  
154. PRINT "decoded"
155. PRINT string1
156. PRINT
157. PRINT
158.  
159. END
160.  

Title: Re: Base 64 encoder / decoder
Post by: SMcNeill on December 18, 2020, 08:13:31 pm

One note:

DIM b8, b7, b6, b5, b4, b3, b2, b1 AS INTEGER

You do realize only b1 is an INTEGER?  The other b's are SINGLE.

Title: Re: Base 64 encoder / decoder
Post by: NOVARSEG on December 18, 2020, 09:57:47 pm

Thanks SMcNeill
It's amazing it still worked!

Updated

Code: QB64: [Select]

1. 'BASE 128 encoder  / decoder
2. 'input string is encoded then decoded
3.  
4. DIM b8 AS INTEGER
5. DIM b7 AS INTEGER
6. DIM b6 AS INTEGER
7. DIM b5 AS INTEGER
8. DIM b4 AS INTEGER
9. DIM b3 AS INTEGER
10. DIM b2 AS INTEGER
11. DIM b1 AS INTEGER
12.  
13. DIM s8 AS STRING
14. DIM s7 AS STRING
15. DIM s6 AS STRING
16. DIM s5 AS STRING
17. DIM s4 AS STRING
18. DIM s3 AS STRING
19. DIM s2 AS STRING
20. DIM s1 AS STRING
21. DIM n AS INTEGER
22. DIM string1 AS STRING 'input string
23. DIM string2 AS STRING 'output string
24. _FULLSCREEN
25. string1 = "ASCII stands for American Standard Code for Information Interchange..." + CHR$(166) + CHR$(1) + CHR$(168) + CHR$(169) + CHR$(170) + CHR$(171) + CHR$(172)
26. 'string1 = "ASCII stands for American Standard Code for Information Interchange..."
27.  
28. 'string1 must be a multiple of 7 bytes
29.  
30. PRINT "string1"
31. PRINT string1
32. PRINT
33. PRINT
34. n = 65 'offset into ASCII table  starts at asc 65 "A"  to  asc 192
35. 'no quotes, comma, :, @
36.  
37. 'Encode
38. FOR x% = 1 TO LEN(string1) STEP 7
39.  
40.     b7 = ASC(string1, x%)
41.     b6 = ASC(string1, x% + 1)
42.     b5 = ASC(string1, x% + 2)
43.     b4 = ASC(string1, x% + 3)
44.     b3 = ASC(string1, x% + 4)
45.     b2 = ASC(string1, x% + 5)
46.     b1 = ASC(string1, x% + 6)
47.  
48.     IF b7 >= 128 THEN
49.         b7 = b7 - 128
50.         b8 = 64
51.     END IF
52.     s7 = CHR$(b7 + n)
53.  
54.     IF b6 >= 128 THEN
55.         b6 = b6 - 128
56.         b8 = b8 + 32
57.     END IF
58.     s6 = CHR$(b6 + n)
59.  
60.     IF b5 >= 128 THEN
61.         b5 = b5 - 128
62.         b8 = b8 + 16
63.     END IF
64.     s5 = CHR$(b5 + n)
65.  
66.     IF b4 >= 128 THEN
67.         b4 = b4 - 128
68.         b8 = b8 + 8
69.     END IF
70.     s4 = CHR$(b4 + n)
71.  
72.     IF b3 >= 128 THEN
73.         b3 = b3 - 128
74.         b8 = b8 + 4
75.     END IF
76.     s3 = CHR$(b3 + n)
77.  
78.     IF b2 >= 128 THEN
79.         b2 = b2 - 128
80.         b8 = b8 + 2
81.     END IF
82.     s2 = CHR$(b2 + n)
83.  
84.     IF b1 >= 128 THEN
85.         b1 = b1 - 128
86.         b8 = b8 + 1
87.     END IF
88.     s1 = CHR$(b1 + n)
89.  
90.     s8 = CHR$(b8 + n)
91.  
92.     string2 = string2 + (s8 + s7 + s6 + s5 + s4 + s3 + s2 + s1)
93.  
94. NEXT x%
95.  
96. string1 = ""
97.  
98. PRINT "string1 encoded"
99. PRINT string2
100. PRINT
101. PRINT
102.  
103.  
104. 'Decode
105. FOR x% = 1 TO LEN(string2) STEP 8
106.  
107.     b8 = ASC(string2, x%) - n
108.     b7 = ASC(string2, x% + 1) - n
109.     b6 = ASC(string2, x% + 2) - n
110.     b5 = ASC(string2, x% + 3) - n
111.     b4 = ASC(string2, x% + 4) - n
112.     b3 = ASC(string2, x% + 5) - n
113.     b2 = ASC(string2, x% + 6) - n
114.     b1 = ASC(string2, x% + 7) - n
115.  
116.     IF b8 >= 64 THEN
117.         b8 = b8 - 64
118.         b7 = b7 + 128
119.     END IF
120.     s7 = CHR$(b7)
121.  
122.     IF b8 >= 32 THEN
123.         b8 = b8 - 32
124.         b6 = b6 + 128
125.     END IF
126.     s6 = CHR$(b6)
127.  
128.     IF b8 >= 16 THEN
129.         b8 = b8 - 16
130.         b5 = b5 + 128
131.     END IF
132.     s5 = CHR$(b5)
133.  
134.     IF b8 >= 8 THEN
135.         b8 = b8 - 8
136.         b4 = b4 + 128
137.     END IF
138.     s4 = CHR$(b4)
139.  
140.     IF b8 >= 4 THEN
141.         b8 = b8 - 4
142.         b3 = b3 + 128
143.     END IF
144.     s3 = CHR$(b3)
145.  
146.     IF b8 >= 2 THEN
147.         b8 = b8 - 2
148.         b2 = b2 + 128
149.     END IF
150.     s2 = CHR$(b2)
151.  
152.     IF b8 >= 1 THEN
153.         b8 = b8 - 1
154.         b1 = b1 + 128
155.     END IF
156.     s1 = CHR$(b1)
157.  
158.     string1 = string1 + (s7 + s6 + s5 + s4 + s3 + s2 + s1)
159.  
160.  
161. NEXT x%
162.  
163. PRINT "decoded"
164. PRINT string1
165. PRINT
166. PRINT
167.  
168. END
169.  

Title: Re: Base 64 encoder / decoder
Post by: Petr on December 19, 2020, 03:12:49 am

@Dav: Here is it: https://www.qb64.org/forum/index.php?topic=2041.0

Title: Re: Base 64 encoder / decoder
Post by: Dav on December 19, 2020, 07:45:39 am

Quote from: Petr on December 19, 2020, 03:12:49 am

@Dav: Here is it: https://www.qb64.org/forum/index.php?topic=2041.0

Thank you @Petr!

- Dav

Title: Re: Base 64 encoder / decoder
Post by: NOVARSEG on December 19, 2020, 10:11:41 pm

Base 256 to base 128 decoder using _SHR , _SHL,  AND

There are no conditional statements or loops other than one FOR NEXT which is need to process either 7 or 8 bytes at a time

How it works.  7 bytes are encoded at a time.  The MSB of the 7 input bytes form an 8th byte.

Decoding left shifts the 8th byte to obtain the MSB which is  added to the original byte.
Code should run pretty fast.

Code: QB64: [Select]

1. 'BASE 128 encoder  / decoder   using _SHR , _SHL,  AND
2. 'input string is encoded then decoded
3.  
4. DIM b8 AS INTEGER
5. DIM b7 AS INTEGER
6. DIM b6 AS INTEGER
7. DIM b5 AS INTEGER
8. DIM b4 AS INTEGER
9. DIM b3 AS INTEGER
10. DIM b2 AS INTEGER
11. DIM b1 AS INTEGER
12.  
13. DIM n AS INTEGER
14. DIM string1 AS STRING
15. DIM string2 AS STRING
16.  
17. _FULLSCREEN
18. string1 = "ASCII stands for American Standard Code for Information Interchange..." + CHR$(127) + CHR$(128) + CHR$(129) + CHR$(130) + CHR$(1) + CHR$(2) + CHR$(1)
19.  
20.  
21. 'string1 must be a multiple of 7 bytes
22.  
23. PRINT "string1"
24. PRINT string1
25. PRINT
26. PRINT
27.  
28. n = 65 'offset into ASCII table  starts at asc 65 "A"  to  asc 192
29. 'no quotes, comma, :, @
30.  
31. 'Encode
32. FOR x% = 1 TO LEN(string1) STEP 7
33.  
34.     b7 = ASC(string1, x%)
35.     b6 = ASC(string1, x% + 1)
36.     b5 = ASC(string1, x% + 2)
37.     b4 = ASC(string1, x% + 3)
38.     b3 = ASC(string1, x% + 4)
39.     b2 = ASC(string1, x% + 5)
40.     b1 = ASC(string1, x% + 6)
41.  
42.  
43.     b8 = (128 AND b7) + b8
44.     b8 = _SHR(b8, 1)
45.     b7 = (b7 AND 127) + n
46.  
47.     b8 = (128 AND b6) + b8
48.     b8 = _SHR(b8, 1)
49.     b6 = (b6 AND 127) + n
50.  
51.     b8 = (128 AND b5) + b8
52.     b8 = _SHR(b8, 1)
53.     b5 = (b5 AND 127) + n
54.  
55.     b8 = (128 AND b4) + b8
56.     b8 = _SHR(b8, 1)
57.     b4 = (b4 AND 127) + n
58.  
59.     b8 = (128 AND b3) + b8
60.     b8 = _SHR(b8, 1)
61.     b3 = (b3 AND 127) + n
62.  
63.     b8 = (128 AND b2) + b8
64.     b8 = _SHR(b8, 1)
65.     b2 = (b2 AND 127) + n
66.  
67.     b8 = (128 AND b1) + b8
68.     b8 = _SHR(b8, 1)
69.     b1 = (b1 AND 127) + n
70.  
71.     b8 = b8 + n
72.  
73.  
74.     string2 = string2 + (CHR$(b8) + CHR$(b7) + CHR$(b6) + CHR$(b5) + CHR$(b4) + CHR$(b3) + CHR$(b2) + CHR$(b1))
75.  
76.  
77. NEXT x%
78.  
79. string1 = ""
80.  
81. PRINT "string1 encoded"
82. PRINT string2
83. PRINT
84. PRINT
85.  
86.  
87. 'Decode
88. FOR x% = 1 TO LEN(string2) STEP 8
89.  
90.     b8 = ASC(string2, x%) - n
91.     b7 = ASC(string2, x% + 1) - n
92.     b6 = ASC(string2, x% + 2) - n
93.     b5 = ASC(string2, x% + 3) - n
94.     b4 = ASC(string2, x% + 4) - n
95.     b3 = ASC(string2, x% + 5) - n
96.     b2 = ASC(string2, x% + 6) - n
97.     b1 = ASC(string2, x% + 7) - n
98.  
99.  
100.     b8 = _SHL(b8, 1)
101.     b1 = (128 AND b8) + b1
102.  
103.     b8 = _SHL(b8, 1)
104.     b2 = (128 AND b8) + b2
105.  
106.     b8 = _SHL(b8, 1)
107.     b3 = (128 AND b8) + b3
108.  
109.     b8 = _SHL(b8, 1)
110.     b4 = (128 AND b8) + b4
111.  
112.     b8 = _SHL(b8, 1)
113.     b5 = (128 AND b8) + b5
114.  
115.     b8 = _SHL(b8, 1)
116.     b6 = (128 AND b8) + b6
117.  
118.     b8 = _SHL(b8, 1)
119.     b7 = (128 AND b8) + b7
120.  
121.  
122.     string1 = string1 + (CHR$(b7) + CHR$(b6) + CHR$(b5) + CHR$(b4) + CHR$(b3) + CHR$(b2) + CHR$(b1))
123.  
124. NEXT x%
125.  
126. PRINT "decoded"
127. PRINT string1
128. PRINT
129. PRINT
130.  
131. END
132.  

Text Only | Text with Attachments