Print Page - A simple command line tool translating DEF FN functions into FUNCTIONs

Title: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: TempodiBasic on April 30, 2020, 10:31:24 am

Hi guys
cause I see often the request " How to solve the porting in QB64 of program written inQbasic and QB with the DEF FN statement?"
I have developed in Qbasic and ported to QB64 this tool
it translates code from Qbasic to QB64...

after compiled into QB64 you can use the program from command line or with drag & drop ...
Here attached the code DEF2FUN.BAS and some Qbasic code with DEF FN on one line and multiline.
There are 2 compressed files .7z and .tar for different software in your possess.
Thanks to try and for feedbacks

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: Pete on April 30, 2020, 10:48:37 am

Request. If this is just one QB64 file (program) would you please edit your post to also include the code?

Example:

Code: QB64: [Select]

PRINT "Ewwwe I hates unzippin' things, varmint!"
END
 

Pete

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: bplus on April 30, 2020, 11:50:36 am

Quote from: Pete on April 30, 2020, 10:48:37 am

Request. If this is just one QB64 file (program) would you please edit your post to also include the code?

Example:

Code: QB64: [Select]
PRINT "Ewwwe I hates unzippin' things, varmint!"
END

Pete

Well I appreciate TempodiBasic having 2 different package options for the 4 bas files included, that is convenient! Thanks TempodiBasic.

But I see Pete's point, would be nice to just view the main bas code, so for that reason I offer this service:

Code: QB64: [Select]

DECLARE SUB OneLine (LineOfCode$, Count%)
DECLARE SUB Multiline (Line$, Count%)
DECLARE FUNCTION Incr% (Intero%)
 
'_________INFO_______________________________________
' le funzioni DEF FN possono essere monoriga
' DEF fnP (a%)  = a% + 1
 
' oppure  multiriga
' DEF fnP (a%)
'      a% = a% * 3
'      fnP= a% + 1
' END DEF
' le definizioni monoriga  o multiriga non si possono impilare a matrioska
' le DEF Fn devono avere almeno un parametro
' le DEF Fn non possono accedere alle variabili condivise
' nŠ avere variabili con lo stesso nome delle variabili condivise o globali
' ______________END of INFO___________________________
 
' Project of program__________________________________________
' pseudocodice per il traduttore di FN a FUNCTION
' siccome in QB64 FN non Š un token allora lo lasciamo dov'Š
' e prendiamo una strata pi— semplice
 
' apri il file da tradurre
' apri il file da tradotto da scrivere
' leggi il file riga per riga fino alla fine
' se c'Š un DEF FN
'               se c'Š = Š una funzione a singola riga
'                     scrivi nel file tradotto
'                               FUNCTION e la parte della riga da FN e =
'                               FNnomefunzione = la parte della riga dopo =
'                               END FUNCTION
'               altrimenti Š una funzione multiriga
'                     scrivi nel file tradotto
'                               FUNCTION e la parte della riga da FN in poi
'                               memorizza il nome della FN
'                               leggi il file riga per riga fino a quando
'                               trova END DEF o ottiene fine file
'                                       se Š presente EXIT DEF scrivi EXIT FUNCTION
'                                       se Š presente END DEF esci dal loop
'                                       scrivi la riga
'                               END FUNCTION
'
' End of Project of Program____________________________________________________
 
 
' constants of token to translate
CONST Primo = "DEF FN", Secondo = "=", Terzo = "FN"
CONST Quarto = "EXIT DEF", Quinto = "END DEF", Sesto = "("
' variable to process lines of code
Counter% = 0 ' it counts how many functions are translated
Fi$ = "" ' File of input
Fo$ = "" ' File of output
Fdef$ = "" ' Temporary file for function translated
LineOfCode$ = "" ' it brings the line of code read from file
 
Fi$ = COMMAND$ ' File of input
IF Fi$ = "" THEN
    CLS
    PRINT "DEF2FUN Help:"
    PRINT " Usage: DEF2FUN NamefileToTranslate"
    PRINT " It needs one parameter at run "
    END
END IF
 
