QB64.org Forum

Active Forums => Programs => Topic started by: Cobalt on August 12, 2020, 09:43:30 pm

Title: Changing the BIOS font.
Post by: Cobalt on August 12, 2020, 09:43:30 pm

Many moons ago Galleon set me up with a way to change the BIOS font to a custom one.
With the loss of .NET this is a copy I have been using in the game I was cloning at the time "Reaping the Dungeon"
The font was created with "FONT by Davey W Taylor" from WAY BACK! (I think it can be found in the A.B.C. archive).

Charset.h  must be placed in the QB64 folder
 

Code: QB64: [Select]

1. DECLARE LIBRARY "charset"
2.  SUB Charset_8x8 (BYVAL o AS _OFFSET)
3.  SUB Charset_8x16 (BYVAL o AS _OFFSET)
4. END DECLARE
5. DIM SHARED c16(7, 15, 255) AS _UNSIGNED _BYTE, charload AS _UNSIGNED _BYTE
6.  
7. 'Usage:
8. Load_BIOS_Font "yourfontfile.fnt"
9. Charset_8x16 _OFFSET(c16(0, 0, 0))
10.  
11.  
12. SUB Load_BIOS_Font (Font$)
13.  OPEN Font$ FOR BINARY AS #1
14.  FOR c% = 0 TO 255
15.   FOR y% = 0 TO 15
16.    GET #1, , charload
17.    FOR x% = 0 TO 7
18.     IF _READBIT(charload, x%) THEN c16(7 - x%, y%, c%) = 1 'any non-0 value should work
19.    NEXT
20.   NEXT
21.  NEXT
22.  CLOSE #1
23. END SUB
24.  
25.  

Font Edit V1.0 (c. 1995?) By Davey W. Taylor

Code: QB64: [Select]

