Print Page - Complete Input Popup Menu

Code: QB64: [Select]

SCREEN _NEWIMAGE(640, 480, 32)
$COLOR:32
RANDOMIZE TIMER
 
FOR i = 1 TO 100
    'LINE (RND * 640, RND * 640)-(RND * 640, RND * 640), &HFF000000 + RND * &HFFFFFF, BF
NEXT
 
 
 
choice = PopUpMenu("New|Start|Run|Quit", 100, 100, 16, 2, _RGB32(255, 255, 0), _RGB32(255, 128, 255))
CLS , SkyBlue
PRINT "You chose choice #"; choice
 
f = _LOADFONT("courbd.ttf", 72, "monospace")
 
choice = PopUpMenu("Cheese|Beef|Soda|Frog", 150, 150, f, 5, Silver, Purple)
 
PRINT choice
PRINT
PRINT "And this time you chose choice #"; choice
 
 
FUNCTION PopUpMenu (choice$, left, top, font, framesize, framecolor, fontcolor)
    D = _DEST
    fh = _FONTHEIGHT(font)
    tempimage = _NEWIMAGE(1000, 1000, 32)
    _DEST tempimage
    _FONT font
 
    DO
        count = count + 1
        REDIM _PRESERVE temp(count) AS STRING
        l = INSTR(choice$, "|")
 
        IF l THEN
            temp(count) = LEFT$(choice$, l - 1)
            choice$ = MID$(choice$, l + 1)
        ELSE
            temp(count) = choice$
        END IF
        IF _PRINTWIDTH(temp(count)) > pw THEN pw = _PRINTWIDTH(temp(count))
 
        PRINT count, temp(count)
    LOOP UNTIL l = 0
    _FREEIMAGE tempimage
 
    iw = pw + framesize * 2
    ih = fh * count + (framesize) * (count + 2) - 1
 
    tempimage = _NEWIMAGE(iw, ih, 32)
    _DEST tempimage: _FONT font
    FOR i = 0 TO framesize - 1: LINE (i, i)-(iw - i, ih - i), framecolor, B: NEXT
 
    COLOR fontcolor, 0
    FOR i = 1 TO UBOUND(temp)
        Center fh * (i - 1) + framesize * (i + 1), temp(i), tempimage
    NEXT
    Highlight = BoxImage(iw - framesize + 2, fh + framesize * 2, framesize, 0, fontcolor)
    _DEST Highlight: CLS , 0
    FOR i = 0 TO framesize - 1: LINE (i, i)-(iw - i - framesize * 2, fh + framesize - i), fontcolor, B: NEXT
    _DEST D
 
    BG = _NEWIMAGE(_WIDTH(D), _HEIGHT(D), 32)
    _PUTIMAGE , D, BG
    PopUpMenu = 1
    B = _BLEND(D)
 
    oldmouse = -1
    DO
        _DONTBLEND D
        _PUTIMAGE , BG, D 'Restore our original background
        _BLEND D
        _PUTIMAGE (left, top), tempimage, D 'Put our options on the screen
        _PUTIMAGE (left + framesize, top + (fh + framesize) * (PopUpMenu - 1) + framesize), Highlight, D 'put our highlight onto the screen
        k = _KEYHIT
        SELECT CASE k
            CASE 20480: PopUpMenu = (PopUpMenu + 1) 'down
            CASE 18432: PopUpMenu = (PopUpMenu - 1) 'up
            CASE 13, 32: EXIT DO 'space or enter to select
        END SELECT
 
        scroll = 0
        WHILE _MOUSEINPUT
            scroll = scroll + _MOUSEWHEEL
        WEND
        PopUpMenu = (PopUpMenu + SGN(scroll)) 'up/down from scrolling the mousewheel
        IF _MOUSEX >= left AND _MOUSEX <= left + iw THEN 'we're in the right spot of the screen for mouse input
            IF _MOUSEY > top + framesize AND _MOUSEY < top + ih THEN
                y = (_MOUSEY - top - framesize) \ (fh + framesize * 2)
                PopUpMenu = y + 1
                IF _MOUSEBUTTON(1) AND NOT oldmouse THEN EXIT DO
            END IF
        END IF
        IF _MOUSEBUTTON(1) AND NOT oldmouse THEN EXIT DO
        'Note:  If you only want the mouse to work inside the box, and not be counted as a viable click, then
        'remark out the command above
        oldmouse = _MOUSEBUTTON(1): scroll = 0
 
 
        FOR i = 1 TO 3 'We have up/down movement on the joystick
            IF ABS(STICK(1, i) - 127) > 10 THEN PopUpMenu = PopUpMenu + SGN(STICK(1, i) - 127): _DELAY .25
        NEXT
        IF STRIG(1) AND STRIG(0) THEN EXIT DO 'Joystick button 1 was pressed.
        IF PopUpMenu > count THEN PopUpMenu = 1
        IF PopUpMenu < 1 THEN PopUpMenu = count
 
        _LIMIT 10
        _DISPLAY
    LOOP
 
    _FREEIMAGE tempimage 'free the menu text
    _FREEIMAGE Highlight 'free the highlight box
    _DONTBLEND D
    _PUTIMAGE , BG, D 'Restore our original background
    _FREEIMAGE BG 'free the background copy
    _DEST D
    IF B = 0 THEN _DONTBLEND D
    _DISPLAY
