Print Page - on what occasion it can be used

Active Forums => QB64 Discussion => Topic started by: Kiara87 on September 25, 2020, 05:22:12 pm

Title: on what occasion it can be used
Post by: Kiara87 on September 25, 2020, 05:22:12 pm

hi all I saw an instruction that changes a variable and is called
swap variable
then I noticed that you can also create it without swap
leaning on a third variable making a transfer of variable

uno$ = "buon"
due$ = "giorno"

tre$ = uno$
uno$ = due$
due$ = tre$

PRINT uno$, uno$
PRINT due$, due$

invece swap

a$ = "one"
b$ = "two"

SWAP a$, b$

PRINT a$
PRINT b$

my question and what can make this change useful for?

if you want to write a variable you can write one first and after the other there would be no need to change?
someone to an example of some program to make me understand why this can be useful?

Title: Re: on what occasion it can be used
Post by: bplus on September 25, 2020, 06:00:35 pm

Very often used in sorting where you want to switch the values of 2 array items so they will be in alphabetic order.

Have you ever tried making a little sort routine?

Title: Re: on what occasion it can be used
Post by: Pete on September 25, 2020, 06:27:07 pm

Quick... Someone get Steve a bucket!

Code: QB64: [Select]

REM SWAP demo to alphabetize a list...
myarray$(1) = "dog"
myarray$(2) = "cat"
myarray$(3) = "rabbit"
myarray$(4) = "frog"
myarray$(5) = "horse"
h = 5
FOR i = 1 TO h
    FOR j = 1 TO h
        IF i <> j THEN
            IF myarray$(i) < myarray$(j) THEN SWAP myarray$(i), myarray$(j)
        END IF
NEXT j, i
 
FOR i = 1 to h
PRINT myarray$(i)
NEXT
 

Pete

Title: Re: on what occasion it can be used
Post by: _vince on September 25, 2020, 06:50:57 pm

Mainly convenience, you also avoid creating a new variable tre$ which compromises code readability and possibly memory usage.

Also, some computers are faster at swapping things than copying things, this lets them know that what you really want is a mere swap which they are much more eager to perform.

Code: QB64: [Select]

un$ = "palpiti"
dos$ = "sentir "
 
 
? un$, dos$
 
for i=1 to len(un$)
        un$ = mid$(un$,1,i-1)+chr$(asc(mid$(un$, i, 1)) xor asc(mid$(dos$, i, 1)))+mid$(un$,i+1, len(un$)-1)
        dos$ = mid$(dos$,1,i-1)+chr$(asc(mid$(dos$, i, 1)) xor asc(mid$(un$, i, 1)))+mid$(dos$,i+1, len(dos$)-1)
        un$ = mid$(un$,1,i-1)+chr$(asc(mid$(un$, i, 1)) xor asc(mid$(dos$, i, 1)))+mid$(un$,i+1, len(un$)-1)
next
 
? un$, dos$
 
sleep
system
 

Title: Re: on what occasion it can be used
Post by: Kiara87 on September 26, 2020, 08:00:36 am

thank you all
I understood that it also recognizes letters if they are major or minor as in the example below
example recognizes that a is less than b and b is less than c

Code: QB64: [Select]

REM SWAP demo TO alphabetize a LIST...
myarray$(1) = "aa"
myarray$(2) = "ab"
myarray$(3) = "ac"
myarray$(4) = "ad"
myarray$(5) = "af"
myarray$(6) = "ag"
myarray$(7) = "ah"
myarray$(8) = "ai"
myarray$(9) = "al"
myarray$(10) = "am"
 
 
 
 
 
h = 10
FOR i = 1 TO h
    FOR j = 1 TO h
        IF i <> j THEN
            IF myarray$(i) < myarray$(j) THEN SWAP myarray$(i), myarray$(j)
        END IF
NEXT j, i
 
FOR i = 1 TO h
    PRINT myarray$(i)
 
NEXT

another question because the for loop only gets to 10 if I go beyond it doesn't go anymore

like in this example?

Code: QB64: [Select]

REM SWAP demo TO alphabetize a LIST...
myarray$(1) = "aa"
myarray$(2) = "ab"
myarray$(3) = "ac"
myarray$(4) = "ad"
myarray$(5) = "af"
myarray$(6) = "ag"
myarray$(7) = "ah"
myarray$(8) = "ai"
myarray$(9) = "al"
myarray$(10) = "am"
myarray$(11) = "ao"
 
 
 
 
h = 11
FOR i = 1 TO h
    FOR j = 1 TO h
        IF i <> j THEN
            IF myarray$(i) < myarray$(j) THEN SWAP myarray$(i), myarray$(j)
        END IF
NEXT j, i
 
FOR i = 1 TO h
    PRINT myarray$(i)
 
NEXT

so i can't get from a to z ?

thanks

Title: Re: on what occasion it can be used
Post by: bplus on September 26, 2020, 11:41:13 am

You have to DIM an array > 10

