Print Page - Ah Spring!

Title: Ah Spring!
Post by: bplus on August 04, 2020, 08:34:40 pm

Ken had me wondering about spring things:

Ball Bearing Springs:

Code: QB64: [Select]

_TITLE "simple spring" 'b+ 2020-08-04
'from: "Mouse down, drag ball, release...  Boing" 'B+ 2019-01-08 from
'from: boing.bas for SmallBASIC 2015-07-25 MGA/B+
'2020-08-04 overhaul completely to use 3D spheres instead of lines horizontally across the screen.
'           103 fixes to make look almost right
 
CONST xmax = 1000
CONST ymax = 700
SCREEN _NEWIMAGE(xmax, ymax, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
 
COLOR , &H884444
CLS
 
PRINT "Building spring from spheres hopefully to get 3D coloring effect."
PRINT "Check a 250 pixel radius sphere centered on screen, press any to continue..."
drawBB 500, 350, 250 'check a good sized sphere
SLEEP
CLS
 
'            discover by experiment how to draw a spring with control over variables
y = _HEIGHT / 2 ' through middle vertically
radius = 100
da = _PI(2 / radius)
astart = _PI(-.5): astop = _PI(3 / 2) + 2 * da ' so spring starts and ends at 12 o'clock on screen
 
winds = 10
x = -2 * radius
FOR a = astart TO astop + (winds + 2) * _PI(2) STEP da
    sx = x + radius * COS(a)
    sy = y + radius * SIN(a)
    drawBB sx, sy, 6
    x = x + 1 'dx at 1 is perfect for moving 1 radius amount to right in one wind
NEXT
PRINT x; "OK x advances exactly 1 radius amount for every 1 wind or circle cycle of angle. "
PRINT "Press any to continue..."
SLEEP
CLS
 
'OK to get twice the winds, same radius reduce dx by .5
winds = 20
x = -2 * radius
FOR a = astart TO astop + (winds + 6) * _PI(2) STEP da 'need extra winds to show partials from loops to right
    sx = x + radius * COS(a)
    sy = y + radius * SIN(a)
    drawBB sx, sy, 6
    x = x + .5 'cut dx in half
NEXT
PRINT x; "OK 20 winds, dx = .5 covers screen. "
PRINT "Press any to continue..."
SLEEP
CLS
 
'OK to get 1/5 the winds 2 now, increase dx to 5
winds = 2
x = -2 * radius
FOR a = astart TO astop + (winds) * _PI(2) STEP da 'no extra winds needed
    sx = x + radius * COS(a)
    sy = y + radius * SIN(a)
    drawBB sx, sy, 6
    x = x + 5 'cut dx in half
NEXT
PRINT x; "OK 2 winds, dx = 5 covers screen. "
PRINT "Press any to continue..."
SLEEP
CLS
 
' OK do we have enough to make the spring springgy
_TITLE "Simple spring in action!  press esc to quit..."
wDir = .1: winds = 10: dx = 1
DO 'stretch and compact spring
    CLS
    x = -2 * radius
    FOR a = astart TO astop + (winds + 13) * _PI(2) STEP da 'have to go way past right border with winds!
        sx = x + radius * COS(a)
        sy = y + radius * SIN(a)
        drawBB sx, sy, 6
        x = x + dx 'cut dx in half
    NEXT
    _DISPLAY
    _LIMIT 30
    winds = winds + wDir
    IF winds > 40 THEN winds = 40: wDir = -wDir
    IF winds < 2 THEN winds = 2: wDir = -wDir
    m = winds / 10
    dx = 1 / m
LOOP UNTIL _KEYDOWN(27)
 
SUB drawBB (x, y, r) 'this is metal steel ball  needs fcirc
    DIM i, dcdr
    dcdr = 255 / r
    FOR i = r TO 0 STEP -.5
        fcirc x + i / 2 - r / 2, y + i / 2 - r / 2, i, _RGB32(255 - dcdr * i)
    NEXT
END SUB
 
'from Steve Gold standard
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
 

And metal with weird lighting:

Code: QB64: [Select]

_TITLE "simple spring 2020-08-04" 'b+ 2020-08-04
'from: "Mouse down, drag ball, release...  Boing" 'B+ 2019-01-08 from
'from: boing.bas for SmallBASIC 2015-07-25 MGA/B+
' 2020-08-04 overhaul completely to use 3D spheres instead of lines horizontally across the screen.
'           103 fixes to make look almost right
' 2020-08-04 not really liking the spheres, try lines again.
 
CONST xmax = 1000
CONST ymax = 700
SCREEN _NEWIMAGE(xmax, ymax, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
COLOR , &H9999BB
CLS
'            discover by experiment how to draw a spring with control over variables
y = _HEIGHT / 2 ' through middle vertically
radius = 100
da = .1 * _PI(2 / radius)
astart = _PI(-.5): astop = _PI(3 / 2) + 2 * da ' so spring starts and ends at 12 o'clock on screen
 
winds = 10
x = -2 * radius
FOR a = astart TO astop + (winds + 2) * _PI(2) STEP da
    sx = x + radius * COS(a)
    sy = y + radius * SIN(a)
    FOR dy = 6 TO 0 STEP -.5
        LINE (sx, sy + dy)-(sx + 6, sy + dy), _RGB32(185 - dy * 17), BF
    NEXT
    x = x + .1 'dx at 1 is perfect for moving 1 radius amount to right in one wind
NEXT
PRINT x; "OK x advances exactly 1 radius amount for every 1 wind or circle cycle of angle. "
PRINT "Press any to continue..."
SLEEP
CLS
 
'OK to get twice the winds, same radius reduce dx by .5
winds = 20
x = -2 * radius
FOR a = astart TO astop + (winds + 6) * _PI(2) STEP da 'need extra winds to show partials from loops to right
    sx = x + radius * COS(a)
    sy = y + radius * SIN(a)
    FOR dy = 6 TO 0 STEP -.5
        LINE (sx, sy + dy)-(sx + 6, sy + dy), _RGB32(185 - dy * 17), BF
    NEXT
    x = x + .05 'cut dx in half
NEXT
PRINT x; "OK 20 winds, dx = .5 covers screen. "
PRINT "Press any to continue..."
SLEEP
CLS
 
'OK to get 1/5 the winds 2 now, increase dx to 5
winds = 2
x = -2 * radius
FOR a = astart TO astop + winds * _PI(2) STEP da 'no extra winds needed
    sx = x + radius * COS(a)
    sy = y + radius * SIN(a)
    FOR dy = 6 TO 0 STEP -.5
        LINE (sx, sy + dy)-(sx + 6, sy + dy), _RGB32(185 - dy * 17), BF
    NEXT
    x = x + .5 'cut dx in half
NEXT
PRINT x; "OK 2 winds, dx = 5 covers screen. "
PRINT "Press any to continue..."
SLEEP
CLS
 
' OK do we have enough to make the spring springgy
_TITLE "Simple spring in action!  press esc to quit..."
wDir = .1: winds = 10: dx = 1
DO 'stretch and compact spring
    CLS
    x = -2 * radius
    FOR a = astart TO astop + (winds + 13) * _PI(2) STEP da 'have to go way past right border with winds!
        sx = x + radius * COS(a)
        sy = y + radius * SIN(a)
        FOR dy = 6 TO 0 STEP -.5
            LINE (sx, sy + dy)-(sx + 6, sy + dy), _RGB32(185 - dy * 17), BF
        NEXT
        x = x + dx 'cut dx in half
    NEXT
    _DISPLAY
    _LIMIT 30
    winds = winds + wDir
    IF winds > 40 THEN winds = 40: wDir = -wDir
    IF winds < 2 THEN winds = 2: wDir = -wDir
    m = winds / 10
    dx = .1 * (1 / m)
LOOP UNTIL _KEYDOWN(27)
 
 

Title: Re: Ah Spring!
Post by: SierraKen on August 04, 2020, 10:18:47 pm

Those are INCREDIBLE! That does something that I tried to do but couldn't figure out, connecting each end of the spiral. Mine don't connect at the ends. I might try to learn from this. Thanks!

Title: Re: Ah Spring!
Post by: johnno56 on August 04, 2020, 10:59:17 pm

I agree. Incredible... But do they come in blue? Nah. Kidding... great job!

Title: Re: Ah Spring!
Post by: SierraKen on August 04, 2020, 11:25:10 pm

Here is my spring version that's animated. I have no idea how this was made, just playing with numbers really and my old spiral code again. I'll post a picture below but it doesn't really show what it does.

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32)
st = -.125
st2 = 1
tt = .25
 
DO
    FOR d = 150 TO 0 STEP -.125
        s = s + 10 + tt
        t = t + tt
        x = (COS(s * 3.141592 / 180) * d) + t
        y = SIN(s * 3.141592 / 180) * d
        FOR sz = .25 TO 3 STEP .25
            CIRCLE (x + 150, y + 300), sz, _RGB32(255, 255, 255)
        NEXT sz
        c = 0
    NEXT d
    _DELAY .03
    IF st2 = 1 THEN tt = tt - .01
    IF st2 = 2 THEN tt = tt + .1
    IF tt < 0 THEN st2 = 2
    IF tt > .5 THEN st2 = 1
    s = 0
    t = 0
    _DISPLAY
    CLS
LOOP
 

Title: Re: Ah Spring!
Post by: SierraKen on August 04, 2020, 11:27:01 pm

Here is a regular animated spiral spring I made before the last one.

Code: QB64: [Select]

SCREEN _NEWIMAGE(1000, 600, 32)
st = -.125
st2 = 1
tt = .25
 
DO
    FOR d = 150 TO 0 STEP -.125
        s = s + 1 + tt
        t = t + tt
        x = (COS(s * 3.141592 / 180) * d) + t
        y = SIN(s * 3.141592 / 180) * d
        FOR sz = .25 TO 3 STEP .25
            c = c + 25
            CIRCLE (x + 450, y + 300), sz, _RGB32(c, c, c)
        NEXT sz
        c = 0
    NEXT d
    _DELAY .03
    IF st2 = 1 THEN tt = tt - .01
    IF st2 = 2 THEN tt = tt + .01
    IF tt < -.5 THEN st2 = 2
    IF tt > .5 THEN st2 = 1
    s = 0
    t = 0
    _DISPLAY
    CLS
LOOP
 

Title: Re: Ah Spring!
Post by: bplus on August 04, 2020, 11:42:46 pm

Hey Ken the cone thing was neat and the spiral spring is it!, just make d constant at some radius for a cylinder spring.

Basically just calculate points for circle but move the x, y center of the circle as you calculate points.

points of a circle at radius r and x, y center is

for a = 0 to 2*pi * (how many circles it takes)
sx = x + r * cos(a)
sy = y + r * sin(a)
change x and/or y for spring
next a

Title: Re: Ah Spring!
Post by: SierraKen on August 05, 2020, 01:05:10 am

Awesome! Now I have new way to make circles. I just made a regular spring, it's not perfect but it's as good as I can do.

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32)
pi = _PI
y = 100
r = 50
xx = 2
x2 = 1
x3 = 300
DO
    FOR x = 100 TO x3 STEP xx
        FOR a = 0 TO 2 * pi * 50
            sx = x + r * COS(a)
            sy = y + r * SIN(a)
            CIRCLE (sx, sy), 2, _RGB32(255, 255, 255)
        NEXT a
    NEXT x
    IF xx > 80 THEN x2 = 2
    IF xx < 20 THEN x2 = 1
    IF x2 = 1 THEN xx = xx + 2: x3 = x3 + 10
    IF x2 = 2 THEN xx = xx - 2: x3 = x3 - 10
    _DELAY .1
    _DISPLAY
    CLS
