QB64.org Forum

Active Forums => Programs => Topic started by: FellippeHeitor on June 07, 2018, 01:50:48 am

Title: TCP/IP local communication sample
Post by: FellippeHeitor on June 07, 2018, 01:50:48 am

Compile, run the binary 2 times simultaneously and watch how they communicate.

Code: QB64: [Select]

1. DIM SHARED client AS LONG, host AS LONG
2. SCREEN _NEWIMAGE(500, 500, 32)
3.  
4. PRINT "Connecting to host...";
5. host = _OPENCLIENT("TCP/IP:60710:localhost")
6. IF host = 0 THEN
7.  
8.     'this is the host program
9.  
10.     PRINT "not found."
11.     PRINT "Starting host...";
12.     host = _OPENHOST("TCP/IP:60710")
13.     IF host THEN
14.         PRINT "done."
15.         DO
16.             PRINT "Listening on port 60710..."
17.             DO
18.                 client = _OPENCONNECTION(host)
19.                 _LIMIT 30
20.             LOOP UNTIL client
21.  
22.             a$ = "MSG>HELLO!"
23.             Send client, a$
24.             PRINT "Connected. Waiting for requests..."
25.  
26.             DO
27.                 incomingData$ = ""
28.                 GET #client, , incomingData$
29.                 stream$ = stream$ + incomingData$
30.  
31.                 DO WHILE INSTR(stream$, "<END>") > 0
32.                     'process requests from the client
33.                     'custom format: REQUEST>data to be sent<END>
34.  
35.                     'separate command, data and remove this command from the stream
36.                     thisData$ = LEFT$(stream$, INSTR(stream$, "<END>") - 1)
37.                     stream$ = MID$(stream$, INSTR(stream$, "<END>") + 5)
38.                     thisCommand$ = LEFT$(thisData$, INSTR(thisData$, ">") - 1)
39.                     IF thisCommand$ = "" THEN
40.                         thisCommand$ = thisData$
41.                     ELSE
42.                         thisData$ = MID$(thisData$, LEN(thisCommand$) + 2)
43.                     END IF
44.  
45.                     SELECT CASE UCASE$(thisCommand$)
46.                         CASE "TIME"
47.                             myData$ = "MSG>" + TIME$
48.                             Send client, myData$
49.                         CASE "DATE"
50.                             myData$ = "MSG>" + DATE$
51.                             Send client, myData$
52.                         CASE "WISDOM"
53.                             myData$ = "MSG>Time flies like bananas."
54.                             Send client, myData$
55.                         CASE "MSG"
56.                             PRINT "Message from client: "; thisData$
57.                         CASE "BYE"
58.                             PRINT thisData$
59.                             PRINT "Disconnected."
60.                             myData$ = "MSG>BYE!"
61.                             Send client, myData$
62.                             CLOSE client
63.                             client = 0
64.                             EXIT DO
65.                         CASE "MOUSEX"
66.                             mX = CVI(thisData$)
67.                         CASE "MOUSEY"
68.                             mY = CVI(thisData$)
69.                         CASE "MOUSEDOWN"
70.                             CIRCLE (mX, mY), 10, _RGB32(255, 150, 0)
71.                             mouseDown = -1
72.                         CASE "MOUSEUP"
73.                             CIRCLE (mX, mY), 10, _RGB32(0, 255, 0)
74.                             mouseDown = 0
75.                     END SELECT
76.                 LOOP
77.  
78.                 IF mouseDown THEN
79.                     IF mX <> oldMx OR mY <> oldMy THEN
80.                         IF oldMx > 0 AND oldMy > 0 THEN
81.                             LINE (oldMx, oldMy)-(mX, mY)
82.                         ELSE
83.                             PSET (mX, mY)
84.                         END IF
85.                         oldMx = mX
86.                         oldMy = mY
87.                     END IF
88.                 ELSE
89.                     IF mX <> oldMx OR mY <> oldMy THEN
90.                         oldMx = mX
91.                         oldMy = mY
92.                     END IF
93.                 END IF
94.  
95.                 _LIMIT 30
96.             LOOP WHILE client
97.         LOOP
98.     ELSE
99.         PRINT "failed."
100.     END IF
101. ELSE
102.  
103.     'this is the client program
104.  
105.     PRINT
106.     PRINT "Connected."
107.     PRINT "Click around to send mouse data; hit space to enter command..."
108.  
109.     DO
110.         DO
111.             incomingData$ = ""
112.             GET #host, , incomingData$
113.             stream$ = stream$ + incomingData$
114.         LOOP WHILE LEN(incomingData$)
115.  
116.         DO WHILE INSTR(stream$, "<END>") > 0
117.             'process responses from the host
118.             'custom format: RESPONSE>data received<END>
119.  
120.             'separate command, data and remove this command from the stream
121.             thisData$ = LEFT$(stream$, INSTR(stream$, "<END>") - 1)
122.             thisCommand$ = LEFT$(thisData$, INSTR(thisData$, ">") - 1)
123.             thisData$ = MID$(thisData$, LEN(thisCommand$) + 2)
124.             stream$ = MID$(stream$, INSTR(stream$, "<END>") + 5)
125.  
126.             SELECT CASE UCASE$(thisCommand$)
127.                 CASE "MSG"
128.                     PRINT "Message from host: "; thisData$
129.                     IF thisData$ = "BYE!" THEN
130.                         PRINT "Disconnected."
131.                         CLOSE host
132.                         END
133.                     END IF
134.             END SELECT
135.         LOOP
136.  
137.         DO WHILE _MOUSEINPUT
138.             mX = _MOUSEX
139.             mY = _MOUSEY
140.             mb = _MOUSEBUTTON(1)
141.         LOOP
142.  
143.         IF mX <> oldMx OR mY <> oldMy THEN
144.             oldMx = mX
145.             oldMy = mY
146.             c$ = "MOUSEX>" + MKI$(mX)
147.             Send host, c$
148.             c$ = "MOUSEY>" + MKI$(mY)
149.             Send host, c$
150.         END IF
151.  
152.         IF mb THEN
153.             IF NOT mouseDown THEN
154.                 c$ = "MOUSEDOWN>" + MKI$(1)
155.                 Send host, c$
156.                 mouseDown = -1
157.             END IF
158.         ELSE
159.             IF mouseDown THEN
160.                 c$ = "MOUSEUP>" + MKI$(1)
161.                 Send host, c$
162.                 mouseDown = 0
163.             END IF
164.         END IF
165.  
166.  
167.         IF INKEY$ = " " THEN
168.             INPUT "Command (TIME, DATE, WISDOM, MSG>your message, BYE:", c$
169.  
170.             IF INSTR(c$, ">") = 0 THEN c$ = c$ + ">"
171.             Send host, c$
172.             c$ = ""
173.         END IF
174.  
175.         _LIMIT 30
176.     LOOP WHILE host
177. END IF
178.  
179. SUB Send (channel, __theData$)
180.     theData$ = __theData$ + "<END>"
181.     PUT #channel, , theData$
182. END SUB
183.  

Title: Re: TCP/IP local communication sample
Post by: commandvom on June 07, 2018, 11:29:55 am

Good code!  I will borrow some ideas to migrate my project to GL ambient! Thanks!

Title: Re: TCP/IP local communication sample
Post by: FellippeHeitor on June 07, 2018, 12:09:45 pm

I will be delighted if my small contribution is useful for your awesome game to be able to be compiled with the latest version of QB64, commandvom!

Looking forward to hearing from you about how the transition goes.

Text Only | Text with Attachments