Print Page - Raycasting

Sorry I've been scarce this past month. The wife was getting upset that the honey do list was not getting done. Had to limit my time on computer.

Any way, I've been trying to learn ray casting for another topic in my tutorial. I found a pretty good video on YouTube explaining the process. The narrator uses OpenGL and C. I converted it to QB64 as I watched the video. If you watch the video and look at the code below you'll be amazed at just how easy it is to do ray casting.

The code is sloppy. I threw it together as the narrator wrote his code. But it works. :-)

Code: QB64: [Select]

'  [youtube]https://www.youtube.com/watch?v=gYRrGTC7GtA[/youtube]
 
 
 
CONST DARKGRAY = _RGB32(76, 76, 76)
CONST WHITE = _RGB32(255, 255, 255)
CONST BLACK = _RGB32(0, 0, 0)
CONST YELLOW = _RGB32(255, 255, 0)
CONST GREEN = _RGB32(0, 255, 0)
CONST RED = _RGB32(255, 0, 0)
CONST DARKRED = _RGB32(128, 0, 0)
CONST PI = 3.1415926
CONST P2 = PI / 2
CONST P3 = 3 * PI / 2
CONST DR = .0174533
 
DIM SHARED px AS SINGLE '  player position
DIM SHARED py AS SINGLE
DIM SHARED pdx AS SINGLE ' delta X of player
DIM SHARED pdy AS SINGLE ' delta Y of player
DIM SHARED pa AS SINGLE '  angle of player
DIM SHARED mapX AS INTEGER
DIM SHARED mapY AS INTEGER
DIM SHARED mapS AS INTEGER
DIM SHARED map(64) AS INTEGER
 
mapX = 8
mapY = 8
mapS = 64
FOR i = 0 TO 63: READ map(i): NEXT i
 
 
Init
DO
    _LIMIT 60
    CLS , DARKGRAY
    drawMap2D
    drawRays2D
    DrawPlayer
    Buttons
 
 
    _DISPLAY
LOOP
 
DATA 1,1,1,1,1,1,1,1
DATA 1,0,1,0,0,0,0,1
DATA 1,0,1,0,0,0,0,1
DATA 1,0,1,0,0,0,0,1
DATA 1,0,0,0,0,0,0,1
DATA 1,0,0,0,0,1,0,1
DATA 1,0,0,0,0,0,0,1
DATA 1,1,1,1,1,1,1,1
 
 
FUNCTION dist (ax AS SINGLE, ay AS SINGLE, bx AS SINGLE, by AS SINGLE, ang AS SINGLE)
 
    dist = SQR((bx - ax) * (bx - ax) + (by - ay) * (by - ay))
 
