QB64.org Forum

Active Forums => Programs => Topic started by: bplus on July 13, 2018, 11:18:30 pm

Title: eRATication
Post by: bplus on July 13, 2018, 11:18:30 pm

Astroids inspired, though I did similar in SmallBASIC with plasma ray shooter.

Code: QB64: [Select]

1. _TITLE "eRATication by bplus 2018-07-13"
2. 'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
3.  
4. ' 2018-07-13 modified from Asteroids game
5.  
6. 'screen dimensions
7. CONST xmax = 1200
8. CONST ymax = 700
9.  
10. DIM SHARED pi
11. pi = _PI
12.  
13. SCREEN _NEWIMAGE(xmax, ymax, 32)
14. _SCREENMOVE 100, 20
15. RANDOMIZE TIMER
16.  
17. CONST nRats = 100
18. CONST nBullets = 1000
19. CONST bSpeed = 20
20.  
21. 'r for rat prefix have x, y location, r for radius, h for heading, s for speed, k for kolor
22. DIM SHARED rx(nRats), ry(nRats), rr(nRats), rh(nRats), rs(nRats), rk(nRats) AS _UNSIGNED LONG
23. DIM SHARED shooterAngle, shooterX, shooterY, life, points
24. 'b prefix for bullet, x, y, dx, dy, a for active
25. DIM SHARED bx(nBullets), by(nBullets), bdx(nBullets), bdy(nBullets), ba(nBullets)
26. points = 0
27. FOR i = 1 TO 100
28.     newRat i
29. NEXT
30. life = 1
31. shooterX = xmax / 2: shooterY = ymax / 2
32. rats = 5
33. shooterAngle = 0
34. WHILE life <= 3
35.     CLS
36.     FOR i = 1 TO life * rats 'the rats
37.         drawRat i
38.     NEXT
39.  
40.     '    _KEYDOWN WORKS NICE!!!!
41.     'use arrow keys to swing shooter, spacebar to fire
42.     IF _KEYDOWN(19200) THEN shooterAngle = shooterAngle - _PI(1 / 60)
43.     IF _KEYDOWN(19712) THEN shooterAngle = shooterAngle + _PI(1 / 60)
44.     IF _KEYDOWN(18432) OR _KEYDOWN(20480) THEN shooterAngle = shooterAngle + _PI(1 / 30)
45.     IF _KEYDOWN(32) THEN fire = 1 ELSE fire = 0
46.     drawshooter xmax / 2, ymax / 2, shooterAngle
47.  
48.     'handle bullets
49.     FOR i = 0 TO nBullets
50.         IF ba(i) = 0 AND fire = 1 THEN 'have in active bullet index to use
51.             bx(i) = shooterX + 3 * bSpeed * COS(shooterAngle)
52.             by(i) = shooterY + 3 * bSpeed * SIN(shooterAngle)
53.             bdx(i) = bSpeed * COS(shooterAngle)
54.             bdy(i) = bSpeed * SIN(shooterAngle)
55.             ba(i) = 1
56.             fire = 0
57.         END IF
58.         IF ba(i) = 1 THEN 'new location
59.             bx(i) = bx(i) + bdx(i)
60.             by(i) = by(i) + bdy(i)
61.             IF bx(i) > 0 AND bx(i) < xmax AND by(i) > 0 AND by(i) < ymax THEN 'in bounds draw it
62.                 'check for collision with rock
63.                 FOR r = 1 TO rats * life
64.                     IF ((rx(r) - bx(i)) ^ 2 + (ry(r) - by(i)) ^ 2) ^ .5 < .75 * rr(r) THEN
65.                         FOR rad = 1 TO rr(r)
66.                             fcirc rx(r), ry(r), rad, _RGB32(255 - rad, 128 - rad, 0)
67.                             _DISPLAY
68.                         NEXT
69.                         points = points + life ^ life
70.                         _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
71.                         _DISPLAY
72.                         newRat r
73.                         ba(i) = 0
74.                     ELSE
75.                         fcirc bx(i), by(i), 2, _RGB32(255, 255, 0)
76.                     END IF
77.                 NEXT
78.             ELSE
79.                 ba(i) = 0
80.             END IF
81.         END IF
82.     NEXT
83.     _DISPLAY
84.     _LIMIT 30
85. WEND
86. _DELAY 5
87.  
88. SUB drawshooter (x, y, radianAngle) 'simple red iso triangle pointed towards radianAngle
89.     'calculate 3 points of triangle shooter
90.     x1 = x + 60 * COS(radianAngle) 'main point of shooter according to heading
91.     y1 = y + 60 * SIN(radianAngle)
92.     x2 = x + 30 * COS(radianAngle + _PI(2 / 3)) 'next two points are 120 degrees off main point in direction
93.     y2 = y + 30 * SIN(radianAngle + _PI(2 / 3))
94.     x3 = x + 30 * COS(radianAngle - _PI(2 / 3))
95.     y3 = y + 30 * SIN(radianAngle - _PI(2 / 3))
96.     fTri x, y, x1, y1, x2, y2, _RGB(255, 0, 0)
97.     fTri x, y, x1, y1, x3, y3, _RGB(255, 0, 0)
98.     ln x1, y1, x2, y2, _RGB32(255, 255, 128)
99.     ln x1, y1, x3, y3, _RGB32(255, 255, 128)
100.     ln x1, y1, x, y, _RGB32(255, 255, 128)
101. END SUB
102.  
103. SUB drawRat (i)
104.     rx(i) = rx(i) + rs(i) * COS(rh(i) + RND * _PI(rand(-5, 5) / 10))
105.     ry(i) = ry(i) + rs(i) * SIN(rh(i) + RND * _PI(rand(-5, 5) / 10))
106.     'rat collides with shooter?
107.     IF ((rx(i) - shooterX) ^ 2 + (ry(i) - shooterY) ^ 2) ^ .5 < rr(i) + 20 THEN
108.         FOR rad = 1 TO 200
109.             fcirc shooterX, shooterY, rad, _RGB32(255 - rad, 255 - 2 * rad, 0)
110.             _DISPLAY
111.             _LIMIT 300
112.         NEXT
113.         life = life + 1
114.         IF life <= 3 THEN
115.             _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
116.         ELSE
117.             _TITLE "Rats Hit:" + STR$(points) + " THE END"
118.         END IF
119.         _DISPLAY
120.         newRat i
121.         EXIT SUB
122.     END IF
123.     IF rx(i) > 0 AND rx(i) < xmax AND ry(i) > 0 AND ry(i) < ymax THEN
124.         noseX = rx(i) + 2 * rr(i) * COS(rh(i))
125.         noseY = ry(i) + 2 * rr(i) * SIN(rh(i))
126.         neckX = rx(i) + .75 * rr(i) * COS(rh(i))
127.         neckY = ry(i) + .75 * rr(i) * SIN(rh(i))
128.         tailX = rx(i) + 2 * rr(i) * COS(rh(i) + _PI)
129.         tailY = ry(i) + 2 * rr(i) * SIN(rh(i) + _PI)
130.         earLX = rx(i) + rr(i) * COS(rh(i) - _PI(1 / 12))
131.         earLY = ry(i) + rr(i) * SIN(rh(i) - _PI(1 / 12))
132.         earRX = rx(i) + rr(i) * COS(rh(i) + _PI(1 / 12))
133.         earRY = ry(i) + rr(i) * SIN(rh(i) + _PI(1 / 12))
134.         fcirc rx(i), ry(i), .65 * rr(i), rk(i)
135.         fcirc neckX, neckY, rr(i) * .3, rk(i)
136.         fTri noseX, noseY, earLX, earLY, earRX, earRY, rk(i)
137.         fcirc earLX, earLY, rr(i) * .3, rk(i)
138.         fcirc earRX, earRY, rr(i) * .3, rk(i)
139.         wX = .5 * rr(i) * COS(rh(i) - _PI(11 / 18))
140.         wY = .5 * rr(i) * SIN(rh(i) - _PI(11 / 18))
141.         ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
142.         wX = .5 * rr(i) * COS(rh(i) - _PI(7 / 18))
143.         wY = .5 * rr(i) * SIN(rh(i) - _PI(7 / 18))
144.         ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
145.         ln rx(i), ry(i), tailX, tailY, rk(i)
146.     ELSE
147.         newRat i
148.     END IF
149. END SUB
150.  
151. SUB newRat (iRat)
152.     'bring rock in from one side, need to set heading according to side
153.     'RANDOMIZE TIMER + RND
154.     side = rand(1, 4)
155.     SELECT CASE side
156.         CASE 1: rx(iRat) = 0: ry(iRat) = RND * ymax: rh(iRat) = 3 * pi / 2 + RND * pi
157.         CASE 2: rx(iRat) = xmax: ry(iRat) = RND * ymax: rh(iRat) = pi / 2 + RND * pi
158.         CASE 3: rx(iRat) = RND * xmax: ry(iRat) = 0: rh(iRat) = RND * pi
159.         CASE 4: rx(iRat) = RND * xmax: ry(iRat) = ymax: rh(iRat) = pi + RND * pi
160.     END SELECT
161.     'speed, angle, radius, gray coloring, spin, seed
162.     rs(iRat) = RND * 5 * life + 1
163.     rr(iRat) = RND * 55 + 15
164.     r = rand(60, 255)
165.     rk(iRat) = _RGB32(r, .9 * r, .8 * r)
166. END SUB
167.  
168. FUNCTION rand% (lo%, hi%)
169.     rand% = INT(RND * (hi% - lo% + 1)) + lo%
170. END FUNCTION
171.  
172. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
173. SUB fTri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
174.     a& = _NEWIMAGE(1, 1, 32)
175.     _DEST a&
176.     PSET (0, 0), K
177.     _DEST 0
178.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
179.     _FREEIMAGE a& '<<< this is important!
180. END SUB
181.  
182. SUB ln (x1, y1, x2, y2, K AS _UNSIGNED LONG) 'box frame
183.     LINE (x1, y1)-(x2, y2), K
184. END SUB
185.  
186. 'vince version
187. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG)
188.     x0 = R
189.     y0 = 0
190.     e = 0
191.     DO WHILE y0 < x0
192.         IF e <= 0 THEN
193.             y0 = y0 + 1
194.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
195.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
196.             e = e + 2 * y0
197.         ELSE
198.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
199.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
200.             x0 = x0 - 1
201.             e = e - 2 * x0
202.         END IF
203.     LOOP
204.     LINE (x - R, y)-(x + R, y), C, BF
205. END SUB
206.  
207.  

