Print Page - Need help with decimal point.

I am very close to finishing my first simple calculator, which uses the mouse. But I can't seem to figure out how to add JUST a decimal point to a variable. I know QB64 rounds .0 to 0 with VAL which is my problem. Here is the decimal point code I have so far. I just need a way to click the decimal point button on the calculator to be able to add it. I found some more advanced calculators on the forum but I still can't figure it out. When I'm done with the calculator I'll make a new topic for it. I have been working on the calculator for a couple days.

Code: QB64: [Select]

        IF mouseX > 126 AND mouseX < 200 AND mouseY > 295 AND mouseY < 350 THEN
            num$ = STR$(num) + "."
            num = VAL(num$)
            buttonx = 126: buttony = 295
            GOSUB press:
            GOSUB number:
        END IF
 

Try keeping all your numbers in string form until you need to do the math then VAL(the number).

Then for displaying the number use a function that sets the number of decimal places to display:

Code: QB64: [Select]

PRINT xDP$(11, 5)
PRINT xDP$(0, 2)
PRINT xDP$(1, 0)
PRINT xDP$(0, 0)
PRINT xDP$(RND * 100, 2)
 
FUNCTION xDP$ (x, DP)  ' x is the number to display assuming default Single, DP = decimal places
    DIM test$, p AS INTEGER
    test$ = _TRIM$(STR$(INT(x * 10 ^ DP) / 10 ^ DP))
    p = INSTR(test$, ".")
    IF p = 0 AND DP <> 0 THEN test$ = test$ + "." + STRING$(DP, "0")
    IF p AND DP = 0 THEN test$ = LEFT$(test$, LEN(test$) - 1)
    xDP$ = test$
END FUNCTION

EDIT: updated function with more tests

That gives me a decimal point and places with zero, which is nice. But I'm lost on how to physically add the decimal point to an existing variable in the location of the program that it needs to be in. I am probably missing something really simple. Math with a decimal is fine, but pressing the decimal button to add it to the beginning number is what I'm lost on. If you want to take a look at it, it's here. If I can get this fixed, the whole calculator will be done. Thanks for the help.

Code: QB64: [Select]

_TITLE "Calculator"
DIM num AS DOUBLE
SCREEN _NEWIMAGE(400, 400, 32)
'Setup calculator
LINE (50, 25)-(265, 50), _RGB32(255, 255, 255), B
LINE (50, 75)-(350, 350), _RGB32(255, 255, 255), B
FOR buttony = 75 TO 295 STEP 55
    FOR buttonx = 50 TO 275 STEP 75
        FOR bb = 0 TO 10
            c = c + 10
            LINE (buttonx + bb, buttony + bb)-(buttonx + 75 - bb, buttony + 55 - bb), _RGB32(100 + c, 100 + c, 100 + c), B
        NEXT bb
        PAINT (buttonx + 12, buttony + 12), _RGB32(100 + c, 100 + c, 100 + c)
        c = 0
    NEXT buttonx
NEXT buttony
buttonx = 275: buttony = 20
FOR bb = 0 TO 10
    c = c + 10
    LINE (buttonx + bb, buttony + bb)-(buttonx + 75 - bb, buttony + 55 - bb), _RGB32(50, 100 + c, 50), B
