QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: EricE on March 28, 2020, 05:54:09 pm

Title: Calling the GetTimeZoneInformation function in QB64
Post by: EricE on March 28, 2020, 05:54:09 pm

Here is a program that calls the Windows API function GetTimeZoneInformation

Code: QB64: [Select]

1. TYPE SYSTEMTIME
2.   wYear AS _UNSIGNED INTEGER
3.   wMonth AS _UNSIGNED INTEGER
4.   wDayOfWeek AS _UNSIGNED INTEGER
5.   wDay AS _UNSIGNED INTEGER
6.   wHour AS _UNSIGNED INTEGER
7.   wMinute AS _UNSIGNED INTEGER
8.   wSecond AS _UNSIGNED INTEGER
9.   wMilliseconds AS _UNSIGNED INTEGER
10. END TYPE
11.  
12. TYPE TIME_ZONE_INFORMATION
13.   Bias AS LONG
14.   StandardName AS STRING*64 'WCHAR      StandardName[32];
15.   StandardDate AS SYSTEMTIME
16.   StandardBias AS LONG
17.   DaylightName AS STRING*64 'WCHAR      DaylightName[32];
18.   DaylightDate AS SYSTEMTIME
19.   DaylightBias AS LONG
20. END TYPE
21.  
22. DECLARE DYNAMIC LIBRARY "Kernel32"
23. ' Function prototype:
24. ' DWORD GetTimeZoneInformation( LPTIME_ZONE_INFORMATION lpTimeZoneInformation);
25.   FUNCTION GetTimeZoneInformation& (BYVAL lpTimeZoneInformation AS _UNSIGNED _OFFSET)
26. END DECLARE
27.  
28. DIM tz_info AS TIME_ZONE_INFORMATION
29.  
30. retval& = GetTimeZoneInformation(_OFFSET(tz_info))
31.  
32. PRINT "Returned Value = ";retval&
33. PRINT
34. PRINT "TZ INFO"
35. PRINT " Bias = ";tz_info.Bias
36. PRINT " StandardName = ";tz_info.StandardName
37. PRINT " Standard Date"
38. PRINT "   wYear        = ";tz_info.StandardDate.wYear
39. PRINT "   wMonth       = ";tz_info.StandardDate.wMonth
40. PRINT "   wDayOfWeek   = ";tz_info.StandardDate.wDayOfWeek
41. PRINT "   wDay         = ";tz_info.StandardDate.wDay
42. PRINT "   wHour        = ";tz_info.StandardDate.wHour
43. PRINT "   wMinute      = ";tz_info.StandardDate.wMinute
44. PRINT "   wSecond      = ";tz_info.StandardDate.wSecond
45. PRINT "   wMillisecons = ";tz_info.StandardDate.wMilliseconds
46. PRINT " StandardBias = ";tz_info.StandardBias
47. PRINT
48. PRINT "Press any key to continue"
49. WHILE INKEY$="" :WEND
50. PRINT
51. PRINT " DaylightName = ";tz_info.DaylightName
52. PRINT " DaylightDate"
53. PRINT "   wYear        = ";tz_info.DaylightDate.wYear
54. PRINT "   wMonth       = ";tz_info.DaylightDate.wMonth
55. PRINT "   wDayOfWeek   = ";tz_info.DaylightDate.wDayOfWeek
56. PRINT "   wDay         = ";tz_info.DaylightDate.wDay
57. PRINT "   wHour        = ";tz_info.DaylightDate.wHour
58. PRINT "   wMinute      = ";tz_info.DaylightDate.wMinute
59. PRINT "   wSecond      = ";tz_info.DaylightDate.wSecond
60. PRINT "   wMillisecons = ";tz_info.DaylightDate.wMilliseconds
61. PRINT " DaylightBias = ";tz_info.DaylightBias
62. PRINT

Petr has written a program that calls the GetTimeZoneInformation function in a manner different than specified in the Microsoft documention.

Here is my version of Petr's program.

Code: QB64: [Select]

1. DECLARE DYNAMIC LIBRARY "Kernel32"
2.     SUB GetTimeZoneInformation (a AS INTEGER)
3. END DECLARE
4.  
5. tz& = GETTIMEZONE
6. PRINT "Your time zone is:"; tz&  
7.  
8. FUNCTION GETTIMEZONE
9.     DIM b AS INTEGER
10.        
11.     GetTimeZoneInformation b
12.     PRINT "GetTimeZoneInformation = ";b
13.        
14.     GETTIMEZONE = b / -60 'so it return time zone in hours (+1 for Prague)
15. END FUNCTION

There is certainly a big difference between  using an INTEGER rather than an  _OFFSET as a function's parameter.
Also, notice that Petr's method treats GetTimeZoneInformation as a SUB rather than a FUNCTION.

