QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Pete on October 29, 2020, 02:58:12 am

Title: Wouldn't it be nice if TYPE could be used with STATIC? Oh it can! Thanks BPlus!
Post by: Pete on October 29, 2020, 02:58:12 am

Maybe it can, and just have't figured out how, but doing a flow-through library routine, I just had to define as STATIC 30 variables. I used 3 types for these, so it would have been nie to be able to do something like...

STATIC margin, scrollbar, cursor

instead of what is required...

STATIC margin.left, margin.right, margin.top, margin.bottom, scrollbar.top, scrollbar.bottom, scrollbar.index

etc., etc, etc.

It is neat that you can use TYPE in subs with QB64. I don't believe that was possible in QBasic, but it would be cool to be able to use TYPE in a STATIC statement, to cut down on typing in so many static variables in a sub.

Pete

Title: Re: Wouldn't it be nice if TYPE could be used with STATIC?
Post by: bplus on October 29, 2020, 11:15:28 am

Ah, I don't use STATIC much (I prefer SHARE at module level and being careful with name), STATIC doesn't work for UDT's?

No it works!

Code: QB64: [Select]

1. TYPE xy
2.     x AS INTEGER
3.     y AS INTEGER
4. END TYPE
5.  
6. FOR i = 1 TO 20
7.     foo irnd%(-10, 10), irnd%(-100, 100), lowX, lowY
8.     PRINT i, lowX, lowY
9. NEXT
10.  
11.  
12. SUB foo (a, b, xOut, yOut)
13.     STATIC lowAB AS xy, beenHere
14.     IF beenHere = 0 THEN
15.         lowAB.x = 1000: lowAB.y = 1000
16.         beenHere = 1
17.     END IF
18.     IF a < lowAB.x THEN lowAB.x = a
19.     IF b < lowAB.y THEN lowAB.y = b
20.     xOut = lowAB.x
21.     yOut = lowAB.y
22. END SUB
23.  
24. FUNCTION irnd% (n1, n2) 'return an integer between 2 numbers
25.     DIM l%, h%
26.     IF n1 > n2 THEN l% = n2: h% = n1 ELSE l% = n1: h% = n2
27.     irnd% = INT(RND * (h% - l% + 1)) + l%
28. END FUNCTION
29.  
30.  

Title: Re: Wouldn't it be nice if TYPE could be used with STATIC?
Post by: Pete on October 29, 2020, 05:28:52 pm

That's a more complicated use of TYPE than I use. Actually, up until this year, I never used TYPE.

So I looked over your code example, but I must have goofed somewhere when applying it to mine. Wait, I'm back. Woohoo. I just goofed on forgetting to remove one element.

So the first one works, by explicitly placing each variable in the STATIC statements, and now, thanks to your helpful example, the second one works, too!

Scroll bar demo library. This code does not use or make files.

Code: QB64: [Select]

