Print Page - Need ideas for more API usage....

Fellas, I need more ideas for API usage. Whether it be WinAPI or REST/HTTP/HTTPS. Just some ideas. I'm getting restless waiting at home for call backs for jobs I've been applying to so I'm keeping myself occupied by absorbing myself into QB64. Give me some ideas, bros.

For moving copying deleting... files something to do them in groups selected out of various folders and placed into a shopping cart then at checkout time do the function. I think moving files or copying for backup into one folder is what I have in mind. For instance I'd like to backup all QB64 folders without the exe's to save a ton of room.

So I could basically just build an array with the files that you are wanting to move and then move them to the specified directory? And I guess for the backup thing it would be like a scheduled task? I'll look into this.

@bplus Here is something I did just now....

Code: QB64: [Select]

DIM cart(5) AS STRING
cart(1) = _DIR$("desktop") + "QB64 x64\GetComputerName.bas"
cart(2) = _DIR$("desktop") + "QB64 x64\timediff.bas"
cart(3) = _DIR$("desktop") + "QB64 x64\qrtag api.bas"
cart(4) = _DIR$("desktop") + "QB64 x64\Genderize API.bas"
cart(5) = _DIR$("desktop") + "QB64 x64\rewind.png.MEM"
 
DIM dest AS STRING
dest = _DIR$("desktop")
 
a = RunTransaction(cart(), dest, 2)
 
FUNCTION RunTransaction (filecart() AS STRING, dest AS STRING, mode AS INTEGER) 'dest is optional, only used for Copy and Move
    DIM x AS INTEGER
    DIM a AS INTEGER
    IF RIGHT$(dest, 1) <> "\" THEN
        dest = dest + "\"
    END IF
    SELECT CASE mode
        CASE 1 'Recycle
            FOR x = LBOUND(filecart) TO UBOUND(filecart)
                IF filecart(x) <> "" THEN
                    a = Recycle(filecart(x))
                END IF
            NEXT
        CASE 2 'Copy
            FOR x = LBOUND(filecart) TO UBOUND(filecart)
                IF filecart(x) <> "" THEN
                    a = Copy(filecart(x), dest + StripDirectory(filecart(x)))
                END IF
            NEXT
        CASE 3 'Move
            FOR x = LBOUND(filecart) TO UBOUND(filecart)
                IF filecart(x) <> "" THEN
                    a = Move(filecart(x), dest + StripDirectory(filecart(x)))
                END IF
            NEXT
    END SELECT
END FUNCTION
 