ie DIM MyArray$(1 to 11)

fixed

Code: QB64: [Select]

REM SWAP demo TO alphabetize a LIST...
 
DIM myArray$(1 TO 11)
myArray$(1) = "aa"
myArray$(2) = "Ab"
myArray$(3) = "ac"
myArray$(4) = "ad"
myArray$(5) = "af"
myArray$(6) = "Ag"
myArray$(7) = "ah"
myArray$(8) = "ai"
myArray$(9) = "al"
myArray$(10) = "am"
myArray$(11) = "Ao"
 
 
 
 
h = UBOUND(myArray$)
FOR i = 1 TO h - 1 '<<<<<<<<<<<< fix for slightly better code
    FOR j = i + 1 TO h '<<<<<<<< fix so j <> i ever
        'IF i <> j THEN    i <> j always!!!
        IF myArray$(i) > myArray$(j) THEN SWAP myArray$(i), myArray$(j) ' descending switch < to >
        'END IF
NEXT j, i
 
FOR i = 1 TO h
    PRINT myArray$(i)
 
NEXT
 
 

If you have to sort a much bigger array you might want something faster than this, but fine for little arrays.

Title: Re: on what occasion it can be used
Post by: Pete on September 26, 2020, 03:06:39 pm

10 arrays ought to be enough for anybody... B.G.

Title: Re: on what occasion it can be used
Post by: bplus on September 26, 2020, 06:28:57 pm

Arrays the extra then ;-))

Title: Re: on what occasion it can be used
Post by: OldMoses on September 26, 2020, 09:33:24 pm

Quote from: Pete on September 26, 2020, 03:06:39 pm

10 arrays ought to be enough for anybody... B.G.

Many moons ago, Ten Arrays put on his war paint and met Loops While True in single combat. The battle was long and GUI.

Title: Re: on what occasion it can be used
Post by: Pete on September 26, 2020, 09:39:21 pm

Now that's a post that deserves many moons. It's getting one from me right now. Oops, wrong forum, I'm Skyping on the Oprah Forum. Sorry ladies.

Pete

Title: Re: on what occasion it can be used
Post by: TempodiBasic on September 27, 2020, 02:13:16 pm

@Kiara87
hi
here an example of using Swap for graphic values

Code: QB64: [Select]

'impostare una finestra grafica/ set a graphic window
SCREEN _NEWIMAGE(800, 600, 32)
' imposta il nome finestra / set name of window
_TITLE "OpenGL 1"
 
' costanti generali / general constants
CONST True = -1, False = 0
 
' constanti colori / colors constants
CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255)
' variabili/ variables
DIM Kb AS INTEGER, Done AS INTEGER
DIM SHARED FS AS INTEGER, Init AS INTEGER
DIM SHARED Gc AS SINGLE, Rc AS SINGLE, Bc AS SINGLE, Gc1 AS SINGLE, Rc1 AS SINGLE, Bc1 AS SINGLE
'inizializzazione delle variabili /initalitation of variables
FS = True
Init = True
Kb = 0
Done = False
 
Rc = 1.0: Gc = 1.0: Bc = 0.0: Rc1 = 0.0: Gc1 = 1.0: Bc1 = 1.0
' ciclo principale /main loop
DO
    ' area di ingresso dati /area of input
    Kb = _KEYHIT
    ' traduttore dei comandi dati con tastiera/ translator commands given by keyboard
    IF Kb THEN
        ' se barra spazio cambio lo stato di FS
        IF Kb = 32 THEN
            FS = NOT FS
            Init = True
        END IF
        IF Kb = 27 THEN Done = True
        IF Kb = 13 THEN
            SWAP Gc, Gc1
            SWAP Bc, Bc1
            SWAP Rc, Rc1
        END IF
    END IF
    ' esecutore dei comandi individuati dal traduttore comandi
    ' executor of commands taken from  commands of translator
    IF FS = True THEN
        _FULLSCREEN
    ELSE
        _FULLSCREEN OFF
    END IF
LOOP UNTIL Done = True
END ' fine logica del programma / logical end of the program
 
 
'----Area Subroutines and Functions--------
 