NEXT bb
PAINT (buttonx + 12, buttony + 12), _RGB32(50, 100 + c, 50)
COLOR _RGB32(0, 0, 0), _RGB32(50, 100 + c, 50)
c = 0
_PRINTSTRING (312, 47), "C"
COLOR _RGB32(0, 0, 0), _RGB32(210, 210, 210)
_PRINTSTRING (87, 102), CHR$(251) 'square root
_PRINTSTRING (152, 102), "sin"
_PRINTSTRING (227, 102), "cos"
_PRINTSTRING (302, 102), "tan"
_PRINTSTRING (87, 157), "7"
_PRINTSTRING (162, 157), "8"
_PRINTSTRING (237, 157), "9"
_PRINTSTRING (312, 157), "/"
_PRINTSTRING (87, 212), "4"
_PRINTSTRING (162, 212), "5"
_PRINTSTRING (237, 212), "6"
_PRINTSTRING (312, 212), "x"
_PRINTSTRING (87, 267), "1"
_PRINTSTRING (162, 267), "2"
_PRINTSTRING (237, 267), "3"
_PRINTSTRING (312, 267), "-"
_PRINTSTRING (87, 322), "0"
_PRINTSTRING (162, 322), "."
_PRINTSTRING (237, 322), "="
_PRINTSTRING (312, 322), "+"
num = 0
GOSUB number:
DO
    _LIMIT 20
    DO WHILE _MOUSEINPUT
        mouseX = _MOUSEX
        mouseY = _MOUSEY
        mouseLeftButton = _MOUSEBUTTON(1)
    LOOP
    IF mouseLeftButton THEN
        mouseLeftButton = 0
        IF mouseX > 275 AND mouseX < 350 AND mouseY > 20 AND mouseY < 75 THEN
            num = 0
            a = 0: s = 0: t = 0: d = 0
            buttonx = 275: buttony = 20
            GOSUB zero:
            GOSUB number:
        END IF
        IF mouseX > 50 AND mouseX < 125 AND mouseY > 75 AND mouseY < 130 THEN
            IF num < 0 THEN GOTO skip1:
            num = SQR(num)
            skip1:
            buttonx = 50: buttony = 75
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 126 AND mouseX < 200 AND mouseY > 75 AND mouseY < 130 THEN
            num = SIN(num)
            buttonx = 126: buttony = 75
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 200 AND mouseX < 275 AND mouseY > 75 AND mouseY < 130 THEN
            num = COS(num)
            buttonx = 200: buttony = 75
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 275 AND mouseX < 350 AND mouseY > 75 AND mouseY < 130 THEN
            num = TAN(num)
            buttonx = 275: buttony = 75
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 50 AND mouseX < 125 AND mouseY > 130 AND mouseY < 185 THEN
            num$ = STR$(num) + "7"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 50: buttony = 130
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 126 AND mouseX < 200 AND mouseY > 130 AND mouseY < 185 THEN
            num$ = STR$(num) + "8"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 126: buttony = 130
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 200 AND mouseX < 275 AND mouseY > 130 AND mouseY < 185 THEN
            num$ = STR$(num) + "9"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 200: buttony = 130
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 275 AND mouseX < 350 AND mouseY > 130 AND mouseY < 185 THEN
            IF d = 0 THEN
                d = 1: a = 0: s = 0: t = 0
                oldnum = num
                num = 0
                GOTO nex1:
            END IF
            IF d = 1 AND num <> 0 THEN
                num = oldnum / num
                d = 0
            END IF
            nex1:
            buttonx = 275: buttony = 130
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 50 AND mouseX < 125 AND mouseY > 185 AND mouseY < 240 THEN
            num$ = STR$(num) + "4"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 50: buttony = 185
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 126 AND mouseX < 200 AND mouseY > 185 AND mouseY < 240 THEN
            num$ = STR$(num) + "5"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 126: buttony = 185
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 200 AND mouseX < 275 AND mouseY > 185 AND mouseY < 240 THEN
            num$ = STR$(num) + "6"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 200: buttony = 185
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 275 AND mouseX < 350 AND mouseY > 185 AND mouseY < 240 THEN
            IF t = 0 THEN
                d = 0: a = 0: s = 0: t = 1
                oldnum = num
                num = 0
                GOTO nex2:
            END IF
            IF t = 1 THEN
                num = oldnum * num
                t = 0
            END IF
            nex2:
            buttonx = 275: buttony = 185
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 50 AND mouseX < 125 AND mouseY > 240 AND mouseY < 295 THEN
            num$ = STR$(num) + "1"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 50: buttony = 240
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 126 AND mouseX < 200 AND mouseY > 240 AND mouseY < 295 THEN
            num$ = STR$(num) + "2"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 126: buttony = 240
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 200 AND mouseX < 275 AND mouseY > 240 AND mouseY < 295 THEN
            num$ = STR$(num) + "3"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 200: buttony = 240
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 275 AND mouseX < 350 AND mouseY > 240 AND mouseY < 295 THEN
            IF s = 0 THEN
                IF num = 0 THEN neg = 1: GOTO nex3:
                d = 0: a = 0: s = 1: t = 0
                oldnum = num
                num = 0
                GOTO nex3:
            END IF
            IF s = 1 THEN
                num = oldnum - num
                s = 0
            END IF
            nex3:
            buttonx = 275: buttony = 240
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 50 AND mouseX < 125 AND mouseY > 295 AND mouseY < 350 THEN
            num$ = STR$(num) + "0"
            num = VAL(num$)
            IF neg = 1 THEN num = -num: neg = 0
            buttonx = 50: buttony = 295
            GOSUB press:
            GOSUB number:
        END IF
 
        '-------------------------------------------------------------------------
        'This is the decimal area I am having problems with.
        '-------------------------------------------------------------------------
        IF mouseX > 126 AND mouseX < 200 AND mouseY > 295 AND mouseY < 350 THEN
            buttonx = 126: buttony = 295
            GOSUB press:
            GOSUB number:
        END IF
        '--------------------------------------------------------------------------
 
        IF mouseX > 200 AND mouseX < 275 AND mouseY > 295 AND mouseY < 350 THEN
            IF a = 1 THEN num = oldnum + num: a = 0
            IF s = 1 THEN num = oldnum - num: s = 0
            IF t = 1 THEN num = oldnum * num: t = 0
            IF d = 1 THEN num = oldnum / num: d = 0
            buttonx = 200: buttony = 295
            GOSUB press:
            GOSUB number:
        END IF
        IF mouseX > 275 AND mouseX < 350 AND mouseY > 295 AND mouseY < 350 THEN
            IF a = 0 THEN
                d = 0: a = 1: s = 0: t = 0
                oldnum = num
                num = 0
                GOTO nex4:
            END IF
            IF a = 1 THEN
                num = oldnum + num
                a = 0
            END IF
            nex4:
            buttonx = 275: buttony = 295
            GOSUB press:
            GOSUB number:
        END IF
    END IF