LenFi = LEN(Fi$)
IF INSTR(Fi$, ".") THEN
    ' name file has extention
    ExtFi$ = RIGHT$(Fi$, LEN(Fi$) - INSTR(Fi$, ".") + 1)
    NamFi$ = LEFT$(Fi$, INSTR(Fi$, ".") - 1)
    Fo$ = LEFT$(NamFi$, LenFi - 3) + "Tmp" + ExtFi$
    Fdef$ = LEFT$(NamFi$, LenFi - 3) + ".TMP"
ELSE
    ' name file has no extension
    Fo$ = "Tmp" + LEFT$(Fi$, 3)
    Fdef$ = Fo$ + ".TMP"
END IF
 
 
' open files for input and output
CLS
PRINT "Opening files..."
OPEN Fi$ FOR INPUT AS #1
PRINT " Opened Input file..."
OPEN Fo$ FOR OUTPUT AS #2
OPEN Fdef$ FOR OUTPUT AS #3
PRINT " Opened output file..."
 
' it puts author's sign
PRINT #2, " REM  File made by DEF2FUNC utility by TempodiBasic "
PRINT #2, " REM  DEF2FUNC translate any function DEF FN to the FUNCTION syntax"
PRINT #2, ""
 
' main loop processing file
DO WHILE NOT EOF(1)
    PRINT " Reading file...";
    LINE INPUT #1, LineOfCode$
    PRINT LineOfCode$
    ' search a definition of DEF FN
    IF INSTR(UCASE$(LineOfCode$), Primo) THEN
        PRINT " Found a DEF FN: "; LineOfCode$
        PRINT #3, "FUNCTION ";
        '  is DEF FN in oneline or in multiline?
        IF INSTR(LineOfCode$, Secondo) THEN
            OneLine LineOfCode$, Counter%
        ELSE
            Multiline LineOfCode$, Counter%
        END IF
    ELSE ' no definition of DEF FN
        PRINT #2, LineOfCode$
    END IF
LOOP
PRINT "End of translation..."
PRINT " Rebuilding the file..."
CLOSE ' closes all files
OPEN Fo$ FOR APPEND AS #1
OPEN Fdef$ FOR INPUT AS #2
DO WHILE NOT EOF(2)
    LINE INPUT #2, LineOfCode$
    PRINT #1, LineOfCode$
LOOP
CLOSE ' closes all files
PRINT " File translated ..."
KILL Fdef$
END ' end of program
 
FUNCTION Incr% (Intero%)
    Incr% = Intero% + 1
END FUNCTION
 
SUB Multiline (Line$, Counter%)
    PRINT " It is a multiline DEF FN"
    ' this subprogram process a DEF FN on multiline
    NextLine$ = ""
    Counter% = Incr(Counter%)
    NameOfFN$ = RIGHT$(Line$, LEN(Line$) - (INSTR(UCASE$(Line$), Primo) + LEN(Primo) - 3))
    PRINT #3, NameOfFN$
    DO WHILE NOT EOF(1)
        'here it processes multiline DEF FN after the first line of code
        LINE INPUT #1, NextLine$
        IF INSTR(UCASE$(NextLine$), Quarto) THEN
            PRINT #3, " EXIT FUNCTION "
        ELSEIF INSTR(UCASE$(NextLine$), Quinto) THEN
            EXIT DO
        ELSE
            PRINT #3, NextLine$
        END IF
    LOOP
    PRINT #3, "END FUNCTION"
END SUB
 
SUB OneLine (LineOfCode$, Counter%)
    PRINT " It is a oneline DEF FN"
    ' this subprogram process a DEF FN on oneline
    Counter% = Incr(Counter%)
    Start% = INSTR(UCASE$(LineOfCode$), Primo) + LEN(Primo) - 2
    Lenght% = INSTR(UCASE$(LineOfCode$), Secondo) - Start%
    NameOfFN$ = MID$(LineOfCode$, Start%, Lenght%)
    PRINT "FUNCTION "; NameOfFN$
    PRINT #3, NameOfFN$
    PRINT #3, LEFT$(NameOfFN$, INSTR(NameOfFN$, "(") - 1);
    PRINT #3, RIGHT$(LineOfCode$, LEN(LineOfCode$) - (INSTR(UCASE$(LineOfCode$), Secondo) - 1))
    PRINT #3, "END FUNCTION"
