QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: FellippeHeitor on July 24, 2020, 12:32:31 am

Title: Molecules simulation (simple particle system, part II)
Post by: FellippeHeitor on July 24, 2020, 12:32:31 am

Similarly to the previous video, I create a simple particle system but this time I get them to notice each other in a different way, to simulate atoms coming together to form molecules.

Code:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. RANDOMIZE TIMER
4.  
5. TYPE object
6.     x AS SINGLE
7.     y AS SINGLE
8.     xv AS SINGLE
9.     yv AS SINGLE
10.     size AS INTEGER
11.     c AS _UNSIGNED LONG
12. END TYPE
13.  
14. DIM SHARED o(130) AS object
15. DIM SHARED i AS INTEGER
16.  
17. 'initialize array
18. FOR i = 1 TO UBOUND(o)
19.     o(i).x = RND * _WIDTH
20.     o(i).y = RND * _HEIGHT
21.     o(i).xv = 1 - RND * 2
22.     o(i).yv = 1 - RND * 2
23.     o(i).size = 10
24.     o(i).c = _RGB32(RND * 255, RND * 255, RND * 255, 100)
25. NEXT
26.  
27. DIM SHARED minDistance AS INTEGER
28. minDistance = 50
29.  
30. DO
31.     WHILE _MOUSEINPUT: WEND
32.     mx = _MOUSEX
33.  
34.     minDistance = map(mx, 0, _WIDTH, 0, 200)
35.  
36.     CLS
37.  
38.     LINE (0, _HEIGHT - 20)-(mx, _HEIGHT), _RGB32(255, 50), BF
39.  
40.     FOR i = 1 TO UBOUND(o)
41.         move o(i)
42.         connect o(i)
43.         CircleFill o(i).x, o(i).y, o(i).size, o(i).c
44.     NEXT
45.  
46.     _DISPLAY
47.     _LIMIT 60
48. LOOP UNTIL _KEYHIT = 27
49. SYSTEM
50.  
51. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
52.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
53. END FUNCTION
54.  
55. SUB connect (this AS object)
56.     DIM j AS INTEGER
57.     FOR j = 1 TO UBOUND(o)
58.         IF dist(o(j), this) <= minDistance THEN
59.             LINE (this.x, this.y)-(o(j).x, o(j).y), this.c
60.         END IF
61.     NEXT
62. END SUB
63.  
64. FUNCTION dist! (o1 AS object, o2 AS object)
65.     x1! = o1.x
66.     y1! = o1.y
67.     x2! = o2.x
68.     y2! = o2.y
69.     dist! = _HYPOT((x2! - x1!), (y2! - y1!))
70. END FUNCTION
71.  
72. SUB move (this AS object)
73.     this.x = this.x + this.xv
74.     IF this.x < 0 OR this.x > _WIDTH THEN this.xv = this.xv * -1
75.  
76.     this.y = this.y + this.yv
77.     IF this.y < 0 OR this.y > _HEIGHT THEN this.yv = this.yv * -1
78. END SUB
79.  
80.  
81. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
82.     ' CX = center x coordinate
83.     ' CY = center y coordinate
84.     '  R = radius
85.     '  C = fill color
86.     DIM Radius AS INTEGER, RadiusError AS INTEGER
87.     DIM X AS INTEGER, Y AS INTEGER
88.     Radius = ABS(R)
89.     RadiusError = -Radius
90.     X = Radius
91.     Y = 0
92.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
93.     LINE (CX - X, CY)-(CX + X, CY), C, BF
94.     WHILE X > Y
95.         RadiusError = RadiusError + Y * 2 + 1
96.         IF RadiusError >= 0 THEN
97.             IF X <> Y + 1 THEN
98.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
99.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
100.             END IF
101.             X = X - 1
102.             RadiusError = RadiusError - X * 2
103.         END IF
104.         Y = Y + 1
105.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
106.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
107.     WEND
108. END SUB
109.  

