Print Page - Is there a way to scale a window other than

Active Forums => QB64 Discussion => Topic started by: manstersoft on August 10, 2020, 02:29:48 pm

Title: Is there a way to scale a window other than _FULLSCREEN?
Post by: manstersoft on August 10, 2020, 02:29:48 pm

Say I'm making a program that has a resolution of 100x100 pixels. Is there a way I can scale the program to make it 200x200 and still keep its 100x100 resolution?
Same goes for Full Screen; can I scale the window to make the black frame wider/taller?

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: +KZ on August 10, 2020, 05:13:46 pm

i am using this on my program

http://www.qb64.org/wiki/NEWIMAGE

on PC-Basic i remember used SCREEN, WIDTH and HEIGHT

ignore this, I misunderstood you

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: +KZ on August 10, 2020, 09:41:15 pm

although it occurs to me that you can multiply all graphic things by 2

example:

input pixelx
input pixely
PSET pixelx x2, pixely x2

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: SMcNeill on August 10, 2020, 10:12:47 pm

http://www.qb64.org/wiki/$RESIZE Is the easiest way.

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: bplus on August 10, 2020, 10:23:16 pm

Here's a demo with Mousewheel!

Code: QB64: [Select]

_TITLE "Expand and Contract Window, move mousewheel slowly..."
SCREEN _NEWIMAGE(500, 500, 32)
' using const so the code can be more readable < great idea!
CONST GOLD = &HFFFF9900, BLACK = &HFF000000, RED = &HFFFF0000, SQ = 50
 
n = 0
LINE (46, 46)-STEP(400 + 4, 400 + 4), GOLD, BF
FOR y = 1 TO 8
    FOR x = 1 TO 8
        n = (n + 1) MOD 2
        IF n MOD 2 THEN colore& = RED ELSE colore& = BLACK
        LINE (x * SQ, y * SQ)-STEP(SQ - 4, SQ - 4), colore&, BF
    NEXT
    n = (n + 1) MOD 2 '< for even amount of squares in a row
NEXT
img& = _NEWIMAGE(500, 500, 32)
_PUTIMAGE , 0, img&
DO
    WHILE _MOUSEINPUT
        scroll = scroll + _MOUSEWHEEL
        IF scroll < 200 AND scroll > -200 THEN
            SCREEN _NEWIMAGE(500 + scroll, 500 + scroll, 32)
            _PUTIMAGE , img&, 0
        END IF
    WEND
    _DISPLAY
    _LIMIT 10
 
LOOP UNTIL _KEYDOWN(27)
 
 
 

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: SMcNeill on August 11, 2020, 12:04:42 am

You have a memory leak, bplus. Don’t forgot to freeimage all those newimage screens.

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: bplus on August 11, 2020, 01:24:21 am

Quote from: SMcNeill on August 11, 2020, 12:04:42 am

You have a memory leak, bplus. Don’t forgot to freeimage all those newimage screens.

OK Memory Usage holding steady now:

Code: QB64: [Select]

_TITLE "Expand and Contract Window, move mousewheel slowly..."
SCREEN _NEWIMAGE(500, 500, 32)
' using const so the code can be more readable < great idea!
CONST GOLD = &HFFFF9900, BLACK = &HFF000000, RED = &HFFFF0000, SQ = 50
DIM tmp&(0 TO 10)
n = 0
LINE (46, 46)-STEP(400 + 4, 400 + 4), GOLD, BF
FOR y = 1 TO 8
    FOR x = 1 TO 8
        n = (n + 1) MOD 2
        IF n MOD 2 THEN colore& = RED ELSE colore& = BLACK
        LINE (x * SQ, y * SQ)-STEP(SQ - 4, SQ - 4), colore&, BF
    NEXT
    n = (n + 1) MOD 2 '< for even amount of squares in a row
NEXT
img& = _NEWIMAGE(500, 500, 32)
_PUTIMAGE , 0, img&
lastt = 20
DO
    WHILE _MOUSEINPUT
        scroll = scroll + _MOUSEWHEEL
    WEND
    IF scroll < 200 AND scroll > -200 THEN
        t = (t + 1) MOD 10
        tmp&(t) = _NEWIMAGE(500 + scroll, 500 + scroll, 32)
        SCREEN tmp&(t)
        _PUTIMAGE , img&, 0
    END IF
 
    PRINT lastt, t
 
    IF lastt <> 20 THEN _FREEIMAGE tmp&(lastt)
    lastt = t
    _DISPLAY
    _LIMIT 10