LOOP
number:
COLOR _RGB32(255, 255, 255), _RGB32(0, 0, 0)
_PRINTSTRING (55, 30), "                          "
'num$ = STR$(num)
x = num
_PRINTSTRING (55, 30), xDP$(num, 4)
RETURN
press:
c = 110
FOR bb = 0 TO 10
    c = c - 10
    LINE (buttonx + bb, buttony + bb)-(buttonx + 75 - bb, buttony + 55 - bb), _RGB32(100 + c, 100 + c, 100 + c), B
NEXT bb
_DELAY .25
FOR bb = 0 TO 10
    c = c + 10
    LINE (buttonx + bb, buttony + bb)-(buttonx + 75 - bb, buttony + 55 - bb), _RGB32(100 + c, 100 + c, 100 + c), B
NEXT bb
RETURN
zero:
c = 110
FOR bb = 0 TO 10
    c = c - 10
    LINE (buttonx + bb, buttony + bb)-(buttonx + 75 - bb, buttony + 55 - bb), _RGB32(50, 100 + c, 50), B
NEXT bb
_DELAY .25
FOR bb = 0 TO 10
    c = c + 10
    LINE (buttonx + bb, buttony + bb)-(buttonx + 75 - bb, buttony + 55 - bb), _RGB32(50, 100 + c, 50), B
NEXT bb
RETURN
 