END FUNCTION
 
 
 
SUB Center (FromTop, what$, where)
    D = _DEST: pw = _PRINTWIDTH(what$): sw = _WIDTH(where) 'print width and screen width
    IF pw > sw THEN Explode "Center, with pw > sw"
    _DEST where: _PRINTSTRING ((sw - pw) \ 2, FromTop), what$: _DEST D
END SUB
 
SUB CenterImage (FromTop, what, where)
    pw = _WIDTH(what): sw = _WIDTH(where) 'print width and screen width
    IF pw > sw THEN Explode "CenterImage, with pw > sw"
    _PUTIMAGE ((sw - pw) \ 2, FromTop), what, where
END SUB
 
SUB Explode (where$)
    CLS: _AUTODISPLAY
    PRINT "YOU F'ED UP!!  THERE'S A GLITCH IN THE CODE SOMEWHERE!"
    FOR i = 1 TO 10: PRINT "FIX IT! ": BEEP: _DELAY .5: NEXT
    PRINT: PRINT: PRINT "THE GLITCH IS IN: "; where$
    END
END SUB
 
FUNCTION BoxImage (wide, tall, thick, BGcolor, FrameColor)
    D = _DEST
    BoxImage = _NEWIMAGE(wide, tall, 32)
    _DEST BoxImage
    CLS , BGcolor
    FOR i = 0 TO thick - 1
        LINE (i, i)-STEP(wide - i * 2, tall - i * 2), FrameColor, B
    NEXT
    _DEST D
END FUNCTION

The demo above should showcase what this little snippet is all about -- it pops up a menu on the screen and asks the user to respond to it. Keyboard, mouse, and joystick all should be valid methods to interact with the menu and have it do what you expect it to. Works with all fonts -- monospaced and not -- and restores your background when it closes itself.

I am trying to decide if I like this better than Right Click pop-ups, they seem more refined.

What would you (or anyone) say advantage for this menu system is?

@SMcNeill I am watching the Keyboard Library thread for Samples Gallery, Informatics probably, do you plan to add this to that library? Not completely unrelated for input tools that go nice with Extended Input.

Advantage for me, is just ease of menu integration. If you see the splash screen demo for the game I’ve been working on you’ll see this for the title screen options. It’s all self contained, builds itself, updates itself, and works with mouse, scroll wheel, joystick, and keyboard interactions. It maintains and restores background, so it can be used as a pop-up selection tool, with no worries of screen corruption. Just toss this into a mouse routine to check for Right Clicks, and this can pop-up just like those can — only offering more options with interactions, fonts, and such. ;)

Ah good! Thanks. Do you plan to include it with Keyboard Library with Extended Input?

I can, if you want. There’s also a pop-up text box, message box, and input box which I’ll be sharing soon, for those who might be interested. In the end, it’ll probably be nice to wrap them all up in a library together, but for discussion/examples, I find it easier to keep them independent to avoid any confusion anywhere. :)

Quote from: SMcNeill on November 26, 2020, 01:13:47 pm

I can, if you want. There’s also a pop-up text box, message box, and input box which I’ll be sharing soon, for those who might be interested. In the end, it’ll probably be nice to wrap them all up in a library together, but for discussion/examples, I find it easier to keep them independent to avoid any confusion anywhere. :)

Well you should do it how you want, sorry to interrupt, I was just thinking if all the parts were integrated and work well with each other ie your use of keyhit numbers working with the other parts or if you had a mouse or device routine working with all the other parts. I've discovered the need for one mouse/device handler (probably including keyboard) to cover all the box controls in a screen up at the same time.

QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on November 26, 2020, 08:17:39 am