Print Page - Chrome's dinosaur game prototype

This guy writes a prototype of the dino game you find in Chrome's offline page:

The original is written in javascript, code at https://github.com/TylerPottsDev/chrome-dino-replica/blob/master/main.js, and here's the translation of that code to QB64:

Jump with the spacebar or up arrow, crouch/duck with left shift key or down arrow.

Code: QB64 $NOPREFIX: [Select]

$NOPREFIX
OPTION EXPLICIT
 
CONST true = -1, false = NOT true
 
TYPE Actor
    index AS LONG
 
    x AS SINGLE
    y AS SINGLE
    w AS SINGLE
    h AS SINGLE
    c AS UNSIGNED LONG
 
    dy AS SINGLE
    dx AS SINGLE
    jumpForce AS SINGLE
    originalHeight AS SINGLE
    grounded AS BYTE
    jumpTimer AS SINGLE
 
    state AS BYTE
END TYPE
 
DIM SHARED score AS UNSIGNED INTEGER64
DIM SHARED highScore AS UNSIGNED INTEGER64
 
DIM canvas AS LONG
canvas = NEWIMAGE(800, 300, 32)
SCREEN canvas
 
DIM SHARED gravity AS SINGLE, gameSpeed AS SINGLE
DIM SHARED initialSpawnTimer AS SINGLE, spawnTimer AS SINGLE
DIM SHARED gameOver AS BYTE
initialSpawnTimer = 200
 
DO
    gravity = 1
    gameSpeed = 3
    spawnTimer = initialSpawnTimer
    score = 0
    gameOver = false
 
    DIM SHARED player AS Actor
    player.x = 100
    player.y = 0
    player.w = 50
    player.h = 50
    player.originalHeight = player.h
    player.c = RGB32(255, 0, 0)
    player.jumpForce = 10
    player.grounded = false
 
    REDIM SHARED obstacles(100) AS Actor
 
    DO
        update
        DISPLAY
        LIMIT 60
    LOOP UNTIL gameOver
LOOP
 
SUB update
    DIM i AS LONG
    LINE (0, 0)-(WIDTH, HEIGHT), RGB32(255, 200), BF
 
    spawnTimer = spawnTimer - 1
    IF spawnTimer <= 0 THEN
        spawnObstacle
        spawnTimer = initialSpawnTimer - gameSpeed * 8
 
        IF spawnTimer < 60 THEN
            spawnTimer = 60
        END IF
    END IF
 
    FOR i = 1 TO UBOUND(obstacles)
        IF obstacles(i).state = true THEN
            IF obstacles(i).x + obstacles(i).w < 0 THEN
                obstacles(i).state = false
                CONTINUE
            END IF
 
            IF player.x < obstacles(i).x + obstacles(i).w AND _
               player.x + player.w > obstacles(i).x AND _
               player.y < obstacles(i).y + obstacles(i).h AND _
               player.y + player.h > obstacles(i).y THEN
                gameOver = true
                EXIT SUB
            END IF
        END IF
        updateObstacle i
    NEXT
 
    animate player
    score = score + 1
 
    DIM t AS STRING
    t = "Score:" + STR$(score)
    PRINTSTRING (25, 0), t
 
    IF score > highScore THEN
        highScore = score
    END IF
 
    t = "Highscore:" + STR$(highScore)
    PRINTSTRING (WIDTH - 25 - PRINTWIDTH(t), 0), t
 
    gameSpeed = gameSpeed + .003
END SUB
 
SUB updateObstacle (i AS LONG)
    obstacles(i).x = obstacles(i).x + obstacles(i).dx
    drawit obstacles(i)
    obstacles(i).dx = -gameSpeed
END SUB
 
SUB spawnObstacle
    DIM i AS LONG, kind AS LONG, size AS LONG
    FOR i = 1 TO UBOUND(obstacles)
        IF obstacles(i).state = false THEN
            obstacles(i).index = i
            obstacles(i).state = true
            size = rand(20, 70)
            kind = rand(0, 1)
 
            obstacles(i).x = WIDTH + size
            obstacles(i).y = HEIGHT - size
            obstacles(i).w = size
            obstacles(i).h = size
            obstacles(i).c = RGB32(83, 50, 194)
 
            IF kind = 0 THEN
                obstacles(i).y = obstacles(i).y - player.originalHeight + 10
            END IF
            EXIT SUB
        END IF
    NEXT
END SUB
 
FUNCTION rand& (min AS LONG, max AS LONG)
    rand& = ROUND(RND * (max - min) + min)
END FUNCTION
 
SUB animate (this AS Actor)
    IF KEYDOWN(32) OR KEYDOWN(18432) THEN 'space or up arrow to jump
        jump this
    ELSE
        this.jumpTimer = 0
    END IF
 
    IF KEYDOWN(100304) OR KEYDOWN(20480) THEN 'left-shift or down arrow to duck
        this.h = this.originalHeight / 2
    ELSE
        this.h = this.originalHeight
    END IF
 
    this.y = this.y + this.dy
 
    'gravity
    IF this.y + this.h < HEIGHT THEN
        this.dy = this.dy + gravity
        this.grounded = false
    ELSE
        this.dy = 0
        this.grounded = true
        this.y = HEIGHT - this.h
    END IF
 
    drawit this
END SUB
 
SUB jump (this AS Actor)
    IF this.grounded AND this.jumpTimer = 0 THEN
        this.jumpTimer = 1
        this.dy = -this.jumpForce
    ELSEIF this.jumpTimer > 0 AND this.jumpTimer < 15 THEN
        this.jumpTimer = this.jumpTimer + 1
        this.dy = -this.jumpForce - (this.jumpTimer / 50)
    END IF
END SUB
 
SUB drawit (this AS Actor)
    LINE (this.x, this.y)-STEP(this.w, this.h), this.c, BF
END SUB

I tried to remain as faithful to the original as possible with QB64. Here's a screenshot:

Cute little game.

I was thinking of Dodge ball after codevsb12 collision inquiry.

Nice game!

[ This attachment cannot be displayed inline in 'Print Page' view ]

fine !
But I like more you game platform....because it has background and more graphic output.

Good one.... I use to play it my school computer lab when teacher is not there...

Very nice. Simple but annoyingly addictive... Well done!

QB64.org Forum

Active Forums => Programs => Topic started by: FellippeHeitor on February 24, 2020, 02:37:10 pm