LOOP UNTIL _KEYDOWN(27)
 
 
 

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: TempodiBasic on August 11, 2020, 08:36:50 am

Hi
but this question

Quote

Say I'm making a program that has a resolution of 100x100 pixels. Is there a way I can scale the program to make it 200x200 and still keep its 100x100 resolution?

has behind (or covers) this one?

Quote

With scaling from 100x100 to 200x200 the objects(buttons, checkbox, sprite in movement are responsive to mouse's and keyboard's input...

We have our great IDE that suffers sometimes of interaction between menu and mouse when the dimensions of its window aren't the standard or it is in fullscreen!
So if this is a simple graphic output question, the answer solves the issue, otherwise if the questions is about the interaction between user's input by mouse and keyboard and the graphic interface I think that the solution can be reached following this idea but the coder must use a variable to check the position of mouse for interaction...

I can suggest another way... the use of WINDOW SCREEN (0,0)-(100,100) on the new window created.
As Bplus stressed in another thread you must manage by hand the interaction with _mouseX _mouseY

Good Luck in coding...

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: manstersoft on August 11, 2020, 10:12:33 am

Quote from: +KZ on August 10, 2020, 09:41:15 pm

although it occurs to me that you can multiply all graphic things by 2

Quote from: bplus on August 10, 2020, 10:23:16 pm

Here's a demo with Mousewheel!

Quote from: TempodiBasic on August 11, 2020, 08:36:50 am

I can suggest another way... the use of WINDOW SCREEN (0,0)-(100,100) on the new window created.

I should have said, I work with text only. That checkers example is one smooooth program though.

Quote from: SMcNeill on August 10, 2020, 10:12:47 pm

http://www.qb64.org/wiki/$RESIZE Is the easiest way.

Thank you. I don't know how I had missed the RESIZE commands all these years.
This almost does the trick, but is it possible for me to set _SCREENWIDTH and _SCREENHEIGHT within the program?

It's not looking like there's a way to edit the scale in _FULLSCREEN either. Might have a couple of feature requests brewing.

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: SMcNeill on August 11, 2020, 11:34:39 am

SCREEN _NEWIMAGE(Width, Height, 0)
F = _LOADFONT(“cour.ttf”, 32, “monospace”)
_FONT F

The combination of the three commands above may be what you’re looking for. Set the width and height of rows and columns with _NEWIMAGE, and choose your fontsize with _LOADFONT and _FONT.

A normal SCREEN 0 is 8 x 16 characters, with 80 columns and 25 rows, with a total size of 640x480 pixels.

If you want 80 columns and 25 rows of double sized characters, to increase scale for readability, _LOADFONT(desiredfont$, 32, “monospace”).

A 100x100 pixel-sized screen as you described, would be 12x6 columns and rows. Simply loading a size 32 font of 1:2 ratio would be enough to scale the screen to 200x200 in size.

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: bplus on August 11, 2020, 01:20:56 pm

TEXT ONLY!

Code: QB64: [Select]

DEFINT A-Z
_TITLE "ASCII Fireworks,    Move Mousewheel to Expand or Contract" '2020-01-01
' 2020-01-02 update with graivity effect by tsh73 from JB forum
' 2020-08-11 modified for xpanding and contracting screen size
 
CONST nR = 5, t = "     Happy New Year QB64 Forum, ASCII Fireworks Brought To You By Bplus Inspired by Pete, TempodiBasic and [banned user] Recent Efforts, Gravity Effect by tsh73 at JB Forum, Go In Peace 2020!....."
TYPE rocket
    x AS SINGLE
    y AS SINGLE
    bang AS INTEGER
    age AS INTEGER
    c AS INTEGER
END TYPE
DIM SHARED qb(15) AS _UNSIGNED LONG
qb(0) = &HFF000000
qb(1) = &HFF000088
qb(2) = &HFF008800
qb(3) = &HFF008888
qb(4) = &HFF880000
qb(5) = &HFF880088
qb(6) = &HFF888800
qb(7) = &HFFCCCCCC
qb(8) = &HFF888888
qb(9) = &HFF0000FF
qb(10) = &HFF00FF00
qb(11) = &HFF00FFFF
qb(12) = &HFFFF0000
qb(13) = &HFFFF00FF
qb(14) = &HFFFFFF00
qb(15) = &HFFFFFFFF
 
DIM SHARED r(1 TO nR) AS rocket
FOR i = 1 TO nR
    new i
NEXT
DIM SHARED fire&
fire& = _NEWIMAGE(640, 400, 32)
DIM tmp&(0 TO 10)
lastt = 20
sc& = _NEWIMAGE(640, 400, 32)
 
DO
    _DEST fire&
    CLS
    COLOR qb(13)
    lc = lc + 1
    IF lc MOD 3 = 0 THEN p = (p + 1) MOD LEN(t)
    LOCATE 2, 20: PRINT MID$(t, p + 1, 40);
    rocs = rocs + 1
    IF rocs > nR THEN rocs = nR
    FOR i = 1 TO rocs
        drawRocket i
    NEXT
 
 
    _DEST 0
    WHILE _MOUSEINPUT
        scroll = scroll + _MOUSEWHEEL
    WEND
    IF scroll < 800 AND scroll > -400 THEN
        tp = (tp + 1) MOD 10
        tmp&(tp) = _NEWIMAGE(640 + scroll, 400 + scroll, 32)
        SCREEN tmp&(tp)
        _PUTIMAGE , fire&, 0
    ELSE
        lastt = 20
    END IF
 
    'debug
    'COLOR qb(15)
    'LOCATE 1, 1: PRINT lastt, tp, scroll
 
    IF lastt <> 20 THEN _FREEIMAGE tmp&(lastt)
    lastt = tp
 
    _DISPLAY
    _LIMIT 20
LOOP UNTIL _KEYDOWN(27)
 
SUB new (i)
    r(i).x = RND * 60 + 10
    r(i).y = 25
    r(i).bang = RND * 20
    r(i).age = 0
    r(i).c = INT(RND * 15) + 1
END SUB
 
SUB drawRocket (i)
    IF r(i).y > r(i).bang THEN
        COLOR qb(15)
        LOCATE r(i).y, r(i).x: PRINT CHR$(24);
        r(i).y = r(i).y - 1
    ELSE
        r(i).age = r(i).age + 1
        IF r(i).age > 25 THEN
            new i
        ELSE
            COLOR qb(r(i).c)
            IF r(i).age > 4 THEN start = r(i).age - 4 ELSE start = 1
            FOR a = start TO r(i).age
                FOR j = 1 TO 12
                    xx = r(i).x + 1 * a * COS(j * _PI / 6)
                    yy = r(i).y + .5 * a * SIN(j * _PI / 6)
                    yy = yy + (r(i).y - a) ^ 2 / 15 '<<<< tsh73 gravity
                    IF xx > 0 AND xx < 81 AND yy > 0 AND yy < 26 THEN
                        LOCATE INT(yy), INT(xx)
                        PRINT "*";
                    END IF
                NEXT
            NEXT
        END IF
    END IF
END SUB
 
 
 
 

[ This attachment cannot be displayed inline in 'Print Page' view ]

[ This attachment cannot be displayed inline in 'Print Page' view ]

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: TempodiBasic on August 11, 2020, 07:32:50 pm

Quote from: manstersoft on August 11, 2020, 10:12:33 am

I should have said, I work with text only. That checkers example is one smooooth program though.

Yes I agree, however this is your window on which you're working!

Code: QB64: [Select]

k = 100
s$ = "a"
DO
    IF s$ <> "" THEN
        w = k / 8
        h = k / 16
        SCREEN _NEWIMAGE(w, h, 0)
        'WINDOW SCREEN(1, 1)-(100, 100) '<-- this activates an error of illegal function
        LOCATE 1, 1
        FOR a = 1 TO w
            PRINT LTRIM$(STR$(a MOD 10));
            _DELAY .1
        NEXT a
        LOCATE 2
        FOR a = 2 TO h
            LOCATE a, 1
            PRINT LTRIM$(STR$(a MOD 10));
            LOCATE a, w
            PRINT LTRIM$(STR$(a MOD 10));
            _DELAY .1
        NEXT a
        LOCATE 3, 3: PRINT w;
        LOCATE 4, 4: PRINT h;
    END IF
    s$ = INKEY$
    IF s$ = CHR$(32) THEN IF k > 100 THEN k = 100 ELSE k = k + 100
LOOP UNTIL s$ = CHR$(27)

Why do you talk about pixels when you work in Screen 0 (console mode)? It is preferable to talk in row and column dimensions...
It is clear that here we NEED the opinion of the King of ASCII screen mode!
I'll invite Pete to talk about this issue.

PS:
Bplus I find great your fireworks!

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: manstersoft on August 12, 2020, 08:42:32 pm

Quote from: TempodiBasic on August 11, 2020, 07:32:50 pm

Why do you talk about pixels when you work in Screen 0 (console mode)? It is preferable to talk in row and column dimensions...

Excuse my terminology screw up. Since I switched to QB64 I'm actually using...

Code: QB64: [Select]

SCREEN _NEWIMAGE(scale * 8, scale * 8, 256): _FONT 8

I can't stand using only 8 background colors.

The SCREEN() function is a major reason I've stuck with Quick Basic; many other variants don't have anything like this function. My main worry with rendering text as graphics is that I won't be able to use the SCREEN() function.
Side note: SCREEN() does have an issue where it confuses a non-COLOR ,0 " " for a block when using SCREEN _NEWIMAGE.

I haven't had time today to look at the code y'all posted though (I'm selling my house/land; anyone in Central Virginia want to buy it?), so there might be some answers in there. I want to mess with that ASCII fireworks program anyway.

And thanks for all of the replies.

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: bplus on August 12, 2020, 08:59:10 pm

_FONT 8 for fireworks, great idea! A number of changes (and the program is less lines!):

Code: QB64: [Select]

DEFINT A-Z
_TITLE "ASCII Fireworks  Move Mousewheel to Expand or Contract #2" '2020-01-01
' 2020-01-02 update with graivity effect by tsh73 from JB forum
' 2020-08-11 modified for xpanding and contracting screen size
' 2020-08-11 Steve catches memory leak, fixed!
' 2020-08-12 manstersoft gives me idea for Font 8, added more works and switched color to more! RGB32
 
CONST nR = 9, t = "     Happy New Year QB64 Forum, ASCII Fireworks Brought To You By Bplus Inspired by Pete, TempodiBasic and [banned user] Recent Efforts, Gravity Effect by tsh73 at JB Forum, Thanks Steve for saving memory and manstersoft for Font 8 idea, Go In Peace 2020!....."
TYPE rocket
    x AS SINGLE
    y AS SINGLE
    bang AS INTEGER
    age AS INTEGER
    c AS _UNSIGNED LONG
END TYPE
 
DIM SHARED r(1 TO nR) AS rocket
FOR i = 1 TO nR
    new i
NEXT
DIM SHARED fire&
fire& = _NEWIMAGE(640, 400, 32)
DIM tmp&(0 TO 10)
lastt = 20
sc& = _NEWIMAGE(640, 400, 32)
_FONT 8
DO
    _DEST fire&
    _FONT 16
    CLS
    COLOR &HFFFF88AA
    lc = lc + 1
    IF lc MOD 3 = 0 THEN p = (p + 1) MOD LEN(t)
    LOCATE 2, 20: PRINT MID$(t, p + 1, 40);
    _FONT 8
    rocs = rocs + 1
    IF rocs > nR THEN rocs = nR
    FOR i = 1 TO rocs
        drawRocket i
    NEXT
 
 
    _DEST 0
    WHILE _MOUSEINPUT
        scroll = scroll + _MOUSEWHEEL
    WEND
    IF scroll < 800 AND scroll > -400 THEN
        tp = (tp + 1) MOD 10
        tmp&(tp) = _NEWIMAGE(640 + scroll, 400 + scroll, 32)
        SCREEN tmp&(tp)
        _PUTIMAGE , fire&, 0
    ELSE
        lastt = 20
    END IF
 
    'debug
    'COLOR qb(15)
    'LOCATE 1, 1: PRINT lastt, tp, scroll
 
    IF lastt <> 20 THEN _FREEIMAGE tmp&(lastt)
    lastt = tp
 
    _DISPLAY
    _LIMIT 20
LOOP UNTIL _KEYDOWN(27)
 
SUB new (i)
    r(i).x = RND * 60 + 10
    r(i).y = 50
    r(i).bang = RND * 30
    r(i).age = 0
    r(i).c = _RGB32(200 * RND + 55, 200 * RND + 55, 200 * RND + 55)
END SUB
 
SUB drawRocket (i)
    IF r(i).y > r(i).bang THEN
        COLOR r(i).c
        LOCATE r(i).y, r(i).x: PRINT CHR$(24);
        r(i).y = r(i).y - 1
    ELSE
        r(i).age = r(i).age + 1
        IF r(i).age > 50 THEN
            new i
        ELSE
            COLOR r(i).c
            IF r(i).age > 4 THEN start = r(i).age - 4 ELSE start = 1
            FOR a = start TO r(i).age
                FOR j = 1 TO 12
                    xx = r(i).x + 1 * a * COS(j * _PI / 6)
                    yy = r(i).y + .5 * a * SIN(j * _PI / 6)
                    yy = yy + (r(i).y - a) ^ 2 / 15 '<<<< tsh73 gravity
                    IF xx > 0 AND xx < 81 AND yy > 0 AND yy < 51 THEN
                        LOCATE INT(yy), INT(xx)
                        PRINT "*";
                    END IF
                NEXT
            NEXT
        END IF
    END IF
END SUB
 
 

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: manstersoft on August 13, 2020, 12:03:12 am

Quote from: bplus on August 12, 2020, 08:59:10 pm

_FONT 8 for fireworks, great idea! A number of changes (and the program is less lines!):

Wow, what a program. I'll have to post a gif of that on Twitter. There are a lot of ASCII nuts on there.
And thanks for the shout-out. _FONT 8 was a game-changer for me.

Sheesh, I've still got so much to learn. I can't make heads or tails of that code.
If I ever posted any of my programs on here I'm sure SMcNeill would find 200 memory leaks.
Speaking of which, I gotta try out that code he posted.

Edit: Tried it out. The Screen function isn't compatible with it (it even throws up an error).

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: SMcNeill on August 13, 2020, 04:13:10 am

Quote from: manstersoft on August 13, 2020, 12:03:12 am

If I ever posted any of my programs on here I'm sure SMcNeill would find 200 memory leaks.
Speaking of which, I gotta try out that code he posted.

Edit: Tried it out. The Screen function isn't compatible with it (it even throws up an error).

Which code? This little snippet?

SCREEN _NEWIMAGE(Width, Height, 0)
F = _LOADFONT(“cour.ttf”, 32, “monospace”)
_FONT F

What's the error? Font not found? Width or Height being 0? I didn't place the code in a code box as you'd need to specify all those elements -- desired width and height in columns and rows, and the path to your favorite mono space font on your system. ;)

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: manstersoft on August 13, 2020, 11:02:59 am

No, I changed all of the variables. Like I said, the SCREEN Function throws an error.

Code: QB64: [Select]

SCREEN _NEWIMAGE(640, 480, 256)
F = _LOADFONT("myfont.ttf", 32, "monospace") 'replacing with F = 8 works fine
_FONT F
PRINT "TESTING"
PRINT CHR$(SCREEN(1, 1))
 

I get an illegal function call on line 5.

Could it be a glitch?

Edit: Ah, it is a glitch.
Using SCREEN 0 wile using a custom font works fine.
Using SCREEN _NEWIMAGE(,,256) without a custom font works fairly well (there's that non COLOR ,0 " " as block issue).
But, you can't do both SCREEN _NEWIMAGE(,,256) and a Custom Font and use SCREEN()

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: bplus on August 13, 2020, 12:05:12 pm

Yeah I remember some problem I had using the SCREEN function (default font) and it was probably with SCREEN _NEWIMAGE, I think I was trying to get characters/text.

@manstersoft may I ask why you prefer 256 color mode? To be compatible to old programs? That's the way you learned color? I made jump from 16 colors (1990's) to _RGB in 2014 and thought I died and went to heaven!

Title: Re: Is there a way to scale a window other than _FULLSCREEN?
Post by: manstersoft on August 13, 2020, 10:45:29 pm

Quote from: bplus on August 13, 2020, 12:05:12 pm

@manstersoft may I ask why you prefer 256 color mode? To be compatible to old programs? That's the way you learned color? I made jump from 16 colors (1990's) to _RGB in 2014 and thought I died and went to heaven!

I like using palettes.

Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: manstersoft on August 10, 2020, 02:29:48 pm