Why does Petr's method work in that it returns a correct value for the time zone Bias value?

Title: Re: Calling the GetTimeZoneInformation function in QB64
Post by: EricE on March 29, 2020, 01:23:18 am

I have the answer.
The Time Zone Bias INTEGER value (it really should be a LONG) that is returned is correct because it is the first field in the Time Zone structure and the value fits in an INTEGER.
All the other fields don't make it out of the call to the GetTimeZoneInformation function and are lost.

Here is my debug code, if anyone wants to see it.
I changed the GetTimeZoneInformation parameter from an INTEGER which it was in Petr's code to a fixed string type, STRING*1000 to make room for the returned data.

Code: QB64: [Select]

1. TYPE SYSTEMTIME
2.   wYear AS _UNSIGNED INTEGER
3.   wMonth AS _UNSIGNED INTEGER
4.   wDayOfWeek AS _UNSIGNED INTEGER
5.   wDay AS _UNSIGNED INTEGER
6.   wHour AS _UNSIGNED INTEGER
7.   wMinute AS _UNSIGNED INTEGER
8.   wSecond AS _UNSIGNED INTEGER
9.   wMilliseconds AS _UNSIGNED INTEGER
10. END TYPE
11.  
12. TYPE TIME_ZONE_INFORMATION
13.   Bias AS LONG
14.   StandardName AS STRING*64 'WCHAR      StandardName[32];
15.   StandardDate AS SYSTEMTIME
16.   StandardBias AS LONG
17.   DaylightName AS STRING*64 'WCHAR      DaylightName[32];
18.   DaylightDate AS SYSTEMTIME
19.   DaylightBias AS LONG
20. END TYPE
21.  
22.  
23. DECLARE DYNAMIC LIBRARY "Kernel32"
24.     ' SUB GetTimeZoneInformation (a as INTEGER)
25.     SUB GetTimeZoneInformation (a as string)
26. END DECLARE
27.  
28. DIM SHARED tz_info AS TIME_ZONE_INFORMATION
29. DIM SHARED m as _MEM
30.  
31. tz& = GETTIMEZONE
32. PRINT "Your time zone is:"; tz&  
33.  
34. FUNCTION GETTIMEZONE
35.     'DIM b AS INTEGER
36.         DIM b AS STRING*1000
37.        
38.     GetTimeZoneInformation b
39.         '----
40.         m=_MEM(b)
41.         _MEMGET m, m.OFFSET, Bias%
42.     PRINT "GetTimeZoneInformation = ";Bias%
43.     '----  
44.     GETTIMEZONE = Bias% / -60 'so it return time zone in hours (+1 for Prague)
45.         '----
46.         _MEMGET m, m.OFFSET, tz_info
47.         Print_TimeZone_Info tz_info
48.         _MEMFREE m
49.         '----
50. END FUNCTION
51.  
52. SUB Print_TimeZone_Info( tzi AS TIME_ZONE_INFORMATION)
53.   PRINT
54.   PRINT "TZ INFO"
55.   PRINT " Bias = ";tz_info.Bias
56.   print " StandardName = ";tzi.StandardName
57.   PRINT " Standard Date"
58.   PRINT "   wYear        = ";tzi.StandardDate.wYear
59.   PRINT "   wMonth       = ";tzi.StandardDate.wMonth
60.   PRINT "   wDayOfWeek   = ";tzi.StandardDate.wDayOfWeek
61.   PRINT "   wDay         = ";tzi.StandardDate.wDay
62.   PRINT "   wHour        = ";tzi.StandardDate.wHour
63.   PRINT "   wMinute      = ";tzi.StandardDate.wMinute
64.   PRINT "   wSecond      = ";tzi.StandardDate.wSecond
65.   PRINT "   wMillisecons = ";tzi.StandardDate.wMilliseconds
66.   PRINT " StandardBias = ";tzi.StandardBias
67.   PRINT
68.   PRINT "Press any key to continue"
69.   WHILE INKEY$="" :WEND
70.   PRINT
71.   PRINT " DaylightName = ";tzi.DaylightName
72.   PRINT " DaylightDate"
73.   PRINT "   wYear        = ";tzi.DaylightDate.wYear
74.   PRINT "   wMonth       = ";tzi.DaylightDate.wMonth
75.   PRINT "   wDayOfWeek   = ";tzi.DaylightDate.wDayOfWeek
76.   PRINT "   wDay         = ";tzi.DaylightDate.wDay
77.   PRINT "   wHour        = ";tzi.DaylightDate.wHour
78.   PRINT "   wMinute      = ";tzi.DaylightDate.wMinute
79.   PRINT "   wSecond      = ";tzi.DaylightDate.wSecond
80.   PRINT "   wMillisecons = ";tzi.DaylightDate.wMilliseconds
81.   PRINT " Daylig
82. END SUB