SUB _GL ()
    'qui vanno tutte le istruzioni _gl / here all _gl instructions
    IF Init THEN
        ' area di inizializzazione/initialization area
 
        ' se  e' schermo intero imposta l'intero schermo come viewport
        ' if it is  full screen it sets whole screen as viewport
 
        IF FS THEN
            _glViewport 0, 0, _WIDTH, _HEIGHT
        ELSE
            ' se non e' schermo intero imposta il quarto in basso a destra come viewport
            ' if it is not full screen  it sets the quarter at bottom right as viewport
            _glViewport _WIDTH / 2, _HEIGHT / 2, _WIDTH, _HEIGHT
        END IF
 
        _glClearColor 0.7, 0.0, 0.0, 1.0 ' colore sfondo / background
        Init = False ' disattiva il flag  / it disactivates the flag
        'END IF
    ELSE
        _glClear (_GL_COLOR_BUFFER_BIT OR _GL_DEPTH_BUFFER_BIT) ' rigenera il color buffer bit / it clear color buffer bit
 
 
        IF FS THEN
            ' esegue a tutto schermo/ it executes in fullscreen mode
            _glBegin _GL_LINE_LOOP
            _glColor3f Rc, Gc, Bc
            _glVertex3d -1.0, -1.0, 0.0
            _glVertex3d 0.0, 1.0, 0.0
            _glVertex3d -0.0, -0.5, 0.0
            _glEnd
        ELSE
            ' esegue a finestra / it executes in window mode
            _glBegin _GL_LINE_STRIP
            _glColor3f Rc1, Gc1, Bc1
            _glVertex3d 0.0, 0.0, 0.0
            _glVertex3d 1.0, -0.6, -0.7
            _glVertex3d 1.0, 0.0, 0.0
            _glVertex3d 0.0, -0.6, -0.7
            _glEnd
        END IF
        _glFlush
    END IF
 
END SUB

every time you press Enter you change the color of the lines drawn... with Spacebar you change the mode and the lines that you can see, and at the end Escape let you quit the program.
You save to typing more code and save RAM creating less variables as our friends has shown you above.

Title: Re: on what occasion it can be used
Post by: bplus on September 27, 2020, 05:00:19 pm

I just used SWAP here: https://www.qb64.org/forum/index.php?topic=3053.msg123250#msg123250

To select the lesser of two random picked x, y coordinates for a top left corner of a box, and the other random picked x, y for the bottom right corner of a box which needed a greater x and y than used in top left corner.

Title: Re: on what occasion it can be used
Post by: SMcNeill on September 27, 2020, 06:02:46 pm

To address the simplest answer:

Swap *never* has to be used. If you want to trade values from X and Y, you can *always* use a temp variable as the go between to do so.

temp = X
X = Y
Y = temp

So why *would* you ever want to use SWAP?

1) Readability. Once you’re used to the command, it’s simply reading and deciphering one single, self-documenting function, in your code.

2) Reduced typing. With expressive character names, or types, it’s much quicker and less strain than typing multiple variables names over and over. Without using SWAP, you type those variable names six times. With it, you only type them twice. Reduce repetitive stress as much as possible — your joints will thank you for it later!

3) Less memory usage and program overhead. Adding a temp variable means allocating the memory for that variable. Now, on modern 128GB systems, 4-bytes isn’t anything to care about, but it’s never a good practice to get into making bloatware. Who knows what microprocessor/system you’ll want to code on in the future?

SWAP *never* has to be used, but generally speaking, it *should* generally be your goto method for swapping two values. When you can use it, use it. Honestly, it doesn’t make any sense not to, that I know of.

Can anyone out there think of a time/reason when it’d be best to use a temp variable as a middleman and manually do the process, ratherthan just use SWAP? I’m honestly drawing a blank on why one wouldn’t use it, when they could.

Title: Re: on what occasion it can be used
Post by: Pete on September 27, 2020, 07:16:01 pm

Quote from: SMcNeill on September 27, 2020, 06:02:46 pm

Can anyone out there think of a time/reason when it’d be best to use a temp variable as a middleman and manually do the process, ratherthan just use SWAP? I’m honestly drawing a blank on why one wouldn’t use it, when they could.

Yes, dammit, because some of us like doing everything the hard way!!!!!!

Pete :D

Title: Re: on what occasion it can be used
Post by: Kiara87 on October 02, 2020, 03:25:20 pm

obviously it doesn't make sense to use a temporary variable

since there is education

which changes the variable automatically

thank

Quote from: SMcNeill on September 27, 2020, 06:02:46 pm

To address the simplest answer:

Swap *never* has to be used. If you want to trade values from X and Y, you can *always* use a temp variable as the go between to do so.

temp = X
X = Y
Y = temp

So why *would* you ever want to use SWAP?

1) Readability. Once you’re used to the command, it’s simply reading and deciphering one single, self-documenting function, in your code.

2) Reduced typing. With expressive character names, or types, it’s much quicker and less strain than typing multiple variables names over and over. Without using SWAP, you type those variable names six times. With it, you only type them twice. Reduce repetitive stress as much as possible — your joints will thank you for it later!

3) Less memory usage and program overhead. Adding a temp variable means allocating the memory for that variable. Now, on modern 128GB systems, 4-bytes isn’t anything to care about, but it’s never a good practice to get into making bloatware. Who knows what microprocessor/system you’ll want to code on in the future?

SWAP *never* has to be used, but generally speaking, it *should* generally be your goto method for swapping two values. When you can use it, use it. Honestly, it doesn’t make any sense not to, that I know of.

Can anyone out there think of a time/reason when it’d be best to use a temp variable as a middleman and manually do the process, ratherthan just use SWAP? I’m honestly drawing a blank on why one wouldn’t use it, when they could.

Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Kiara87 on September 25, 2020, 05:22:12 pm