END SUB
 
 

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: Pete on April 30, 2020, 12:04:21 pm

Thanks Mark! Yeah, I'm getting on in years, and I can't stand taking extra steps to do things, if there is an easier way. Select - Copy - Paste into the IDE. Those are the only code samples I look at and try these days. One exception. If I see something interesting, and the zip has multiple files and/or is too big to post, because of board limits. Actually, in the case of multiple files, the zip is a step saver. I just would appreciate if all small enough to post code snippets without dependency files, would be posted in code boxes. Now if you will excuse me, this laxative isn't going to drink itself. Oh dam, chocolate again!

Pete

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: bplus on April 30, 2020, 12:14:04 pm

I am testing TempodiBasic's conversion and I have a question about the old QB45 way to use DEF FN: Didn't it use to be like this:

Code: QB64: [Select]

DEF FN oneTheHardWay(theta) = sin(theta) ^2 + cos(theta) ^2
 
print oneTheHardWay(_pi/4)

TempodiBasic has it this way, with the FN as part of the function name:

Code: QB64: [Select]

DEF fnPiuUno (z%) = z% + 1
DEF FNPer2 (z%) = z% * 2
DEF fNPer10 (z%) = z% * 10
DEF FnDiv1 (z%) = z% / 1
 
FOR a% = 1 TO 10 STEP 1
   PRINT fnPiuUno(a%), FNPer2(a%), fNPer10(a%), FnDiv1(a%)
 
NEXT a%
END

It's been like 25 years! Is the FN supposed to be part of the DEF FN name?

I ask because the conversion did this:

Code: QB64: [Select]

 REM  File made by DEF2FUNC utility by TempodiBasic 
 REM  DEF2FUNC translate any function DEF FN to the FUNCTION syntax
 
 
print oneTheHardWay(_pi/4)
 
FUNCTION FN oneTheHardWay(theta) 
FN oneTheHardWay= sin(theta) ^2 + cos(theta) ^2
END FUNCTION
 

Which is surely not going to work.

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: Pete on April 30, 2020, 12:17:59 pm

Nice and neat!

You may want to consider FOR BINARY instead of INPUT. If I ran my older 50K QB programs through this, FOR BINARY would make the conversions a lot faster. Smaller programs, still faster but hardly noticeable.

I like that it appears to handle one or more DEF FN lines. One screw up that could happen is a rare instance of something like this...

Code: QB64: [Select]

REM DEF FN: Pete is the biggest and best function ever created!

Would it stumble on that?

Anyway, this may or may not need any tweaking, but if perfect as is or could be made perfect, this would be a shining star addition to the tool box and would help lay to rest any more "demands" for adding DEF FN to the language. Honestly, it was only added to QB to save the space that language so so limited by.

Pete

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: bplus on April 30, 2020, 12:24:48 pm

Hi Pete, so FN has to be a prefix to the function name ie DEF FNmyFunction and not DEF FN myFunction ?

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: Pete on April 30, 2020, 12:26:35 pm

@bplus: Mark, I used to use this for INKEY$ routines, and I still remember adding the variable to the DEF FN as DEF FNb$, so yes, it's been a long time, but I recall you had to combine the variable to the FN part. FN I'm not mistaken!

Pete

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: TempodiBasic on April 30, 2020, 03:09:11 pm

Hi guys
Thanks for feedbacks

1. this is the information that I have got from QBASIC and QB45 Help

Quote

'_________INFO_______________________________________
'DEF FN functions can be single-line
'DEF fnP (a%) = a% + 1

'or multi-line
'DEF fnP (a%)
'a% = a% * 3
'fnP = a% + 1
'END DEF
'single line or multi line definitions cannot be stacked in matryoshka
'DEF Fn must have at least one parameter
'DEF Fn cannot access shared variables
'no have variables with the same name as shared or global variables
'______________END of INFO___________________________