Title: Re: Calling the GetTimeZoneInformation function in QB64
Post by: EricE on March 29, 2020, 01:23:42 am

Why do I make all this work for myself?

Title: Re: Calling the GetTimeZoneInformation function in QB64
Post by: EricE on March 29, 2020, 05:07:21 am

Here is the debug program using _MEM's unreferenced syntax.

This debug code shows that GetTimeZoneInformation writes to memory past the INTEGER output parameter!

Code: QB64: [Select]

1. TYPE SYSTEMTIME
2.   wYear AS _UNSIGNED INTEGER
3.   wMonth AS _UNSIGNED INTEGER
4.   wDayOfWeek AS _UNSIGNED INTEGER
5.   wDay AS _UNSIGNED INTEGER
6.   wHour AS _UNSIGNED INTEGER
7.   wMinute AS _UNSIGNED INTEGER
8.   wSecond AS _UNSIGNED INTEGER
9.   wMilliseconds AS _UNSIGNED INTEGER
10. END TYPE
11.  
12. TYPE TIME_ZONE_INFORMATION
13.   Bias AS LONG
14.   StandardName AS STRING*64 'WCHAR      StandardName[32];
15.   StandardDate AS SYSTEMTIME
16.   StandardBias AS LONG
17.   DaylightName AS STRING*64 'WCHAR      DaylightName[32];
18.   DaylightDate AS SYSTEMTIME
19.   DaylightBias AS LONG
20. END TYPE
21.  
22.  
23. DECLARE DYNAMIC LIBRARY "Kernel32"
24.     SUB GetTimeZoneInformation (a as INTEGER)
25.     'SUB GetTimeZoneInformation (a as string)
26. END DECLARE
27.  
28. DIM SHARED tz_info AS TIME_ZONE_INFORMATION
29. DIM SHARED m as _MEM
30.  
31. tz& = GETTIMEZONE
32. PRINT "Your time zone is:"; tz&  
33.  
34. FUNCTION GETTIMEZONE
35.     DIM b AS INTEGER
36.         'DIM b AS STRING*1000
37.        
38.     GetTimeZoneInformation b
39.         '----
40.         'm=_MEM(b)
41.         m = _MEM(_OFFSET(b), 1000) ' _MEM Unsecure syntax
42.        
43.         _MEMGET m, m.OFFSET, Bias%
44.     PRINT "GetTimeZoneInformation = ";Bias%
45.     '----  
46.     GETTIMEZONE = Bias% / -60 'so it return time zone in hours (+1 for Prague)
47.         '----
48.         _MEMGET m, m.OFFSET, tz_info
49.         Print_TimeZone_Info tz_info
50.         _MEMFREE m
51.         '----
52. END FUNCTION
53.  
54. SUB Print_TimeZone_Info( tzi AS TIME_ZONE_INFORMATION)
55.   PRINT
56.   PRINT "TZ INFO"
57.   PRINT " Bias = ";tz_info.Bias
58.   print " StandardName = ";tzi.StandardName
59.   PRINT " Standard Date"
60.   PRINT "   wYear        = ";tzi.StandardDate.wYear
61.   PRINT "   wMonth       = ";tzi.StandardDate.wMonth
62.   PRINT "   wDayOfWeek   = ";tzi.StandardDate.wDayOfWeek
63.   PRINT "   wDay         = ";tzi.StandardDate.wDay
64.   PRINT "   wHour        = ";tzi.StandardDate.wHour
65.   PRINT "   wMinute      = ";tzi.StandardDate.wMinute
66.   PRINT "   wSecond      = ";tzi.StandardDate.wSecond
67.   PRINT "   wMillisecons = ";tzi.StandardDate.wMilliseconds
68.   PRINT " StandardBias = ";tzi.StandardBias
69.   PRINT
70.   PRINT "Press any key to continue"
71.   WHILE INKEY$="" :WEND
72.   PRINT
73.   PRINT " DaylightName = ";tzi.DaylightName
74.   PRINT " DaylightDate"
75.   PRINT "   wYear        = ";tzi.DaylightDate.wYear
76.   PRINT "   wMonth       = ";tzi.DaylightDate.wMonth
77.   PRINT "   wDayOfWeek   = ";tzi.DaylightDate.wDayOfWeek
78.   PRINT "   wDay         = ";tzi.DaylightDate.wDay
79.   PRINT "   wHour        = ";tzi.DaylightDate.wHour
80.   PRINT "   wMinute      = ";tzi.DaylightDate.wMinute
81.   PRINT "   wSecond      = ";tzi.DaylightDate.wSecond
82.   PRINT "   wMillisecons = ";tzi.DaylightDate.wMilliseconds
83.   PRINT " Daylig
84. END FUNCTION
85.  

Text Only | Text with Attachments