1. ' MAIN DEMO -----------------------------------------------------------------
2. DIM SHARED debug%
3. DO: PRINT "Input screen width: 60 - 140, blank for default demo or -1 for debug mode: ";: INPUT screen_width%
4.     IF screen_width% = -1 THEN debug% = -1: m_top% = 1: m_bottom% = 5: m_left% = 124: m_right% = 8: screen_width% = 150: text_lines% = 99: GOTO make_fake_text ' Debug mode.
5.     IF screen_width% = 0 THEN m_top% = 0: m_bottom% = 0: m_left% = 10: m_right% = 12: screen_width% = 80: text_lines% = 99: GOTO make_fake_text ' Use defaults for demo.
6.     IF screen_width% >= 60 AND screen_width% <= 140 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
7. LOOP
8. DO: PRINT "Input number of text entries 10 - 99: ";: INPUT text_lines%
9.     IF text_lines% >= 10 AND text_lines% <= 99 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
10. LOOP
11. DO: PRINT "Input margin top 0 to 10: ";: INPUT m_top%
12.     IF m_top% >= 0 AND m_top% <= 10 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
13. LOOP
14. DO: PRINT "Input margin bottom 0 to 10: ";: INPUT m_bottom%
15.     IF m_bottom% >= 0 AND m_bottom% <= 10 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
16. LOOP
17. DO: PRINT "Input margin left 0 to 20: ";: INPUT m_left%
18.     IF m_left% >= 0 AND m_left% <= 20 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
19. LOOP
20. DO: PRINT "Input margin right: 2 to 20: ";: INPUT m_right%
21.     IF m_right% >= 2 AND m_right% <= 20 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
22. LOOP
23.  
24. make_fake_text:
25. CLS: REDIM mytext$(text_lines%)
26. FOR i% = 1 TO text_lines%
27.     FOR j% = 1 TO screen_width% - (m_left% + m_right%) - 3
28.         k% = (RND * 24) + 97 + 8
29.         IF k% > 122 THEN
30.             IF RIGHT$(mytext$(i%), 1) <> " " AND LEN(mytext$(i%)) THEN a$ = " " ELSE a$ = CHR$((RND * 24) + 97)
31.         ELSE
32.             a$ = CHR$(k%)
33.         END IF
34.         mytext$(i%) = mytext$(i%) + a$
35.     NEXT j%
36.     mytext$(i%) = STRING$(2 - LEN(LTRIM$(STR$(i%))), "0") + LTRIM$(STR$(i%)) + " " + mytext$(i%)
37. NEXT i%
38.  
39. WIDTH screen_width%, 25
40. IF screen_width% > 90 THEN _SCREENMOVE 0, 0
41.  
42. DO
43.     CALL scrollbar_library(mytext$(), text_lines%, m_top%, m_bottom%, m_left%, m_right%, text_row%, text_scrolled%)
44. LOOP
45. END ' -----------------------------------------------------------------------
46.  
47. SUB scrollbar_library (x$(), noe%, margin.t, margin.b, margin.l, margin.r, row%, scr%)
48.     STATIC initiate_scrb%
49.     STATIC scrn.w, scrn.h
50.     STATIC scrb.t, scrb.b, scrb.l, scrb.d, scrb.x, scrb.i, scrb.h, scrb.s
51.     STATIC cursor.find, cursor.scbrrow, cursor.scbrcol, cursor.holdscr, cursor.holdrow, cursor.holdscrbx
52.     STATIC page.h%, delay_on!, mb.l, mb.dragon, mb.drag
53.  
54.     IF initiate_scrb% = 0 THEN
55.         GOSUB getvar_setscrn
56.         initiate_scrb% = -1
57.         GOSUB displayscrn: GOSUB makescrb
58.     END IF
59.  
60.     IF debug% THEN GOSUB analize ' Debug only.
61.  
62.     GOSUB getkey
63.  
64.     EXIT SUB
65.  
66.     getvar_setscrn:
67.  
68.     TYPE margin
69.         t AS INTEGER
70.         b AS INTEGER
71.         l AS INTEGER
72.         r AS INTEGER
73.     END TYPE
74.  
75.     TYPE scrb
76.         t AS INTEGER
77.         b AS INTEGER
78.         l AS INTEGER
79.         x AS INTEGER
80.         i AS INTEGER
81.         d AS INTEGER
82.         h AS INTEGER
83.         s AS INTEGER
84.     END TYPE
85.  
86.     TYPE cursor
87.         find AS INTEGER
88.         scbrrow AS INTEGER ' row% + scr%
89.         scbrcol AS INTEGER ' POS(0)
90.         holdscr AS INTEGER ' Holds scr%
91.         holdrow AS INTEGER ' Holds row%
92.         holdscrbx AS INTEGER ' Holds scrb.x
93.     END TYPE
94.  
95.     TYPE mb
96.         l AS INTEGER
97.         r AS INTEGER
98.         m AS INTEGER
99.         drag AS INTEGER
100.         dragon AS INTEGER
101.     END TYPE
102.  
103.     scrn.w = _WIDTH
104.     scrn.h = _HEIGHT
105.     scrb.x = 0 ' Relative position of the scrollbar cursor from top of scrb.h. 0 Off / 1 to
106.     IF row% = 0 THEN row% = 1
107.  
108.     ' Calculations
109.     page.w% = scrn.w - (margin.l + margin.r)
110.     page.h% = scrn.h - (margin.t + margin.b)
111.     scrb.t = margin.t + 1
112.     scrb.b = margin.t + page.h%
113.     scrb.l = margin.l + page.w% + 2
114.     scrb.d = scrb.b - scrb.t + 1
115.     scrb.h = scrb.b - scrb.t - 1 ' Max. vertical scroll. Bar minus the top and bottom arrow symbols.
116.  
117.     LOCATE margin.t + row%, margin.l + 1, 1
118.     cursor.scbrrow = row% + scr%: cursor.scbrcol = POS(0)
119.     RETURN
120.  
121.     displayscrn:
122.     yy% = CSRLIN: xx% = POS(0)
123.     LOCATE , , 0: ' Cursor hide.
124.     j% = 0
125.     DO ' page.h% determines how mnay rows of text are displayed.
126.         j% = j% + 1
127.         LOCATE margin.t + j%, margin.l + 1
128.         PRINT x$(scr% + j%);
129.         IF j% = page.h% OR j% = noe% THEN EXIT DO
130.     LOOP
131.     LOCATE yy%, xx%
132.     IF cursor.find THEN
133.         cursor.find = 0
134.         IF cursor.scbrrow > scr% AND cursor.scbrrow <= scr% + page.h% THEN
135.             LOCATE margin.t + cursor.scbrrow - scr%, cursor.scbrcol, 1 ' Cursor show.
136.         END IF
137.     ELSE
138.         LOCATE , , 1 ' Show cursor.
139.     END IF
140.     RETURN
141.  
142.     makescrb:
143.     yy% = CSRLIN: xx% = POS(0)
144.     LOCATE scrb.t, scrb.l
145.     COLOR 0, 7
146.     PRINT CHR$(24);
147.     COLOR 7, 0
148.     FOR i% = 1 TO scrb.h
149.         LOCATE scrb.t + i%, scrb.l
150.         PRINT CHR$(177);
151.     NEXT i%
152.     LOCATE scrb.b, scrb.l
153.     COLOR 0, 7
154.     PRINT CHR$(25);
155.     COLOR 7, 0
156.  
157.     IF noe% > scrb.h + 2 THEN
158.         scrb.s = (scrb.h + 1) * 2 - noe%
159.         IF scrb.s <= 0 THEN scrb.s = 1
160.         FOR i% = 1 TO scrb.s
161.             LOCATE scrb.t + i% + scrb.x, scrb.l
162.             COLOR 1, 0
163.             PRINT CHR$(176); ' Scrollbar index cursor.
164.         NEXT
165.         COLOR 7, 0
166.     END IF
167.     LOCATE yy%, xx%
168.     RETURN
169.  
170.     getkey:
171.     _LIMIT 60 ' Can be reduced or removed. Since this is a flow-through library, this limit will affect the entire program.
172.     row% = CSRLIN - margin.t
173.     IF b$ = "" THEN b$ = INKEY$ ' Since library is flow-through b$ might be initiated by another routine.
174.     IF LEN(b$) THEN
175.         SELECT CASE b$
176.             CASE CHR$(0) + "H"
177.                 GOSUB backtocursor
178.                 IF row% + scr% > 0 THEN
179.                     IF row% = 1 THEN
180.                         IF scr% > 0 THEN
181.                             scr% = scr% - 1
182.                             GOSUB displayscrn
183.                         END IF
184.                     ELSE
185.                         row% = row% - 1
186.                     END IF
187.                     LOCATE row% + margin.t, margin.l + 1
188.                     GOSUB getcurrow
189.                 END IF
190.             CASE CHR$(0) + "P"
191.                 GOSUB backtocursor
192.                 IF row% + scr% < noe% THEN
193.                     IF row% = page.h% THEN
194.                         scr% = scr% + 1
195.                         GOSUB displayscrn
196.                     ELSE
197.                         row% = row% + 1
198.                     END IF
199.                     LOCATE row% + margin.t, margin.l + 1
200.                     GOSUB getcurrow
201.                 END IF
202.             CASE CHR$(9)
203.                 RUN
204.             CASE CHR$(27)
205.                 SYSTEM
206.         END SELECT
207.  
208.         ' Reverse algorithm. Not needed for this routine. scrb.x = scrb.i / ((noe% - scrb.d) / (scrb.h - scrb.s))
209.  
210.         IF row% + scr% >= INT((scrb.x + 1) * ((noe% - scrb.d) / (scrb.h - scrb.s))) + page.h% THEN
211.             scrb.x = scrb.x + 1
212.  
213.             GOSUB makescrb
214.  
215.             scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
216.         ELSEIF row% + scr% <= scrb.i THEN
217.             scrb.x = scrb.x - 1
218.  
219.             GOSUB makescrb
220.  
221.             scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
222.         END IF
223.         b$ = ""
224.     END IF
225.  
226.     IF delay_on! THEN ' Scrollbar delay.
227.         _DELAY delay_on!
228.         delay_on! = 0 ' Toggle off.
229.     END IF
230.  
231.     WHILE _MOUSEINPUT: WEND
232.  
233.     mb.l = _MOUSEBUTTON(1)
234.  
235.     IF mb.l THEN
236.         mx% = _MOUSEX ' Mouse column.
237.         my% = _MOUSEY ' Mouse row%.
238.  
239.         IF mx% = scrb.l AND scrb.s AND my% >= scrb.t AND my% <= scrb.b OR mb.dragon THEN ' Mouse on scrollbar or doing a bar cursor drag.
240.             SELECT CASE mb.dragon
241.                 CASE 0
242.                     IF my% = scrb.t AND scrb.x > 0 OR my% = scrb.b AND scrb.x + scrb.s < scrb.h THEN ' Mouse on a scrollbar arrow.
243.                         IF my% = scrb.t THEN scrb.x = scrb.x - 1 ELSE scrb.x = scrb.x + 1 ' Top or bottom arrow.
244.                         delay_on! = .15
245.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
246.                         scr% = scrb.i
247.                         cursor.find = -1
248.  
249.                         GOSUB displayscrn: GOSUB makescrb
250.  
251.                     ELSEIF my% - (scrb.t + 1) >= scrb.x AND my% - (scrb.t + 1) <= scrb.x + scrb.s - 1 THEN ' Mouse on scrollbar cursor.
252.                         mb.drag = my% - (scrb.t + 1)
253.                         mb.dragon = -1
254.                     ELSEIF my% > scrb.t AND my% < scrb.b OR mb.dragon THEN ' Mouse on scrollbar between scrollbar arrow and cursor.
255.                         IF my% - (scrb.t + 1) < scrb.x THEN
256.                             scrb.x = my% - (scrb.t + 1)
257.                         ELSE
258.                             scrb.x = my% - (scrb.t + 1) - (scrb.s - 1) ' The second argument compensates for large scroll cursors with fewer elements to scroll. Example: 15 elements in a 10 height scrollbar has a 3-space scrollbar cursor.
259.                         END IF
260.                         delay_on! = .15
261.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
262.                         scr% = scrb.i
263.                         cursor.find = -1
264.  
265.                         GOSUB displayscrn: GOSUB makescrb
266.  
267.                     END IF
268.  
269.                 CASE ELSE ' Scrollbar cursor drag.
270.                     IF my% - (scrb.t + 1) < mb.drag AND my% - (scrb.t + 1) - (mb.drag - scrb.x) >= 0 THEN
271.                         i% = mb.drag - scrb.x
272.                         scrb.x = my% - (scrb.t + 1) - i%
273.                         mb.drag = scrb.x + i%
274.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
275.                         scr% = scrb.i
276.                         cursor.find = -1
277.  
278.                         GOSUB displayscrn: GOSUB makescrb
279.  
280.                     ELSEIF my% - (scrb.t + 1) > mb.drag AND my% - (scrb.t + 1) + (scrb.x - mb.drag) < scrb.h - (scrb.s - 1) THEN
281.                         i% = scrb.x - mb.drag
282.                         scrb.x = my% - (scrb.t + 1) + i%
283.                         mb.drag = scrb.x - i%
284.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
285.                         scr% = scrb.i
286.                         cursor.find = -1
287.  
288.                         GOSUB displayscrn: GOSUB makescrb
289.                     ELSE
290.                         i% = my% - (scrb.t + 1)
291.                         IF i% >= scrb.t AND i% <= scrb.h THEN mb.drag = my% - (scrb.t + 1)
292.                     END IF
293.             END SELECT
294.  
295.         ELSEIF my% >= margin.t + 1 AND my% <= margin.t + page.h% THEN
296.             IF mx% >= margin.l + 1 AND mx% <= scrn.w - margin.r THEN
297.                 LOCATE my%, mx%, 1 ' Locate by left mouse click and show cursor.
298.                 GOSUB getcurrow
299.             END IF
300.         END IF
301.     ELSE
302.         mb.drag = 0: mb.dragon = 0
303.     END IF
304.     RETURN
305.  
306.     getcurrow:
307.     row% = CSRLIN - margin.t
308.     cursor.scbrrow = row% + scr%
309.     cursor.scbrcol = POS(0)
310.     cursor.holdscr = scr%
311.     cursor.holdrow = row%
312.     cursor.holdscrbx = scrb.x
313.     RETURN
314.  
315.     backtocursor:
316.     IF cursor.scbrrow > scr% AND cursor.scbrrow <= scr% + page.h% THEN
317.         ' Display region does not contain cursor. Do nothing.
318.     ELSE ' Display region contains the cursor.
319.         scr% = cursor.holdscr
320.         row% = cursor.holdrow
321.         scrb.x = cursor.holdscrbx
322.         scrb.i = scr%
323.         GOSUB makescrb
324.         GOSUB displayscrn
325.     END IF
326.     RETURN
327.  
328.     analize:
329.     ss% = CSRLIN: tt% = POS(0)
330.     LOCATE 2, 1
331.     PRINT " initiate_scrb% ="; initiate_scrb%
332.     PRINT " scrn.w ="; scrn.w; " scrn.h ="; scrn.h; scrb.s; "     "
333.     PRINT " margin.t ="; margin.t; " margin.b ="; margin.b; " margin.l ="; margin.l; " margin.r ="; margin.r; scrb.s; "     "
334.     PRINT " scrb.t ="; scrb.t; " scrb.b ="; scrb.b; " scrb.l ="; scrb.l; " scrb.d ="; scrb.d; " scrb.x = "; scrb.x; " scrb.i ="; scrb.i; " scrb.h ="; scrb.h; " scrb.s ="; scrb.s; "     "
335.     PRINT " cursor.find ="; cursor.find; " cursor.scbrrow ="; cursor.scbrrow; " cursor.scbrcol = "; cursor.scbrcol; scrb.s; "     "
336.     PRINT " cursor.holdscr ="; cursor.holdscr; " cursor.holdrow ="; cursor.holdrow; " cursor.holdscrbx ="; cursor.holdscrbx
337.     PRINT " page.h% ="; page.h%; " noe% = "; noe%; " delay_on! ="; delay_on!; " row% = "; row%; " scr% ="; scr%; " mx% ="; mx%; " my% ="; my%; " mb.l ="; mb.l; " mb.dragon ="; mb.dragon; " mb.drag ="; mb.drag; "     "
338.     LOCATE ss%, tt%
339.     _DELAY .05
340.     RETURN
341.  
342.     $IF  THEN
343.         Notes: DIM SHARED variables for a GLOBAL format option.---------------
344.         DIM SHARED initiate_scrb%
345.         DIM SHARED scrn.w, scrn.h
346.         DIM SHARED margin.t, margin.b, margin.l, margin.r
347.         DIM SHARED scrb.t, scrb.b, scrb.l, scrb.d, scrb.x, scrb.i, scrb.h, scrb.s
348.         DIM SHARED cursor.find, cursor.scbrrow, cursor.scbrcol, cursor.holdscr, cursor.holdrow, cursor.holdscrbx
349.         DIM SHARED page.h%, noe%, delay_on!, row%, scr%, mb.l, mb.dragon, mb.drag
350.     $END IF
351.  
352. END SUB

