QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: EricE on March 27, 2020, 08:14:00 pm

Title: Request for next QB64 Release, Time Zone information
Post by: EricE on March 27, 2020, 08:14:00 pm

I would like to put in a request for the next QB64 release.

Could a function be added to give the local time zone?
This would allow UTC to be computed by adding an offset to the computer's local time value.

Title: Re: Request for next QB64 Release, Time Zone information
Post by: EricE on March 27, 2020, 09:29:02 pm

Microsoft documentation for the Time Zone Information structure

TIME_ZONE_INFORMATION structure
https://docs.microsoft.com/en-us/windows/win32/api/timezoneapi/ns-timezoneapi-time_zone_information (https://docs.microsoft.com/en-us/windows/win32/api/timezoneapi/ns-timezoneapi-time_zone_information)

Perhaps a QB64 function could be added to the compiler that would return all of this available information?

Title: Re: Request for next QB64 Release, Time Zone information
Post by: Petr on March 28, 2020, 06:39:03 am

Hi. You won't wait:

Code: QB64: [Select]

1. DECLARE DYNAMIC LIBRARY "Kernel32"
2.     FUNCTION GetUserDefaultLCID%
3.     FUNCTION GetSystemDefaultLangID%
4.     SUB GetTimeZoneInformation (a AS INTEGER)
5. END DECLARE
6.  
7.  
8.  
9. PRINT "Your time zone is:"; GETTIMEZONE; "and your default language ID code is:"; GETLCID
10. 'for LCID use this table https://www.science.co.il/language/Locale-codes.php  and 3th column.
11.  
12.  
13. FUNCTION GETTIMEZONE
14.     DIM b AS INTEGER
15.     GetTimeZoneInformation b
16.     GETTIMEZONE = b / -60 'so it return time zone in hours (+1 for Prague)
17. END FUNCTION
18.  
19. FUNCTION GETLCID
20.     GETLCID = GetUserDefaultLCID%
21.     IF GetUserDefaultLCID% = 0 AND GetSystemDefaultLangID% THEN GETLCID = GetSystemDefaultLangID%
22.     IF GetUserDefaultLCID% = 0 AND GetSystemDefaultLangID% = 0 THEN GETLCID = -1 'error finding LCID
23. END FUNCTION
24.  

Title: Re: Request for next QB64 Release, Time Zone information
Post by: EricE on March 28, 2020, 09:27:11 am

Thank you Petr.
This is useful.

One question about your code.
Should the function GetTimeZoneInformation parameter be a pointer to a TIME_ZONE_INFORMATION structure?

https://docs.microsoft.com/en-us/windows/win32/api/timezoneapi/nf-timezoneapi-gettimezoneinformation (https://docs.microsoft.com/en-us/windows/win32/api/timezoneapi/nf-timezoneapi-gettimezoneinformation)

Title: Re: Request for next QB64 Release, Time Zone information
Post by: Petr on March 28, 2020, 11:08:20 am

Hi EricE, no. This is not pointer to this structure, but parameter (a as INTEGER) return your time shift in minutes. You can try it, if you set other time zone in time settings in Windows.

Title: Re: Request for next QB64 Release, Time Zone information
Post by: EricE on March 28, 2020, 03:58:20 pm

Here is a program for calling GetTimeZoneInformation with an INTEGER parameter.

Code: QB64: [Select]

1. DECLARE DYNAMIC LIBRARY "Kernel32"
2.     SUB GetTimeZoneInformation (a AS INTEGER)
3. END DECLARE
4.  
5. tz& = GETTIMEZONE
6. PRINT "Your time zone is:"; tz&  
7.  
8. FUNCTION GETTIMEZONE
9.     DIM b AS INTEGER
10.        
11.     GetTimeZoneInformation b
12.     PRINT "GetTimeZoneInformation = ";b
13.        
14.     GETTIMEZONE = b / -60 'so it return time zone in hours (+1 for Prague)
15. END FUNCTION

On my computer this is the output:

GetTimeZoneInformation =  480
Your time zone is:-8

My location is on Pacific Time (UTC-7), so the correct time zone for me should be -7.

Title: Re: Request for next QB64 Release, Time Zone information
Post by: EricE on March 28, 2020, 04:57:49 pm

Here is a QB64 program that calls the GetTimeZoneInformation function in a way according to the Microsoft API documentation.
The output of the program for my location gives a value of -60 for the DayloghtBias, and using that value to adjust the Bias value of 480 gives the correct value for my local time zone.

