QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on November 11, 2020, 09:53:49 am

Title: A Quick ToolTip Example
Post by: SMcNeill on November 11, 2020, 09:53:49 am

Since someone posted somewhere here the other day asking about a ToolTip type library, I thought I'd go ahead and take a moment to play around with something along those lines, as I way to get my mind distracted from the "bad handle" issue my other project keeps tossing me.   Sometimes the brain just needs to switch gears and reset, so I thought I'd pass it something completely different to work on for a little bit.  :)

Code: QB64: [Select]

1. TYPE ToolTipInfo
2.     text AS STRING
3.     x AS INTEGER
4.     y AS INTEGER
5. END TYPE
6.  
7. DIM SHARED RegisteredTips(100) AS ToolTipInfo
8.  
9. SCREEN _NEWIMAGE(800, 600, 32)
10.  
11. RegisterToolTip "Cheese is tasty and made from moo moo cows!", 245, 100
12. RegisterToolTip "A fridge is the cold thing which folks hold their cheeses in!", 380, 100
13. DO
14.     CLS
15.     _PRINTSTRING (100, 100), "People like cheese  in their fridge ."
16.     WHILE _MOUSEINPUT: WEND
17.     DisplayToolTips
18.     _LIMIT 30 'don't melt my damn CPU
19.     _DISPLAY
20. LOOP UNTIL _KEYDOWN(27)
21.  
22.  
23.  
24.  
25.  
26. SUB RegisterToolTip (what$, x, y)
27.     IF what$ = "" THEN EXIT SUB 'can't register nothing
28.     IF x < 0 OR y < 0 THEN EXIT SUB 'don't put your tooltip off the damn screen!
29.     IF x > _WIDTH - _FONTWIDTH OR y > _HEIGHT - _FONTHEIGHT THEN EXIT SUB 'honestly, I say, don't put your tooltip off the damn screen!
30.     FOR i = 1 TO 100
31.         IF RegisteredTips(i).text = "" THEN 'it's a free tooltip spot
32.             RegisteredTips(i).text = what$
33.             RegisteredTips(i).x = x
34.             RegisteredTips(i).y = y
35.             EXIT SUB 'We're done.  We've registered!
36.         END IF
37.     NEXT
38.     'If we make it to here, we failed.  Some dummy probably has more than 100 tooltips, or else they registered them inside a loop, or such.
39.     '(Note, this dummy could be your's truly...)
40. END SUB
41.  
42. SUB FreeToolTip (x, y)
43.     FOR i = 1 TO 100
44.         IF RegisteredTips(i).x = x AND RegisteredTips(i).y = y THEN 'it's a free tooltip spot
45.             RegisteredTips(i).text = ""
46.             RegisteredTips(i).x = -1
47.             RegisteredTips(i).y = -1
48.             EXIT SUB 'We're done.  We've registered!
49.         END IF
50.     NEXT
51. END SUB
52.  
53. SUB DisplayToolTips
54.     STATIC Qbox AS LONG
55.     d = _DEST
56.  
57.     IF Qbox = 0 THEN
58.         Qbox = _NEWIMAGE(_FONTWIDTH, _FONTHEIGHT, 32)
59.         _DEST Qbox
60.         COLOR _RGB32(255, 255, 0), _RGB32(0, 0, 128) 'Yellow on blue
61.         _PRINTSTRING (0, 0), "?"
62.     END IF
63.     FOR i = 1 TO 100
64.         IF RegisteredTips(i).text <> "" THEN
65.             _PUTIMAGE (RegisteredTips(i).x, RegisteredTips(i).y), Qbox
66.             IF _MOUSEX >= RegisteredTips(i).x AND _MOUSEX < RegisteredTips(i).x + _FONTWIDTH THEN 'in right spot
67.                 IF _MOUSEY >= RegisteredTips(i).y AND _MOUSEY < RegisteredTips(i).y + _FONTHEIGHT THEN 'we're REALLY in the right spot
68.                     'show that damn tool tip
69.  
70.                     temp = _PRINTWIDTH(RegisteredTips(i).text)
71.                     h = (temp \ (_WIDTH \ 2) + 3) * _FONTHEIGHT
72.                     temp = _NEWIMAGE(_WIDTH \ 2, h, 32)
73.                     _DEST temp
74.                     CLS , _RGB32(255, 255, 255) 'white background
75.                     COLOR _RGB32(0, 0, 0), 0
76.                     LOCATE 2, 1: PRINT RegisteredTips(i).text;
77.                     _DEST d
78.                     _PUTIMAGE (RegisteredTips(i).x, RegisteredTips(i).y - h), temp
79.                     _FREEIMAGE temp
80.                 END IF
81.             END IF
82.         END IF
83.     NEXT
84.     _DEST d
85. END SUB