Title: Re: Molecules simulation (simple particle system, part II)
Post by: Ashish on July 24, 2020, 04:58:20 am

See, what I found :D . It does something similar to your code. -

Code: QB64: [Select]

1. 'Coded by Ashish in Qb64
2. 'inspire from Shiffman's video.
3. TYPE vector
4.     x AS _FLOAT
5.     y AS _FLOAT
6.     z AS _FLOAT
7. END TYPE
8.  
9. TYPE particle
10.     pos AS vector
11.     rr AS _FLOAT
12.     i AS INTEGER
13.     j AS INTEGER
14.     r AS INTEGER
15.     g AS INTEGER
16.     b AS INTEGER
17. END TYPE
18. RANDOMIZE TIMER
19. _TITLE "Processing Network"
20. SCREEN _NEWIMAGE(800, 500, 32)
21.  
22. CONST speed = .05
23. DIM SHARED Particles(100) AS particle
24. DIM SHARED glAllow AS _BYTE
25. FOR i = 0 TO UBOUND(Particles)
26.     Particles(i).pos.x = RND * _WIDTH
27.     Particles(i).pos.y = RND * _HEIGHT
28.     Particles(i).pos.z = RND * 100
29.     Particles(i).j = RND * 7
30.     Particles(i).i = 5
31.     IF RND * 2 > 1 THEN Particles(i).i = -Particles(i).i
32.     Particles(i).rr = RND * 3
33.     SELECT CASE Particles(i).j
34.         CASE 0: Particles(i).r = 5: Particles(i).g = 205: Particles(i).b = 229
35.         CASE 1: Particles(i).r = 255: Particles(i).g = 184: Particles(i).b = 3
36.         CASE 2: Particles(i).r = 91: Particles(i).g = 3: Particles(i).b = 255
37.         CASE 3: Particles(i).r = 61: Particles(i).g = 62: Particles(i).b = 62
38.         CASE 4: Particles(i).r = 255: Particles(i).g = 0: Particles(i).b = 255
39.         CASE 5: Particles(i).r = 255: Particles(i).g = 0: Particles(i).b = 0
40.         CASE 6: Particles(i).r = 0: Particles(i).g = 255: Particles(i).b = 0
41.         CASE 7: Particles(i).r = 0: Particles(i).g = 0: Particles(i).b = 255
42.     END SELECT
43.     IF RND * 2 > 1 THEN Particles(i).j = -Particles(i).j
44. NEXT
45.  
46. glAllow = -1
47. DO
48.     CLS , _RGB(255, 255, 255)
49.     FOR i = 0 TO UBOUND(particles)
50.         CIRCLE (Particles(i).pos.x, Particles(i).pos.y), Particles(i).rr, _RGB(Particles(i).r, Particles(i).g, Particles(i).b)
51.         PAINT (Particles(i).pos.x, Particles(i).pos.y), _RGB(Particles(i).r, Particles(i).g, Particles(i).b), _RGB(Particles(i).r, Particles(i).g, Particles(i).b)
52.         Particles(i).pos.x = Particles(i).pos.x + Particles(i).j * speed
53.         Particles(i).pos.y = Particles(i).pos.y + Particles(i).i * speed
54.         IF Particles(i).pos.y > _HEIGHT - Particles(i).rr THEN Particles(i).i = -Particles(i).i
55.         IF Particles(i).pos.y < 0 + Particles(i).rr THEN Particles(i).i = -Particles(i).i
56.         IF Particles(i).pos.x > _WIDTH - Particles(i).rr THEN Particles(i).j = -Particles(i).j
57.         IF Particles(i).pos.x < 0 + Particles(i).rr THEN Particles(i).j = -Particles(i).j
58.     NEXT
59.     '   _LIMIT 60
60.     _DISPLAY
61. LOOP
62.  
63.  
64. SUB _GL STATIC
65.     IF NOT glAllow THEN EXIT SUB
66.     '  _glClearColor 1, 1, 1, 1
67.     ' _glClear _GL_COLOR_BUFFER_BIT OR _GL_DEPTH_BUFFER_BIT
68.  
69.     _glEnable _GL_BLEND
70.     '   _glColor4f 1, 1, 1, .05
71.     FOR i = 0 TO UBOUND(particles)
72.         FOR j = i + 1 TO UBOUND(particles)
73.             IF distance(Particles(i).pos.x, Particles(i).pos.y, Particles(j).pos.x, Particles(j).pos.y) < 80 THEN
74.                 FOR n = j + 1 TO UBOUND(particles)
75.                     IF distance(Particles(j).pos.x, Particles(j).pos.y, Particles(n).pos.x, Particles(n).pos.y) < 80 THEN
76.                         _glColor4f Particles(i).r / 255, Particles(i).g / 255, Particles(i).b / 255, .1
77.                         _glBegin _GL_TRIANGLES
78.                         _glVertex3f toGlX(Particles(i).pos.x), toGlY(Particles(i).pos.y), 0
79.                         _glVertex3f toGlX(Particles(j).pos.x), toGlY(Particles(j).pos.y), 0
80.                         _glVertex3f toGlX(Particles(n).pos.x), toGlY(Particles(n).pos.y), 0
81.                         _glEnd
82.                     END IF
83.                 NEXT
84.             END IF
85.         NEXT
86.     NEXT
87.     _glFlush
88. END SUB
89.  
90. FUNCTION toGlX## (x#)
91.     x# = (_WIDTH / 2) - x#
92.     toGlX## = map(x#, -(_WIDTH / 2), _WIDTH / 2, 1, -1)
93. END FUNCTION
94.  
95. FUNCTION toGlY## (y#)
96.     y# = (_HEIGHT / 2) - y#
97.     toGlY## = map(y#, -(_HEIGHT / 2), _HEIGHT / 2, -1, 1)
98. END FUNCTION
99. FUNCTION toGlZ## (z#)
100.     toGlZ## = map(z#, 0, 100, 0, 1)
101. END FUNCTION
102.  
103. FUNCTION map## (value##, minRange##, maxRange##, newMinRange##, newMaxRange##)
104.     map## = ((value## - minRange##) / (maxRange## - minRange##)) * (newMaxRange## - newMinRange##) + newMinRange##
105. END FUNCTION
106.  
107. FUNCTION distance## (x1##, y1##, x2##, y2##)
108.     IF x1## > x2## THEN dx## = x1## - x2## ELSE dx## = x2## - x1##
109.     IF y1## > y2## THEN dy## = y1## - y2## ELSE dy## = y2## - y1##
110.     distance## = SQR(dx## * dx## + dy## * dy##)
111. END FUNCTION
112.  
113.  
114.  

Title: Re: Molecules simulation (simple particle system, part II)
Post by: FellippeHeitor on July 24, 2020, 05:34:47 am

Aha! That's why this was at the back of my mind! We'd written it before 😂

Thanks for sharing!

Title: Re: Molecules simulation (simple particle system, part II)
Post by: bplus on July 24, 2020, 11:35:13 am

@FellippeHeitor Ah so that's that map function you are always using, very clear now that I've seen it applied. :)

Also liked the mouse bar at bottom of screen.

Next mod up is translucent triangular planes between 3 points.

Title: Re: Molecules simulation (simple particle system, part II)
Post by: FellippeHeitor on July 24, 2020, 12:10:54 pm

@bplus that's the one!

Looking forward to your mod!

Title: Re: Molecules simulation (simple particle system, part II)
Post by: bplus on July 24, 2020, 02:01:35 pm

Quote from: FellippeHeitor on July 24, 2020, 12:10:54 pm

@bplus that's the one!

Looking forward to your mod!

Sounds like an invitation so
https://www.qb64.org/forum/index.php?topic=2851.msg121134#msg121134

Text Only | Text with Attachments