FUNCTION xDP$ (x, DP)
    DIM test$, p AS INTEGER
    test$ = _TRIM$(STR$(INT(x * 10 ^ DP) / 10 ^ DP))
    p = INSTR(test$, ".")
    IF p = 0 AND DP <> 0 THEN test$ = test$ + "." + STRING$(DP, "0")
    IF p AND DP = 0 THEN test$ = LEFT$(test$, LEN(test$) - 1)
    xDP$ = test$
END FUNCTION
 
 
 
 
 
 
 
 
 
 
 
 

Again like I said, don't convert the number string to a number you are typing in until you are ready to do the math.

Say the number is "12", you click decimal, then number$ = number$ + "." , you click the 9 then number$ = number$ + "9" keep it as a string!

BTW when you click the decimal you should check if the number has a decimal in it already and not add it into the number$ string if it does have one.

Then when you do the math say add, then num = val(number$) + val(lastNumber$)

Then when you display that number (the sum) use _printstring(x, y), xDP$(num, howManyPlaces)

You can also keep everything right justified using a set width in number display panel. Say 10 places maximum display width use:
_printstring (x, y), right$(space$(10) + number$, 10) ' <<< for displaying a number build
or _printstring(x, y), right$(space$(10) + xDP$(x, decimals), 10) ' <<< for displaying result of math operation

Remember use these buttons only to build the number string 1,2,3,4,5,6,7,8,9,0, . and neg button to maybe toggle a - sign in front of the number string.

Hi SierraKen

I can see that you have a revival about spaghetti code!
That's ok, you're trying to use a too versatle tool (GOTO/GOSUB) with no headache!
But please, let me know why do you make no comment to your code?

Well however I must ask to you:
why do you play with num$ and num every time?
why do you display 4 decimal cifers after decimal point from starting time?
-----
feedbacks:
1- after the calculation the user cannot modify num by button's input
2- in windows calculation thenumber is on the right side and not at left
Good Coding
PS:
IMHO you can solve the issue using a string variable for num, but you must adapt the Bplus function ! Or make another one.

yep! Bplus has already written the solution and the control issue on decimal point!

How is this coming Ken?

Have you figured the way to simplify your code?

BTW those buttons look great!

Thanks B+ :). I started changing it yesterday but got tired so I'm back at it today. :) I can't promise anything but I'll try it for awhile. Thank you for the help! Your way does logically sound the best.

Indeed, those are nice looking buttons. I need to study those. Great work so far Ken.

Thanks OldMoses. I'm getting closer! Man what a puzzle. lol

B+, I had to remove your INT in your Function because every time I did something like 2.5 your code turned it into 2.4999 or something like that. Which is strange, but removing your INT fixed it. I hope to be done with this today.

Quote from: SierraKen on July 28, 2020, 01:11:35 pm

Thanks OldMoses. I'm getting closer! Man what a puzzle. lol

B+, I had to remove your INT in your Function because every time I did something like 2.5 your code turned it into 2.4999 or something like that. Which is strange, but removing your INT fixed it. I hope to be done with this today.

Well INT was absolutely essential to this function as it controls the number of decimals:

Code: QB64: [Select]

FUNCTION xDP$ (x, DP)
    DIM test$, p AS INTEGER
    test$ = _TRIM$(STR$(INT(x * 10 ^ DP) / 10 ^ DP))
    p = INSTR(test$, ".")
    IF p = 0 AND DP <> 0 THEN test$ = test$ + "." + STRING$(DP, "0")
    IF p AND DP = 0 THEN test$ = LEFT$(test$, LEN(test$) - 1)
    xDP$ = test$
END FUNCTION
 

Maybe you are using it wrong and/or maybe you don't even need it. I don't recall if I needed it on calculators I've worked on. Only for displaying numbers that are results of math calculations to control the number of digits past the decimal.

The calculator is finished! I put it under a new forum thread here, so people can find it better:

https://www.qb64.org/forum/index.php?topic=2867.msg121306#msg121306

QB64.org Forum

Active Forums => Programs => Topic started by: SierraKen on July 27, 2020, 05:28:34 pm