Title: Re: eRATication
Post by: bplus on July 14, 2018, 07:23:21 am

Code: QB64: [Select]

1. I ran your program (called it ratgame.bas) and defeated it by holding down UpArrow and Space and
2. let it run indefinitely and killed 100s of rats..
3.  
4. Erik.
5.  

Yeah, not exactly meant to be a game of skill... ;)

Life #1 easy peasy, 1 point per rat
Life #2 might work up a sweat, 4 points per rat
Life #3 Ha! 27 points per rat

Title: Re: eRATication
Post by: bplus on July 14, 2018, 07:33:17 am

Yeah, so you CAN play this like a game of skill and try to kill one rat with one shot (or burst) PLUS you can just hose the rats off screen, very satisfying like popping bubble wrap. I won't judge which way you try. ;)

Title: Re: eRATication
Post by: Petr on July 14, 2018, 02:18:17 pm

Nice work! :-D

Title: Re: eRATication
Post by: bplus on July 15, 2018, 09:01:48 am

Thanks Petr, thanks to Erik's feedback, I hope to add a rat palette and track life/death of each rat so as to not delay action when one is hit. Perhaps if I just leave out poisoned cheese, no shooting would be necessary. ;D

Title: Re: eRATication
Post by: Petr on July 15, 2018, 09:06:20 am

Bplus, I'll come to see TJP behind you and Erik. 

Title: Re: eRATication
Post by: bplus on July 15, 2018, 02:37:56 pm

Hi Petr,

I can keep you updated here.

Here is improvements suggested by Erik PLUS I made life #3 even harder to survive. ;D

Code: QB64: [Select]