time zone = (480-60)/(-60) = -7

Why does Petr's program give the correct value for the time zone bias (for my computer 480) when the GetTimeZoneInformation function is called differently from the way the Microsoft documentation indicates? It should not work, but it does.

Code: QB64: [Select]

1. TYPE SYSTEMTIME
2.   wYear AS _UNSIGNED INTEGER
3.   wMonth AS _UNSIGNED INTEGER
4.   wDayOfWeek AS _UNSIGNED INTEGER
5.   wDay AS _UNSIGNED INTEGER
6.   wHour AS _UNSIGNED INTEGER
7.   wMinute AS _UNSIGNED INTEGER
8.   wSecond AS _UNSIGNED INTEGER
9.   wMilliseconds AS _UNSIGNED INTEGER
10. END TYPE
11.  
12. TYPE TIME_ZONE_INFORMATION
13.   Bias as LONG
14.   StandardName AS String*64 'WCHAR      StandardName[32];
15.   StandardDate AS SYSTEMTIME
16.   StandardBias AS LONG
17.   DaylightName AS STRING*64 'WCHAR      DaylightName[32];
18.   DaylightDate AS SYSTEMTIME
19.   DaylightBias AS LONG
20. END TYPE
21.  
22. DECLARE DYNAMIC LIBRARY "Kernel32"
23. ' Function prototype:
24. ' DWORD GetTimeZoneInformation( LPTIME_ZONE_INFORMATION lpTimeZoneInformation);
25.   FUNCTION GetTimeZoneInformation& (BYVAL lpTimeZoneInformation AS _UNSIGNED _OFFSET)
26. END DECLARE
27.  
28. DIM tz_info AS TIME_ZONE_INFORMATION
29.  
30. retval& = GetTimeZoneInformation(_OFFSET(tz_info))
31.  
32. PRINT "Returned Value = ";retval&
33. PRINT
34. PRINT "TZ INFO"
35. PRINT " Bias = ";tz_info.Bias
36. print " StandardName = ";tz_info.StandardName
37. PRINT " Standard Date"
38. PRINT "   wYear        = ";tz_info.StandardDate.wYear
39. PRINT "   wMonth       = ";tz_info.StandardDate.wMonth
40. PRINT "   wDayOfWeek   = ";tz_info.StandardDate.wDayOfWeek
41. PRINT "   wDay         = ";tz_info.StandardDate.wDay
42. PRINT "   wHour        = ";tz_info.StandardDate.wHour
43. PRINT "   wMinute      = ";tz_info.StandardDate.wMinute
44. PRINT "   wSecond      = ";tz_info.StandardDate.wSecond
45. PRINT "   wMillisecons = ";tz_info.StandardDate.wMilliseconds
46. PRINT " StandardBias = ";tz_info.StandardBias
47. PRINT
48. PRINT "Press any key to continue"
49. WHILE INKEY$="" :WEND
50. PRINT
51. PRINT " DaylightName = ";tz_info.DaylightName
52. PRINT " DaylightDate"
53. PRINT "   wYear        = ";tz_info.DaylightDate.wYear
54. PRINT "   wMonth       = ";tz_info.DaylightDate.wMonth
55. PRINT "   wDayOfWeek   = ";tz_info.DaylightDate.wDayOfWeek
56. PRINT "   wDay         = ";tz_info.DaylightDate.wDay
57. PRINT "   wHour        = ";tz_info.DaylightDate.wHour
58. PRINT "   wMinute      = ";tz_info.DaylightDate.wMinute
59. PRINT "   wSecond      = ";tz_info.DaylightDate.wSecond
60. PRINT "   wMillisecons = ";tz_info.DaylightDate.wMilliseconds
61. PRINT " DaylightBias = ";tz_info.DaylightBias
62. PRINT

Title: Re: Request for next QB64 Release, Time Zone information
Post by: Petr on March 28, 2020, 05:22:09 pm

Thank you for the information, in fact, you are the first, which test this with me. :)

Title: Re: Request for next QB64 Release, Time Zone information
Post by: EricE on March 28, 2020, 05:56:45 pm

Petr,

I have started a new thread regarding the GetTimeZoneInformation function.
It is important we understand as it involves how to call a Win32 API function.

Also, testing is fun! :)

Text Only | Text with Attachments