LOOP
 

Title: Re: Ah Spring!
Post by: bplus on August 05, 2020, 01:42:32 am

Here's something simpler for you tweak numbers. You just needed to move x while "drawing circle", at same time.

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32)
pi = _PI  'constant
y = 300  'constant for now
r = 50    'constant for now for cylinder springs
FOR a = 0 TO 2 * pi * 16 STEP 2 * pi / 360  ' stepping 1 degree, a circle = 2*pi divide by 360 = 1 degree
    sx = x + r * COS(a)
    sy = y + r * SIN(a)
    IF a > 0 THEN LINE (lastsx, lastsy)-(sx, sy), _RGB32(255, 255, 255) ' a>0 because you need a lastsx, lastxy
    lastsx = sx: lastsy = sy
    x = x + .1
    _LIMIT 200
NEXT a
 
 
 
 
 

Title: Re: Ah Spring!
Post by: _vince on August 05, 2020, 09:54:33 am

@bplus I tried

Code: QB64: [Select]

DEFINT A-Z
 
CONST z0 = 2500
CONST y0 = -200
CONST d = 700
 
CONST sw = 640
CONST sh = 480
 
DIM SHARED pi AS DOUBLE
pi = 4 * ATN(1)
 
SCREEN _NEWIMAGE(sw, sh, 32)
 
 
DIM a AS DOUBLE
DIM t AS DOUBLE
t = 0
DO
    t = t + 0.1
    h = 120 + 100 * SIN(t)
 
    LINE (0, 0)-(sw, sh), _RGB(0, 0, 0), BF
 
    ox = 500 * COS(0)
    oz = 500 * SIN(0)
    oy = -500 + 0 * h / (2 * pi)
    'PSET (sw / 2 + ox * d / (oz + z0), sh / 2 - (oy + y0) * d / (oz + z0))
 
    FOR a = 0.1 TO 15 * 2 * pi STEP 0.1
        x = 500 * COS(a)
        z = 500 * SIN(a)
        y = -500 + a * h / (2 * pi)
 
        DIM dy AS SINGLE
        FOR dy = 6 TO 0 STEP -.5
            LINE (sw / 2 + ox * d / (oz + z0), sh / 2 - (oy + y0) * d / (oz + z0) + dy)-(sw / 2 + x * d / (z + z0) + 6, sh / 2 - (y + y0) * d / (z + z0) + dy), _RGB32(185 - dy * 17), BF
        NEXT
 
        ox = x
        oy = y
        oz = z
    NEXT
 
    _DISPLAY
    _LIMIT 30