There's a million different ways to do one of these, but I chose one of the simplest just to kinda highlight the process behind them.  At their heart, they're nothing more than a little routine which "designates proper coordinate for the mouse to be at to generate a pop up", "check to see if the mouse is in those coordinates", "if so, then pop up something!"

For this to be a proper little routine, it needs some work on positioning of the tooltip (right now, you can pop it up with portions -- or even the whole thing -- completely offscreen), but it's basically the process one would use for this type of job. 

It could also use a slightly smarter detection method, and background storage/replacement, but those are "advanced" features, and just complicate the basics which is what I really wanted to show here.  ;)

Anywho, it is what it is.  Maybe it'll be enough for a start to help someone sort out how they'd want to implement something similar in their own programs.  :)

Title: Re: A Quick ToolTip Example
Post by: SMcNeill on November 11, 2020, 11:19:16 am

And here's a slightly more advanced version which runs off a timer, stores its own background, and processes the mouse input for us automatically (if we want it to).

Code: QB64: [Select]

1. TYPE ToolTipInfo
2.     text AS STRING
3.     x AS INTEGER
4.     y AS INTEGER
5. END TYPE
6.  
7. DIM SHARED RegisteredTips(100) AS ToolTipInfo, t1
8. CONST True = -1, False = 0
9.  
10. t1 = _FREETIMER 'get a timer number from _FREETIMER ONLY!
11. ON TIMER(t1, .001) DisplayToolTips
12.  
13.  
14.  
15.  
16. SCREEN _NEWIMAGE(800, 600, 32)
17. CLS , _RGB32(128, 128, 0)
18. RANDOMIZE TIMER
19. FOR i = 1 TO 100 'just a background to get and restore
20.     LINE (RND * 800, RND * 600)-(RND * 800, RND * 600), _RGB32(RND * 255, RND * 255, RND * 255), BF
21. NEXT
22.  
23. RegisterToolTip "Cheese is tasty and made from moo moo cows!", 245, 100
24. RegisterToolTip "A fridge is the cold thing which folks hold their cheeses in!", 380, 100
25.  
26. PowerToolTips True, True 'This tells us to turn tool tips ON (first true), and to have it process the mouse (second true)
27.  
28. _PRINTSTRING (100, 100), "People like cheese  in their fridge ." 'Notice we're printing once and not rebuilding the display each cycle?
29.  
30. DO
31.     _LIMIT 30 'don't melt my damn CPU
32.     _DISPLAY
33. LOOP UNTIL _KEYDOWN(27)
34.  
35.  
36. SUB PowerToolTips (OnOff, MouseNoMouse)
37.     IF OnOff THEN
38.         TIMER(t1) ON
39.     ELSE
40.         TIMER(t1) OFF
41.     END IF
42.     RegisteredTips(0).y = MouseNoMouse
43. END SUB
44.  
45.  
46. SUB RegisterToolTip (what$, x, y)
47.     IF what$ = "" THEN EXIT SUB 'can't register nothing
48.     IF x < 0 OR y < 0 THEN EXIT SUB 'don't put your tooltip off the damn screen!
49.     IF x > _WIDTH - _FONTWIDTH OR y > _HEIGHT - _FONTHEIGHT THEN EXIT SUB 'honestly, I say, don't put your tooltip off the damn screen!
50.     FOR i = 1 TO 100
51.         IF RegisteredTips(i).text = "" THEN 'it's a free tooltip spot
52.             RegisteredTips(i).text = what$
53.             RegisteredTips(i).x = x
54.             RegisteredTips(i).y = y
55.             EXIT SUB 'We're done.  We've registered!
56.         END IF
57.     NEXT
58.     'If we make it to here, we failed.  Some dummy probably has more than 100 tooltips, or else they registered them inside a loop, or such.
59.     '(Note, this dummy could be your's truly...)
60. END SUB
61.  
62. SUB FreeToolTip (x, y)
63.     FOR i = 1 TO 100
64.         IF RegisteredTips(i).x = x AND RegisteredTips(i).y = y THEN 'it's a free tooltip spot
65.             RegisteredTips(i).text = ""
66.             RegisteredTips(i).x = -1
67.             RegisteredTips(i).y = -1
68.             EXIT SUB 'We're done.  We've registered!
69.         END IF
70.     NEXT
71. END SUB
72.  
73. SUB DisplayToolTips
74.     STATIC Qbox AS LONG, Background AS LONG, Bx, By
75.     d = _DEST
76.  
77.     IF Qbox = 0 THEN
78.         Qbox = _NEWIMAGE(_FONTWIDTH, _FONTHEIGHT, 32)
79.         _DEST Qbox
80.         COLOR _RGB32(255, 255, 0), _RGB32(0, 0, 128) 'Yellow on blue
81.         _PRINTSTRING (0, 0), "?"
82.     END IF
83.  
84.     IF RegisteredTips(i).y THEN WHILE _MOUSEINPUT: WEND 'If required, then read/update the mouse
85.  
86.     FOR i = 1 TO 100
87.         IF RegisteredTips(i).text <> "" THEN _PUTIMAGE (RegisteredTips(i).x, RegisteredTips(i).y), Qbox
88.     NEXT
89.  
90.  
91.     FOR i = 1 TO 100
92.         IF RegisteredTips(i).text <> "" THEN
93.             IF _MOUSEX >= RegisteredTips(i).x AND _MOUSEX < RegisteredTips(i).x + _FONTWIDTH AND _MOUSEY >= RegisteredTips(i).y AND _MOUSEY < RegisteredTips(i).y + _FONTHEIGHT THEN 'we're in the right spot
94.                 'show that damn tool tip
95.                 IF Background THEN
96.                     _PUTIMAGE (Bx, By), Background, d
97.                     _FREEIMAGE Background
98.                     Background = 0
99.                 END IF
100.                 temp = _PRINTWIDTH(RegisteredTips(i).text)
101.                 h = (temp \ (_WIDTH \ 2) + 3) * _FONTHEIGHT
102.                 temp = _NEWIMAGE(_WIDTH \ 2, h, 32)
103.                 Background = _NEWIMAGE(_WIDTH \ 2, h, 32)
104.                 _DEST temp
105.                 CLS , _RGB32(255, 255, 255) 'white background
106.                 COLOR _RGB32(0, 0, 0), 0
107.                 LOCATE 2, 1: PRINT RegisteredTips(i).text;
108.                 _DEST d
109.                 Bx = RegisteredTips(i).x: By = RegisteredTips(i).y - h
110.                 _PUTIMAGE , d, Background, (Bx, By)-STEP(_WIDTH \ 2 - 1, h - 1)
111.                 _PUTIMAGE (Bx, By), temp
112.                 _FREEIMAGE temp
113.                 _DEST d
114.                 EXIT SUB
115.             END IF
116.         END IF
117.     NEXT
118.     IF Background THEN
119.         _PUTIMAGE (Bx, By), Background, d
120.         _FREEIMAGE Background
121.         Background = 0
122.     END IF
123.     _DEST d
124.     IF _AUTODISPLAY = 0 THEN _DISPLAY
125. END SUB

If you notice, my main program loop is just this:

DO
    _LIMIT 30 'don't melt my damn CPU
    _DISPLAY
LOOP UNTIL _KEYDOWN(27)

Everything is handled by the timer and our sub routines, which we call with these few lines:

RegisterToolTip "Cheese is tasty and made from moo moo cows!", 245, 100
RegisterToolTip "A fridge is the cold thing which folks hold their cheeses in!", 380, 100

PowerToolTips True, True 'This tells us to turn tool tips ON (first true), and to have it process the mouse (second true)


It really is that simple.  ;)

Text Only | Text with Attachments