QB64.org Forum

Active Forums => Programs => Topic started by: loudar on August 07, 2020, 08:11:35 am

Title: Transparency for all windows at the same time!
Post by: loudar on August 07, 2020, 08:11:35 am

I've been using WindowTop for a while now and I don't like that it applies to only one window at a time. It thought: There must be a way I can apply transparency to all windows at the same time, right?

I'm a sucker for pretty backgrounds but also rarely see them when I work. Some slight transparency solves that :D

Here's a program where every window you focused since the start of it will have the transparency applied, you can modulate it with "+" and "-".
You can also choose with the enter key which window to activate/deactivate the transparency on.
The arrow on the right side shows the currently focused window.

Code: QB64: [Select]

1. CONST SWP_NOSIZE = &H0001 'ignores cx and cy size parameters
2. CONST SWP_NOMOVE = &H0002 'ignores x and y position parameters
3. CONST SWP_NOZORDER = &H0004 'keeps z order and ignores hWndInsertAfter parameter
4. CONST SWP_NOREDRAW = &H0008 'does not redraw window changes
5. CONST SWP_NOACTIVATE = &H0010 'does not activate window
6. CONST SWP_FRAMECHANGED = &H0020
7. CONST SWP_SHOWWINDOW = &H0040
8. CONST SWP_HIDEWINDOW = &H0080
9. CONST SWP_NOCOPYBITS = &H0100
10. CONST SWP_NOOWNERZORDER = &H0200
11. CONST SWP_NOSENDCHANGING = &H0400
12. CONST SWP_DRAWFRAME = SWP_FRAMECHANGED
13. CONST SWP_NOREPOSITION = SWP_NOOWNERZORDER
14. CONST SWP_DEFERERASE = &H2000
15. CONST SWP_ASYNCWINDOWPOS = &H4000
16. CONST HWND_TOP = 0 'window at top of z order no focus
17. CONST HWND_BOTTOM = 1 'window at bottom of z order no focus
18. CONST HWND_TOPMOST = -1 'window above all others no focus unless active
19. CONST HWND_NOTOPMOST = -2 'window below active no focus
20. DECLARE DYNAMIC LIBRARY "user32"
21.     'sets a created window region
22.     FUNCTION SetWindowRgn& (BYVAL hwnd&, BYVAL hrgn&, BYVAL bredraw%)
23.     FUNCTION SetLayeredWindowAttributes& (BYVAL hwnd AS LONG, BYVAL crKey AS LONG, BYVAL bAlpha AS _UNSIGNED _BYTE, BYVAL dwFlags AS LONG)
24.     FUNCTION GetWindowLong& ALIAS "GetWindowLongA" (BYVAL hwnd AS LONG, BYVAL nIndex AS LONG)
25.     FUNCTION SetWindowLong& ALIAS "SetWindowLongA" (BYVAL hwnd AS LONG, BYVAL nIndex AS LONG, BYVAL dwNewLong AS LONG)
26.     FUNCTION FindWindowA%& (BYVAL lpClassName%&, BYVAL lpWindowName%&)
27.     FUNCTION GetForegroundWindow&
28.     'FUNCTION GetWindowTextLengthA (BYVAL hwnd&)
29.     'FUNCTION GetWindowTextA (BYVAL hwnd&, BYVAL lpString%&, BYVAL nMaxCount)
30. END DECLARE
31. DECLARE DYNAMIC LIBRARY "gdi32"
32.     'creates a rectangular region
33.     FUNCTION CreateRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
34.     'creates an elliptical region
35.     FUNCTION CreateEllipticRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
36.     'creates a rectangular region with rounded corners
37.     FUNCTION CreateRoundRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&, BYVAL x3&, BYVAL y3&)
38. END DECLARE
39. DECLARE DYNAMIC LIBRARY "kernel32"
40.     FUNCTION GetLastError~& ()
41. END DECLARE
42.  
43. maxwindows = 200
44. DIM SHARED re&(maxwindows) 'you'll never have more than 200 windows open, eh?
45. DIM SHARED applied(maxwindows)
46. DIM SHARED maxr
47.  
48. SCREEN _NEWIMAGE(600, 200, 32)
49. COLOR _RGBA(0, 0, 0, 255), _RGBA(255, 255, 255, 255)
50. CLS
51.  
52. 'notification "WinIsTrans", "is now active."
53.  
54. t = 255
55. selected = 1
56. DO
57.     Taste$ = INKEY$
58.     IF Taste$ = "+" THEN
59.         IF t < 255 THEN
60.             t = t + 1
61.         END IF
62.     END IF
63.     IF Taste$ = "-" THEN
64.         IF t > 20 THEN
65.             t = t - 1
66.         END IF
67.     END IF
68.     IF Taste$ = CHR$(0) + CHR$(80) THEN
69.         IF selected < maxr THEN
70.             selected = selected + 1
71.         ELSE
72.             selected = 1
73.         END IF
74.     END IF
75.     IF Taste$ = CHR$(0) + CHR$(72) THEN
76.         IF selected > 1 THEN
77.             selected = selected - 1
78.         ELSE
79.             selected = maxr
80.         END IF
81.     END IF
82.     IF Taste$ = CHR$(13) THEN
83.         IF applied(selected) = 0 THEN
84.             applied(selected) = 1
85.         ELSE
86.             applied(selected) = 0
87.         END IF
88.     END IF
89.  
90.     hwnd& = GetForegroundWindow&
91.  
92.     'check for invalid
93.     IF maxr > 0 THEN
94.         DO
95.             repeat = 0
96.             r = 0: DO: r = r + 1
97.                 IF re&(r) = 0 AND r < maxr THEN
98.                     repeat = 1
99.                     DO
100.                         re&(r) = re&(r + 1)
101.                         r = r + 1
102.                     LOOP UNTIL r >= maxr - 1
103.                     r = 0
104.                     maxr = maxr - 1
105.                 ELSEIF re&(r) = 0 AND r = maxr THEN
106.                     repeat = 0
107.                     maxr = maxr - 1
108.                     r = 0
109.                 END IF
110.             LOOP UNTIL r >= maxr
111.         LOOP WHILE repeat = 1
112.     END IF
113.  
114.     'check for existence
115.     found = 0
116.     IF maxr > 0 THEN
117.         r = 0: DO: r = r + 1
118.             IF re&(r) = hwnd& THEN
119.                 found = 1
120.             END IF
121.         LOOP UNTIL r = maxr
122.     END IF
123.     IF found = 0 THEN
124.         maxr = maxr + 1
125.         resize
126.         re&(maxr) = hwnd&
127.     END IF
128.  
129.     'apply transparency
130.     IF maxr > 0 THEN
131.         r = 0: DO: r = r + 1
132.             IF re&(r) <> _WINDOWHANDLE AND applied(r) = 1 THEN
133.                 SetWindowOpacity re&(r), t
134.             ELSE
135.                 SetWindowOpacity re&(r), 255
136.             END IF
137.         LOOP UNTIL r = maxr
138.     END IF
139.  
140.     CLS
141.     LOCATE 1, 1
142.     COLOR _RGBA(0, 0, 0, 255)
143.     PRINT "Transparency: "; t
144.     r = 0: DO: r = r + 1
145.         LOCATE r + 1, 1
146.         IF selected = r THEN
147.             PRINT "> ";
148.         END IF
149.         IF applied(r) = 1 THEN
150.             COLOR _RGBA(61, 194, 67, 255)
151.         ELSE
152.             COLOR _RGBA(0, 0, 0, 255)
153.         END IF
154.         PRINT LTRIM$(STR$(re&(r)));
155.         IF re&(r) = GetForegroundWindow& THEN
156.             PRINT " <"
157.         ELSE
158.             PRINT ""
159.         END IF
160.         'l = GetWindowTextLengthA(re&(r))
161.         'PRINT l, GetWindowTextA(re&(r), 0, l)
162.     LOOP UNTIL r = maxr
163.     _DISPLAY
164.     _LIMIT 60
165. LOOP UNTIL Taste$ = CHR$(27)
166. IF maxr > 0 THEN
167.     r = 0: DO: r = r + 1
168.         SetWindowOpacity re&(r), 255
169.     LOOP UNTIL r = maxr
170. END IF
171. SYSTEM
172.  
173. SUB notification (title$, text$)
174.     com$ = com$ + "[reflection.assembly]::loadwithpartialname(" + CHR$(34) + "System.Windows.Forms" + CHR$(34) + ") " + CHR$(13)
175.     com$ = com$ + "[reflection.assembly]::loadwithpartialname(" + CHR$(34) + "System.Drawing" + CHR$(34) + ")" + CHR$(13)
176.     com$ = com$ + "$notify = new-object system.windows.forms.notifyicon" + CHR$(13)
177.     com$ = com$ + "$notify.icon = [System.Drawing.SystemIcons]::WinLogo" + CHR$(13)
178.     com$ = com$ + "$notify.visible = $true" + CHR$(13)
179.     com$ = com$ + "$notify.showballoontip(10," + CHR$(34) + title$ + CHR$(34) + "," + CHR$(34) + text$ + CHR$(34) + ",[system.windows.forms.tooltipicon]::None)"
180.     SHELL com$
181. END SUB
182.  
183. SUB resize
184.     fh = _FONTHEIGHT
185.     SCREEN _NEWIMAGE(600, 200 + (fh * (maxr)), 32)
186.     COLOR _RGBA(0, 0, 0, 255), _RGBA(255, 255, 255, 255)
187.     CLS
188. END SUB
189.  
190. SUB SetWindowOpacity (hWnd&, Level)
191.     DIM Msg AS LONG
192.     CONST G = -20
193.     CONST LWA_ALPHA = &H2
194.     CONST WS_EX_LAYERED = &H80000
195.     Msg = GetWindowLong(hWnd, G)
196.     Msg = Msg OR WS_EX_LAYERED
197.     Crap = SetWindowLong(hWnd&, G, Msg)
198.     Crap = SetLayeredWindowAttributes(hWnd&, 0, Level, LWA_ALPHA)
199.     IF Crap = 0 THEN hWnd& = 0
200. END SUB

Title: Re: Transparency for all windows at the same time!
Post by: Ashish on August 07, 2020, 01:05:12 pm

Nice one! I had fun running this! :)

Text Only | Text with Attachments