LOOP UNTIL _KEYHIT = 27
SYSTEM
 

no shading

Code: [Select]

defint a-z

const z0 = 2500
const y0 = -200

const d = 700

const sw = 640
const sh = 480

dim shared pi as double
pi = 4*atn(1)

screen _newimage(sw, sh, 32)

dim a as double
dim t as double
t = 0

r = 400
rr = 1000

do
    t = t + 0.1
    h = 120 + 100*sin(t)

    line (0, 0)-(sw, sh), _rgb(0, 0, 0), bf

    oy = -500 + 0*h/(2*pi)
    ox = r*cos(0)
    oz = r*sin(0)

    for a = 0.1 to 15*2*pi step 0.1
        y = -500 + a*h/(2*pi)
        x = r*cos(a)
        z = r*sin(a)

		ou = sw/4 + ox*d/(oz + z0)
		ov = sh/2 - (oy + y0)*d/(oz + z0)

		u = sw/4 + x*d/(z + z0)
		v = sh/2 - (y + y0)*d/(z + z0)
		line (ou, ov)-(u, v)

        ox = x
        oy = y
        oz = z
    next

    _display
    _limit 20
loop until _keyhit = 27
system

Title: Re: Ah Spring!
Post by: bplus on August 05, 2020, 11:10:16 am