1. _TITLE "eRATication no 2 by bplus 2018-07-15"
2. 'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
3.  
4. ' 2018-07-13 modified from Asteroids game
5. ' 2018-07-15 eRATication 2
6. ' color rats, eliminate jerks when kill rat,
7. ' decrease rat size as life progresses
8.  
9. 'screen dimensions
10. CONST xmax = 1200
11. CONST ymax = 700
12.  
13. DIM SHARED pi
14. pi = _PI
15.  
16. SCREEN _NEWIMAGE(xmax, ymax, 32)
17. _SCREENMOVE 100, 20
18. RANDOMIZE TIMER
19.  
20. CONST nRats = 100
21. CONST nBullets = 1000
22. CONST bSpeed = 20
23.  
24. 'r for rat prefix have x, y location, r for radius, h for heading, s for speed, k for kolor
25. DIM SHARED rx(nRats), ry(nRats), rr(nRats), rh(nRats), rs(nRats), rdead(nRats), rk(nRats) AS _UNSIGNED LONG
26. DIM SHARED shooterAngle, shooterX, shooterY, life, points, walk
27. 'b prefix for bullet, x, y, dx, dy, a for active
28. DIM SHARED bx(nBullets), by(nBullets), bdx(nBullets), bdy(nBullets), ba(nBullets)
29.  
30. life = 1
31. rats = 5
32. points = 0
33. shooterAngle = 0
34. shooterX = xmax / 2
35. shooterY = ymax / 2
36. FOR i = 0 TO nRats - 1
37.     newRat i
38. NEXT
39. WHILE life <= 3
40.     CLS , _RGB32(188, 178, 168)
41.     walk = (walk + 1) MOD 2
42.     FOR i = 1 TO life * rats 'the rats
43.         drawRat i
44.     NEXT
45.  
46.     '    _KEYDOWN WORKS NICE!!!!
47.     'use arrow keys to swing shooter, spacebar to fire
48.     IF _KEYDOWN(19200) THEN shooterAngle = shooterAngle - _PI(1 / 60)
49.     IF _KEYDOWN(19712) THEN shooterAngle = shooterAngle + _PI(1 / 60)
50.     IF _KEYDOWN(18432) OR _KEYDOWN(20480) THEN shooterAngle = shooterAngle + _PI(1 / 30)
51.     IF _KEYDOWN(32) THEN fire = 1 ELSE fire = 0
52.     drawshooter xmax / 2, ymax / 2, shooterAngle
53.  
54.     'handle bullets
55.     FOR i = 0 TO nBullets
56.         IF ba(i) = 0 AND fire = 1 THEN 'have in active bullet index to use
57.             bx(i) = shooterX + 3 * bSpeed * COS(shooterAngle)
58.             by(i) = shooterY + 3 * bSpeed * SIN(shooterAngle)
59.             bdx(i) = bSpeed * COS(shooterAngle)
60.             bdy(i) = bSpeed * SIN(shooterAngle)
61.             ba(i) = 1
62.             fire = 0
63.         END IF
64.         IF ba(i) = 1 THEN 'new location
65.             bx(i) = bx(i) + bdx(i)
66.             by(i) = by(i) + bdy(i)
67.             IF bx(i) > 0 AND bx(i) < xmax AND by(i) > 0 AND by(i) < ymax THEN 'in bounds draw it
68.                 'check for collision with rock
69.                 FOR r = 0 TO rats * life
70.                     IF ((rx(r) - bx(i)) ^ 2 + (ry(r) - by(i)) ^ 2) ^ .5 < .75 * rr(r) THEN
71.                         IF rdead(r) = 0 THEN
72.                             rdead(r) = 1
73.                             points = points + life ^ life
74.                             _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
75.                             ba(i) = 0
76.                         END IF
77.                     ELSE
78.                         fcirc bx(i), by(i), 2, _RGB32(30, 60, 80)
79.                     END IF
80.                 NEXT
81.             ELSE
82.                 ba(i) = 0
83.             END IF
84.         END IF
85.     NEXT
86.     _DISPLAY
87.     _LIMIT 30
88. WEND
89. _DELAY 5 'so don't start printing spaces in the editor
90.  
91. SUB drawshooter (x, y, radianAngle) 'simple red iso triangle pointed towards radianAngle
92.     'calculate 3 points of triangle shooter
93.     x1 = x + 60 * COS(radianAngle) 'main point of shooter according to heading
94.     y1 = y + 60 * SIN(radianAngle)
95.     x2 = x + 30 * COS(radianAngle + _PI(2 / 3)) 'next two points are 120 degrees off main point in direction
96.     y2 = y + 30 * SIN(radianAngle + _PI(2 / 3))
97.     x3 = x + 30 * COS(radianAngle - _PI(2 / 3))
98.     y3 = y + 30 * SIN(radianAngle - _PI(2 / 3))
99.     fTri x, y, x1, y1, x2, y2, _RGB(255, 0, 0)
100.     fTri x, y, x1, y1, x3, y3, _RGB(255, 0, 0)
101.     ln x1, y1, x2, y2, _RGB32(255, 255, 128)
102.     ln x1, y1, x3, y3, _RGB32(255, 255, 128)
103.     ln x1, y1, x, y, _RGB32(255, 255, 128)
104. END SUB
105.  
106. SUB drawRat (i)
107.     IF rdead(i) = 0 THEN 'if rat not dead move it
108.         rx(i) = rx(i) + rs(i) * COS(rh(i)) + rand(-.1 * rr(i), .1 * rr(i))
109.         ry(i) = ry(i) + rs(i) * SIN(rh(i)) + rand(-.1 * rr(i), .1 * rr(i))
110.     END IF
111.  
112.     'rat collides with shooter?
113.     IF ((rx(i) - shooterX) ^ 2 + (ry(i) - shooterY) ^ 2) ^ .5 < rr(i) + 20 THEN
114.         FOR rad = 1 TO 350
115.             fcirc shooterX, shooterY, rad, _RGB32(255 - .25 * rad, 128 - .125 * rad, 0)
116.             _DISPLAY
117.             _LIMIT 300
118.         NEXT
119.         life = life + 1
120.         'new set o rats
121.         FOR i = 0 TO nRats - 1
122.             newRat i
123.         NEXT
124.         IF life <= 3 THEN
125.             _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
126.         ELSE
127.             _TITLE "Rats Hit:" + STR$(points) + " THE END"
128.             _DELAY 5 'so don't start printing spaces in the editor
129.             END
130.         END IF
131.         _DISPLAY
132.         EXIT SUB
133.     END IF
134.  
135.     IF rx(i) > 0 AND rx(i) < xmax AND ry(i) > 0 AND ry(i) < ymax THEN 'inbounds
136.         IF rdead(i) THEN 'show the burn out until reaches rat radius
137.             rdead(i) = rdead(i) + 2
138.             IF rdead(i) < rr(i) THEN
139.                 fcirc rx(i), ry(i), rr(i) - rdead(i), _RGB32(255 - rdead(i), 128 - rdead(i), 0)
140.                 _DISPLAY
141.             ELSE
142.                 newRat i
143.             END IF
144.         ELSE
145.             noseX = rx(i) + 2 * rr(i) * COS(rh(i))
146.             noseY = ry(i) + 2 * rr(i) * SIN(rh(i))
147.             neckX = rx(i) + .75 * rr(i) * COS(rh(i))
148.             neckY = ry(i) + .75 * rr(i) * SIN(rh(i))
149.             tailX = rx(i) + 2 * rr(i) * COS(rh(i) + _PI)
150.             tailY = ry(i) + 2 * rr(i) * SIN(rh(i) + _PI)
151.             earLX = rx(i) + rr(i) * COS(rh(i) - _PI(1 / 12))
152.             earLY = ry(i) + rr(i) * SIN(rh(i) - _PI(1 / 12))
153.             earRX = rx(i) + rr(i) * COS(rh(i) + _PI(1 / 12))
154.             earRY = ry(i) + rr(i) * SIN(rh(i) + _PI(1 / 12))
155.             fcirc rx(i), ry(i), .65 * rr(i), rk(i)
156.             fcirc neckX, neckY, rr(i) * .3, rk(i)
157.             fTri noseX, noseY, earLX, earLY, earRX, earRY, rk(i)
158.             fcirc earLX, earLY, rr(i) * .3, rk(i)
159.             fcirc earRX, earRY, rr(i) * .3, rk(i)
160.             wX = .5 * rr(i) * COS(rh(i) - _PI(11 / 18))
161.             wY = .5 * rr(i) * SIN(rh(i) - _PI(11 / 18))
162.             ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
163.             wX = .5 * rr(i) * COS(rh(i) - _PI(7 / 18))
164.             wY = .5 * rr(i) * SIN(rh(i) - _PI(7 / 18))
165.             ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
166.             ln rx(i), ry(i), tailX, tailY, rk(i)
167.         END IF
168.     ELSE 'out of bounds
169.         newRat i
170.     END IF
171. END SUB
172.  
173. SUB newRat (iRat)
174.     'bring rock in from one side, need to set heading according to side
175.     'RANDOMIZE TIMER + RND
176.     side = rand(1, 4)
177.     SELECT CASE side
178.         CASE 1: rx(iRat) = 0: ry(iRat) = RND * ymax: rh(iRat) = 3 * pi / 2 + RND * pi
179.         CASE 2: rx(iRat) = xmax: ry(iRat) = RND * ymax: rh(iRat) = pi / 2 + RND * pi
180.         CASE 3: rx(iRat) = RND * xmax: ry(iRat) = 0: rh(iRat) = RND * pi
181.         CASE 4: rx(iRat) = RND * xmax: ry(iRat) = ymax: rh(iRat) = pi + RND * pi
182.     END SELECT
183.     'speed, angle, radius, gray coloring, spin, seed
184.     rs(iRat) = RND * 5 * life + 1
185.     rr(iRat) = RND * 60 / life + 10
186.     rdead(iRat) = 0
187.     rk(iRat) = ratKolor~&
188. END SUB
189.  
190. FUNCTION ratKolor~& ()
191.     r% = INT(RND * 140)
192.     g% = rand(INT(.5 * r%), INT(.8 * r%))
193.     b% = rand(INT(.5 * g%), INT(.8 * g%))
194.     ratKolor~& = _RGB32(r%, g%, b%)
195. END FUNCTION
196.  
197. FUNCTION rand% (lo%, hi%)
198.     rand% = INT(RND * (hi% - lo% + 1)) + lo%
199. END FUNCTION
200.  
201. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
202. SUB fTri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
203.     a& = _NEWIMAGE(1, 1, 32)
204.     _DEST a&
205.     PSET (0, 0), K
206.     _DEST 0
207.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
208.     _FREEIMAGE a& '<<< this is important!
209. END SUB
210.  
211. SUB ln (x1, y1, x2, y2, K AS _UNSIGNED LONG) 'box frame
212.     LINE (x1, y1)-(x2, y2), K
213. END SUB
214.  
215. 'vince version
216. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG)
217.     x0 = R
218.     y0 = 0
219.     e = 0
220.     DO WHILE y0 < x0
221.         IF e <= 0 THEN
222.             y0 = y0 + 1
223.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
224.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
225.             e = e + 2 * y0
226.         ELSE
227.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
228.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
229.             x0 = x0 - 1
230.             e = e - 2 * x0
231.         END IF
232.     LOOP
233.     LINE (x - R, y)-(x + R, y), C, BF
234. END SUB
235.  
236.  