Now the same code but trying to get UDT in STATIC, unsuccessfully...

Code: QB64: [Select]

1. ' MAIN DEMO -----------------------------------------------------------------
2. DIM SHARED debug%
3. DO: PRINT "Input screen width: 60 - 140, blank for default demo or -1 for debug mode: ";: INPUT screen_width%
4.     IF screen_width% = -1 THEN debug% = -1: m_top% = 1: m_bottom% = 5: m_left% = 124: m_right% = 8: screen_width% = 150: text_lines% = 99: GOTO make_fake_text ' Debug mode.
5.     IF screen_width% = 0 THEN m_top% = 0: m_bottom% = 0: m_left% = 10: m_right% = 12: screen_width% = 80: text_lines% = 99: GOTO make_fake_text ' Use defaults for demo.
6.     IF screen_width% >= 60 AND screen_width% <= 140 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
7. LOOP
8. DO: PRINT "Input number of text entries 10 - 99: ";: INPUT text_lines%
9.     IF text_lines% >= 10 AND text_lines% <= 99 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
10. LOOP
11. DO: PRINT "Input margin top 0 to 10: ";: INPUT m_top%
12.     IF m_top% >= 0 AND m_top% <= 10 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
13. LOOP
14. DO: PRINT "Input margin bottom 0 to 10: ";: INPUT m_bottom%
15.     IF m_bottom% >= 0 AND m_bottom% <= 10 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
16. LOOP
17. DO: PRINT "Input margin left 0 to 20: ";: INPUT m_left%
18.     IF m_left% >= 0 AND m_left% <= 20 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
19. LOOP
20. DO: PRINT "Input margin right: 2 to 20: ";: INPUT m_right%
21.     IF m_right% >= 2 AND m_right% <= 20 THEN EXIT DO ELSE PRINT: PRINT "Redo...": PRINT
22. LOOP
23.  
24. make_fake_text:
25. CLS: REDIM mytext$(text_lines%)
26. FOR i% = 1 TO text_lines%
27.     FOR j% = 1 TO screen_width% - (m_left% + m_right%) - 3
28.         k% = (RND * 24) + 97 + 8
29.         IF k% > 122 THEN
30.             IF RIGHT$(mytext$(i%), 1) <> " " AND LEN(mytext$(i%)) THEN a$ = " " ELSE a$ = CHR$((RND * 24) + 97)
31.         ELSE
32.             a$ = CHR$(k%)
33.         END IF
34.         mytext$(i%) = mytext$(i%) + a$
35.     NEXT j%
36.     mytext$(i%) = STRING$(2 - LEN(LTRIM$(STR$(i%))), "0") + LTRIM$(STR$(i%)) + " " + mytext$(i%)
37. NEXT i%
38.  
39. WIDTH screen_width%, 25
40. IF screen_width% > 90 THEN _SCREENMOVE 0, 0
41.  
42. DO
43.     CALL scrollbar_library(mytext$(), text_lines%, m_top%, m_bottom%, m_left%, m_right%, text_row%, text_scrolled%)
44. LOOP
45. END ' -----------------------------------------------------------------------
46.  
47. SUB scrollbar_library (x$(), noe%, margin.t, margin.b, margin.l, margin.r, row%, scr%)
48.  
49.     STATIC initiate_scrb%, debug%, page.h%, delay_on!
50.     STATIC scrn AS my_scrn, scrb AS my_scrb, cursor AS my_cursor, mb AS my_mb
51.  
52.     IF initiate_scrb% = 0 THEN
53.         debug% = 0 ' Set to non-zero for debug data.
54.         GOSUB getvar_setscrn
55.         initiate_scrb% = -1
56.         GOSUB displayscrn: GOSUB makescrb
57.     END IF
58.  
59.     IF debug% THEN GOSUB analize ' Debug only.
60.  
61.     GOSUB getkey
62.  
63.     EXIT SUB
64.  
65.     getvar_setscrn:
66.  
67.     TYPE my_scrn
68.         w AS INTEGER
69.         h AS INTEGER
70.     END TYPE
71.  
72.     TYPE my_margin
73.         t AS INTEGER
74.         b AS INTEGER
75.         l AS INTEGER
76.         r AS INTEGER
77.     END TYPE
78.  
79.     TYPE my_scrb
80.         t AS INTEGER
81.         b AS INTEGER
82.         l AS INTEGER
83.         x AS INTEGER
84.         i AS INTEGER
85.         d AS INTEGER
86.         h AS INTEGER
87.         s AS INTEGER
88.     END TYPE
89.  
90.     TYPE my_cursor
91.         find AS INTEGER
92.         scbrrow AS INTEGER ' row% + scr%
93.         scbrcol AS INTEGER ' POS(0)
94.         holdscr AS INTEGER ' Holds scr%
95.         holdrow AS INTEGER ' Holds row%
96.         holdscrbx AS INTEGER ' Holds scrb.x
97.     END TYPE
98.  
99.     TYPE my_mb
100.         l AS INTEGER
101.         r AS INTEGER
102.         m AS INTEGER
103.         drag AS INTEGER
104.         dragon AS INTEGER
105.     END TYPE
106.  
107.     scrn.w = _WIDTH
108.     scrn.h = _HEIGHT
109.     scrb.x = 0 ' Relative position of the scrollbar cursor from top of scrb.h. 0 Off / 1 to
110.     IF row% = 0 THEN row% = 1
111.  
112.     ' Calculations
113.     page.w% = scrn.w - (margin.l + margin.r)
114.     page.h% = scrn.h - (margin.t + margin.b)
115.     scrb.t = margin.t + 1
116.     scrb.b = margin.t + page.h%
117.     scrb.l = margin.l + page.w% + 2
118.     scrb.d = scrb.b - scrb.t + 1
119.     scrb.h = scrb.b - scrb.t - 1 ' Max. vertical scroll. Bar minus the top and bottom arrow symbols.
120.  
121.     LOCATE margin.t + row%, margin.l + 1, 1
122.     cursor.scbrrow = row% + scr%: cursor.scbrcol = POS(0)
123.     RETURN
124.  
125.     displayscrn:
126.     yy% = CSRLIN: xx% = POS(0)
127.     LOCATE , , 0: ' Cursor hide.
128.     j% = 0
129.     DO ' page.h% determines how mnay rows of text are displayed.
130.         j% = j% + 1
131.         LOCATE margin.t + j%, margin.l + 1
132.         PRINT x$(scr% + j%);
133.         IF j% = page.h% OR j% = noe% THEN EXIT DO
134.     LOOP
135.     LOCATE yy%, xx%
136.     IF cursor.find THEN
137.         cursor.find = 0
138.         IF cursor.scbrrow > scr% AND cursor.scbrrow <= scr% + page.h% THEN
139.             LOCATE margin.t + cursor.scbrrow - scr%, cursor.scbrcol, 1 ' Cursor show.
140.         END IF
141.     ELSE
142.         LOCATE , , 1 ' Show cursor.
143.     END IF
144.     RETURN
145.  
146.     makescrb:
147.     yy% = CSRLIN: xx% = POS(0)
148.     LOCATE scrb.t, scrb.l
149.     COLOR 0, 7
150.     PRINT CHR$(24);
151.     COLOR 7, 0
152.     FOR i% = 1 TO scrb.h
153.         LOCATE scrb.t + i%, scrb.l
154.         PRINT CHR$(177);
155.     NEXT i%
156.     LOCATE scrb.b, scrb.l
157.     COLOR 0, 7
158.     PRINT CHR$(25);
159.     COLOR 7, 0
160.  
161.     IF noe% > scrb.h + 2 THEN
162.         scrb.s = (scrb.h + 1) * 2 - noe%
163.         IF scrb.s <= 0 THEN scrb.s = 1
164.         FOR i% = 1 TO scrb.s
165.             LOCATE scrb.t + i% + scrb.x, scrb.l
166.             COLOR 1, 0
167.             PRINT CHR$(176); ' Scrollbar index cursor.
168.         NEXT
169.         COLOR 7, 0
170.     END IF
171.     LOCATE yy%, xx%
172.     RETURN
173.  
174.     getkey:
175.     _LIMIT 60 ' Can be reduced or removed. Since this is a flow-through library, this limit will affect the entire program.
176.     row% = CSRLIN - margin.t
177.     IF b$ = "" THEN b$ = INKEY$ ' Since library is flow-through b$ might be initiated by another routine.
178.     IF LEN(b$) THEN
179.         SELECT CASE b$
180.             CASE CHR$(0) + "H"
181.                 GOSUB backtocursor
182.                 IF row% + scr% > 0 THEN
183.                     IF row% = 1 THEN
184.                         IF scr% > 0 THEN
185.                             scr% = scr% - 1
186.                             GOSUB displayscrn
187.                         END IF
188.                     ELSE
189.                         row% = row% - 1
190.                     END IF
191.                     LOCATE row% + margin.t, margin.l + 1
192.                     GOSUB getcurrow
193.                 END IF
194.             CASE CHR$(0) + "P"
195.                 GOSUB backtocursor
196.                 IF row% + scr% < noe% THEN
197.                     IF row% = page.h% THEN
198.                         scr% = scr% + 1
199.                         GOSUB displayscrn
200.                     ELSE
201.                         row% = row% + 1
202.                     END IF
203.                     LOCATE row% + margin.t, margin.l + 1
204.                     GOSUB getcurrow
205.                 END IF
206.             CASE CHR$(9)
207.                 RUN
208.             CASE CHR$(27)
209.                 SYSTEM
210.         END SELECT
211.  
212.         ' Reverse algorithm. Not needed for this routine. scrb.x = scrb.i / ((noe% - scrb.d) / (scrb.h - scrb.s))
213.  
214.         IF row% + scr% >= INT((scrb.x + 1) * ((noe% - scrb.d) / (scrb.h - scrb.s))) + page.h% THEN
215.             scrb.x = scrb.x + 1
216.  
217.             GOSUB makescrb
218.  
219.             scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
220.         ELSEIF row% + scr% <= scrb.i THEN
221.             scrb.x = scrb.x - 1
222.  
223.             GOSUB makescrb
224.  
225.             scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
226.         END IF
227.         b$ = ""
228.     END IF
229.  
230.     IF delay_on! THEN ' Scrollbar delay.
231.         _DELAY delay_on!
232.         delay_on! = 0 ' Toggle off.
233.     END IF
234.  
235.     WHILE _MOUSEINPUT: WEND
236.  
237.     mb.l = _MOUSEBUTTON(1)
238.  
239.     IF mb.l THEN
240.         mx% = _MOUSEX ' Mouse column.
241.         my% = _MOUSEY ' Mouse row%.
242.  
243.         IF mx% = scrb.l AND scrb.s AND my% >= scrb.t AND my% <= scrb.b OR mb.dragon THEN ' Mouse on scrollbar or doing a bar cursor drag.
244.             SELECT CASE mb.dragon
245.                 CASE 0
246.                     IF my% = scrb.t AND scrb.x > 0 OR my% = scrb.b AND scrb.x + scrb.s < scrb.h THEN ' Mouse on a scrollbar arrow.
247.                         IF my% = scrb.t THEN scrb.x = scrb.x - 1 ELSE scrb.x = scrb.x + 1 ' Top or bottom arrow.
248.                         delay_on! = .15
249.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
250.                         scr% = scrb.i
251.                         cursor.find = -1
252.  
253.                         GOSUB displayscrn: GOSUB makescrb
254.  
255.                     ELSEIF my% - (scrb.t + 1) >= scrb.x AND my% - (scrb.t + 1) <= scrb.x + scrb.s - 1 THEN ' Mouse on scrollbar cursor.
256.                         mb.drag = my% - (scrb.t + 1)
257.                         mb.dragon = -1
258.                     ELSEIF my% > scrb.t AND my% < scrb.b OR mb.dragon THEN ' Mouse on scrollbar between scrollbar arrow and cursor.
259.                         IF my% - (scrb.t + 1) < scrb.x THEN
260.                             scrb.x = my% - (scrb.t + 1)
261.                         ELSE
262.                             scrb.x = my% - (scrb.t + 1) - (scrb.s - 1) ' The second argument compensates for large scroll cursors with fewer elements to scroll. Example: 15 elements in a 10 height scrollbar has a 3-space scrollbar cursor.
263.                         END IF
264.                         delay_on! = .15
265.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
266.                         scr% = scrb.i
267.                         cursor.find = -1
268.  
269.                         GOSUB displayscrn: GOSUB makescrb
270.  
271.                     END IF
272.  
273.                 CASE ELSE ' Scrollbar cursor drag.
274.                     IF my% - (scrb.t + 1) < mb.drag AND my% - (scrb.t + 1) - (mb.drag - scrb.x) >= 0 THEN
275.                         i% = mb.drag - scrb.x
276.                         scrb.x = my% - (scrb.t + 1) - i%
277.                         mb.drag = scrb.x + i%
278.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
279.                         scr% = scrb.i
280.                         cursor.find = -1
281.  
282.                         GOSUB displayscrn: GOSUB makescrb
283.  
284.                     ELSEIF my% - (scrb.t + 1) > mb.drag AND my% - (scrb.t + 1) + (scrb.x - mb.drag) < scrb.h - (scrb.s - 1) THEN
285.                         i% = scrb.x - mb.drag
286.                         scrb.x = my% - (scrb.t + 1) + i%
287.                         mb.drag = scrb.x - i%
288.                         scrb.i = INT(scrb.x * ((noe% - scrb.d) / (scrb.h - scrb.s)))
289.                         scr% = scrb.i
290.                         cursor.find = -1
291.  
292.                         GOSUB displayscrn: GOSUB makescrb
293.                     ELSE
294.                         i% = my% - (scrb.t + 1)
295.                         IF i% >= scrb.t AND i% <= scrb.h THEN mb.drag = my% - (scrb.t + 1)
296.                     END IF
297.             END SELECT
298.  
299.         ELSEIF my% >= margin.t + 1 AND my% <= margin.t + page.h% THEN
300.             IF mx% >= margin.l + 1 AND mx% <= scrn.w - margin.r THEN
301.                 LOCATE my%, mx%, 1 ' Locate by left mouse click and show cursor.
302.                 GOSUB getcurrow
303.             END IF
304.         END IF
305.     ELSE
306.         mb.drag = 0: mb.dragon = 0
307.     END IF
308.     RETURN
309.  
310.     getcurrow:
311.     row% = CSRLIN - margin.t
312.     cursor.scbrrow = row% + scr%
313.     cursor.scbrcol = POS(0)
314.     cursor.holdscr = scr%
315.     cursor.holdrow = row%
316.     cursor.holdscrbx = scrb.x
317.     RETURN
318.  
319.     backtocursor:
320.     IF cursor.scbrrow > scr% AND cursor.scbrrow <= scr% + page.h% THEN
321.         ' Display region does not contain cursor. Do nothing.
322.     ELSE ' Display region contains the cursor.
323.         scr% = cursor.holdscr
324.         row% = cursor.holdrow
325.         scrb.x = cursor.holdscrbx
326.         scrb.i = scr%
327.         GOSUB makescrb
328.         GOSUB displayscrn
329.     END IF
330.     RETURN
331.  
332.     analize:
333.     ss% = CSRLIN: tt% = POS(0)
334.     LOCATE 2, 1
335.     PRINT " initiate_scrb% ="; initiate_scrb%
336.     PRINT " scrn.w ="; scrn.w; " scrn.h ="; scrn.h; scrb.s; "     "
337.     PRINT " margin.t ="; margin.t; " margin.b ="; margin.b; " margin.l ="; margin.l; " margin.r ="; margin.r; scrb.s; "     "
338.     PRINT " scrb.t ="; scrb.t; " scrb.b ="; scrb.b; " scrb.l ="; scrb.l; " scrb.d ="; scrb.d; " scrb.x = "; scrb.x; " scrb.i ="; scrb.i; " scrb.h ="; scrb.h; " scrb.s ="; scrb.s; "     "
339.     PRINT " cursor.find ="; cursor.find; " cursor.scbrrow ="; cursor.scbrrow; " cursor.scbrcol = "; cursor.scbrcol; scrb.s; "     "
340.     PRINT " cursor.holdscr ="; cursor.holdscr; " cursor.holdrow ="; cursor.holdrow; " cursor.holdscrbx ="; cursor.holdscrbx
341.     PRINT " page.h% ="; page.h%; " noe% = "; noe%; " delay_on! ="; delay_on!; " row% = "; row%; " scr% ="; scr%; " mx% ="; mx%; " my% ="; my%; " mb.l ="; mb.l; " mb.dragon ="; mb.dragon; " mb.drag ="; mb.drag; "     "
342.     LOCATE ss%, tt%
343.     _DELAY .05
344.     RETURN
345.  
346.     $IF  THEN
347.         Notes: DIM SHARED variables for a GLOBAL format option.---------------
348.         DIM SHARED initiate_scrb%
349.         DIM SHARED scrn.w, scrn.h
350.         DIM SHARED margin.t, margin.b, margin.l, margin.r
351.         DIM SHARED scrb.t, scrb.b, scrb.l, scrb.d, scrb.x, scrb.i, scrb.h, scrb.s
352.         DIM SHARED cursor.find, cursor.scbrrow, cursor.scbrcol, cursor.holdscr, cursor.holdrow, cursor.holdscrbx
353.         DIM SHARED page.h%, noe%, delay_on!, row%, scr%, mb.l, mb.dragon, mb.drag
354.     $END IF
355.  
356. END SUB
357.  