Using Qbasic, the FN part of Syntax is not changed by the parser (or syntax's checker) while DEF is uppercased!
In the first attempt I was trying to remove the FN part of the name of the function (I got this), but it is indifferent for QB64 and this task increases time used so I leave FN there.

2. thanks for suggestion to improve this little tool

about REM or ' it is good to fix that also if it is rare to find a REM for oneline function but it is possible

about a BINARY access to the file I'll do the update as soon as to make faster the tool

Thanks again

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: TempodiBasic on May 02, 2020, 11:48:07 am

Hi
going deeper to develope the managment of exception of comments with REM or '
I find another exception... when DEF FN is in a string (closed between two " ") and it requires some controls to work well.
Soon DEF2FUN 1.0
Thanks for feedbacks

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: TempodiBasic on May 08, 2020, 07:31:46 pm

Hi guys
I'll be back for DEF2FUN 1.0
and it is here!

[ This attachment cannot be displayed inline in 'Print Page' view ]

Thanks to feedbacks and suggestion of Pete and Bplus I have moved to the second pass gaining the 1.0 version
1. added BINARY access to file with LINE INPUT aa only QB64 let's do http://qb64.org/wiki/LINE_INPUT_(file_statement) (http://qb64.org/wiki/LINE_INPUT_(file_statement))

Quote

NOTE: LINE INPUT will work faster in BINARY mode than in INPUT mode.
Using LINE INPUT # in BINARY mode is possible in version 1.000 and up

2. comments issue:
the first is this

Code: QB64: [Select]

REM DEF FN: Pete is the biggest and best function ever created!

that opens the way to a set of issue about
REM and ' as comments operators

Now DEF2FUN manages REM and ' both in first position both as added comments to the line of code

3. String issue:
as for REM and '

Code: QB64: [Select]

PRINT " this is a DEF Fn demo"

Now DEF2FUN manages string containing Keywords of DEF FN

Here the code of this command line tool ( remember that you can drag & drop file to translate)

Code: QB64: [Select]

DECLARE SUB OneLine (LineOfCode$, Count%)
DECLARE SUB Multiline (Line$, Count%)
DECLARE FUNCTION Incr% (Intero%)
 
'_________INFO_______________________________________
' le funzioni DEF FN possono essere monoriga
' DEF fnP (a%)  = a% + 1
 
' oppure  multiriga
' DEF fnP (a%)
'      a% = a% * 3
'      fnP= a% + 1
' END DEF
' le definizioni monoriga  o multiriga non si possono impilare a matrioska
' le DEF Fn devono avere almeno un parametro
' le DEF Fn non possono accedere alle variabili condivise
' nŠ avere variabili con lo stesso nome delle variabili condivise o globali
' bisogna evitare di tradurre un REM o '
' se non Š passato il nome del file mostra la info
' ______________END of INFO___________________________
_TITLE "DEF_FN_2_FUNCTION 1.0"
' constants of token to translate
CONST Primo = "DEF FN", Secondo = "=", Terzo = "FN"
CONST Quarto = "EXIT DEF", Quinto = "END DEF", Sesto = "("
 
' variable to process lines of code
Counter% = 0 ' it counts how many functions are translated
Fi$ = "" ' File of input
Fo$ = "" ' File of output
Fdef$ = "" ' Temporary file for function translated
LineOfCode$ = "" ' it brings the line of code read from file
 
Fi$ = COMMAND$ ' File of input
IF Fi$ = "" THEN
    CLS
    PRINT "DEF2FUN Help:"
    PRINT " Usage: DEF2FUN NamefileToTranslate"
    PRINT " It needs one parameter at run "
    END
END IF
 
LenFi = LEN(Fi$)
IF INSTR(Fi$, ".") THEN
    ' name file has extention
    ExtFi$ = RIGHT$(Fi$, LEN(Fi$) - INSTR(Fi$, ".") + 1)
    NamFi$ = LEFT$(Fi$, INSTR(Fi$, ".") - 1)
    Fo$ = LEFT$(NamFi$, LenFi - 3) + "Tmp" + ExtFi$
    Fdef$ = LEFT$(NamFi$, LenFi - 3) + ".TMP"
ELSE
    ' name file has no extension
    Fo$ = "Tmp" + LEFT$(Fi$, 3)
    Fdef$ = Fo$ + ".TMP"
END IF
 
 
' open files for input and output
CLS
PRINT "Opening files..."
OPEN Fi$ FOR BINARY AS #1 ' only QB64 1.0 or more can use LINE INPUT in Binary mode
' suggested by Pete
PRINT " Opened Input file..."
OPEN Fo$ FOR OUTPUT AS #2
OPEN Fdef$ FOR OUTPUT AS #3
PRINT " Opened output file..."
 
' it puts author's sign
PRINT #2, " REM  File made by DEF2FUNC utility by TempodiBasic "
PRINT #2, " REM  DEF2FUNC translate any function DEF FN to the FUNCTION syntax"
PRINT #2, ""
 
' main loop processing file
DO WHILE NOT EOF(1)
    PRINT " Reading file...";
    LINE INPUT #1, LineOfCode$
    PRINT LineOfCode$
    ' search a definition of DEF FN
    DefPos% = INSTR(UCASE$(LineOfCode$), Primo) ' is there a DEF FN?
    RemPos% = INSTR(UCASE$(LineOfCode$), "REM") ' is there a REM?
    Rem2Pos% = INSTR(UCASE$(LineOfCode$), "'") ' is there an '?
    StringPos% = INSTR(UCASE$(LineOfCode$), CHR$(34)) ' is there an " ?
    StringPos2% = INSTR(StringPos% + 1, UCASE$(LineOfCode$), CHR$(34)) ' is there a second "?
 
    ' if it must be translated
    IF DefPos% > 0 THEN
 
        ' if DEF FN is into a string it'll be put into file
        IF (StringPos% > 0 AND StringPos2% > 0) AND ((DefPos% > StringPos%) AND (DefPos% < StringPos2%)) THEN
            'write to file main
            PRINT #2, LineOfCode$
        ELSEIF (RemPos% > 0) XOR (Rem2Pos% > 0) THEN
            ' there is a comment with REM XOR '
 
            ' if it is a comment so it'll be put into file
            IF (RemPos% = 1 XOR Rem2Pos% = 1) THEN
                'write to file main
                PRINT #2, LineOfCode$
 
            ELSEIF ((RemPos% < DefPos% AND RemPos%) XOR (Rem2Pos% < DefPos% AND Rem2Pos%)) THEN
                ' if there is DEF FN in the same line it is at right of comment's keywords
                ' it is in the comment so it'll put into file
                PRINT #2, LineOfCode$
 
            ELSEIF (RemPos% > DefPos%) THEN
                ' a REM after DEF FN
                RemLine$ = RIGHT$(LineOfCode$, LEN(LineOfCode$) - RemPos% + 1)
                LineOfCode$ = LEFT$(LineOfCode$, RemPos% - 1)
                PRINT #3, RemLine$
                Extract_DEF_Fn (LineOfCode$)
 
            ELSEIF (Rem2Pos% > DefPos%) THEN
                ' an ' after DEF FN
                RemLine$ = RIGHT$(LineOfCode$, LEN(LineOfCode$) - Rem2Pos% + 1)
                LineOfCode$ = LEFT$(LineOfCode$, Rem2Pos% - 1)
                PRINT #3, RemLine$
                Extract_DEF_Fn (LineOfCode$)
            END IF
        ELSE
            ' there is DEF FN and no REM ' " "
            Extract_DEF_Fn (LineOfCode$)
        END IF
    ELSE
        ' it has no DEF FN
        ' write line to the main file because it mustn't be translated
        PRINT #2, LineOfCode$
    END IF
LOOP
PRINT "End of translation..."
PRINT " Rebuilding the file..."
CLOSE ' closes all files
OPEN Fo$ FOR APPEND AS #1
OPEN Fdef$ FOR INPUT AS #2
DO WHILE NOT EOF(2)
    LINE INPUT #2, LineOfCode$
    PRINT #1, LineOfCode$
LOOP
CLOSE ' closes all files
PRINT " File translated ..."
KILL Fdef$
END ' end of program
 
 
SUB Extract_DEF_Fn (LineOfCode$)
    ' if there is a DEF FN
    PRINT " Found a DEF FN: "; LineOfCode$
    PRINT #3, "FUNCTION ";
    '  is DEF FN in oneline or in multiline?
    IF INSTR(LineOfCode$, Secondo) THEN
        OneLine LineOfCode$, Counter%
    ELSE
        Multiline LineOfCode$, Counter%
    END IF
 
END SUB
 
 
FUNCTION Incr% (Intero%)
    Incr% = Intero% + 1
END FUNCTION
 
SUB Multiline (Line$, Counter%)
    PRINT " It is a multiline DEF FN"
    ' this subprogram process a DEF FN on multiline
    NextLine$ = ""
    Counter% = Incr(Counter%)
    NameOfFN$ = RIGHT$(Line$, LEN(Line$) - (INSTR(UCASE$(Line$), Primo) + LEN(Primo) - 3))
    PRINT #3, NameOfFN$
    DO WHILE NOT EOF(1)
        'here it processes multiline DEF FN after the first line of code
        LINE INPUT #1, NextLine$
        IF INSTR(UCASE$(NextLine$), Quarto) THEN
            PRINT #3, " EXIT FUNCTION "
        ELSEIF INSTR(UCASE$(NextLine$), Quinto) THEN
            EXIT DO
        ELSE
            PRINT #3, NextLine$
        END IF
    LOOP
    PRINT #3, "END FUNCTION"
END SUB
 
SUB OneLine (LineOfCode$, Counter%)
    PRINT " It is an oneline DEF FN"
    ' this subprogram process a DEF FN on oneline
    Counter% = Incr(Counter%)
    Start% = INSTR(UCASE$(LineOfCode$), Primo) + LEN(Primo) - 2
    Lenght% = INSTR(UCASE$(LineOfCode$), Secondo) - Start%
    NameOfFN$ = MID$(LineOfCode$, Start%, Lenght%)
    PRINT "FUNCTION "; NameOfFN$
    PRINT #3, NameOfFN$
    PRINT #3, LEFT$(NameOfFN$, INSTR(NameOfFN$, "(") - 1);
    PRINT #3, RIGHT$(LineOfCode$, LEN(LineOfCode$) - (INSTR(UCASE$(LineOfCode$), Secondo) - 1))
    PRINT #3, "END FUNCTION"
END SUB
 

here code_files to test it:
DEFFN8.BAS

Code: QB64: [Select]

DEF fnPiuUno (z%) = z% + 1 ' sum demo " Def Fn
DEF FNPer2 (z%) = z% * 2  REM " Def Fn *2"
DEF fNPer10 (z%) = z% * 10  REM multiplication function demo
DEF FnDiv1 (z%) = z% / 1   'division function demo
 
 
' here main block starts 
FOR a% = 1 TO 10 STEP 1
   PRINT " Def Fn Demo"
   PRINT fnPiuUno(a%), FNPer2(a%), fNPer10(a%), FnDiv1(a%)
   REM  PRINT  " All done DEF Fn Demo"
NEXT a%
END
 

DEFFN9.BAS

Code: QB64: [Select]

DEF fnPiuUno (z%) = z% + 1
DEF FNPer2 (z%) = z% * 2
DEF fNPer10 (z%) = z% * 10
DEF FnDiv1 (z%) = z% / 1   'division function demo
 
 
' here main block starts 
FOR a% = 1 TO 10 STEP 1
   PRINT " Def Fn Demo"
   PRINT fnPiuUno(a%), FNPer2(a%), fNPer10(a%), FnDiv1(a%)
   REM  PRINT  " All done DEF Fn Demo"
NEXT a%
END
 

DEFFN4.BAS

Code: QB64: [Select]

' DEF FnP1(z%) = z%+999
' DEF fNP2(z%)
'      fNP2= z%*1000
' END DEF
 
DEF fnPiuUno (z%)
        fnPiuUno = z% + 1
END DEF
DEF fNPer10 (z%) = z% * 10
DEF FNPer2(z%)
    FNPer2 = fNPer10(z%) * 2
END DEF
DEF FnDiv1 (z%) = z% / 1
 
' main
CLS
PRINT "this is a DEF Fn demo"
FOR a% = 1 TO 10 STEP 1
   PRINT fnPiuUno(a%), FNPer2(a%), fNPer10(a%), FnDiv1(a%)
NEXT a%
END
 

DEFFN3.BAS

Code: QB64: [Select]

' DEF FnP1(z%) = z%+999
' DEF fNP2(z%)
'      fNP2= z%*1000
' END DEF
 
DEF fnPiuUno (z%)
        fnPiuUno = z% + 1
END DEF
DEF fNPer10 (z%) = z% * 10
DEF FNPer2(z%)
    FNPer2 = fNPer10(z%) * 2
END DEF
DEF FnDiv1 (z%) = z% / 1
 
' main
CLS
FOR a% = 1 TO 10 STEP 1
   PRINT fnPiuUno(a%), FNPer2(a%), fNPer10(a%), FnDiv1(a%)
NEXT a%
END
 

DEFFN2.BAS

Code: QB64: [Select]

REM DEF FnP1(z%) = z%+999
REM DEF fNP2(z%)
REM      fNP2= z%*1000
REM END DEF
 
DEF fnPiuUno (z%)
        fnPiuUno = z% + 1
END DEF
DEF fNPer10 (z%) = z% * 10
DEF FNPer2(z%)
    FNPer2 = fNPer10(z%) * 2
END DEF
DEF FnDiv1 (z%) = z% / 1
 
' main
CLS
FOR a% = 1 TO 10 STEP 1
   PRINT fnPiuUno(a%), FNPer2(a%), fNPer10(a%), FnDiv1(a%)
NEXT a%
END
 

DEFFN1.BAS

Code: QB64: [Select]

DEF fnPiuUno (z%) = z% + 1
 
 
FOR a% = 1 TO 10 STEP 1
   PRINT fnPiuUno(a%)
NEXT a%
END

DEFFN0.BAS

Code: QB64: [Select]

DEF fnPiuUno (z%)
        fnPiuUno = z% + 1
END DEF
DEF fNPer10 (z%) = z% * 10
DEF FNPer2(z%)
    FNPer2 = fNPer10(z%) * 2
END DEF
DEF FnDiv1 (z%) = z% / 1
 
' main
CLS
FOR a% = 1 TO 10 STEP 1
   PRINT fnPiuUno(a%), FNPer2(a%), fNPer10(a%), FnDiv1(a%)
NEXT a%
END
 

Thanks to read and try
Welcome feedbacks

@Pete
No zip or tar or other compressed files, do you like this?

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: FellippeHeitor on May 08, 2020, 08:21:20 pm

One thing you may want to consider is scope. DEF FN procedures can access variables in the main module, since they belong to that scope. When you turn them into a function, older programs may completely break if they rely on the FN accessing local variables.

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: Pete on May 09, 2020, 03:03:22 pm

Quote from: FellippeHeitor on May 08, 2020, 08:21:20 pm

One thing you may want to consider is scope. DEF FN procedures can access variables in the main module, since they belong to that scope. When you turn them into a function, older programs may completely break if they rely on the FN accessing local variables.

Well in that CASE, I think Temp could look into making a variable in DEF FN local, by putting it in a STATIC statement.

DEF FN can only pass variables by value and I recall in my multi-modular programs, they were only global to the module they were contained in. In other words, if you had a 2 module program and you wanted the same DEF FN to work in both, you'd have to define the DEF FN statements in each module, and if you wanted variables passed to the other module, you had to define those variables as COMMON SHARED. Wow, this stuff takes me back to the 90's. Remind me to pick up my hair for the return trip. This Donald Trump comb over is a real pain without access to my dollar store teenage girl hairspray.

Pete

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: TempodiBasic on May 09, 2020, 05:38:15 pm

Hi Fellippe and Pete
thanks for feedbacks

@Fellippe
never used into a program DEF Fn so my knowledge about it is purely theoretic

about scope

Quote

One thing you may want to consider is scope. DEF FN procedures can access variables in the main module, since they belong to that scope. When you turn them into a function, older programs may completely break if they rely on the FN accessing local variables.

@Pete
Yes the Help in Qbasic describes the limitation of DEF Fn for the single module where it is declared.

Thanks so these more informations can lead to more development of this little tool.

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: TempodiBasic on May 09, 2020, 06:21:40 pm

Hi

I have made some experiments with DEF Fn in QBasic and yes I have missed that feature to access to the main module's variables without SHARED in DEF Fn or DIM SHARED in main module. Moreover SHARED is forbidden into DEF Fn multiline.
Surely it is impossible to declare in DEF Fn multiline a variable with the same name of those in main module already declared, but as good Qbasic/QB bug you can declare a variable in main and also in DEF Fn multiline with DIM if DEF Fn is before the declaration in main module!.

So I think that if it is impossible to distinguish between variables of DEF FN multiline and variables used in DEF fn multiline but declared into main module.
if you run this code into Qbasic

Code: Text: [Select]

DEF FnDue(z%)
DIM  a%
PRINT a%
FnDue = z% * a%
END DEF
 
CLS
a% = 10
PRINT a%
PRINT FnDue(4)
END
 

and after F5 you'll get as output

Quote

10
10
40

This output lets us think that the code is running first main module sequence and after the DEF Fn sequence.
But is it legal in QBasic/QB/QB64 declare a variable with assignation and then declare the same variable with DIM? NO
So the first line of DEF FN multiline

Code: Text: [Select]

DIM a%

must activate the error like we get if in main we type

Code: QB64: [Select]

c% = 1
DIM c%

just if a% in the main module and DIM a% in DEF Fn are the same variable! In the case that the two previous variables are different (and not the same) we must get as output

Quote

10
0
0

because in DEF Fn a% has no assignment . Indeed here we found another dual experience of principle of Heisenberg https://en.wikipedia.org/wiki/Uncertainty_principle (https://en.wikipedia.org/wiki/Uncertainty_principle) :-) we don't know the whole universe!

Coming back to the translator of DEF Fn to FUNCTION we must admit that the issue of broken correlation between main module and DEF Fn multiline comes out for DEF Fn multiline.
The point of gray is the real possibility to define a variable into DEF FN using DIM with the same name of a variable declared into main module using the assignment statement. (as showed into following code)

Code: Text: [Select]

DEF FnQbasicBug (z%)
DIM a%
FnQbasicBug= z% * a%
END DEF
 
a% = 10
PRINT a%, FnQbasicBug(4)
 

and this strange behaviour is claimed in the same help of Qbasic with a warning don't modify global variable into DEF Fn and don't execute graphic statements into DEF Fn.

Well in conclusion I think that the issue can be solved except for the rare case of a coder that declare in DEF Fn a variable with the same name of another variable declared into the main module .

Waiting suggestions to solve this task for now I have thought an array for a list of variable of main to shared.

Thanks to read and talk.

Title: Re: A simple command line tool translating DEF FN functions into FUNCTIONs
Post by: TempodiBasic on May 10, 2020, 05:45:12 pm

Moreover it seems that you can read variables from main module into DEF Fn
run this code in Qbasic

Code: Text: [Select]

DEF FnQbasicVariableScope(z%)
 c = 1
FnQbasicVariableScope= 1+ z%
PRINT a%, b%, c
END DEF
 
 
a% = 10
b% = FnQbasicVariableScope (20)
PRINT a%,b%,c
END
 

and you'll get this result

Quote

10 0 1
10 21 1

so DEF_FN can read directly variables in main module and main module can read directly variables in DEF_FN:
it seems more a GOSUB than a separated function.
With the addition of the bug that lets declare a variable in DEFFN by DIM before to declare the same variable by assignment statement into main module.

Now we can begin to understand why Galleon doesn't like to support DEF FN in QB64 and also why the same developers of QB and Qbasic warning to modify variable of main from DEF_FN or make operations or graphic work .

Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: TempodiBasic on April 30, 2020, 10:31:24 am