Title: Re: eRATication
Post by: bplus on July 15, 2018, 02:53:05 pm

better gun action with arrows keys:

Code: QB64: [Select]

1.     '    _KEYDOWN WORKS NICE!!!!
2.     'use arrow keys to swing shooter, spacebar to fire
3.     IF _KEYDOWN(19200) THEN shooterAngle = shooterAngle - _PI(1 / 60)
4.     IF _KEYDOWN(19712) THEN shooterAngle = shooterAngle + _PI(1 / 60)
5.     IF _KEYDOWN(18432) THEN shooterAngle = shooterAngle - _PI(1 / 20)
6.     IF _KEYDOWN(20480) THEN shooterAngle = shooterAngle + _PI(1 / 20)
7.     IF _KEYDOWN(32) THEN fire = 1 ELSE fire = 0
8.     drawshooter xmax / 2, ymax / 2, shooterAngle
9.  

fast and slow swing both ways.

Title: Re: eRATication
Post by: Petr on July 15, 2018, 05:36:58 pm

Nice! Strategy if i spin to right, is reliable, but small mice i have to shoot straight, they are monsters :-D

Title: Re: eRATication
Post by: johnno56 on July 15, 2018, 05:46:25 pm

Oh. You noticed THAT too? Those sneaky little mongrels! You shoot at them with a hail of bullets, but NO, they're small enough to avoid getting hit and then "stab you in the back" when you least expect it!

B+. You have a mean streak within you. Clever but mean! lol

J

Title: Re: eRATication
Post by: Ashish on July 16, 2018, 03:55:18 am

Nice game, bplus! Here's my highscore in the attachment.

Title: Re: eRATication
Post by: bplus on July 16, 2018, 09:04:53 am

Thanks guys! your comments have me smiling and laughing.

Erik has done some interesting mods at TJP, slowing the bullet speed but doubling the bullets. He also has overridden the max life # of 3 to 10 input at the beginning of the game. He also is tracking high score adding a comma delimited score. Is he optimistic or what? ;)   PLUS he is storing high scores to file using _STARTDIR$ keyword for current directory.

So up to 10 lives! ? He allows.

Let's take a closer look at how a new rat is started, Johnno you might get some ideas about taking the edge off my cruel streak. ;)

Code: QB64: [Select]

1. SUB newRat (iRat)
2.     'bring rock in from one side, need to set heading according to side
3.     'RANDOMIZE TIMER + RND
4.     side = rand(1, 4)
5.     SELECT CASE side
6.         CASE 1: rx(iRat) = 0: ry(iRat) = RND * ymax: rh(iRat) = 3 * pi / 2 + RND * pi
7.         CASE 2: rx(iRat) = xmax: ry(iRat) = RND * ymax: rh(iRat) = pi / 2 + RND * pi
8.         CASE 3: rx(iRat) = RND * xmax: ry(iRat) = 0: rh(iRat) = RND * pi
9.         CASE 4: rx(iRat) = RND * xmax: ry(iRat) = ymax: rh(iRat) = pi + RND * pi
10.     END SELECT
11.     'speed, angle, radius, gray coloring, spin, seed
12.     rs(iRat) = RND * 5 * life + 1    '<<<<<<<<<<<<<<<<<<<<<< rat speed is set here and adjusted according to life #
13.     rr(iRat) = RND * 60 / life + 10 ' <<<<<<<<<<<<<<<<<<<<<< rat radius or size of rat is set here and also adjusted according to life #
14.     rdead(iRat) = 0
15.     rk(iRat) = ratKolor~&
16. END SUB
17.  

With a range of life from 1 to 10 as Erik has it, rat speeds will vary from 1 to 6 in life #1 and 1 to 51 in life #10.   51!!!! Yikes!
With a range of life from 1 to 10 as Erik has it, rat radii will vary from 10 to 70 in life #1 and 10 to 16 in life #10

