QB64.org Forum

Active Forums => Programs => Topic started by: Petr on December 04, 2020, 03:44:00 pm

Title: 3D cube + using sprite texture with MapTriangle (3D)
Post by: Petr on December 04, 2020, 03:44:00 pm

Hi. This is easy demo how use software sprite as hardware texture on surface. Image is output my uncomplete program, you can know it from Windows... it is created from ANI file:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DIM Frame(15) AS LONG
3. img = _LOADIMAGE("hg.gif", 32)
4. _SETALPHA 100, &HFF000000 TO &HFF111111, img
5. 'create sprite
6. FOR s = 1 TO 15
7.     Frame(s) = _NEWIMAGE(32, 32, 32)
8.     _DEST Frame(s)
9.     CLS , &H30909090
10.     _PUTIMAGE , img, Frame(s), (32 * (s - 1), 0)-(32 * (s - 1) + 31, 31)
11. NEXT
12.  
13. 'software animation to hardware animation
14. FOR t = 1 TO 15
15.     sw = _COPYIMAGE(Frame(t), 33)
16.     _FREEIMAGE Frame(t)
17.     Frame(t) = sw
18. NEXT
19.  
20. 'create 3D cube and place animation as texture
21. TYPE vertex3d
22.     x AS SINGLE
23.     y AS SINGLE
24.     z AS SINGLE
25.     a AS SINGLE
26.     l AS SINGLE
27. END TYPE
28.  
29. DIM V(1 TO 8) AS vertex3d '8 3D vertexes
30.  
31. V(1).x = -1: V(1).y = 1: V(1).z = -3: V(2).x = 1: V(2).y = 1: V(2).z = -3: V(3).x = -1: V(3).y = -1: V(3).z = -3: V(4).x = 1: V(4).y = -1: V(4).z = -3 'openGL coordinate system
32. V(5).x = -1: V(5).y = 1: V(5).z = -5: V(6).x = 1: V(6).y = 1: V(6).z = -5: V(7).x = -1: V(7).y = -1: V(7).z = -5: V(8).x = 1: V(8).y = -1: V(8).z = -5
33.  
34. camX = 0
35. camZ = -5
36.  
37.  
38. 'calculate points angles (.a) and line lenght from middle (.l) - middle of the cube is in 0, 0, 0, rotation center is on 0, 0, camZ
39. FOR a = 1 TO 8
40.     V(a).a = _ATAN2(V(a).z + 4, V(a).x) '  4 in Z axis is middle between coordinate 5 and 3
41.     V(a).l = _HYPOT(V(a).z + 4, V(a).x)
42. NEXT a
43.  
44.  
45. DIM NP(1 TO 8) AS vertex3d 'NP = new points
46.  
47. i = 1: Himg = Frame(i)
48. ON TIMER(1 / 10) GOSUB ChangeFrame
49. TIMER ON
50. DO UNTIL _KEYHIT = 27
51.     roto = roto + .001
52.  
53.     'calculate new points position: - rotation X/Z
54.     FOR c = 1 TO 8
55.         NP(c).x = COS(roto + V(c).a) * V(c).l
56.         NP(c).z = camZ + SIN(roto + V(c).a) * V(c).l
57.         NP(c).y = V(c).y
58.     NEXT c
59.  
60.     'map cube   SEE ATTACHED PICTURE!
61.     index:
62.     DATA 7,8,3,4: 'dno          bottom
63.     DATA 5,6,1,2: 'vrch         top
64.     DATA 1,2,3,4: 'celo         front
65.     DATA 5,6,7,8: 'zadek        back
66.     DATA 1,5,3,7: 'levy bok     left side
67.     DATA 2,6,4,8: 'pravy bok    right side
68.  
69.     RESTORE index
70.     FOR D = 1 TO 6
71.         READ i1, i2, i3, i4
72.         _MAPTRIANGLE (0, 0)-(32, 0)-(0, 32), Himg TO(NP(i1).x, NP(i1).y, NP(i1).z)-(NP(i2).x, NP(i2).y, NP(i2).z)-(NP(i3).x, NP(i3).y, NP(i3).z), 0
73.         _MAPTRIANGLE (32, 0)-(0, 32)-(32, 32), Himg TO(NP(i2).x, NP(i2).y, NP(i2).z)-(NP(i3).x, NP(i3).y, NP(i3).z)-(NP(i4).x, NP(i4).y, NP(i4).z), 0
74.     NEXT D
75.     _DISPLAY
76. LOOP
77.  
78. END
79. ChangeFrame:
80. i = i + 1: IF i > 15 THEN i = 1
81. Himg = Frame(i)
82. RETURN
83.  

sprite image need for run:
  [ This attachment cannot be displayed inline in 'Print Page' view ]  

This image show order in which is surface textured (source code row 60)
  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: 3D cube + using sprite texture with MapTriangle (3D)
Post by: FellippeHeitor on December 04, 2020, 03:57:11 pm

OOOhh, fancy transparency! Very good looking, Petr.

Title: Re: 3D cube + using sprite texture with MapTriangle (3D)
Post by: Petr on December 04, 2020, 04:17:52 pm

:) Thank you, Fellippe.

Title: Re: 3D cube + using sprite texture with MapTriangle (3D)
Post by: Dav on December 04, 2020, 04:34:26 pm

Yes, very good example!   Thanks for sharing this.

- Dav

Title: Re: 3D cube + using sprite texture with MapTriangle (3D)
Post by: Petr on December 05, 2020, 04:11:12 am