1. DECLARE SUB char (ch%, sx%, sy%)
2. DECLARE FUNCTION getXY! (c%, x%, y%)
3. DIM SHARED fot(255) AS STRING * 16
4. xp% = 1: yp% = 1
5. cb$ = STRING$(16, 0)
6. Show:
7. ON ERROR GOTO 0
8. SCREEN 7, , 1, 1
9. CLS
10. COLOR 4, 0
11. PRINT "FONT EDIT v1.0 by Davey W Taylor"
12. LOCATE 25, 1: PRINT "Press 'H' for help";
13. LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 15, B
14. ch% = 0
15. FOR y% = 1 TO 8
16.  FOR x% = 1 TO 32
17.   sx% = (x% - 1) * 10
18.   sy% = y% * 20
19.   ch% = ch% + 1
20.   char ch%, sx%, sy%
21.  NEXT x%
22. NEXT y%
23. ml:
24. ON ERROR GOTO 0
25. DO
26.  in$ = INKEY$
27.  SELECT CASE in$
28.   CASE "h", "H"
29.    SCREEN 7, , 0, 0
30.    CLS
31.    COLOR 15, 0
32.    PRINT "Keys:"
33.    PRINT " Left/Right/Up/Down - Change character"
34.    PRINT " ENTER - Edit character"
35.    PRINT " L - Load font"
36.    PRINT " S - Save font"
37.    PRINT " ESC - Quit"
38.    PRINT
39.    PRINT "Press any key"
40.    DO: LOOP UNTIL INKEY$ <> ""
41.    SCREEN 7, , 1, 1
42.   CASE CHR$(0) + "K" 'Lt
43.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 0, B
44.    IF xp% > 1 THEN xp% = xp% - 1
45.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 15, B
46.   CASE CHR$(0) + "M" 'Rt
47.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 0, B
48.    IF xp% < 32 THEN xp% = xp% + 1
49.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 15, B
50.   CASE CHR$(0) + "H" 'Up
51.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 0, B
52.    IF yp% > 1 THEN yp% = yp% - 1
53.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 15, B
54.   CASE CHR$(0) + "P" 'Dn
55.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 0, B
56.    IF yp% < 8 THEN yp% = yp% + 1
57.    LINE ((xp% - 1) * 10, (yp% * 20))-(9 + (xp% - 1) * 10, 17 + (yp% * 20)), 15, B
58.   CASE "l", "L"
59.    SCREEN 7, , 0, 0
60.    CLS
61.    COLOR 15, 0
62.    PRINT "Load font-file: ";
63.    LINE INPUT "", f$
64.    ON ERROR GOTO nofile
65.    OPEN f$ FOR INPUT AS #1
66.    IF LOF(1) = 256 * 16 THEN er% = 0 ELSE er% = 1
67.    CLOSE #1
68.    ON ERROR GOTO 0
69.    IF er% THEN
70.     PRINT "A font-file must be exactly 256 * 16 bytes long!"
71.     DO: LOOP UNTIL INKEY$ <> ""
72.     SCREEN 7, , 1, 1
73.     GOTO ml
74.    END IF
75.    OPEN f$ FOR BINARY ACCESS READ AS #1
76.     FOR ch% = 0 TO 255
77.      GET #1, , fot(ch%)
78.     NEXT ch%
79.    CLOSE #1
80.    GOTO Show
81.   CASE "s", "S"
82.    SCREEN 7, , 0, 0
83.    CLS
84.    COLOR 15, 0
85.    PRINT "Save font-file: ";
86.    LINE INPUT "", f$
87.    chf% = 0
88.    ON ERROR GOTO fc
89.    OPEN f$ FOR INPUT AS #1
90.    CLOSE #1
91.    ON ERROR GOTO 0
92.    IF chf% = 0 THEN
93.     PRINT "File exists, overwrite? ";
94.     DO: in$ = UCASE$(INKEY$): LOOP UNTIL in$ = "Y" OR in$ = "N"
95.     IF in$ = "N" THEN
96.      SCREEN 7, , 1, 1
97.      GOTO ml
98.     END IF
99.    END IF
100.    ON ERROR GOTO diskfull
101.    OPEN f$ FOR OUTPUT AS #1
102.    CLOSE #1
103.    OPEN f$ FOR BINARY ACCESS WRITE AS #1
104.     FOR n% = 0 TO 255
105.      PUT #1, , fot(n%)
106.     NEXT n%
107.    CLOSE #1
108.    ON ERROR GOTO 0
109.    SCREEN 7, , 1, 1
110.   CASE CHR$(13)
111.    SCREEN 7, , 0, 0
112.    CLS
113.    ch% = (xp% - 1) + (32 * (yp% - 1))
114.    xe% = 1: ye% = 1
115. upd:
116.    FOR y% = 1 TO 16
117.     FOR x% = 1 TO 8
118.      xs% = 1 + (x% - 1) * 10
119.      ys% = 1 + (y% - 1) * 10
120.      IF getXY(ch%, x%, y%) THEN
121.       LINE (xs%, ys%)-(xs% + 8, ys% + 8), 14, BF
122.      ELSE
123.       LINE (xs%, ys%)-(xs% + 8, ys% + 8), 1, BF
124.      END IF
125.     NEXT x%
126.    NEXT y%
127.    LOCATE 1, 15: PRINT "up/dn/lt/rt - move cursor"
128.    LOCATE 2, 15: PRINT "space - toggle pixel"
129.    LOCATE 3, 15: PRINT "enter - when done"
130.    LOCATE 4, 15: PRINT "H - flip horizontal"
131.    LOCATE 5, 15: PRINT "V - flip vertical"
132.    LOCATE 6, 15: PRINT "I - invert"
133.    LOCATE 7, 15: PRINT "C - copy"
134.    LOCATE 8, 15: PRINT "P - paste"
135.    LOCATE 9, 15: PRINT "X - clear"
136.    LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 12, B
137.    DO
138.     in$ = INKEY$
139.     SELECT CASE in$
140.      CASE CHR$(0) + "K" 'Lt
141.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 0, B
142.       IF xe% > 1 THEN xe% = xe% - 1
143.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 12, B
144.      CASE CHR$(0) + "M" 'Rt                                
145.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 0, B
146.       IF xe% < 8 THEN xe% = xe% + 1
147.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 12, B
148.      CASE CHR$(0) + "H" 'Up
149.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 0, B
150.       IF ye% > 1 THEN ye% = ye% - 1
151.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 12, B
152.      CASE CHR$(0) + "P" 'Dn
153.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 0, B
154.       IF ye% < 16 THEN ye% = ye% + 1
155.       LINE ((xe% - 1) * 10, (ye% - 1) * 10)-(10 + (xe% - 1) * 10, 10 + (ye% - 1) * 10), 12, B
156.      CASE " "
157.       xv% = 2 ^ (8 - xe%)
158.       IF getXY(ch%, xe%, ye%) THEN
159.        MID$(fot(ch%), ye%, 1) = CHR$(ASC(MID$(fot(ch%), ye%, 1)) - xv%)
160.       ELSE
161.        MID$(fot(ch%), ye%, 1) = CHR$(ASC(MID$(fot(ch%), ye%, 1)) + xv%)
162.       END IF
163.       xs% = 1 + (xe% - 1) * 10
164.       ys% = 1 + (ye% - 1) * 10
165.       IF getXY(ch%, xe%, ye%) THEN
166.        LINE (xs%, ys%)-(xs% + 8, ys% + 8), 14, BF
167.       ELSE
168.        LINE (xs%, ys%)-(xs% + 8, ys% + 8), 1, BF
169.       END IF
170.      CASE "v", "V"
171.       v$ = fot(ch%)
172.       FOR n% = 1 TO 16
173.        MID$(fot(ch%), n%, 1) = MID$(v$, 17 - n%, 1)
174.       NEXT n%
175.       GOTO upd
176.      CASE "h", "H"
177.       v$ = STRING$(16, 0)
178.       FOR y% = 1 TO 16
179.        FOR x% = 1 TO 8
180.         xv% = 2 ^ (x% - 1)
181.         IF getXY(ch%, x%, y%) THEN
182.          MID$(v$, y%, 1) = CHR$(ASC(MID$(v$, y%, 1)) + xv%)
183.         END IF
184.        NEXT x%
185.       NEXT y%
186.       fot(ch%) = v$
187.       GOTO upd
188.      CASE "i", "I"
189.       v$ = fot(ch%)
190.       FOR n% = 1 TO 16
191.        MID$(fot(ch%), n%, 1) = CHR$(255 - ASC(MID$(v$, n%, 1)))
192.       NEXT n%
193.       GOTO upd
194.      CASE "c", "C"
195.       cb$ = fot(ch%)
196.      CASE "p", "P"
197.       fot(ch%) = cb$
198.       GOTO upd
199.      CASE "x", "X"
200.       fot(ch%) = STRING$(16, 0)
201.       GOTO upd
202.     END SELECT
203.    LOOP UNTIL in$ = CHR$(13)
204.    SCREEN 7, , 1, 1
205.    sx% = (xp% - 1) * 10
206.    sy% = yp% * 20
207.    char ch% + 1, sx%, sy%
208.   CASE CHR$(27)
209.    SCREEN 7, , 0, 0
210.    CLS
211.    COLOR 15, 0
212.    PRINT "Save your work first? ";
213.    DO: in$ = UCASE$(INKEY$): LOOP UNTIL in$ = "N" OR in$ = "Y"
214.    IF in$ = "Y" THEN
215.     PRINT "Y"
216.     PRINT "Save font-file: ";
217.     LINE INPUT "", f$
218.     chf% = 0
219.     ON ERROR GOTO fc
220.     OPEN f$ FOR INPUT AS #1
221.     CLOSE #1
222.     ON ERROR GOTO 0
223.     IF chf% = 0 THEN
224.      PRINT "File exists, overwrite? ";
225.      DO: in$ = UCASE$(INKEY$): LOOP UNTIL in$ = "Y" OR in$ = "N"
226.      IF in$ = "N" THEN
227.       SCREEN 7, , 1, 1
228.       GOTO ml
229.      END IF
230.     END IF
231.     ON ERROR GOTO diskfull
232.     OPEN f$ FOR OUTPUT AS #1
233.     CLOSE #1
234.     OPEN f$ FOR BINARY ACCESS WRITE AS #1
235.      FOR n% = 0 TO 255
236.       PUT #1, , fot(n%)
237.      NEXT n%
238.     CLOSE #1
239.     ON ERROR GOTO 0
240.    END IF
241.    END
242.  END SELECT
243. LOOP
244. nofile:
245.  CLOSE #1
246.  PRINT "Can't find file!"
247.  DO: LOOP UNTIL INKEY$ <> ""
248.  SCREEN 7, , 1, 1
249.  RESUME ml
250. fc:
251.  hm% = ERR
252.  SELECT CASE ERR
253.   CASE 76, 75, 64, 52
254.    PRINT "Invalid filename!"
255.    DO: LOOP UNTIL INKEY$ <> ""
256.    SCREEN 7, , 1, 1
257.    RESUME ml
258.   CASE ELSE
259.    chf% = 1
260.    RESUME NEXT
261.  END SELECT
262. diskfull:
263.  CLOSE #1
264.  PRINT "The disk is full!"
265.  DO: LOOP UNTIL INKEY$ <> ""
266.  SCREEN 7, , 1, 1
267.  RESUME ml
268.  
269. SUB char (ch%, sx%, sy%)
270.  FOR uy% = 1 TO 16
271.   x% = ASC(MID$(fot(ch% - 1), uy%, 1))
272.   x% = 256 * (x% + (256 * (x% > 127)))
273.   LINE (sx% + 1, sy% + uy%)-(sx% + 8, sy% + uy%), 1
274.   LINE (sx% + 1, sy% + uy%)-(sx% + 8, sy% + uy%), 14, , x%
275.  NEXT uy%
276. END SUB
277.  
278. FUNCTION getXY (c%, x%, y%)
279. xv% = 2 ^ (8 - x%)
280. B% = ASC(MID$(fot(c%), y%, 1))
281. getXY = SGN(B% AND xv%)
282. END FUNCTION
283.  
284.  

Title: Re: Changing the BIOS font.
Post by: FellippeHeitor on August 12, 2020, 09:53:44 pm

Thanks for sharing, Cobalt.

Text Only | Text with Attachments