And the number of rats is 5 * life so start with 5 in life #1 and could go as high as 50 in life # 10.

I think if you really want to get into point systems if you are taking trouble to store High scores:
1. You should make a table for High Scores depending on the life # you choose to play.
2. You might start getting deductions for wasteful use of bullets ie skill starts to be factored into score.

Oh BTW if you are in life #10 and kill a rat that is worth 10 ^ 10 points! No wonder Erik starts to need a comma delimited score!

Title: Re: eRATication
Post by: FellippeHeitor on July 16, 2018, 11:03:21 am

Very fun to play, bplus!

You may consider using the main canvas to show score/lives as the title bar doesn't update as reliably on Linux/macOS (if you intend to support those platforms as well).

Title: Re: eRATication
Post by: bplus on July 16, 2018, 11:58:40 pm

Hi Fellippe, Thanks for feedback with Linux.

Title: Re: eRATication
Post by: Cobalt on July 17, 2018, 10:19:57 am

very interesting game Bplus. I give it a B+!

One thing I noticed(least in the first version at top of the thread) is that you only hit the rats in the arse area, and the shot continues on after the hit.

A slight improvement to would be to have the explosions happen as part of the main loop so there is not that slight pause every time you make a kill, that may just be my old laptop causing it though.  basically you have a explosion routine that is called each loop that makes the explosion grow a step. That way the explosions happen but the game doesn't pause, and it could even have multiple kills happening at once. kind of how my first (and only 100% completed) BASIC game , Space Dodger and the Giant Killer Space Hamsters, ran. a game lost to Geocities I'm afraid. 

Title: Re: eRATication
Post by: bplus on July 17, 2018, 10:35:47 am

Hi Cobalt,

I think we have the gun action fixed in eRATication #2, Erik was complaining of jerkiness and that was caused by the delay to display a rat burn but now that is done in the main looping display.

Bullets have been made inactive with rat hit, ba(i) = 0

See reply #6 for eRATication #2 code, and then new gun action in next reply.

Ha, you did Hamsters! Great minds think alike.

Thanks for your grade, B is for Best! :D

Title: Re: eRATication
Post by: _vince on July 17, 2018, 10:37:41 am

in the fcirc sub

Code: QB64: [Select]

1. e = 0

should be

Code: QB64: [Select]

1. e = -R

A mistake I made that got spread about. Otherwise, anyone's welcome to use the fcirc, simplest implementation of midpoint circle fill algo, no credit necessary.

Title: Re: eRATication
Post by: bplus on July 17, 2018, 10:44:03 am

Hi v,

Thanks for correction. I did notice when playing with gradient code (see recent dithering thread) that Steve's fcirc did seem less bumpy around the edges. Maybe just my imagination, would the -R make a difference for that?

Title: Re: eRATication
Post by: _vince on July 17, 2018, 11:04:21 am

Quote from: bplus on July 17, 2018, 10:44:03 am

would the -R make a difference for that?

Yes it will make it just like Steve's

Title: Re: eRATication
Post by: Cobalt on July 17, 2018, 10:51:13 pm

If you want to have some good laughs change the following line in the NEWRAT routine,

rr(iRat) = RND * 60 / life + 10

to

rr(iRat) = RND * 60 / life + 1

and try shooting that little turd!

a possible scoring mod would be having a base score say 71 per rat and subtract the size of the rat from that
so a full size rat (60+10) would only give you 1 point(71-70) but a micro rat (0+1) would give 70, if you could hit the thing that is! you could multiply it by the rats speed too.
 
 

Title: Re: eRATication
Post by: Cobalt on July 18, 2018, 12:40:59 am

hope you dont mind Bplus but I've made some slight mods to your game, and now the player can move the shooter around the screen!

Code: QB64: [Select]

1.  'use arrow keys to swing shooter, spacebar to fire
2.  'left shift to speed up rotation, this frees up the UP arrow to allow for movement
3.  'of the players craft.
4.  IF _KEYDOWN(100304) THEN speed%% = 20 ELSE speed%% = 60
5.  IF _KEYDOWN(19200) THEN P.Rot = P.Rot - _PI(1 / speed%%)
6.  IF _KEYDOWN(19712) THEN P.Rot = P.Rot + _PI(1 / speed%%)
7.  
8.  IF _KEYDOWN(18432) THEN 'up arrow provides thrust!
9.   P.Momentum = P.Momentum + .056
10.   IF P.Momentum > 1.86 THEN P.Momentum = 1.86
11.  ELSEIF P.Momentum THEN 'player is no longer thrusting and still has momentum
12.   P.Momentum = P.Momentum - Drag
13.   IF P.Momentum < 0 THEN P.Momentum = 0
14.  END IF
15.  
16.  ' IF _KEYDOWN(20480) THEN P.Rot = P.Rot + _PI(1 / 30)
17.  IF _KEYDOWN(32) THEN fire = 1 ELSE fire = 0
18.  
19.  'move player around if they have momentum
20.  P.Xloc = P.Xloc + P.Momentum * COS(P.Rot)
21.  P.Yloc = P.Yloc + P.Momentum * SIN(P.Rot)
22.  'stop the player if they encroach upon the screen bounds
23.  IF P.Xloc < 30 OR P.Yloc < 30 OR P.Xloc > ScrnX - 30 OR P.Yloc > ScrnY - 30 THEN P.Momentum = 0
24.  'now that does allow player to move extreamly slow, like they are stuck in tar! but they
25.  'can still leave screen, in that case they lose a life.
26.  
27.  IF P.Xloc <= 0 OR P.Xloc >= ScrnX OR P.Yloc <= 0 OR P.Yloc >= ScrnY THEN
28.   P.Life = P.Life + 1 'player left screen by force! KILL EM'
29.   P.Xloc = ScrnX \ 2: P.Yloc = ScrnY \ 2
30.  END IF
31.  drawshooter P.Xloc, P.Yloc, P.Rot
32.  

'drag' is a CONST set to .01 and slows the player rather quickly not that 1.86 moves the player that fast anyway.
I've taken the liberty and setup my own variables as TYPEs just cause that is easier for me to work with.
it still needs some work cause I'd like the craft to keep moving in the direction the player was traveling when they
let go of the UP key regaurdless of whether they rotate. but not quite sure how to do that one. maybe a variable
for thrust Rotation (p.Thrstrot) that stores the rotation of the craft at the time the key was held. and just use that
variable instead of p.rot in the movement lines.

Title: Re: eRATication
Post by: Cobalt on July 18, 2018, 01:29:24 am

not sure what i did but every so often one of my rats has lost his arse! this shot shows one of the smaller rats but they do get even smaller than that when you change that +10 to a +1!

Title: Re: eRATication
Post by: bplus on July 18, 2018, 08:57:19 am

Hi Cobalt,

Mod all you want, that is the beauty of sharing code. It's fun to see what other people are doing with it. I myself was inspired by SirCrow's efforts. Besides, it's not like this idea is original. :)