Nice one @_vince

That was what I was going for next showing both ends with set amount of coils contacting and expanding, your perspective is better too!

Oh hey, you have 3D thing going!

I can close those gaps in back by making the STEP .01 and that shows coloring better too.

Title: Re: Ah Spring!
Post by: SierraKen on August 05, 2020, 12:18:48 pm

I haven't tried Vince's yet, but I just made your simple version, b+, into a bouncy spring.

Code: QB64: [Select]

'Spring by B+, mod by SierraKen
SCREEN _NEWIMAGE(800, 600, 32)
pi = _PI 'constant
y = 300 'constant for now
r = 50 'constant for now for cylinder springs
xx = .01
xx2 = 1
DO
    _LIMIT 7
    FOR a = 0 TO 2 * pi * 16 STEP 2 * pi / 360 ' stepping 1 degree, a circle = 2*pi divide by 360 = 1 degree
        sx = x + r * COS(a)
        sy = y + r * SIN(a)
        IF a > 0 THEN LINE (lastsx, lastsy)-(sx, sy), _RGB32(255, 255, 255) ' a>0 because you need a lastsx, lastxy
        lastsx = sx: lastsy = sy
        x = x + xx
    NEXT a
    _DISPLAY
    CLS
    x = 0
    IF xx > .25 THEN xx2 = 2
    IF xx < .01 THEN xx2 = 1
    IF xx2 = 1 THEN xx = xx + .025
    IF xx2 = 2 THEN xx = xx - .025
LOOP
 

Title: Re: Ah Spring!
Post by: SierraKen on August 05, 2020, 12:20:24 pm

That looks amazing Vince!

Title: Re: Ah Spring!
Post by: _vince on August 05, 2020, 01:18:05 pm

now lets have it crawl down a set of 3D stairs

Title: Re: Ah Spring!
Post by: bplus on August 05, 2020, 01:53:11 pm

Nice mod Ken :)

@_vince that 3D approach might be just the thing for me to study. I learned how to use SIN and COS (for computer graphics) from a little snippet for drawing a hexagon 5+ years ago.

Title: Re: Ah Spring!
Post by: _vince on August 05, 2020, 02:05:28 pm

The projection used here is proper 3D and the coordinates are calculated with the similar triangle method: eye to screen to object. Plenty of tutorials on the matter, but in short:

if (x, y, z) is the 3D coordinate, where z axis is pointing into the screen, projecting to 2D coordinate (u, v) I do as follows:

u = x*d/(z + z0)
v = y*d/(z + z0)

then you must select d and z0 to whatever looks right. In my programs I've used d = 700 and z0 = 2500

The easiest way to do 3D is parallel projection:

u = x + d*z
v = y + d*z

where, again, pick d to something that looks right. Here, I usually use d = 0.7

I used my hyperboloid animation from a while ago as a reference to draw the spiral here, using similar values for projection.

These methods are easy enough for simple wireframe type drawings but things get a lot more complicated when you want hidden lines, objects behind camera, complex rotation, etc. In that case the easiest thing is to just learn OpenGL.

Title: Re: Ah Spring!
Post by: bplus on August 05, 2020, 09:04:13 pm

Quote from: _vince on August 05, 2020, 01:18:05 pm

now lets have it crawl down a set of 3D stairs

Then, down/up an Esher stairway! ;-))

Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: bplus on August 04, 2020, 08:34:40 pm