FUNCTION StripDirectory$ (OFile$)
    DO
        OFile$ = RIGHT$(OFile$, LEN(OFile$) - INSTR(OFile$, "\"))
    LOOP WHILE INSTR(OFile$, "\")
    StripDirectory$ = OFile$
END FUNCTION

hmm... maybe not enough of a challenge.

I realized I could write the backup thing with QB64, I'm pretty sure, specially after we were doing trees of our files.

I would like to write a QB64 program, compile it and run it in shell from same program that wrote the program.
I don't know if API can help with that? What do you think?

@bplus
Here are screenshots from a tweak I made to the transaction thing. It can be used for your backup idea.

[ This attachment cannot be displayed inline in 'Print Page' view ] [ This attachment cannot be displayed inline in 'Print Page' view ] [ This attachment cannot be displayed inline in 'Print Page' view ]

Code: QB64: [Select]

$CONSOLE:ONLY
_DEST _CONSOLE
 
'To - From, From - To Flags
CONST FO_MOVE = &H1
CONST FO_COPY = &H2
CONST FO_DELETE = &H3
CONST FO_RENAME = &H4
 
'File Op Flags
CONST FOF_MULTIDESTFILES = &H1
CONST FOF_CONFIRMMOUSE = &H2
CONST FOF_SILENT = &H4
CONST FOF_RENAMEONCOLLISION = &H8
CONST FOF_NOCONFIRMATION = &H10
CONST FOF_WANTMAPPINGHANDLE = &H20
CONST FOF_ALLOWUNDO = &H40
CONST FOF_FILESONLY = &H80
CONST FOF_SIMPLEPROGRESS = &H100
CONST FOF_NOCONFIRMMKDIR = &H200
CONST FOF_NOERRORUI = &H400
CONST FOF_NOCOPYSECURITYATTRIBS = &H800
CONST FOF_NORECURSION = &H1000
CONST FOF_NO_CONNECTED_ELEMENTS = &H2000
CONST FOF_WANTNUKEWARNING = &H4000
CONST FOF_NORECURSEREPARSE = &H8000
CONST FOF_NO_UI = FOF_SILENT
 
'Return Values
CONST DE_SAMEFILE = &H71
CONST DE_MANYSRC1DEST = &H72
CONST DE_DIFFDIR = &H73
CONST DE_ROOTDIR = &H74
CONST DE_OPCANCELLED = &H75
CONST DE_DESTSUBTREE = &H76
CONST DE_ACCESSDENIEDSRC = &H78
CONST DE_PATHTOODEEP = &H79
CONST DE_MANYDEST = &H7A
CONST DE_INVALIDFILES = &H7C
CONST DE_DESTSAMETREE = &H7D
CONST DE_FLDDESTISFILE = &H7E
CONST DE_FILEDESTISFLD = &H80
CONST DE_FILENAMETOOLONG = &H81
CONST DE_DEST_IS_CDROM = &H82
CONST DE_DEST_IS_DVD = &H83
CONST DE_DEST_IS_CDRECORD = &H84
CONST DE_FILE_TOO_LARGE = &H85
CONST DE_SRC_IS_CDROM = &H86
CONST DE_SRC_IS_DVD = &H87
CONST DE_SRC_IS_CDRECORD = &H88
CONST DE_ERROR_MAX = &HB7
CONST UNKNOWN = &H402
CONST ERRORONDEST = &H10000
CONST DE_ROOTDIR_ERRORONDEST = &H10074
 
TYPE SHFILEOPSTRUCTA
    hwnd AS _OFFSET
    $IF 64BIT THEN
        wfunc AS _UNSIGNED _INTEGER64 'To - From, From - To Flags
    $ELSE
    wfunc AS _UNSIGNED LONG
    $END IF
    pFrom AS _OFFSET
    pTo AS _OFFSET
    fFlags AS LONG
    fAnyOperationsAborted AS _BYTE
    hNameMappings AS _OFFSET
    lpszProgressTitle AS _OFFSET
END TYPE
 
TYPE SHQUERYRBINFO
    $IF 64BIT THEN
        cbsize AS _INTEGER64
        i64Size AS _INTEGER64
        i64NumItems AS _INTEGER64
    $ELSE
    cbsize AS LONG
    i64Size AS _INTEGER64
    i64NumItems AS _INTEGER64
    $END IF
END TYPE
 
DECLARE DYNAMIC LIBRARY "Shell32"
    FUNCTION FileOperation% ALIAS SHFileOperationA (lpFileOp AS SHFILEOPSTRUCTA)
    FUNCTION EmptyRecycleBin% ALIAS SHEmptyRecycleBinA (BYVAL hwnd AS LONG, BYVAL pszRootPath AS _OFFSET, BYVAL dwFlags AS LONG)
    FUNCTION QueryRecycleBin~& ALIAS SHQueryRecycleBinA (pszRootPath AS STRING, pSHQueryRBInfo AS SHQUERYRBINFO)
END DECLARE
 
'Test code
'IF _FILEEXISTS(_DIR$("desktop") + "this is a test.txt") = 0 THEN
'    OPEN _DIR$("desktop") + "this is a test.txt" FOR OUTPUT AS #1
'    CLOSE #1
'END IF
'PRINT Copy(_DIR$("desktop") + "this is a test.txt", _DIR$("desktop") + "this is a test as well.txt")
'_DELAY 2
'PRINT Rename(_DIR$("desktop") + "this is a test as well.txt", _DIR$("desktop") + "this is a test also.txt")
'_DELAY 2
'PRINT Recycle(_DIR$("desktop") + "this is a test also.txt")
'_DELAY 2
'PRINT GetRecycleInfo
'_DELAY 2
'PRINT EmptyBin
'SLEEP
 
'DIM cart(5) AS STRING
'cart(1) = _DIR$("desktop") + "QB64 x64\GetComputerName.bas"
'cart(2) = _DIR$("desktop") + "QB64 x64\timediff.bas"
'cart(3) = _DIR$("desktop") + "QB64 x64\qrtag api.bas"
'cart(4) = _DIR$("desktop") + "QB64 x64\Genderize API.bas"
'cart(5) = _DIR$("desktop") + "QB64 x64\rewind.png.MEM"
 
'DIM dest AS STRING
'dest = _DIR$("desktop")
 
'a = RunTransaction(cart(), dest, 2)
 
'bplus backup test code
SHELL _HIDE "PowerShell Get-ChildItem '" + _STARTDIR$ + "' -exclude *.exe | where {! $_.PSIsContainer} | foreach {$_.Name} | Out-File dirslist.txt -Encoding ASCII" 'Replace _STARTDIR$ with whatever directory contains the files
'                                                                                                                                                                    used -exclude *.exe since you said you didn't want EXEs to be copied
OPEN "dirslist.txt" FOR BINARY AS #1
 
DO
    IF NOT EOF(1) THEN
        x = x + 1
        REDIM _PRESERVE filelist(x) AS STRING
        LINE INPUT #1, filelist(x)
        filelist(x) = _STARTDIR$ + "\" + filelist(x)
    END IF
LOOP UNTIL EOF(1)
CLOSE #1
DIM dest AS STRING
dest = _DIR$("desktop") + "Test Folder"
a = RunTransaction(filelist(), dest, 2)
 
FUNCTION GetRecycleInfo$
    DIM RecycleInfo AS SHQUERYRBINFO
    DIM path AS STRING
    DIM a~&
    path = "" + CHR$(0)
    RecycleInfo.cbsize = LEN(RecycleInfo)
    a~& = QueryRecycleBin(path, RecycleInfo)
    GetRecycleInfo = _TRIM$(STR$(RecycleInfo.i64Size)) + " bytes, " + _TRIM$(STR$(RecycleInfo.i64NumItems)) + " items"
END FUNCTION
 
FUNCTION Recycle% (file AS STRING)
    DIM lpFileOp AS SHFILEOPSTRUCTA
    DIM doublenull AS STRING
    doublenull = CHR$(0) + CHR$(0)
    file = file + doublenull
    lpFileOp.hwnd = _WINDOWHANDLE
    lpFileOp.wfunc = FO_DELETE
    lpFileOp.pFrom = _OFFSET(file)
    lpFileOp.fFlags = FOF_ALLOWUNDO + FOF_WANTNUKEWARNING
    Recycle = FileOperation(lpFileOp)
END FUNCTION
 
FUNCTION Copy% (file AS STRING, dest AS STRING)
    DIM lpFileOp AS SHFILEOPSTRUCTA
    DIM doublenull AS STRING
    doublenull = CHR$(0) + CHR$(0)
    file = file + doublenull
    dest = dest + doublenull
    lpFileOp.hwnd = _WINDOWHANDLE
    lpFileOp.wfunc = FO_COPY
    lpFileOp.pFrom = _OFFSET(file)
    lpFileOp.pTo = _OFFSET(dest)
    lpFileOp.fFlags = FOF_ALLOWUNDO
    Copy = FileOperation(lpFileOp)
END FUNCTION
 
FUNCTION Move% (file AS STRING, dest AS STRING)
    DIM lpFileOp AS SHFILEOPSTRUCTA
    DIM doublenull AS STRING
    doublenull = CHR$(0) + CHR$(0)
    file = file + doublenull
    dest = dest + doublenull
    lpFileOp.hwnd = _WINDOWHANDLE
    lpFileOp.wfunc = FO_MOVE
    lpFileOp.pFrom = _OFFSET(file)
    lpFileOp.pTo = _OFFSET(dest)
    lpFileOp.fFlags = FOF_ALLOWUNDO
    Move = FileOperation(lpFileOp)
END FUNCTION
 
FUNCTION Rename% (file AS STRING, newname AS STRING)
    DIM lpFileOp AS SHFILEOPSTRUCTA
    DIM doublenull AS STRING
    doublenull = CHR$(0) + CHR$(0)
    file = file + doublenull
    newname = newname + doublenull
    lpFileOp.hwnd = _WINDOWHANDLE
    lpFileOp.wfunc = FO_RENAME
    lpFileOp.pFrom = _OFFSET(file)
    lpFileOp.pTo = _OFFSET(newname)
    lpFileOp.fFlags = FOF_ALLOWUNDO
    Rename = FileOperation(lpFileOp)
END FUNCTION
 
FUNCTION EmptyBin%
    DIM drive AS STRING
    drive = ""
    EmptyBin = EmptyRecycleBin(0, _OFFSET(drive), 0)
END FUNCTION
 
FUNCTION RunTransaction (filecart() AS STRING, dest AS STRING, mode AS INTEGER) 'dest is optional, only used for Copy and Move
    DIM x AS INTEGER
    DIM a AS INTEGER
    IF RIGHT$(dest, 1) <> "\" THEN
        dest = dest + "\"
    END IF
    SELECT CASE mode
        CASE 1 'Recycle
            FOR x = LBOUND(filecart) TO UBOUND(filecart)
                IF filecart(x) <> "" THEN
                    a = Recycle(filecart(x))
                    PRINT "Recycling item "; x; " of "; UBOUND(filecart); " ("; filecart(x); ")"
                END IF
            NEXT
        CASE 2 'Copy
            FOR x = LBOUND(filecart) TO UBOUND(filecart)
                IF filecart(x) <> "" THEN
                    a = Copy(filecart(x), dest + StripDirectory(filecart(x)))
                    PRINT "Copying item "; x; " of "; UBOUND(filecart); " ("; filecart(x); ")"
                END IF
            NEXT
        CASE 3 'Move
            FOR x = LBOUND(filecart) TO UBOUND(filecart)
                IF filecart(x) <> "" THEN
                    a = Move(filecart(x), dest + StripDirectory(filecart(x)))
                    PRINT "Moving item "; x; " of "; UBOUND(filecart); " ("; filecart(x); ")"
                END IF
            NEXT
    END SELECT
END FUNCTION
 
FUNCTION StripDirectory$ (OFile$)
    DO
        OFile$ = RIGHT$(OFile$, LEN(OFile$) - INSTR(OFile$, "\"))
    LOOP WHILE INSTR(OFile$, "\")
    StripDirectory$ = OFile$
END FUNCTION

Quote from: bplus on September 24, 2020, 12:37:17 am

I would like to write a QB64 program, compile it and run it in shell from same program that wrote the program.
I don't know if API can help with that? What do you think?

I suppose you could do this by making a console program, having it write a BAS source for a console program using PRINT commands, then SHELLing to QB64 to compile the program then SHELL the program inside the first console program which will run the new one in the same window.

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: SpriggsySpriggs on September 23, 2020, 11:29:53 pm