END FUNCTION
 
 
SUB drawRays2D ()
 
    DIM r AS INTEGER
    DIM mx AS INTEGER
    DIM my AS INTEGER
    DIM mp AS INTEGER
    DIM dof AS INTEGER
    DIM rx AS SINGLE
    DIM ry AS SINGLE
    DIM ra AS SINGLE
    DIM xo AS SINGLE
    DIM yo AS SINGLE
    DIM aTan AS SINGLE
    DIM nTan AS SINGLE
    DIM disH AS SINGLE
    DIM hx AS SINGLE
    DIM hy AS SINGLE
    DIM disV AS SINGLE
    DIM vx AS SINGLE
    DIM vy AS SINGLE
    DIM disTT AS SINGLE
    DIM lineH AS SINGLE
    DIM lineO AS SINGLE
    DIM ca AS SINGLE
    DIM clr AS _UNSIGNED LONG
 
    ra = pa - DR * 30
    IF ra < 0 THEN ra = ra + 2 * PI
    IF ra > 2 * PI THEN ra = ra - 2 * PI
 
    FOR r = 0 TO 59
        '--- Check Horizontal Lines ---
        dof = 0
        disH = 1000000
        hx = px
        hy = py
        aTan = -1 / TAN(ra)
        IF ra > PI THEN
            'ry = ((INT(py) / 64) * 64) - .0001
 
            ry = INT(py / 64) * 64 - .0001
 
 
            rx = (py - ry) * aTan + px
            yo = -64
            xo = -yo * aTan
        END IF
        IF ra < PI THEN
            'ry = ((INT(py) / 64) * 64) + 64
 
            ry = INT(py / 64) * 64 + 64
 
 
            rx = (py - ry) * aTan + px
            yo = 64
            xo = -yo * aTan
        END IF
        IF (ra = 0) OR (ra = PI) THEN
            rx = px
            ry = py
            dof = 8
        END IF
        WHILE dof < 8
            'mx = INT(rx) / 64
            'my = INT(ry) / 64
 
            mx = INT(rx / 64)
            my = INT(ry / 64)
 
            mp = my * mapX + mx
 
            'LOCATE 1, 1: PRINT mp; pa;
            '_DISPLAY
 
            IF mp < 0 THEN mp = 0
            IF mp > 63 THEN mp = 63
 
            'IF (mp < mapX * mapY) AND map(mp) = 1 THEN ' -- hit wall
            IF map(mp) = 1 THEN
                hx = rx
                hy = ry
                disH = dist(px, py, hx, hy, ra)
                dof = 8
            ELSE '                                       -- next line
                rx = rx + xo
                ry = ry + yo
                dof = dof + 1
            END IF
        WEND
 
 
        '--- Check Vertical Lines ---
        dof = 0
        disV = 1000000
        vx = px
        vy = py
 
        nTan = -TAN(ra)
        IF ra > P2 AND ra < P3 THEN
            'ry = ((INT(py) / 64) * 64) - .0001
 
            rx = INT(px / 64) * 64 - .0001
 
 
            ry = (px - rx) * nTan + py
            xo = -64
            yo = -xo * nTan
        END IF
        IF ra < P2 OR ra > P3 THEN
            'ry = ((INT(py) / 64) * 64) + 64
 
            rx = INT(px / 64) * 64 + 64
 
 
            ry = (px - rx) * nTan + py
            xo = 64
            yo = -xo * nTan
        END IF
        IF (ra = 0) OR (ra = PI) THEN
            rx = px
            ry = py
            dof = 8
        END IF
        WHILE dof < 8
            'mx = INT(rx) / 64
            'my = INT(ry) / 64
 
            mx = INT(rx / 64)
            my = INT(ry / 64)
 
            mp = my * mapX + mx
 
            'LOCATE 1, 1: PRINT mp; pa;
            '_DISPLAY
 
            IF mp < 0 THEN mp = 0
            IF mp > 63 THEN mp = 63
 
            'IF (mp < mapX * mapY) AND map(mp) = 1 THEN ' -- hit wall
            IF map(mp) = 1 THEN
                vx = rx
                vy = ry
                disV = dist(px, py, vx, vy, ra)
                dof = 8
            ELSE '                                       -- next line
                rx = rx + xo
                ry = ry + yo
                dof = dof + 1
            END IF
        WEND
 
        IF disV < disH THEN ' -- Vertical wall hit
            rx = vx
            ry = vy
            disTT = disV
            clr = RED
        END IF
        IF disH < disV THEN ' -- Horizontal wall hit
            rx = hx
            ry = hy
            disTT = disH
            clr = DARKRED
        END IF
 
        LINE (px, py)-(rx, ry), RED
 
        '--- Draw 3D Walls ---
 
        ca = pa - ra
        IF ca < 0 THEN ca = ca + 2 * PI
        IF ca > 2 * PI THEN ca = ca - 2 * PI
        disTT = disTT * COS(ca) '          -- fix fish eye
 
        lineH = mapS * 320 / disTT
        IF lineH > 320 THEN lineH = 320 ' -- Line height
        lineO = 160 - lineH / 2 '         -- Line offset
        LINE (r * 8 + 530 - 4, lineO)-(r * 8 + 530 + 4, lineH + lineO), clr, BF
 
 
 
        ra = ra + DR
        IF ra < 0 THEN ra = ra + 2 * PI
        IF ra > 2 * PI THEN ra = ra - 2 * PI
 
 
 
    NEXT r
 
 
 