I have thought about moving the shooter like Asteroids but there seem to be too many buttons needed for one comfortable control. So it becomes a 2 handed job, but my left hand is not very smart when my right hand is busy. ha! just got an idea, use mouse to move shooter and left and right mouse buttons to spin the shooter. That leaves the simple task of pounding the spacebar to the left hand (or vice versa for Lefties).

Speaking of spacebars, do you think they serve coffee there?

Title: Re: eRATication
Post by: Cobalt on July 19, 2018, 01:36:44 pm

so here is a preview release of the MODed version of Bplus's eRATication game.
Still some work to do but, it gives you an idea of the feel I'm going for.
probably start new thread when Its completed.

Code: QB64: [Select]

1. 'eRATication by Bplus 2018-07-15
2. 'Ultra Mod version by Cobalt 2018-07-19 13:25 Build 0001 Ver 1.0beta
3.  
4. 'known things to fix/complete:
5. '   re-add rat collision with player
6. '    À-Currently in GOD mode. :)
7. '   add Title screen and Title Bar text
8. '   fix bullet collision with rat so Mini rats are hit correctly
9. '    À-add more points of detection shots tend to pass right by :(
10. '   add highscore list
11. '   re-add hit explosions
12. '    À-rats simply vanish at the moment :(
13.  
14. TYPE RatData
15.  Xloc AS SINGLE 'X location
16.  Yloc AS SINGLE 'Y location
17.  Siz AS INTEGER 'Size(radius)
18.  Rot AS SINGLE 'Rotation(heading)
19.  Spd AS SINGLE 'Speed
20.  Colr AS _UNSIGNED LONG 'color of rat
21.  Val AS _UNSIGNED _BYTE 'score value of rat
22. END TYPE
23.  
24. TYPE Bulletdata
25.  Xloc AS SINGLE 'locations
26.  Yloc AS SINGLE
27.  DXval AS SINGLE 'movement values
28.  DYval AS SINGLE
29.  RemFlag AS _BYTE 'if the shot has hit a rat or gone offscreen flag for removal
30. END TYPE
31.  
32. TYPE PlayerData
33.  Rot AS SINGLE
34.  Xloc AS SINGLE
35.  Yloc AS SINGLE
36.  Life AS _BYTE
37.  Points AS _UNSIGNED LONG
38.  walk AS SINGLE '???
39.  Momentum AS SINGLE 'players movement speed
40.  ThrstRot AS SINGLE 'the rotation of players craft when thrust was stopped
41. END TYPE
42.  
43. 'constants
44. CONST ScrnX = 800
45. CONST ScrnY = 600
46.  
47. CONST MaxRats = 100
48. CONST MaxBullets = 25
49. CONST MaxShots = 3 'only 3 shots at a time on screen
50. CONST BulletSpeed = 20
51. CONST RatScore = 71 'how much the base score of each rat is
52. CONST Drag = .015 'how much the players movement slows over time
53. CONST Rate = .25 'delay between shots fired
54. CONST RatCount = 5 'base rat count
55. CONST TRUE = -1, FALSE = NOT TRUE
56.  
57. 'Make screen and set timer
58. SCREEN _NEWIMAGE(ScrnX, ScrnY, 32)
59. RANDOMIZE TIMER
60.  
61. 'set up arrays
62. DIM SHARED P AS PlayerData
63. DIM SHARED Rats(MaxRats) AS RatData
64. DIM SHARED Shot(MaxBullets) AS Bulletdata
65.  
66. 'set up layers, an idea for haveing everything on its own layer then
67. 'combining them on to the display
68. 'DIM SHARED shiplayer&, ratlayer&
69. 'shiplayer& = _NEWIMAGE(ScrnX, ScrnY, 32)
70. 'ratlayer& = _NEWIMAGE(ScrnX, ScrnY, 32)
71.  
72. 'initilize starting Values
73. ShotsFired%% = 0 'number of shots fired
74. P.Life = 1 'player on life #1
75. P.Points = 0
76. P.Rot = 0
77. P.Xloc = ScrnX \ 2
78. P.Yloc = ScrnY \ 2
79.  
80. 'make some Rats
81. FOR i%% = 0 TO RatCount - 1
82.  newRat i%%
83. NEXT
84. 'OPEN "debug.txt" FOR OUTPUT AS #1
85. DO
86.  CLS
87.  walk = (walk + 1) MOD 2
88.  FOR i = 1 TO P.Life * RatCount 'the rats
89.   drawRat i
90.  NEXT
91.  
92.  'use arrow keys to swing shooter, spacebar to fire
93.  'left shift to speed up rotation, this frees up the UP arrow to allow for movement
94.  'of the players craft.
95.  IF _KEYDOWN(100304) THEN speed%% = 20 ELSE speed%% = 60
96.  IF _KEYDOWN(19200) THEN P.Rot = P.Rot - _PI(1 / speed%%)
97.  IF _KEYDOWN(19712) THEN P.Rot = P.Rot + _PI(1 / speed%%)
98.  
99.  IF _KEYDOWN(18432) THEN 'up arrow provides thrust!
100.   P.Momentum = P.Momentum + .056
101.   IF P.Momentum > 2.86 THEN P.Momentum = 2.86
102.   P.ThrstRot = P.Rot 'get current rotation
103.  ELSEIF P.Momentum THEN 'player is no longer thrusting and still has momentum
104.   P.Momentum = P.Momentum - Drag
105.   IF P.Momentum < 0 THEN P.Momentum = 0
106.  END IF
107.  
108.  ' IF _KEYDOWN(20480) THEN P.Rot = P.Rot + _PI(1 / 30)
109.  'added cooldown to shooting so you can't auto gun 'normally' maybe add specails
110.  'or bonuses to allow that later
111.  IF _KEYDOWN(32) AND ShotsFired%% < MaxShots AND cooldown! + Rate < TIMER THEN
112.   ShotsFired%% = NewShot(ShotsFired%%): cooldown! = TIMER
113.  ELSE
114.  END IF
115.  
116.  IF ShotsFired%% THEN ShotsFired%% = shotprocess(ShotsFired%%)
117.  PlayerMovement
118.  drawshooter P.Xloc, P.Yloc, P.Rot
119.  
120.  IF P.Life > 3 THEN ExitFlag%% = TRUE
121.  IF INKEY$ = CHR$(27) THEN ExitFlag%% = TRUE
122.  
123.  LOCATE 1, 1: PRINT "Life:"; P.Life; TAB(10); "Points:";
124.  PRINT USING "#,###,###"; P.Points
125.  
126.  _DELAY .05
127. LOOP UNTIL ExitFlag%%
128.  
129.  
130. SUB newRat (iRat)
131.  'bring rock in from one side, need to set heading according to side
132.  'RANDOMIZE TIMER + RND
133.  side%% = INT(RND * 4) + 1
134.  SELECT CASE side%%
135.   CASE 1: Rats(iRat).Xloc = 0: Rats(iRat).Yloc = RND * ScrnY: Rats(iRat).Rot = 3 * _PI / 2 + RND * _PI
136.   CASE 2: Rats(iRat).Xloc = ScrnX: Rats(iRat).Yloc = RND * ScrnY: Rats(iRat).Rot = _PI / 2 + RND * _PI
137.   CASE 3: Rats(iRat).Xloc = RND * ScrnX: Rats(iRat).Yloc = 0: Rats(iRat).Rot = RND * _PI
138.   CASE 4: Rats(iRat).Xloc = RND * ScrnX: Rats(iRat).Yloc = ScrnY: Rats(iRat).Rot = _PI + RND * _PI
139.  END SELECT
140.  
141.  'speed, angle, radius, gray coloring, spin, seed
142.  Rats(iRat).Spd = RND * 5 * P.Life + 1
143.  Rats(iRat).Siz = RND * 60 / P.Life + 3
144.  Rats(iRat).Colr = ratKolor~&
145. END SUB
146.  
147. SUB drawRat (i)
148.  'move the rat
149.  Rats(i).Xloc = Rats(i).Xloc + Rats(i).Spd * COS(Rats(i).Rot) + rand(-.1 * Rats(i).Siz, .1 * Rats(i).Siz)
150.  Rats(i).Yloc = Rats(i).Yloc + Rats(i).Spd * SIN(Rats(i).Rot) + rand(-.1 * Rats(i).Siz, .1 * Rats(i).Siz)
151.  
152.  IF Rats(i).Xloc > 0 AND Rats(i).Xloc < ScrnX AND Rats(i).Yloc > 0 AND Rats(i).Yloc < ScrnY THEN 'inbounds
153.   noseX = Rats(i).Xloc + 2 * Rats(i).Siz * COS(Rats(i).Rot)
154.   noseY = Rats(i).Yloc + 2 * Rats(i).Siz * SIN(Rats(i).Rot)
155.   neckX = Rats(i).Xloc + .75 * Rats(i).Siz * COS(Rats(i).Rot)
156.   neckY = Rats(i).Yloc + .75 * Rats(i).Siz * SIN(Rats(i).Rot)
157.   tailX = Rats(i).Xloc + 2 * Rats(i).Siz * COS(Rats(i).Rot + _PI)
158.   tailY = Rats(i).Yloc + 2 * Rats(i).Siz * SIN(Rats(i).Rot + _PI)
159.   earLX = Rats(i).Xloc + Rats(i).Siz * COS(Rats(i).Rot - _PI(1 / 12))
160.   earLY = Rats(i).Yloc + Rats(i).Siz * SIN(Rats(i).Rot - _PI(1 / 12))
161.   earats.sizats.xloc = Rats(i).Xloc + Rats(i).Siz * COS(Rats(i).Rot + _PI(1 / 12))
162.   earats.sizats.yloc = Rats(i).Yloc + Rats(i).Siz * SIN(Rats(i).Rot + _PI(1 / 12))
163.   fcirc Rats(i).Xloc, Rats(i).Yloc, .65 * Rats(i).Siz, Rats(i).Colr
164.   fcirc neckX, neckY, Rats(i).Siz * .3, Rats(i).Colr
165.   fTri noseX, noseY, earLX, earLY, earats.sizats.xloc, earats.sizats.yloc, Rats(i).Colr
166.   fcirc earLX, earLY, Rats(i).Siz * .3, Rats(i).Colr
167.   fcirc earats.sizats.xloc, earats.sizats.yloc, Rats(i).Siz * .3, Rats(i).Colr
168.   wX = .5 * Rats(i).Siz * COS(Rats(i).Rot - _PI(11 / 18))
169.   wY = .5 * Rats(i).Siz * SIN(Rats(i).Rot - _PI(11 / 18))
170.   LINE (noseX + wX, noseY + wY)-(noseX - wX, noseY - wY), Rats(i).Colr
171.   wX = .5 * Rats(i).Siz * COS(Rats(i).Rot - _PI(7 / 18))
172.   wY = .5 * Rats(i).Siz * SIN(Rats(i).Rot - _PI(7 / 18))
173.   LINE (noseX + wX, noseY + wY)-(noseX - wX, noseY - wY), Rats(i).Colr
174.   LINE (Rats(i).Xloc, Rats(i).Yloc)-(tailX, tailY), Rats(i).Colr
175.  ELSE 'out of bounds
176.   newRat i
177.  END IF
178. END SUB
179.  
180. SUB fTri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
181.  a& = _NEWIMAGE(1, 1, 32)
182.  _DEST a&
183.  PSET (0, 0), K
184.  _DEST 0
185.  _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
186.  _FREEIMAGE a& '<<< this is important!
187. END SUB
188.  
189. 'vince version
190. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG)
191.  x0 = R
192.  y0 = 0
193.  e = 0
194.  DO WHILE y0 < x0
195.   IF e <= 0 THEN
196.    y0 = y0 + 1
197.    LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
198.    LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
199.    e = e + 2 * y0
200.   ELSE
201.    LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
202.    LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
203.    x0 = x0 - 1
204.    e = e - 2 * x0
205.   END IF
206.  LOOP
207.  LINE (x - R, y)-(x + R, y), C, BF
208. END SUB
209.  
210. FUNCTION ratKolor~& ()
211.  r% = INT(RND * 70) + 70
212.  g% = INT(RND * (.5 * r%)) + .2 * r%
213.  b% = INT(RND * (.4 * g%)) + .1 * g%
214.  ' r% = 165: g% = 95: b% = 25
215.  ratKolor~& = _RGB32(r%, g%, b%)
216. END FUNCTION
217.  
218. FUNCTION rand% (lo%, hi%)
219.  rand% = INT(RND * (hi% - lo% + 1)) + lo%
220. END FUNCTION
221.  
222. SUB drawshooter (x, y, radianAngle) 'simple red iso triangle pointed towards radianAngle
223.  'calculate 3 points of triangle shooter
224.  x1 = x + 60 * COS(radianAngle) 'main point of shooter according to heading
225.  y1 = y + 60 * SIN(radianAngle)
226.  x2 = x + 30 * COS(radianAngle + _PI(2 / 3)) 'next two points are 120 degrees off main point in direction
227.  y2 = y + 30 * SIN(radianAngle + _PI(2 / 3))
228.  x3 = x + 30 * COS(radianAngle - _PI(2 / 3))
229.  y3 = y + 30 * SIN(radianAngle - _PI(2 / 3))
230.  fTri x, y, x1, y1, x2, y2, _RGB(255, 0, 0)
231.  fTri x, y, x1, y1, x3, y3, _RGB(255, 0, 0)
232.  LINE (x1, y1)-(x2, y2), _RGB32(255, 255, 128)
233.  LINE (x1, y1)-(x3, y3), _RGB32(255, 255, 128)
234.  LINE (x1, y1)-(x, y), _RGB32(255, 255, 128)
235. END SUB
236.  
237. FUNCTION shotprocess (Count%%)
238.  IF Count%% THEN 'are there active shots to move
239.   FOR i%% = 0 TO Count%% - 1
240.    Shot(i%%).Xloc = Shot(i%%).Xloc + Shot(i%%).DXval
241.    Shot(i%%).Yloc = Shot(i%%).Yloc + Shot(i%%).DYval
242.  
243.    'check for shot hitting rat
244.    IF RatCollision(i%%) THEN behappy = yes
245.  
246.    IF Shot(i%%).Xloc > 0 AND Shot(i%%).Xloc < ScrnX AND Shot(i%%).Yloc > 0 AND Shot(i%%).Yloc < ScrnY THEN 'in bounds draw it
247.     fcirc Shot(i%%).Xloc, Shot(i%%).Yloc, 2, _RGB32(170, 130, 10)
248.    ELSE 'shot is off screen
249.     Shot(i%%).RemFlag = TRUE
250.    END IF
251.   NEXT i%%
252.   'check for offscreen shots
253.   FOR j%% = 0 TO Count%%
254.    IF Shot(j%%).RemFlag THEN 'shot is flaged for removal from rathit or offscreen
255.     FOR i%% = j%% TO Count%% + 1
256.      Shot(i%%).Xloc = Shot(i%% + 1).Xloc
257.      Shot(i%%).Yloc = Shot(i%% + 1).Yloc
258.      Shot(i%%).DXval = Shot(i%% + 1).DXval
259.      Shot(i%%).DYval = Shot(i%% + 1).DYval
260.      Shot(i%%).RemFlag = Shot(i%% + 1).RemFlag
261.     NEXT i%%
262.     Count%% = Count%% - 1
263.    END IF
264.   NEXT j%%
265.  END IF
266.  shotprocess = Count%%
267. END FUNCTION
268.  
269. FUNCTION NewShot (id%%)
270.  'fire a bullet
271.  Shot(id%%).Xloc = P.Xloc + 3 * BulletSpeed * COS(P.Rot)
272.  Shot(id%%).Yloc = P.Yloc + 3 * BulletSpeed * SIN(P.Rot)
273.  Shot(id%%).DXval = BulletSpeed * COS(P.Rot)
274.  Shot(id%%).DYval = BulletSpeed * SIN(P.Rot)
275.  Shot(id%%).RemFlag = FALSE
276.  id%% = id%% + 1
277.  NewShot = id%%
278. END FUNCTION
279.  
280. SUB PlayerMovement
281.  'move player around if they have momentum
282.  P.Xloc = P.Xloc + P.Momentum * COS(P.ThrstRot)
283.  P.Yloc = P.Yloc + P.Momentum * SIN(P.ThrstRot)
284.  'stop the player if they encroach upon the screen bounds
285.  IF P.Xloc < 30 OR P.Yloc < 30 OR P.Xloc > ScrnX - 30 OR P.Yloc > ScrnY - 30 THEN P.Momentum = 0
286.  'now that does allow player to move extreamly slow, like they are stuck in tar! but they
287.  'can still leave screen, in that case they lose a life.
288.  
289.  IF P.Xloc <= 0 OR P.Xloc >= ScrnX OR P.Yloc <= 0 OR P.Yloc >= ScrnY THEN
290.   P.Life = P.Life + 1 'player left screen by force! KILL EM'
291.   P.Xloc = ScrnX \ 2: P.Yloc = ScrnY \ 2
292.  END IF
293. END SUB
294.  
295. FUNCTION RatCollision (id%%)
296.  FOR j%% = 0 TO RatCount * P.Life
297.   check~& = POINT(Shot(id%%).Xloc, Shot(id%%).Yloc)
298.   IF check~& <> 0 THEN 'if bullet finds a nother color
299.    FOR i%% = 0 TO RatCount * P.Life 'which rat was hit.
300.     IF Rats(i%%).Colr = check~& THEN 'found dead rat
301.      'give player points
302.      P.Points = P.Points + (RatScore - Rats(i%%).Siz)
303.      'kill that rat
304.      newRat i%%
305.      'kill the shot
306.      Shot(id%%).RemFlag = TRUE
307.      'exit the for next loop
308.      i%% = RatCount * P.Life + 2
309.     END IF
310.    NEXT i%%
311.    results%% = TRUE
312.   ELSE
313.    results%% = FALSE
314.   END IF
315.  NEXT j%%
316.  RatCollision = results%%
317. END FUNCTION
318.  