Title: Re: Wouldn't it be nice if TYPE could be used with STATIC? Oh it can! Thanks BPlus!
Post by: bplus on October 29, 2020, 07:11:32 pm

@Pete

I am surprised to see Types Defined in a SUB I do mine at top of module... but that doesn't seem a concern.  I would be careful to get a Type Defined before you do try to DIM a variable or array with STATIC AS the Type.

Just a couple of thoughts. That's a nice bit of code. Do you have an editor in a SUB? It looks close.

Title: Re: Wouldn't it be nice if TYPE could be used with STATIC? Oh it can! Thanks BPlus!
Post by: Pete on October 29, 2020, 08:35:10 pm

QB64 allows TYPE in subs, but QBasic doesn't. This was a nice addition, especially for making libraries.

I have made a few editors over the years, and I'm fiddling with something new, now. I hardly ever look back at old code, because it's just fun for me to make old things new, from scratch. What I am thinking about, is my son asks me about programs from time to time, and while he isn't into learning coding from the ground up, I have no problem with him being able to put libraries together, to build some apps. As I get older, I'll probably appreciate these libraries, too. When I first started coding, I actually did libraries for games. I stopped doing that after I started business apps, simply because I only needed one app, and it would have taken a lot longer to build everything up as libraries. Funny how what is old is new again.

Again, thanks for the help in demonstrating how to use UDT's with STATIC; much appreciated.

Pete

Text Only | Text with Attachments