END SUB
 
 
SUB drawMap2D ()
 
    DIM x AS INTEGER
    DIM y AS INTEGER
    DIM xo AS INTEGER
    DIM yo AS INTEGER
    DIM clr AS _UNSIGNED LONG
 
    FOR y = 0 TO mapY - 1
        FOR x = 0 TO mapX - 1
            IF map(y * mapX + x) = 1 THEN clr = WHITE ELSE clr = BLACK
            xo = x * mapS
            yo = y * mapS
            LINE (xo + 1, yo + 1)-(xo + mapS - 1, yo + mapS - 1), clr, BF
        NEXT x
    NEXT y
 
END SUB
 
 
SUB Buttons ()
 
    IF _KEYDOWN(97) THEN
        pa = pa - .1
        IF pa < 0 THEN pa = pa + 2 * PI
    END IF
    IF _KEYDOWN(100) THEN
        pa = pa + .1
        IF pa > 2 * PI THEN pa = pa - 2 * PI
    END IF
    pdx = COS(pa) * 5
    pdy = SIN(pa) * 5
    IF _KEYDOWN(119) THEN px = px + pdx: py = py + pdy
    IF _KEYDOWN(115) THEN px = px - pdx: py = py - pdy
 
END SUB
 
 
SUB DrawPlayer ()
 
    LINE (px - 4, py - 4)-(px + 4, py + 4), YELLOW, BF
 
    LINE (px, py)-(px + pdx * 5, py + pdy * 5), YELLOW
 
END SUB
 
 
 
SUB Init ()
 
 
    SCREEN _NEWIMAGE(1024, 512, 32)
    CLS , DARKGRAY
    px = 300
    py = 300
    pdx = COS(pa) * 5
    pdy = SIN(pa) * 5
 
END SUB
 
 

Wow!

Excellent!

I knew if I waited long enough someone would figure this out here! Thank you! Back in the mid 90's someone posted something just like this for QBasic on the newsgroup comp.lang.basic.misc and it was tons of code if I recall and they also used DATA for their map. It worked very slowly though back then. I wish I still had it but I think I lost it over time. I've wanted to learn this ever since and now that you made an example, I'm going to study like crazy. :)) It's a wish come true, thank you!

Yeah, I always viewed ray tracing as coding voodoo, probably because Wolfenstein 3D came out right around the time I was really getting into coding. I figured the math alone behind this was something to tackle. Turns out it's a very simple effect to achieve.

The narrator in the video does a good job of explaining each part of the code. I kept the variable names, functions, and subroutines named the same as well. I had to make a few changes here and there because of the funky way C handles IF statements but for the most part it's a one to one conversion.

I watched the video and it's a bit beyond me for now. He did say we can change the map so I made the map bigger with more walls, etc. Doing that we could even remove the 2D map and make it as large as you want I would think, just keep all of the 2D code so it knows where the walls are, but not the graphic. I also noticed that you can walk through the walls. I tried scanning through the code to see if there was a simple way to say something like hit = 1 when the wall is too close and you can't move anymore, but I can't really find it. Maybe you can add it sometime so people can't walk through them. But still an awesome job!

Finally got around to watching the video too. The guy's really funny, which is a bonus.

Cool video. I like the way he walks (no pun intended) you through the process. I have keyed in raycasters before but none of the listings really explained 'how' it all works. Knowledge of OpenGL, in this case, seems to be a per-requisite. Trigonometry was never by best subject, so I found the math, somewhat intimidating. The video was easy to follow - understanding completely will take some time - but the results are there to see... Wow is right.

I hope he does do texture; collision; objects etc videos. Wolf3D. Watch out!

Thank you, Terry!!

Cool!
I find it more fun and clearer than this one of Biswit that I saw some year ago and I posted the first part (that written in Qbasic) in [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] for some issue about runtime errors.
https://www.youtube.com/watch?v=HQYsFshbkYw (https://www.youtube.com/watch?v=HQYsFshbkYw)
LOL I find at the bottom of comments just 3 years ago a comment of an unknown TempodiBasic Programming

Thanks to share this resource !
Great translation into QB64!

Amazing! :D

QB64.org Forum

Active Forums => Programs => Topic started by: TerryRitchie on July 13, 2020, 01:56:42 pm