Here is an example of how to look at the same body from two sides at once - the image on the right is rotated 90 degrees compared to the original, to make it easier to distinguish that it is really a rotation of the cube, I intentionally extend its X axis. Use the same attachment as in previous case.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DIM Frame(15) AS LONG
3. img = _LOADIMAGE("hg.gif", 32)
4. _SETALPHA 100, &HFF000000 TO &HFF111111, img
5. 'create sprite
6.  
7. FOR s = 1 TO 15
8.     Frame(s) = _NEWIMAGE(32, 32, 32)
9.     _DEST Frame(s)
10.     CLS , &H30909090
11.     _PUTIMAGE , img, Frame(s), (32 * (s - 1), 0)-(32 * (s - 1) + 31, 31)
12. NEXT
13.  
14. 'software animation to hardware animation
15. FOR t = 1 TO 15
16.     sw = _COPYIMAGE(Frame(t), 33)
17.     _FREEIMAGE Frame(t)
18.     Frame(t) = sw
19. NEXT
20.  
21. 'create 3D cube and place animation as texture
22. TYPE vertex3d
23.     x AS SINGLE
24.     y AS SINGLE
25.     z AS SINGLE
26.     a AS SINGLE
27.     l AS SINGLE
28. END TYPE
29.  
30. DIM V(1 TO 8) AS vertex3d '8 3D vertexes
31.  
32. V(1).x = -2: V(1).y = 1: V(1).z = -3: V(2).x = 2: V(2).y = 1: V(2).z = -3: V(3).x = -2: V(3).y = -1: V(3).z = -3: V(4).x = 2: V(4).y = -1: V(4).z = -3 'openGL coordinate system
33. V(5).x = -2: V(5).y = 1: V(5).z = -5: V(6).x = 2: V(6).y = 1: V(6).z = -5: V(7).x = -2: V(7).y = -1: V(7).z = -5: V(8).x = 2: V(8).y = -1: V(8).z = -5
34.  
35. camX = -4
36. camZ = -10
37.  
38. camX2 = 4
39. camZ2 = -10
40.  
41.  
42.  
43. 'calculate points angles (.a) and line lenght from middle (.l) - middle of the cube is in 0, 0, 0, rotation center is on 0, 0, camZ
44. FOR a = 1 TO 8
45.     V(a).a = _ATAN2(V(a).z + 4, V(a).x) '  4 in Z axis is middle between coordinate 5 and 3
46.     V(a).l = _HYPOT(V(a).z + 4, V(a).x)
47. NEXT a
48.  
49.  
50. DIM NP(1 TO 8) AS vertex3d 'NP = new points
51. DIM NP2(1 TO 8) AS vertex3d 'NP2 = new points - rotated 90 degrees from the NP
52.  
53.  
54.  
55. i = 1: Himg = Frame(i)
56. ON TIMER(1 / 25) GOSUB ChangeFrame
57. TIMER ON
58. DO UNTIL _KEYHIT = 27
59.     roto = roto + .001
60.  
61.     'calculate new points position: - rotation X/Z
62.     FOR c = 1 TO 8
63.         NP(c).x = camX + COS(roto + V(c).a) * V(c).l
64.         NP(c).z = camZ + SIN(roto + V(c).a) * V(c).l
65.         NP(c).y = V(c).y
66.  
67.         NP2(c).x = camX2 + COS(roto - _PI / 2 + V(c).a) * V(c).l
68.         NP2(c).z = camZ2 + SIN(roto - _PI / 2 + V(c).a) * V(c).l
69.         NP2(c).y = V(c).y
70.     NEXT c
71.  
72.     'map cube   SEE ATTACHED PICTURE!
73.     index:
74.     DATA 7,8,3,4: 'dno          bottom
75.     DATA 5,6,1,2: 'vrch         top
76.     DATA 1,2,3,4: 'celo         front
77.     DATA 5,6,7,8: 'zadek        back
78.     DATA 1,5,3,7: 'levy bok     left side
79.     DATA 2,6,4,8: 'pravy bok    right side
80.  
81.     RESTORE index
82.     FOR D = 1 TO 6
83.         READ i1, i2, i3, i4
84.         _MAPTRIANGLE (0, 0)-(32, 0)-(0, 32), Himg TO(NP(i1).x, NP(i1).y, NP(i1).z)-(NP(i2).x, NP(i2).y, NP(i2).z)-(NP(i3).x, NP(i3).y, NP(i3).z), 0
85.         _MAPTRIANGLE (32, 0)-(0, 32)-(32, 32), Himg TO(NP(i2).x, NP(i2).y, NP(i2).z)-(NP(i3).x, NP(i3).y, NP(i3).z)-(NP(i4).x, NP(i4).y, NP(i4).z), 0
86.  
87.         _MAPTRIANGLE (0, 0)-(32, 0)-(0, 32), Himg TO(NP2(i1).x, NP2(i1).y, NP2(i1).z)-(NP2(i2).x, NP2(i2).y, NP2(i2).z)-(NP2(i3).x, NP2(i3).y, NP2(i3).z), 0
88.         _MAPTRIANGLE (32, 0)-(0, 32)-(32, 32), Himg TO(NP2(i2).x, NP2(i2).y, NP2(i2).z)-(NP2(i3).x, NP2(i3).y, NP2(i3).z)-(NP2(i4).x, NP2(i4).y, NP2(i4).z), 0
89.  
90.  
91.     NEXT D
92.     _DISPLAY
93. LOOP
94.  
95. END
96. ChangeFrame:
97. i = i + 1: IF i > 15 THEN i = 1
98. Himg = Frame(i)
99. RETURN
100.  

Text Only | Text with Attachments