Title: Re: eRATication
Post by: bplus on July 20, 2018, 12:25:26 pm

Hi Cobalt,

To me, it seems like you are a little stingy with the bullets. ;-))

But it appears you are moving the shooter like I did with Lander, which is cool, specially now that I have practiced. :)

Oh I also meant to report I have tried the idea I mentioned above and love the control!!

Title: Re: eRATication
Post by: Cobalt on July 20, 2018, 05:09:18 pm

Quote from: bplus on July 20, 2018, 12:25:26 pm

To me, it seems like you are a little stingy with the bullets. ;-))

It does add a bit of difficulty doesn't it! It may become part of the difficulty setting if I go that far with this.

Quote from: bplus on July 20, 2018, 12:25:26 pm

But it appears you are moving the shooter like I did with Lander, which is cool, specially now that I have practiced. :)

not totally happy with it, as if your drifting and thrust again you instantly start moving in the new direction instead of slowing down\stopping first, but fixing that is beyond my skill.

but I have the Title screen done and have added sounds with background music! Check it out!
Haven't converted the wav to mp3 yet cause I'm still tweaking them, rest assured when I decide I'm happy with them they will be compressed down to mp3 files. The BGM came that way thats why it already is. The sounds are from 'FreeSound.org' and the BGM is from 'dig.ccmixter.org' , a credits screen is in the works but not there yet.

Title: Re: eRATication
Post by: bplus on July 20, 2018, 07:18:13 pm

Quote

' 2018-07-20 eRATication 3
' Shooter: location controlled by mouse
'          mouse left and right button works like left and right arrow keys.
' Code: use type for objects, simplify math where possible
'       complete makeover of code.
'       Fixed problem of running into burning rat.
' Display: Life # and Points on screen as Fellippe suggested.
' Points: should be directly proportional to rat's speed and indirectly
'          proportional to size, so speed\size!
'          but compare that to number of shots taken!


'================================ Instructions ==========================
' Up and down arrows for fast rotation of shooter.
' Left and right arrows for more fine tuned rotation of shooter.
' Shooter is connected to mouse, moving mouse moves shooter.
' Left mouse button down for counter-clock wise rotation and
' Right mouse button down for clock- wise rotation.
' Spacebar fires bullets.
'========================================================================

DEFINT A-Z

Text Only | Text with Attachments