QB64.org Forum

Active Forums => Programs => Topic started by: TempodiBasic on January 26, 2020, 10:38:22 am

Title: child windows into window of the program: a demonstration
Post by: TempodiBasic on January 26, 2020, 10:38:22 am

Hy guys

programming is like to go on bike, you never forget it but you must empower your coding muscles to travel far...

so I have done a demo for  this thread https://www.qb64.org/forum/index.php?topic=2115.msg113538#msg113538 (https://www.qb64.org/forum/index.php?topic=2115.msg113538#msg113538)
but when I wanted to empower the demo with multiple windows (yes there are only 3 but code works for more than 3 windows) I loose myself in the hood of my imagination! So for a little but essential change in the order of the operations of the code I have had an hard session of debugging of 4-6 h  ... so it is clear that my Debugging muscles are very weak!

At the end this is the result, what is the content of each window is specific and I leave at your fantasy what put into it.
Originally I wanted to do a monitor of health with BMI and weight. But after all these hours of debugging for now I stop here.

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8.  
9. ' 2020 01 25  A program with child windows into it
10. ' we need a system to manage multiple windows
11. ' and a system to manage input/output
12. ' and a system to make graphic report
13.  
14. ' settings-------------------------------------------------------
15. SCREEN _NEWIMAGE(800, 600, 32)
16. _TITLE "Child windows"
17. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
18. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
19. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
20. CONST Minim = 20, Maxim = 10, Closed = 100, wMin = 3, aNull = 0, aQuit = 9999
21. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
22. CONST Dragging = 300, Focusing = 200
23.  
24. _FULLSCREEN
25.  
26.  
27. 'dataset  -----------------------------------------------
28. TYPE person
29.     name AS STRING * 10
30.     age AS INTEGER
31.     weight AS INTEGER
32.     height AS INTEGER
33.     BMI AS INTEGER
34. END TYPE
35.  
36. TYPE wChild
37.     X AS INTEGER
38.     Y AS INTEGER
39.     Width AS INTEGER
40.     Height AS INTEGER
41.     Zorder AS INTEGER
42.     Status AS INTEGER
43.     Color AS _UNSIGNED LONG
44. END TYPE
45.  
46. REDIM Windows(0 TO wMin) AS wChild
47. DIM SHARED wMax AS INTEGER
48. wMax = UBOUND(windows)
49.  
50. ' windows(0) is for Dragging
51.  
52. Windows(1).X = 1
53. Windows(1).Y = 1
54. Windows(1).Width = 300
55. Windows(1).Height = 400
56. Windows(1).Zorder = 1
57. Windows(1).Status = Minim
58. Windows(1).Color = Blu
59.  
60. Windows(2).X = 100
61. Windows(2).Y = 1
62. Windows(2).Width = 300
63. Windows(2).Height = 400
64. Windows(2).Zorder = 2
65. Windows(2).Status = Minim
66. Windows(2).Color = Yellow
67.  
68. Windows(3).X = 200
69. Windows(3).Y = 1
70. Windows(3).Width = 300
71. Windows(3).Height = 400
72. Windows(3).Zorder = 3
73. Windows(3).Status = Minim
74. Windows(3).Color = Green
75.  
76. DIM Action AS INTEGER
77.  
78.  
79. ' main loop -----------------------------------------------
80. DO
81.     ' set the main window
82.     Action = aNull
83.     CLS , Orange
84.     DrawAllWin
85.  
86.     GetInput Action
87.  
88.     DoAction Action
89.     _LIMIT 20
90. LOOP
91. END
92.  
93. ' SUBs and FUNCTIONs --------------------------------------
94. SUB DrawAllWin
95.     SHARED Windows() AS wChild
96.     DIM Finished AS INTEGER
97.     Finished = wMax
98.     DO
99.         FOR a = 1 TO wMax
100.             IF Windows(a).Zorder = Finished THEN
101.                 DrawWindow Windows(a)
102.                 Finished = Finished - 1
103.                 EXIT FOR
104.             END IF
105.         NEXT a
106.     LOOP UNTIL Finished = 0
107. END SUB
108.  
109. SUB Focus (Index AS INTEGER)
110.     SHARED Windows() AS wChild
111.     DIM b AS INTEGER
112.     FOR b = 1 TO wMax
113.         IF Windows(b).Zorder = 1 THEN EXIT FOR
114.     NEXT b
115.     SWAP Windows(Index).Zorder, Windows(b).Zorder
116.     DrawAllWin
117. END SUB
118.  
119. SUB DoAction (Act AS INTEGER)
120.     SHARED Windows() AS wChild
121.     DIM a AS INTEGER
122.  
123.     SELECT CASE Act
124.         CASE aQuit
125.             END
126.  
127.         CASE Maxim
128.             _FULLSCREEN
129.  
130.         CASE Minim
131.             _FULLSCREEN _OFF
132.  
133.         CASE mLeft
134.             DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER, Actio AS INTEGER
135.             mX = _MOUSEX
136.             mY = _MOUSEY
137.             ' search where and what mouse has touched by leftclick
138.             FOR a = 1 TO wMax ' windows(0) is out of action
139.                 Actio = IsInWindow(mX, mY, Windows(a))
140.                 IF Actio THEN EXIT FOR ' if windows(a) is on the stack it gets the click of mouse
141.             NEXT a
142.  
143.             SELECT CASE Actio
144.                 CASE Dragging
145.                     Focus a
146.                     Windows(0).X = Windows(a).X
147.                     Windows(0).Y = Windows(a).Y
148.                     Windows(0).Width = Windows(a).Width
149.                     Windows(0).Height = Windows(a).Height
150.                     Windows(0).Status = Windows(a).Status
151.                     Windows(0).Color = Windows(a).Color
152.                     OmX = _MOUSEX - Windows(0).X
153.                     OmY = _MOUSEY - Windows(0).Y
154.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
155.                     DO WHILE _MOUSEBUTTON(1)
156.                         IF _MOUSEINPUT THEN
157.                             CLS , Orange
158.                             DrawAllWin
159.                             Windows(0).X = (_MOUSEX - OmX)
160.                             Windows(0).Y = (_MOUSEY - OmY)
161.                             dragWindow Windows(0)
162.                         END IF
163.                     LOOP
164.                     ' new position of window
165.                     Windows(a).X = Windows(0).X
166.                     Windows(a).Y = Windows(0).Y
167.                     Windows(a).Width = Windows(0).Width
168.                     Windows(a).Height = Windows(0).Height
169.                     Windows(a).Status = Windows(0).Status
170.                     Windows(a).Color = Windows(0).Color
171.                     Windows(a).Zorder = 1
172.  
173.                 CASE Focusing
174.                     Focus a
175.             END SELECT
176.         CASE ELSE
177.     END SELECT
178. END SUB
179.  
180. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
181.     IsInWindow = mFalse
182.     IF IsInTheRange%(X, Win.X, Win.X + Win.Width) THEN
183.         IF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
184.             IsInWindow = Dragging
185.         ELSEIF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
186.             IsInWindow = Focusing
187.         END IF
188.     END IF
189. END FUNCTION
190.  
191. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
192.     IF Min > Max THEN SWAP Min, Max
193.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
194. END FUNCTION
195.  
196. SUB dragWindow (Win AS wChild)
197.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), White, B
198.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), White, BF 'title bar for dragging window
199. END SUB
200.  
201.  
202. SUB DrawWindow (Win AS wChild)
203.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Win.Color, BF
204.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Red, BF 'title bar for dragging window
205. END SUB
206.  
207. SUB GetInput (Act AS INTEGER)
208.     DIM mInput AS INTEGER
209.  
210.  
211.     ' keyboard input
212.     a$ = INKEY$
213.     IF a$ = CHR$(27) THEN Act = aQuit
214.  
215.     'mouse input
216.     mInput = mFalse
217.     IF _MOUSEINPUT THEN mInput = mTrue
218.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
219.     LOOP
220.     IF mInput THEN
221.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
222.             mInput = mLR
223.         ELSEIF _MOUSEBUTTON(1) THEN
224.             mInput = mLeft
225.         ELSEIF _MOUSEBUTTON(2) THEN
226.             mInput = mRight
227.         ELSEIF _MOUSEBUTTON(3) THEN
228.             mInput = mMiddle
229.         END IF
230.     END IF
231.  
232.     IF mInput = mLR THEN
233.         Act = aQuit
234.     ELSEIF mInput = mMiddle THEN
235.         Act = Minim
236.     ELSEIF mInput = mRight THEN
237.         Act = Maxim
238.     ELSEIF mInput = mLeft THEN
239.         Act = mInput
240.     END IF
241. END SUB

Instruction:
Click by right mouse button to _Fullscreen
Click by Middle mouse button to _Minimize to normal window
Click by left mouse button into a child window  to choose a child window (there are 3 windows Blu, Green and Yellow)
click by left mouse button on Red top bar of a child window to move it by dragging in the main window of the program

Thanks to take a look!

Title: Re: child windows into window of the program: a demonstration
Post by: bplus on January 26, 2020, 11:18:57 am

Looks like a start, you know that _DISPLAY will stop the annoying blinking.

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on January 26, 2020, 11:23:35 am

Yes but I must remember it! :-)

Title: Re: child windows into window of the program: a demonstration
Post by: bplus on January 26, 2020, 11:42:40 am

Quote from: TempodiBasic on January 26, 2020, 11:23:35 am

Yes but I must remember it! :-)

Then remember also, once you start using it, you have to use it ever where OR switch it OFF with _AUTODISPLAY, otherwise you will wonder why nothing seems to be working. ;-)) (like when you want to drag the window)

I say this not to you particularly TempodiBasic but to all the poor souls who could get fouled up and lost by this one little problem. Oh the frustration... ;-(

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on January 27, 2020, 10:22:49 am

Yes  one of the black beasts is _DISPLAY  vs  _AUTODISPLAY,  followed by  settings of color when you pass from a program written for ASCII screen or Qb45's legacy SCREEN to _NEWIMAGE (Width,Height,32)... remembering the exact sinthax and extension of each color command _RGB _RGBA  _RGB32 _RGBA32  for this case is a good advance the $COLOR of version 1.4 to use HTML code scheme.

Title: Re: child windows into window of the program: a demonstration
Post by: SMcNeill on January 27, 2020, 10:54:53 am

Here's a quick and simple demo of how I'd do multiple windows like this:

Code: QB64: [Select]

1. $COLOR:32
2. SCREEN _NEWIMAGE(800, 600, 32) 'the main screen
3. DIM Windows(3) AS _UNSIGNED LONG 'handles to hold extra windows
4. FOR i = 0 TO 3: Windows(i) = _NEWIMAGE(640, 480, 32): NEXT 'make some extra windows
5.  
6. _DEST Windows(0) 'window 0
7. CLS , Blue
8. COLOR Red, 0
9. PRINT
10. PRINT "This is just some text on the first window, which I'm writing as an illustration.  It doesn't really mean anything, and doesn't do anything, except show that this is an independent screen, unaffected by any others."
11.  
12. _DEST Windows(1) 'window 1
13. CLS , Silver
14. LINE (100, 100)-(540, 380), Purple, BF
15. CIRCLE (300, 300), 100, Green
16. PAINT (300, 300), Green
17.  
18. _DEST Windows(2) 'window 2
19. CLS , Yellow
20. COLOR Red
21. PRINT "Once upon a time, long ago and far away, Steve wrote a program in QB64!"
22.  
23. _DEST 0
24. COLOR Black, 0
25. DO
26.     _DEST 0
27.     CLS , 0
28.     FOR i = 0 TO 3
29.         LINE (100 + 163 * i, 70)-STEP(150, 20), Silver, BF
30.         _PRINTSTRING (100 + 163 * i, 72), "      Window" + STR$(i)
31.     NEXT
32.     LINE (100, 100)-(740, 580), Silver, B
33.  
34.     _DEST Windows(3)
35.     CLS , 0
36.     LINE (x, 150)-STEP(100, 100), _RGB32(RND * 256, RND * 256, RND * 256), BF
37.     x = (x + 5) MOD 640
38.  
39.     k = _KEYHIT
40.     SELECT CASE k
41.         CASE 48, 49, 50, 51: W = k - 48
42.         CASE 27: SYSTEM
43.     END SELECT
44.     _PUTIMAGE (100, 100), Windows(W), 0
45.     _LIMIT 30
46.     _DISPLAY
47. LOOP
48. SYSTEM

I didn't bother to code in any mouse handling routine, though they'd be simple enough to add if someone wants them.  For this, just use the number keys for 0, 1, 2, 3 to swap between the 4 different window displays.

Window 0 is just a simple text window which I typed some junk on.
Window 1 is a graphical image, which could represent whatever my program needs.
Window 2 is another independent text window. 
Window 3 is an animated window where there's a simple box which scrolls from one side of the screen to the other.

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on January 27, 2020, 04:10:08 pm

Hi Steve

Your alternative way to build child windows as panel/Layer on which build output and to show on the main window is very cool. So I have decided to give another perspective to your idea, instead to use alternatively panels here the panels have different size among them and are on stack and user pressing 0123 can choose how the stack is build up. The program shows all the active panels together following the order of stack.

Code: QB64: [Select]

1. $COLOR:32
2. SCREEN _NEWIMAGE(800, 600, 32) 'the main screen
3. DIM Windows(3) AS _UNSIGNED LONG 'handles to hold extra windows
4. FOR i = 0 TO 3: Windows(i) = _NEWIMAGE(200 + (i * 100), 400, 32): NEXT 'make some extra windows
5.  
6. _DEST Windows(0) 'window 0
7. CLS , Blue
8. COLOR Red, 0
9. PRINT
10. PRINT "This is just some text on the first window, which I'm writing as an illustration.  It doesn't really mean anything, and doesn't do anything, except show that this is an independent screen, unaffected by any others."
11.  
12. _DEST Windows(1) 'window 1
13. CLS , Silver
14. LINE (100, 100)-(540, 380), Purple, BF
15. CIRCLE (300, 300), 100, Green
16. PAINT (300, 300), Green
17.  
18. _DEST Windows(2) 'window 2
19. CLS , Yellow
20. COLOR Red
21. PRINT "Once upon a time, long ago and far away, Steve wrote a program in QB64!"
22.  
23. _DEST 0
24. COLOR Black, 0
25.  
26. DIM Zorder AS STRING
27. Zorder = "0123"
28.  
29. DO
30.     _DEST 0
31.     CLS , Pink
32.     LOCATE 10, 2: PRINT Zorder
33.     FOR i = 0 TO 3
34.         LINE (100 + 163 * i, 70)-STEP(150, 20), Silver, BF
35.         _PRINTSTRING (100 + 163 * i, 72), "      Window" + STR$(i)
36.     NEXT
37.     LINE (100, 100)-(740, 580), Silver, B
38.  
39.     _DEST Windows(3)
40.     CLS , 0
41.     LINE (x, 150)-STEP(100, 100), _RGB32(RND * 256, RND * 256, RND * 256), BF
42.     x = (x + 5) MOD 640
43.  
44.     k = _KEYHIT
45.     SELECT CASE k
46.         CASE 48, 49, 50, 51: W = k - 48
47.  
48.             z = INSTR(Zorder, LTRIM$(STR$(W)))
49.             Zorder = LTRIM$(STR$(W)) + LEFT$(Zorder, z - 1) + RIGHT$(Zorder, 4 - z)
50.  
51.         CASE 27: SYSTEM
52.     END SELECT
53.     FOR z = 0 TO 3
54.         W = VAL(MID$(Zorder, z, 1))
55.         _PUTIMAGE (100, 100), Windows(W), 0
56.     NEXT z
57.     _LIMIT 30
58.     _DISPLAY
59. LOOP
60. SYSTEM
61.  
62.  

 

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on January 28, 2020, 07:27:26 pm

@Bplus
Here a no flickering version...
only for your eyes ... also a more smooth aspect of child windows

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8.  
9. ' 2020 01 25  A program with child windows into it
10. ' we need a system to manage multiple windows
11. ' and a system to manage input/output
12. ' and a system to make graphic report
13.  
14. ' settings-------------------------------------------------------
15. SCREEN _NEWIMAGE(800, 600, 32)
16. _TITLE "Child windows"
17. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
18. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
19. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
20. CONST Minim = 20, Maxim = 10, Closed = 100, wMin = 3, aNull = 0, aQuit = 9999
21. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
22. CONST Dragging = 300, Focusing = 200
23.  
24. _FULLSCREEN
25.  
26.  
27. 'dataset  -----------------------------------------------
28. TYPE person
29.     name AS STRING * 10
30.     age AS INTEGER
31.     weight AS INTEGER
32.     height AS INTEGER
33.     BMI AS INTEGER
34. END TYPE
35.  
36. TYPE wChild
37.     X AS INTEGER
38.     Y AS INTEGER
39.     Width AS INTEGER
40.     Height AS INTEGER
41.     Zorder AS INTEGER
42.     Status AS INTEGER
43.     Color AS _UNSIGNED LONG
44. END TYPE
45.  
46. REDIM Windows(0 TO wMin) AS wChild
47. DIM SHARED wMax AS INTEGER
48. wMax = UBOUND(windows)
49.  
50.  
51. ' windows(0) is for Dragging
52.  
53. Windows(1).X = 1
54. Windows(1).Y = 1
55. Windows(1).Width = 300
56. Windows(1).Height = 400
57. Windows(1).Zorder = 1
58. Windows(1).Status = Minim
59. Windows(1).Color = Blu
60.  
61. Windows(2).X = 100
62. Windows(2).Y = 1
63. Windows(2).Width = 300
64. Windows(2).Height = 400
65. Windows(2).Zorder = 2
66. Windows(2).Status = Minim
67. Windows(2).Color = Yellow
68.  
69. Windows(3).X = 200
70. Windows(3).Y = 1
71. Windows(3).Width = 300
72. Windows(3).Height = 400
73. Windows(3).Zorder = 3
74. Windows(3).Status = Minim
75. Windows(3).Color = Green
76.  
77. DIM Action AS INTEGER
78.  
79.  
80. ' main loop -----------------------------------------------
81.  
82. DO
83.     ' set the main window
84.     Action = aNull
85.     CLS , Orange
86.     DrawAllWin
87.     GetInput Action
88.     DoAction Action
89.     _LIMIT 30
90. LOOP
91. END
92.  
93. ' SUBs and FUNCTIONs --------------------------------------
94. SUB DrawAllWin
95.     SHARED Windows() AS wChild
96.     DIM Finished AS INTEGER
97.     Finished = wMax
98.     DO
99.         FOR a = 1 TO wMax
100.             IF Windows(a).Zorder = Finished THEN
101.                 DrawWindow Windows(a)
102.                 Finished = Finished - 1
103.                 EXIT FOR
104.             END IF
105.         NEXT a
106.     LOOP UNTIL Finished = 0
107.     _DISPLAY
108. END SUB
109.  
110. SUB Focus (Index AS INTEGER)
111.     SHARED Windows() AS wChild
112.     DIM b AS INTEGER
113.     FOR b = 1 TO wMax
114.         IF Windows(b).Zorder = 1 THEN EXIT FOR
115.     NEXT b
116.     SWAP Windows(Index).Zorder, Windows(b).Zorder
117.     DrawAllWin
118. END SUB
119.  
120. SUB DoAction (Act AS INTEGER)
121.     SHARED Windows() AS wChild
122.     DIM a AS INTEGER
123.  
124.     SELECT CASE Act
125.         CASE aQuit
126.             END
127.  
128.         CASE Maxim
129.             _FULLSCREEN
130.  
131.         CASE Minim
132.             _FULLSCREEN _OFF
133.  
134.         CASE mLeft
135.             DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER, Actio AS INTEGER
136.             mX = _MOUSEX
137.             mY = _MOUSEY
138.             ' search where and what mouse has touched by leftclick
139.             FOR a = 1 TO wMax ' windows(0) is out of action
140.                 Actio = IsInWindow(mX, mY, Windows(a))
141.                 IF Actio THEN EXIT FOR ' if windows(a) is on the stack it gets the click of mouse
142.             NEXT a
143.             SELECT CASE Actio
144.                 CASE Dragging
145.                     Focus a
146.                     Windows(0).X = Windows(a).X
147.                     Windows(0).Y = Windows(a).Y
148.                     Windows(0).Width = Windows(a).Width
149.                     Windows(0).Height = Windows(a).Height
150.                     Windows(0).Status = Windows(a).Status
151.                     Windows(0).Color = Windows(a).Color
152.                     OmX = _MOUSEX - Windows(0).X
153.                     OmY = _MOUSEY - Windows(0).Y
154.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
155.                     DO WHILE _MOUSEBUTTON(1)
156.                         IF _MOUSEINPUT THEN
157.                             CLS , Orange
158.                             DrawAllWin
159.                             Windows(0).X = (_MOUSEX - OmX)
160.                             Windows(0).Y = (_MOUSEY - OmY)
161.                             dragWindow Windows(0)
162.                         END IF
163.                     LOOP
164.                     ' new position of window
165.                     Windows(a).X = Windows(0).X
166.                     Windows(a).Y = Windows(0).Y
167.                     Windows(a).Width = Windows(0).Width
168.                     Windows(a).Height = Windows(0).Height
169.                     Windows(a).Status = Windows(0).Status
170.                     Windows(a).Color = Windows(0).Color
171.                     Windows(a).Zorder = 1
172.                 CASE Focusing
173.                     Focus a
174.             END SELECT
175.  
176.         CASE ELSE
177.     END SELECT
178. END SUB
179.  
180. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
181.     IsInWindow = mFalse
182.     IF IsInTheRange%(X, Win.X, Win.X + Win.Width) THEN
183.         IF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
184.             IsInWindow = Dragging
185.         ELSEIF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
186.             IsInWindow = Focusing
187.         END IF
188.     END IF
189. END FUNCTION
190.  
191. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
192.     IF Min > Max THEN SWAP Min, Max
193.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
194. END FUNCTION
195.  
196. SUB dragWindow (Win AS wChild)
197.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), White, B
198.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), White, BF 'title bar for dragging window
199.     _DISPLAY
200. END SUB
201.  
202.  
203. SUB DrawWindow (Win AS wChild)
204.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Win.Color, BF
205.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for dragging window
206.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.Width, Win.Y + 10), Black
207.     LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.Width, Win.Y + Win.Height), Black
208.     LINE (Win.X + Win.Width, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Black
209. END SUB
210.  
211. SUB GetInput (Act AS INTEGER)
212.     DIM mInput AS INTEGER
213.  
214.  
215.     ' keyboard input
216.     a$ = INKEY$
217.     IF a$ = CHR$(27) THEN Act = aQuit
218.  
219.     'mouse input
220.     mInput = mFalse
221.     IF _MOUSEINPUT THEN mInput = mTrue
222.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
223.     LOOP
224.     IF mInput THEN
225.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
226.             mInput = mLR
227.         ELSEIF _MOUSEBUTTON(1) THEN
228.             mInput = mLeft
229.         ELSEIF _MOUSEBUTTON(2) THEN
230.             mInput = mRight
231.         ELSEIF _MOUSEBUTTON(3) THEN
232.             mInput = mMiddle
233.         END IF
234.     END IF
235.  
236.     IF mInput = mLR THEN
237.         Act = aQuit
238.     ELSEIF mInput = mMiddle THEN
239.         Act = Minim
240.     ELSEIF mInput = mRight THEN
241.         Act = Maxim
242.     ELSEIF mInput = mLeft THEN
243.         Act = mInput
244.     END IF
245. END SUB

  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: child windows into window of the program: a demonstration
Post by: bplus on January 28, 2020, 10:28:58 pm

Very nice start TempodiBasic they drag nicely alright and fetching colors too :)

Title: Re: child windows into window of the program: a demonstration
Post by: keybone on January 28, 2020, 10:40:45 pm

looks like something I've been trying to accomplish for a long time.

Well, here's my attempt:
http://keybone.epizy.com/files/234178487/winsys.bas

The windows can be moved, resized, maximized, and restored from maximized (if the functionality is enabled on a per-window basis).
Minimize/iconify functionality is not implemented yet.

And I havent figured out how im going to have events handled within the windows yet.
Still a work in progress...

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on January 29, 2020, 09:22:53 am

Fine Keybone!

... I have seen that also rightclick menu is work in progress. Good one!


about

Quote

And I havent figured out how im going to have events handled within the windows yet.
Still a work in progress...

I think that there are so many ways to do this....

for interaction among objects of the same window or objects of different windows  I can imagine a timer control that activates a short loop or a message system like windows OS...
for events triggered by I/O of user  I imagine a defauld univocal keypress (keyboard or joystick) or area of screen sensible to mouse events or /and a focus system to address and to react in the right manner to the Input (you get the input and pass it to the focused object)
... well , after lunch these are the results of my imagination...
Good work and Good Imagination!

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 05, 2020, 07:39:57 pm

Hi
I go on with child windows...
now there are 3 button on the bar of the window to Maximize to the application window or to Restore default dimension or to reduce to the bar of the child window.
Here the code.

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8. ' 2020 02 05 fixed a minor bug on mouse click events
9. '            activated events Maxim Minim and Closed
10.  
11.  
12. ' 2020 02 03 increasing the windows managed and close initialization to SUB
13. '            removed vMax SHARED variable
14. '            added 3 buttons on the rightest site of the bar of the child window
15. '            SUB wClosed, wMaxim, wMinim
16. '            In this version the user can maximize one child window to the application window
17. '            In the status of Maxim the child window has the focus and can be only
18. '            reduced to status Minim, it cannot be dragging or Closed to bar of window
19.  
20.  
21. ' 2020 01 30 fixed bug on focusing a child window
22. '
23.  
24. ' 2020 01 25  A program with child windows into it
25. ' we need a system to manage multiple windows
26. ' and a system to manage input/output
27. ' and a system to make graphic report
28.  
29. ' settings-------------------------------------------------------
30. SCREEN _NEWIMAGE(800, 600, 32)
31. _TITLE "Child windows"
32. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
33. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
34. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
35. CONST Minim = 20, Maxim = 10, Closed = 100, wMin = 5, aNull = 0, aQuit = 9999
36. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
37. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
38.  
39. _FULLSCREEN
40.  
41.  
42. 'dataset  -----------------------------------------------
43. TYPE person
44.     name AS STRING * 10
45.     age AS INTEGER
46.     weight AS INTEGER
47.     height AS INTEGER
48.     BMI AS INTEGER
49. END TYPE
50.  
51. TYPE wChild
52.     X AS INTEGER
53.     Y AS INTEGER
54.     Width AS INTEGER
55.     Height AS INTEGER
56.     Zorder AS INTEGER
57.     Status AS INTEGER
58.     Color AS _UNSIGNED LONG
59. END TYPE
60.  
61. REDIM Windows(0 TO wMin) AS wChild
62.  
63. InitWin
64.  
65. DIM Action AS INTEGER
66.  
67.  
68. ' main loop -----------------------------------------------
69.  
70. DO
71.     ' set the main window
72.     Action = aNull
73.     CLS , Orange
74.     DrawAllWin
75.     GetInput Action
76.     DoAction Action
77.     _LIMIT 30
78. LOOP
79. END
80.  
81. ' SUBs and FUNCTIONs --------------------------------------
82. SUB InitWin
83.     SHARED Windows() AS wChild
84.     ' windows(0) is for Dragging or Maximize
85.     Windows(0).X = 0
86.     Windows(0).Y = 0
87.     Windows(0).Width = 0
88.     Windows(0).Height = 0
89.     Windows(0).Zorder = 0
90.     Windows(0).Status = 0
91.     Windows(0).Color = 0
92.  
93.     Windows(1).X = 1
94.     Windows(1).Y = 1
95.     Windows(1).Width = 300
96.     Windows(1).Height = 400
97.     Windows(1).Zorder = 1
98.     Windows(1).Status = Minim
99.     Windows(1).Color = Blu
100.  
101.     Windows(2).X = 100
102.     Windows(2).Y = 1
103.     Windows(2).Width = 300
104.     Windows(2).Height = 400
105.     Windows(2).Zorder = 2
106.     Windows(2).Status = Minim
107.     Windows(2).Color = Yellow
108.  
109.     Windows(3).X = 200
110.     Windows(3).Y = 1
111.     Windows(3).Width = 300
112.     Windows(3).Height = 400
113.     Windows(3).Zorder = 3
114.     Windows(3).Status = Minim
115.     Windows(3).Color = Green
116.  
117.     Windows(4).X = 300
118.     Windows(4).Y = 1
119.     Windows(4).Width = 300
120.     Windows(4).Height = 400
121.     Windows(4).Zorder = 4
122.     Windows(4).Status = Minim
123.     Windows(4).Color = Red
124.  
125.     Windows(5).X = 400
126.     Windows(5).Y = 1
127.     Windows(5).Width = 300
128.     Windows(5).Height = 400
129.     Windows(5).Zorder = 5
130.     Windows(5).Status = Minim
131.     Windows(5).Color = Cyan
132. END SUB
133.  
134. SUB DrawAllWin
135.     SHARED Windows() AS wChild
136.     DIM Finished AS INTEGER
137.     Finished = wMin
138.     DO
139.         FOR a = 1 TO wMin
140.             IF Windows(a).Zorder = Finished THEN
141.                 DrawWindow Windows(a)
142.                 Finished = Finished - 1
143.                 EXIT FOR
144.             END IF
145.         NEXT a
146.     LOOP UNTIL Finished = 0
147.     _DISPLAY
148. END SUB
149.  
150. SUB Focus (Index AS INTEGER)
151.     SHARED Windows() AS wChild
152.     DIM b AS INTEGER
153.     FOR b = 1 TO wMin
154.         IF Windows(b).Zorder = 1 THEN EXIT FOR
155.     NEXT b
156.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
157.     DrawAllWin
158. END SUB
159.  
160.  
161. SUB DoAction (Act AS INTEGER)
162.     SHARED Windows() AS wChild
163.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
164.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
165.  
166.     SELECT CASE Act
167.         CASE aQuit
168.             END
169.  
170.         CASE Maxim
171.             _FULLSCREEN
172.  
173.         CASE Minim
174.             _FULLSCREEN _OFF
175.  
176.         CASE mLeft
177.             mX = _MOUSEX
178.             mY = _MOUSEY
179.  
180.             ' search where and what mouse has touched by leftclick
181.             OldA = 0
182.             OldActio = 0
183.             FOR a = 1 TO wMin ' windows(0) is out of action
184.                 Actio = IsInWindow(mX, mY, Windows(a))
185.                 IF Actio THEN
186.                     IF OldA <= 0 THEN
187.                         OldA = a
188.                         OldActio = Actio
189.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN
190.                         OldA = a
191.                         OldActio = Actio
192.                     END IF
193.                 END IF
194.             NEXT a
195.             IF a > OldA THEN
196.                 a = OldA ' restore the last windows interacting
197.                 Actio = OldActio
198.             END IF
199.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB
200.  
201.  
202.             Focus a 'set zorder on the (a) window that gets the input
203.  
204.  
205.             SELECT CASE Actio
206.                 CASE cMinim
207.                     ' here restore to  standard status of child window
208.                     IF NOT Windows(a).Status = Minim THEN
209.                         Windows(a).X = Windows(0).X
210.                         Windows(a).Y = Windows(0).Y
211.                         Windows(a).Width = Windows(0).Width
212.                         Windows(a).Height = Windows(0).Height
213.                         Windows(a).Status = Minim
214.                         Windows(a).Zorder = 1
215.                     END IF
216.  
217.                 CASE cMaxim
218.                     ' here convert the window to full size of main window of the program
219.                     IF NOT Windows(a).Status = Maxim THEN
220.                         ' memorize window's data
221.                         Windows(0).X = Windows(a).X
222.                         Windows(0).Y = Windows(a).Y
223.                         Windows(0).Width = Windows(a).Width
224.                         Windows(0).Height = Windows(a).Height
225.                         ' change status
226.                         Windows(a).Status = Maxim
227.                         Windows(a).Width = _WIDTH
228.                         Windows(a).Height = _HEIGHT
229.                         Windows(a).X = 1
230.                         Windows(a).Y = 1
231.                     END IF
232.                 CASE cClosed
233.                     ' here minimize the child window to its window bar
234.                     IF Windows(a).Status = Minim THEN
235.                         ' memorize window's data
236.                         Windows(0).X = Windows(a).X
237.                         Windows(0).Y = Windows(a).Y
238.                         Windows(0).Width = Windows(a).Width
239.                         Windows(0).Height = Windows(a).Height
240.                         ' change status
241.                         Windows(a).Status = Closed
242.                     END IF
243.                 CASE Dragging
244.                     ' dragging is not possible for maximized window
245.                     ' but it is possible for status Minim child window and
246.                     ' for status Closed that shows only Bar window
247.                     IF NOT Windows(a).Status = Maxim THEN
248.                         Windows(0).X = Windows(a).X
249.                         Windows(0).Y = Windows(a).Y
250.                         Windows(0).Width = Windows(a).Width
251.                         Windows(0).Height = Windows(a).Height
252.                         Windows(0).Status = Windows(a).Status
253.                         Windows(0).Color = Windows(a).Color
254.                         OmX = _MOUSEX - Windows(0).X
255.                         OmY = _MOUSEY - Windows(0).Y
256.                         DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
257.                         DO WHILE _MOUSEBUTTON(1)
258.                             IF _MOUSEINPUT THEN
259.                                 CLS , Orange
260.                                 DrawAllWin
261.                                 Windows(0).X = (_MOUSEX - OmX)
262.                                 Windows(0).Y = (_MOUSEY - OmY)
263.                                 dragWindow Windows(0)
264.                             END IF
265.                         LOOP
266.                         ' new position of window
267.                         Windows(a).X = Windows(0).X
268.                         Windows(a).Y = Windows(0).Y
269.                         Windows(a).Width = Windows(0).Width
270.                         Windows(a).Height = Windows(0).Height
271.                         Windows(a).Status = Windows(0).Status
272.                         Windows(a).Color = Windows(0).Color
273.                         Windows(a).Zorder = 1
274.                     END IF
275.                 CASE Focusing
276.                     Focus a
277.             END SELECT
278.  
279.         CASE ELSE
280.     END SELECT
281. END SUB
282.  
283. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
284.     IsInWindow = mFalse
285.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
286.         ' if window is closed to its bar it cannot get focus on the window area
287.         IF IsInTheRange%(X, Win.X, Win.X + Win.Width) AND (Win.Status <> Closed) THEN IsInWindow = Focusing
288.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
289.         ' if is the window bar area
290.         IF IsInTheRange%(X, Win.X, Win.X + Win.Width - 31) THEN
291.             ' if it is to the left of buttons on the bar
292.             ' maximized window cannot be dragged
293.             IF NOT (Win.Status AND Maxim) THEN IsInWindow = Dragging
294.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 30, Win.X + Win.Width - 21) THEN
295.             ' if it is on the leftest button on the bar
296.             IsInWindow = cMinim ' icon minimize--> restore to child default
297.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 20, Win.X + Win.Width - 11) THEN
298.             ' if it is on the middle button on the bar
299.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
300.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 10, Win.X + Win.Width) THEN
301.             ' if is on the rightest button on the bar
302.             ' maximized child window cannot become minimized to bar of child window
303.             IF NOT (Win.Status AND Maxim) THEN IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
304.         END IF
305.     END IF
306. END FUNCTION
307.  
308. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
309.     IF Min > Max THEN SWAP Min, Max
310.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
311. END FUNCTION
312.  
313. SUB dragWindow (Win AS wChild)
314.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), White, B
315.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), White, BF 'title bar for dragging window
316.     _DISPLAY
317. END SUB
318.  
319. SUB wClosed (Win AS wChild)
320.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
321.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Black, B
322.     LINE (Win.X + Win.Width - 7, Win.Y + 3)-(Win.X + Win.Width - 3, Win.Y + 7), Black
323.     LINE (Win.X + Win.Width - 7, Win.Y + 7)-(Win.X + Win.Width - 3, Win.Y + 3), Black
324. END SUB
325.  
326. SUB wMaxim (win AS wChild)
327.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Pink, BF 'title bar for restore to original dimensions
328.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Black, B
329.     LINE (win.X + win.Width - 17, win.Y + 3)-(win.X + win.Width - 13, win.Y + 7), Black, B
330. END SUB
331.  
332. SUB wMinim (Win AS wChild)
333.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
334.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Black, B
335.     LINE (Win.X + Win.Width - 27, Win.Y + 7)-(Win.X + Win.Width - 23, Win.Y + 7), Black
336. END SUB
337.  
338.  
339. SUB DrawWindow (Win AS wChild)
340.     ' the window
341.     IF Win.Status = Minim OR Win.Status = Maxim THEN
342.         LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Win.Color, BF
343.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.Width, Win.Y + Win.Height), Black
344.         LINE (Win.X + Win.Width, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Black
345.     END IF
346.     ' the status bar
347.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for dragging window
348.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.Width, Win.Y + 10), Black
349.     wMinim Win
350.     wMaxim Win
351.     wClosed Win
352. END SUB
353.  
354. SUB GetInput (Act AS INTEGER)
355.     DIM mInput AS INTEGER
356.  
357.  
358.     ' keyboard input
359.     a$ = INKEY$
360.     IF a$ = CHR$(27) THEN Act = aQuit
361.  
362.     'mouse input
363.     mInput = mFalse
364.     IF _MOUSEINPUT THEN mInput = mTrue
365.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
366.     LOOP
367.     IF mInput THEN
368.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
369.             mInput = mLR
370.         ELSEIF _MOUSEBUTTON(1) THEN
371.             mInput = mLeft
372.         ELSEIF _MOUSEBUTTON(2) THEN
373.             mInput = mRight
374.         ELSEIF _MOUSEBUTTON(3) THEN
375.             mInput = mMiddle
376.         END IF
377.     END IF
378.  
379.     IF mInput = mLR THEN
380.         Act = aQuit
381.     ELSEIF mInput = mMiddle THEN
382.         Act = Minim
383.     ELSEIF mInput = mRight THEN
384.         Act = Maxim
385.     ELSEIF mInput = mLeft THEN
386.         Act = mInput
387.     END IF
388. END SUB
389.  

Thanks to try

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 09, 2020, 04:44:17 am

another step forward, for each window a shadow of info
it fixs a bug of the previous version that stack the chil windows on the same position if you close more windows at different positions and then you click on restore/minimize button (the first from the left) on the windows bar.

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8.  
9. ' 2020 02 08  using a second array we store windows information indipendently so
10. '             now each window can be modified and restored
11.  
12.  
13. ' 2020 02 06  after dragging or maximize a window, restoring it we gives
14. '             to it the last value used in windows(0) so the info of the last
15. '             window that is dragged or maximize when we use Minimize button on
16. '             another child window
17. '             the fix can be got using a shadow array that stores windows informations
18. '             or windows(0) as the child window that takes the information of the
19. '             child window that must be acted (Minimize, Maximize and Closed)
20. '             and we use it as template to make graphic output
21.  
22. ' 2020 02 05 fixed a minor bug on mouse click events
23. '            activated events Maxim Minim and Closed
24.  
25.  
26. ' 2020 02 03 increasing the windows managed and close initialization to SUB
27. '            removed vMax SHARED variable
28. '            added 3 buttons on the rightest site of the bar of the child window
29. '            SUB wClosed, wMaxim, wMinim
30. '            In this version the user can maximize one child window to the application window
31. '            In the status of Maxim the child window has the focus and can be only
32. '            reduced to status Minim, it cannot be dragging or Closed to bar of window
33.  
34.  
35. ' 2020 01 30 fixed bug on focusing a child window
36. '
37.  
38. ' 2020 01 25  A program with child windows into it
39. ' we need a system to manage multiple windows
40. ' and a system to manage input/output
41. ' and a system to make graphic report
42.  
43. ' settings-------------------------------------------------------
44. SCREEN _NEWIMAGE(800, 600, 32)
45. _TITLE "Child windows"
46. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
47. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
48. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
49. CONST Minim = 20, Maxim = 10, Closed = 100, wMin = 5, aNull = 0, aQuit = 9999
50. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
51. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
52.  
53. _FULLSCREEN
54.  
55.  
56. 'dataset  -----------------------------------------------
57. TYPE person
58.     name AS STRING * 10
59.     age AS INTEGER
60.     weight AS INTEGER
61.     height AS INTEGER
62.     BMI AS INTEGER
63. END TYPE
64.  
65. TYPE wChild
66.     X AS INTEGER
67.     Y AS INTEGER
68.     Width AS INTEGER
69.     Height AS INTEGER
70.     Zorder AS INTEGER
71.     Status AS INTEGER
72.     Color AS _UNSIGNED LONG
73. END TYPE
74.  
75. REDIM Windows(1 TO wMin) AS wChild, OldW(1 TO wMin) AS wChild
76.  
77. InitWin
78.  
79. DIM Action AS INTEGER
80.  
81.  
82. ' main loop -----------------------------------------------
83.  
84. DO
85.     ' set the main window
86.     Action = aNull
87.     CLS , Orange
88.     DrawAllWin
89.     GetInput Action
90.     DoAction Action
91.     _DISPLAY
92.     _LIMIT 30
93. LOOP
94. END
95.  
96. ' SUBs and FUNCTIONs --------------------------------------
97. SUB InitWin
98.     SHARED Windows() AS wChild, OldW() AS wChild
99.     DIM a AS INTEGER
100.  
101.     Windows(1).X = 1
102.     Windows(1).Y = 1
103.     Windows(1).Width = 300
104.     Windows(1).Height = 400
105.     Windows(1).Zorder = 1
106.     Windows(1).Status = Minim
107.     Windows(1).Color = Blu
108.  
109.     Windows(2).X = 100
110.     Windows(2).Y = 1
111.     Windows(2).Width = 300
112.     Windows(2).Height = 400
113.     Windows(2).Zorder = 2
114.     Windows(2).Status = Minim
115.     Windows(2).Color = Yellow
116.  
117.     Windows(3).X = 200
118.     Windows(3).Y = 1
119.     Windows(3).Width = 300
120.     Windows(3).Height = 400
121.     Windows(3).Zorder = 3
122.     Windows(3).Status = Minim
123.     Windows(3).Color = Green
124.  
125.     Windows(4).X = 300
126.     Windows(4).Y = 1
127.     Windows(4).Width = 300
128.     Windows(4).Height = 400
129.     Windows(4).Zorder = 4
130.     Windows(4).Status = Minim
131.     Windows(4).Color = Red
132.  
133.     Windows(5).X = 400
134.     Windows(5).Y = 1
135.     Windows(5).Width = 300
136.     Windows(5).Height = 400
137.     Windows(5).Zorder = 5
138.     Windows(5).Status = Minim
139.     Windows(5).Color = Cyan
140.  
141.     FOR a = 1 TO wMin STEP 1
142.         AdjournWin a
143.     NEXT a
144. END SUB
145.  
146. SUB RestoreWin (a AS INTEGER)
147.     SHARED Windows() AS wChild, OldW() AS wChild
148.  
149.     Windows(a).X = OldW(a).X
150.     Windows(a).Y = OldW(a).Y
151.     Windows(a).Width = OldW(a).Width
152.     Windows(a).Height = OldW(a).Height
153.     Windows(a).Zorder = OldW(a).Zorder
154.     Windows(a).Color = OldW(a).Color
155. END SUB
156.  
157. SUB AdjournWin (a AS INTEGER)
158.     SHARED Windows() AS wChild, OldW() AS wChild
159.  
160.     OldW(a).X = Windows(a).X
161.     OldW(a).Y = Windows(a).Y
162.     OldW(a).Width = Windows(a).Width
163.     OldW(a).Height = Windows(a).Height
164.     OldW(a).Zorder = Windows(a).Zorder
165.     OldW(a).Color = Windows(a).Color
166. END SUB
167.  
168. SUB DrawAllWin
169.     SHARED Windows() AS wChild
170.     DIM Finished AS INTEGER
171.     Finished = wMin
172.     DO
173.         FOR a = 1 TO wMin
174.             IF Windows(a).Zorder = Finished THEN
175.                 DrawWindow Windows(a)
176.                 Finished = Finished - 1
177.                 EXIT FOR
178.             END IF
179.         NEXT a
180.     LOOP UNTIL Finished = 0
181. END SUB
182.  
183. SUB Focus (Index AS INTEGER)
184.     SHARED Windows() AS wChild
185.     DIM b AS INTEGER
186.     FOR b = 1 TO wMin
187.         IF Windows(b).Zorder = 1 THEN EXIT FOR
188.     NEXT b
189.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
190.     DrawAllWin
191. END SUB
192.  
193.  
194. SUB DoAction (Act AS INTEGER)
195.     SHARED Windows() AS wChild, OldW() AS wChild
196.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
197.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
198.  
199.     SELECT CASE Act
200.         CASE aQuit
201.             END
202.  
203.         CASE Maxim
204.             _FULLSCREEN
205.  
206.         CASE Minim
207.             _FULLSCREEN _OFF
208.  
209.         CASE mLeft
210.             mX = _MOUSEX
211.             mY = _MOUSEY
212.  
213.             ' search where and what mouse has touched by leftclick
214.             OldA = 0
215.             OldActio = 0
216.             FOR a = 1 TO wMin ' windows(0) is out of action
217.                 Actio = IsInWindow(mX, mY, Windows(a))
218.                 IF Actio THEN
219.                     IF OldA <= 0 THEN
220.                         OldA = a
221.                         OldActio = Actio
222.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN
223.                         OldA = a
224.                         OldActio = Actio
225.                     END IF
226.                 END IF
227.             NEXT a
228.             IF a > OldA THEN
229.                 a = OldA ' restore the last windows interacting
230.                 Actio = OldActio
231.             END IF
232.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB
233.  
234.  
235.             Focus a 'set zorder on the (a) window that gets the input
236.  
237.  
238.             SELECT CASE Actio
239.                 CASE cMinim
240.                     ' here restore to  standard status of child window
241.                     IF NOT Windows(a).Status = Minim THEN
242.                         RestoreWin a
243.                         Windows(a).Status = Minim
244.                     END IF
245.  
246.                 CASE cMaxim
247.                     ' here convert the window to full size of main window of the program
248.                     IF NOT Windows(a).Status = Maxim THEN
249.                         ' memorize window's data
250.                         AdjournWin a
251.                         ' change status
252.                         Windows(a).Status = Maxim
253.                         Windows(a).Width = _WIDTH
254.                         Windows(a).Height = _HEIGHT
255.                         Windows(a).X = 1
256.                         Windows(a).Y = 1
257.                     END IF
258.                 CASE cClosed
259.                     ' here minimize the child window to its window bar
260.                     IF Windows(a).Status = Minim THEN
261.                         'save data of window
262.                         AdjournWin a
263.                         ' change status
264.                         Windows(a).Status = Closed
265.                     END IF
266.                 CASE Dragging
267.                     ' dragging is not possible for maximized window
268.                     ' but it is possible for status Minim child window and
269.                     ' for status Closed that shows only Bar window
270.                     IF NOT Windows(a).Status = Maxim THEN
271.                         AdjournWin a
272.                         OmX = _MOUSEX - OldW(a).X
273.                         OmY = _MOUSEY - OldW(a).Y
274.                         DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
275.                         DO WHILE _MOUSEBUTTON(1)
276.                             IF _MOUSEINPUT THEN
277.                                 CLS , Orange
278.  
279.                                 OldW(a).X = (_MOUSEX - OmX)
280.                                 OldW(a).Y = (_MOUSEY - OmY)
281.                                 DrawAllWin
282.                                 dragWindow OldW(a)
283.                             END IF
284.                         LOOP
285.                         ' new position of window
286.                         RestoreWin a
287.                     END IF
288.                 CASE Focusing
289.                     Focus a
290.             END SELECT
291.  
292.         CASE ELSE
293.     END SELECT
294. END SUB
295.  
296. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
297.     IsInWindow = mFalse
298.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
299.         ' if window is closed to its bar it cannot get focus on the window area
300.         IF IsInTheRange%(X, Win.X, Win.X + Win.Width) AND (Win.Status <> Closed) THEN IsInWindow = Focusing
301.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
302.         ' if is the window bar area
303.         IF IsInTheRange%(X, Win.X, Win.X + Win.Width - 31) THEN
304.             ' if it is to the left of buttons on the bar
305.             ' maximized window cannot be dragged
306.             IF NOT (Win.Status AND Maxim) THEN IsInWindow = Dragging
307.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 30, Win.X + Win.Width - 21) THEN
308.             ' if it is on the leftest button on the bar
309.             IsInWindow = cMinim ' icon minimize--> restore to child default
310.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 20, Win.X + Win.Width - 11) THEN
311.             ' if it is on the middle button on the bar
312.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
313.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 10, Win.X + Win.Width) THEN
314.             ' if is on the rightest button on the bar
315.             ' maximized child window cannot become minimized to bar of child window
316.             IF NOT (Win.Status AND Maxim) THEN IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
317.         END IF
318.     END IF
319. END FUNCTION
320.  
321. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
322.     IF Min > Max THEN SWAP Min, Max
323.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
324. END FUNCTION
325.  
326. SUB dragWindow (Win AS wChild)
327.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), White, B
328.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), White, BF 'title bar for dragging window
329.     _DISPLAY
330. END SUB
331.  
332. SUB wClosed (Win AS wChild)
333.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
334.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Black, B
335.     LINE (Win.X + Win.Width - 7, Win.Y + 3)-(Win.X + Win.Width - 3, Win.Y + 7), Black
336.     LINE (Win.X + Win.Width - 7, Win.Y + 7)-(Win.X + Win.Width - 3, Win.Y + 3), Black
337. END SUB
338.  
339. SUB wMaxim (win AS wChild)
340.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Pink, BF 'title bar for restore to original dimensions
341.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Black, B
342.     LINE (win.X + win.Width - 17, win.Y + 3)-(win.X + win.Width - 13, win.Y + 7), Black, B
343. END SUB
344.  
345. SUB wMinim (Win AS wChild)
346.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
347.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Black, B
348.     LINE (Win.X + Win.Width - 27, Win.Y + 7)-(Win.X + Win.Width - 23, Win.Y + 7), Black
349. END SUB
350.  
351.  
352. SUB DrawWindow (Win AS wChild)
353.     ' the window
354.     IF Win.Status = Minim OR Win.Status = Maxim THEN
355.         LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Win.Color, BF
356.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.Width, Win.Y + Win.Height), Black
357.         LINE (Win.X + Win.Width, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Black
358.     END IF
359.     ' the status bar
360.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for dragging window
361.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.Width, Win.Y + 10), Black
362.     wMinim Win
363.     wMaxim Win
364.     wClosed Win
365. END SUB
366.  
367. SUB GetInput (Act AS INTEGER)
368.     DIM mInput AS INTEGER
369.  
370.  
371.     ' keyboard input
372.     a$ = INKEY$
373.     IF a$ = CHR$(27) THEN Act = aQuit
374.  
375.     'mouse input
376.     mInput = mFalse
377.     IF _MOUSEINPUT THEN mInput = mTrue
378.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
379.     LOOP
380.     IF mInput THEN
381.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
382.             mInput = mLR
383.         ELSEIF _MOUSEBUTTON(1) THEN
384.             mInput = mLeft
385.         ELSEIF _MOUSEBUTTON(2) THEN
386.             mInput = mRight
387.         ELSEIF _MOUSEBUTTON(3) THEN
388.             mInput = mMiddle
389.         END IF
390.     END IF
391.  
392.     IF mInput = mLR THEN
393.         Act = aQuit
394.     ELSEIF mInput = mMiddle THEN
395.         Act = Minim
396.     ELSEIF mInput = mRight THEN
397.         Act = Maxim
398.     ELSEIF mInput = mLeft THEN
399.         Act = mInput
400.     END IF
401. END SUB

 [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 09, 2020, 06:17:39 pm

Hi
here a more complex but versatle system of windowing child windows

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8. ' 2020 02 09  with the power of the second array we implement a different
9. '             child windows' system:
10. '             all child windows can be Closed to window's bar
11. '             all child windows can be dragged on the screen
12.  
13. ' 2020 02 08  using a second array we store windows information indipendently so
14. '             now each window can be modified and restored
15.  
16.  
17. ' 2020 02 06  after dragging or maximize a window, restoring it we gives
18. '             to it the last value used in windows(0) so the info of the last
19. '             window that is dragged or maximize when we use Minimize button on
20. '             another child window
21. '             the fix can be got using a shadow array that stores windows informations
22. '             or windows(0) as the child window that takes the information of the
23. '             child window that must be acted (Minimize, Maximize and Closed)
24. '             and we use it as template to make graphic output
25.  
26. ' 2020 02 05 fixed a minor bug on mouse click events
27. '            activated events Maxim Minim and Closed
28.  
29.  
30. ' 2020 02 03 increasing the windows managed and close initialization to SUB
31. '            removed vMax SHARED variable
32. '            added 3 buttons on the rightest site of the bar of the child window
33. '            SUB wClosed, wMaxim, wMinim
34. '            In this version the user can maximize one child window to the application window
35. '            In the status of Maxim the child window has the focus and can be only
36. '            reduced to status Minim, it cannot be dragging or Closed to bar of window
37.  
38.  
39. ' 2020 01 30 fixed bug on focusing a child window
40. '
41.  
42. ' 2020 01 25  A program with child windows into it
43. ' we need a system to manage multiple windows
44. ' and a system to manage input/output
45. ' and a system to make graphic report
46.  
47. ' settings-------------------------------------------------------
48. SCREEN _NEWIMAGE(800, 600, 32)
49. _TITLE "Child windows"
50. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
51. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
52. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
53. CONST Minim = 10, Maxim = 20, Closed = 100
54. CONST wMin = 5, aNull = 0, aQuit = 9999
55. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
56. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
57.  
58. _FULLSCREEN
59.  
60.  
61. 'dataset  -----------------------------------------------
62. TYPE person
63.     name AS STRING * 10
64.     age AS INTEGER
65.     weight AS INTEGER
66.     height AS INTEGER
67.     BMI AS INTEGER
68. END TYPE
69.  
70. TYPE wChild
71.     X AS INTEGER
72.     Y AS INTEGER
73.     Width AS INTEGER
74.     Height AS INTEGER
75.     Zorder AS INTEGER
76.     Status AS INTEGER
77.     Color AS _UNSIGNED LONG
78. END TYPE
79.  
80. REDIM Windows(1 TO wMin) AS wChild, OldW(0 TO wMin) AS wChild
81.  
82. InitWin
83.  
84. DIM Action AS INTEGER
85.  
86.  
87. ' main loop -----------------------------------------------
88.  
89. DO
90.     ' set the main window
91.     Action = aNull
92.     CLS , Orange
93.     DrawAllWin
94.     GetInput Action
95.     DoAction Action
96.     _DISPLAY
97.     _LIMIT 30
98. LOOP
99. END
100.  
101. ' SUBs and FUNCTIONs --------------------------------------
102. SUB InitWin
103.     SHARED Windows() AS wChild, OldW() AS wChild
104.     DIM a AS INTEGER
105.  
106.     Windows(1).X = 1
107.     Windows(1).Y = 1
108.     Windows(1).Width = 300
109.     Windows(1).Height = 400
110.     Windows(1).Zorder = 1
111.     Windows(1).Status = Minim
112.     Windows(1).Color = Blu
113.  
114.     Windows(2).X = 100
115.     Windows(2).Y = 1
116.     Windows(2).Width = 300
117.     Windows(2).Height = 400
118.     Windows(2).Zorder = 2
119.     Windows(2).Status = Minim
120.     Windows(2).Color = Yellow
121.  
122.     Windows(3).X = 200
123.     Windows(3).Y = 1
124.     Windows(3).Width = 300
125.     Windows(3).Height = 400
126.     Windows(3).Zorder = 3
127.     Windows(3).Status = Minim
128.     Windows(3).Color = Green
129.  
130.     Windows(4).X = 300
131.     Windows(4).Y = 1
132.     Windows(4).Width = 300
133.     Windows(4).Height = 400
134.     Windows(4).Zorder = 4
135.     Windows(4).Status = Minim
136.     Windows(4).Color = Red
137.  
138.     Windows(5).X = 400
139.     Windows(5).Y = 1
140.     Windows(5).Width = 300
141.     Windows(5).Height = 400
142.     Windows(5).Zorder = 5
143.     Windows(5).Status = Minim
144.     Windows(5).Color = Cyan
145.  
146.     FOR a = 1 TO wMin STEP 1
147.         AdjournWin a
148.     NEXT a
149. END SUB
150.  
151. SUB RestoreWin (a AS INTEGER)
152.     SHARED Windows() AS wChild, OldW() AS wChild
153.  
154.     Windows(a).X = OldW(a).X
155.     Windows(a).Y = OldW(a).Y
156.     Windows(a).Width = OldW(a).Width
157.     Windows(a).Height = OldW(a).Height
158.     Windows(a).Zorder = OldW(a).Zorder
159.     Windows(a).Color = OldW(a).Color
160. END SUB
161.  
162. SUB AdjournWin (a AS INTEGER)
163.     SHARED Windows() AS wChild, OldW() AS wChild
164.  
165.     OldW(a).X = Windows(a).X
166.     OldW(a).Y = Windows(a).Y
167.     OldW(a).Width = Windows(a).Width
168.     OldW(a).Height = Windows(a).Height
169.     OldW(a).Zorder = Windows(a).Zorder
170.     OldW(a).Color = Windows(a).Color
171. END SUB
172.  
173. SUB DrawAllWin
174.     SHARED Windows() AS wChild
175.     DIM Finished AS INTEGER
176.     Finished = wMin
177.     DO
178.         FOR a = 1 TO wMin
179.             IF Windows(a).Zorder = Finished THEN
180.                 DrawWindow Windows(a)
181.                 Finished = Finished - 1
182.                 EXIT FOR
183.             END IF
184.         NEXT a
185.     LOOP UNTIL Finished = 0
186. END SUB
187.  
188. SUB Focus (Index AS INTEGER)
189.     SHARED Windows() AS wChild
190.     DIM b AS INTEGER
191.     FOR b = 1 TO wMin
192.         IF Windows(b).Zorder = 1 THEN EXIT FOR
193.     NEXT b
194.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
195.     DrawAllWin
196. END SUB
197.  
198.  
199. SUB DoAction (Act AS INTEGER)
200.     SHARED Windows() AS wChild, OldW() AS wChild
201.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
202.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
203.  
204.     SELECT CASE Act
205.         CASE aQuit
206.             END
207.  
208.         CASE Maxim
209.             _FULLSCREEN
210.  
211.         CASE Minim
212.             _FULLSCREEN _OFF
213.  
214.         CASE mLeft
215.             mX = _MOUSEX
216.             mY = _MOUSEY
217.  
218.             ' search where and what mouse has touched by leftclick
219.             OldA = 0
220.             OldActio = 0
221.             FOR a = 1 TO wMin ' windows(0) is out of action
222.                 Actio = IsInWindow(mX, mY, Windows(a))
223.                 IF Actio THEN
224.                     IF OldA <= 0 THEN
225.                         OldA = a
226.                         OldActio = Actio
227.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN
228.                         OldA = a
229.                         OldActio = Actio
230.                     END IF
231.                 END IF
232.             NEXT a
233.             IF a > OldA THEN
234.                 a = OldA ' restore the last windows interacting
235.                 Actio = OldActio
236.             END IF
237.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB
238.  
239.  
240.             Focus a 'set zorder on the (a) window that gets the input
241.  
242.  
243.             SELECT CASE Actio
244.                 CASE cMinim
245.                     ' here restore to  standard (bar + area of window) status of child window
246.                     IF Windows(a).Status = Closed + Maxim THEN
247.                         ' if windows is a closed maximized window
248.                         ' we restore its status of maximized
249.                         Windows(a).Status = Maxim
250.                     ELSEIF Windows(a).Status = Closed + Minim THEN
251.                         ' if windows is a closed minimized window
252.                         ' we restore its status of minimized
253.                         Windows(a).Status = Minim
254.                     ELSEIF Windows(a).Status = Maxim THEN
255.                         ' if is a window maximized it gets back all info setting
256.                         ' we restore its status of minimized
257.                         RestoreWin a
258.                         Windows(a).Status = Minim
259.                     END IF
260.  
261.  
262.                 CASE cMaxim
263.                     ' here convert the window to full size of main window of the program
264.                     ' OR gives 1 if both parameter are true or al last one is true
265.                     IF (Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim) THEN
266.                         ' it acts if windows if not still maximized
267.                         ' it is minimized window opened or closed
268.                         ' memorize window's data when it is not maximized
269.                         '                        IF Windows(a).Width < _WIDTH THEN
270.                         AdjournWin a
271.                         ' it sets maximized status
272.                         Windows(a).Width = _WIDTH
273.                         Windows(a).Height = _HEIGHT
274.                         Windows(a).X = 1
275.                         Windows(a).Y = 1
276.                         ' change status
277.                         Windows(a).Status = Maxim
278.                     END IF
279.  
280.                 CASE cClosed
281.                     ' here minimize the child window to its window bar
282.                     IF NOT Windows(a).Status > Closed THEN
283.                         Windows(a).Status = Windows(a).Status + Closed
284.                     END IF
285.  
286.                 CASE Dragging
287.                     ' dragging is possible for all status of windows
288.                     '
289.                     ' if minimized or Closed and minimized window we save data info
290.                     IF Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim THEN AdjournWin a
291.                     ' it sets variables for dragging
292.                     OldW(0).X = Windows(a).X
293.                     OldW(0).Y = Windows(a).Y
294.                     OldW(0).Width = Windows(a).Width
295.                     OldW(0).Height = Windows(a).Height
296.  
297.                     OmX = _MOUSEX - OldW(0).X
298.                     OmY = _MOUSEY - OldW(0).Y
299.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
300.                     DO WHILE _MOUSEBUTTON(1)
301.                         IF _MOUSEINPUT THEN
302.                             CLS , Orange
303.  
304.                             OldW(0).X = (_MOUSEX - OmX)
305.                             OldW(0).Y = (_MOUSEY - OmY)
306.                             DrawAllWin
307.                             dragWindow OldW(0)
308.                         END IF
309.                     LOOP
310.                     ' new position of window
311.                     Windows(a).X = OldW(0).X
312.                     Windows(a).Y = OldW(0).Y
313.                     OldW(a).X = Windows(a).X
314.                     OldW(a).Y = Windows(a).Y
315.  
316.                 CASE Focusing
317.                     Focus a
318.             END SELECT
319.  
320.         CASE ELSE
321.     END SELECT
322. END SUB
323.  
324. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
325.     IsInWindow = mFalse
326.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
327.         ' if window is closed to its bar it cannot get focus on the window area
328.         IF IsInTheRange%(X, Win.X, Win.X + Win.Width) AND (Win.Status < Closed) THEN IsInWindow = Focusing
329.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
330.         ' if is the window bar area
331.         IF IsInTheRange%(X, Win.X, Win.X + Win.Width - 31) THEN
332.             ' if it is to the left of buttons on the bar
333.             IsInWindow = Dragging
334.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 30, Win.X + Win.Width - 21) THEN
335.             ' if it is on the leftest button on the bar
336.             IsInWindow = cMinim ' icon minimize--> restore to child default
337.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 20, Win.X + Win.Width - 11) THEN
338.             ' if it is on the middle button on the bar
339.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
340.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 10, Win.X + Win.Width) THEN
341.             ' if is on the rightest button on the bar
342.             IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
343.         END IF
344.     END IF
345. END FUNCTION
346.  
347. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
348.     IF Min > Max THEN SWAP Min, Max
349.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
350. END FUNCTION
351.  
352. SUB dragWindow (Win AS wChild)
353.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), White, B ' windows size
354.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), White, BF 'title bar for dragging window
355.     _DISPLAY
356. END SUB
357.  
358. SUB wClosed (Win AS wChild)
359.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
360.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Black, B
361.     LINE (Win.X + Win.Width - 7, Win.Y + 3)-(Win.X + Win.Width - 3, Win.Y + 7), Black
362.     LINE (Win.X + Win.Width - 7, Win.Y + 7)-(Win.X + Win.Width - 3, Win.Y + 3), Black
363. END SUB
364.  
365. SUB wMaxim (win AS wChild)
366.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Pink, BF 'title bar for restore to original dimensions
367.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Black, B
368.     LINE (win.X + win.Width - 17, win.Y + 3)-(win.X + win.Width - 13, win.Y + 7), Black, B
369. END SUB
370.  
371. SUB wMinim (Win AS wChild)
372.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
373.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Black, B
374.     LINE (Win.X + Win.Width - 27, Win.Y + 7)-(Win.X + Win.Width - 23, Win.Y + 7), Black
375. END SUB
376.  
377.  
378. SUB DrawWindow (Win AS wChild)
379.     ' the window
380.     IF Win.Status = Minim OR Win.Status = Maxim THEN
381.         LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Win.Color, BF
382.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.Width, Win.Y + Win.Height), Black
383.         LINE (Win.X + Win.Width, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Black
384.     END IF
385.     ' the status bar
386.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for dragging window
387.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.Width, Win.Y + 10), Black
388.     wMinim Win
389.     wMaxim Win
390.     wClosed Win
391. END SUB
392.  
393. SUB GetInput (Act AS INTEGER)
394.     DIM mInput AS INTEGER
395.  
396.  
397.     ' keyboard input
398.     a$ = INKEY$
399.     IF a$ = CHR$(27) THEN Act = aQuit
400.  
401.     'mouse input
402.     mInput = mFalse
403.     IF _MOUSEINPUT THEN mInput = mTrue
404.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
405.     LOOP
406.     IF mInput THEN
407.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
408.             mInput = mLR
409.         ELSEIF _MOUSEBUTTON(1) THEN
410.             mInput = mLeft
411.         ELSEIF _MOUSEBUTTON(2) THEN
412.             mInput = mRight
413.         ELSEIF _MOUSEBUTTON(3) THEN
414.             mInput = mMiddle
415.         END IF
416.     END IF
417.  
418.     IF mInput = mLR THEN
419.         Act = aQuit
420.     ELSEIF mInput = mMiddle THEN
421.         Act = Minim
422.     ELSEIF mInput = mRight THEN
423.         Act = Maxim
424.     ELSEIF mInput = mLeft THEN
425.         Act = mInput
426.     END IF
427. END SUB

Thanks to take a look!

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 13, 2020, 04:14:38 pm

another little step:
resizing wchild into main program's window

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8. ' 2020 02 12  with the power of the second array we implement the feature
9. '             of resizable of child window
10.  
11. ' 2020 02 09  with the power of the second array we implement a different
12. '             child windows' system:
13. '             all child windows can be Closed to window's bar
14. '             all child windows can be dragged on the screen
15.  
16. ' 2020 02 08  using a second array we store windows information indipendently so
17. '             now each window can be modified and restored
18.  
19.  
20. ' 2020 02 06  after dragging or maximize a window, restoring it we gives
21. '             to it the last value used in windows(0) so the info of the last
22. '             window that is dragged or maximize when we use Minimize button on
23. '             another child window
24. '             the fix can be got using a shadow array that stores windows informations
25. '             or windows(0) as the child window that takes the information of the
26. '             child window that must be acted (Minimize, Maximize and Closed)
27. '             and we use it as template to make graphic output
28.  
29. ' 2020 02 05 fixed a minor bug on mouse click events
30. '            activated events Maxim Minim and Closed
31.  
32.  
33. ' 2020 02 03 increasing the windows managed and close initialization to SUB
34. '            removed vMax SHARED variable
35. '            added 3 buttons on the rightest site of the bar of the child window
36. '            SUB wClosed, wMaxim, wMinim
37. '            In this version the user can maximize one child window to the application window
38. '            In the status of Maxim the child window has the focus and can be only
39. '            reduced to status Minim, it cannot be dragging or Closed to bar of window
40.  
41.  
42. ' 2020 01 30 fixed bug on focusing a child window
43. '
44.  
45. ' 2020 01 25  A program with child windows into it
46. ' we need a system to manage multiple windows
47. ' and a system to manage input/output
48. ' and a system to make graphic report
49.  
50. ' settings-------------------------------------------------------
51. SCREEN _NEWIMAGE(800, 600, 32)
52. _TITLE "Child windows"
53. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
54. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
55. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
56. CONST Minim = 10, Maxim = 20, Closed = 100
57. CONST wMin = 5, aNull = 0, aQuit = 9999
58. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
59. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
60. CONST cResize = 700, LResize = 710, RResize = 720, StopResize = 730
61.  
62. _FULLSCREEN
63.  
64.  
65. 'dataset  -----------------------------------------------
66. TYPE person
67.     name AS STRING * 10
68.     age AS INTEGER
69.     weight AS INTEGER
70.     height AS INTEGER
71.     BMI AS INTEGER
72. END TYPE
73.  
74. TYPE wChild
75.     X AS INTEGER
76.     Y AS INTEGER
77.     Width AS INTEGER
78.     Height AS INTEGER
79.     Zorder AS INTEGER
80.     Status AS INTEGER
81.     Color AS _UNSIGNED LONG
82. END TYPE
83.  
84. REDIM Windows(1 TO wMin) AS wChild, OldW(0 TO wMin) AS wChild
85.  
86. InitWin
87.  
88. DIM Action AS INTEGER
89.  
90.  
91. ' main loop -----------------------------------------------
92.  
93. DO
94.     ' set the main window
95.     Action = aNull
96.     CLS , Orange
97.     DrawAllWin
98.     GetInput Action
99.     DoAction Action
100.     _DISPLAY
101.     _LIMIT 30
102. LOOP
103. END
104.  
105. ' SUBs and FUNCTIONs --------------------------------------
106. SUB InitWin
107.     SHARED Windows() AS wChild, OldW() AS wChild
108.     DIM a AS INTEGER
109.  
110.     Windows(1).X = 1
111.     Windows(1).Y = 1
112.     Windows(1).Width = 300
113.     Windows(1).Height = 400
114.     Windows(1).Zorder = 1
115.     Windows(1).Status = Minim
116.     Windows(1).Color = Blu
117.  
118.     Windows(2).X = 100
119.     Windows(2).Y = 1
120.     Windows(2).Width = 300
121.     Windows(2).Height = 400
122.     Windows(2).Zorder = 2
123.     Windows(2).Status = Minim
124.     Windows(2).Color = Yellow
125.  
126.     Windows(3).X = 200
127.     Windows(3).Y = 1
128.     Windows(3).Width = 300
129.     Windows(3).Height = 400
130.     Windows(3).Zorder = 3
131.     Windows(3).Status = Minim
132.     Windows(3).Color = Green
133.  
134.     Windows(4).X = 300
135.     Windows(4).Y = 1
136.     Windows(4).Width = 300
137.     Windows(4).Height = 400
138.     Windows(4).Zorder = 4
139.     Windows(4).Status = Minim
140.     Windows(4).Color = Red
141.  
142.     Windows(5).X = 400
143.     Windows(5).Y = 1
144.     Windows(5).Width = 300
145.     Windows(5).Height = 400
146.     Windows(5).Zorder = 5
147.     Windows(5).Status = Minim
148.     Windows(5).Color = Cyan
149.  
150.     FOR a = 1 TO wMin STEP 1
151.         AdjournWin a
152.     NEXT a
153. END SUB
154.  
155. SUB RestoreWin (a AS INTEGER)
156.     SHARED Windows() AS wChild, OldW() AS wChild
157.  
158.     Windows(a).X = OldW(a).X
159.     Windows(a).Y = OldW(a).Y
160.     Windows(a).Width = OldW(a).Width
161.     Windows(a).Height = OldW(a).Height
162.     Windows(a).Zorder = OldW(a).Zorder
163.     Windows(a).Color = OldW(a).Color
164. END SUB
165.  
166. SUB AdjournWin (a AS INTEGER)
167.     SHARED Windows() AS wChild, OldW() AS wChild
168.  
169.     OldW(a).X = Windows(a).X
170.     OldW(a).Y = Windows(a).Y
171.     OldW(a).Width = Windows(a).Width
172.     OldW(a).Height = Windows(a).Height
173.     OldW(a).Zorder = Windows(a).Zorder
174.     OldW(a).Color = Windows(a).Color
175. END SUB
176.  
177. SUB DrawAllWin
178.     SHARED Windows() AS wChild
179.     DIM Finished AS INTEGER
180.     Finished = wMin
181.     DO
182.         FOR a = 1 TO wMin
183.             IF Windows(a).Zorder = Finished THEN
184.                 DrawWindow Windows(a)
185.                 Finished = Finished - 1
186.                 EXIT FOR
187.             END IF
188.         NEXT a
189.     LOOP UNTIL Finished = 0
190. END SUB
191.  
192. SUB Focus (Index AS INTEGER)
193.     SHARED Windows() AS wChild
194.     DIM b AS INTEGER
195.     FOR b = 1 TO wMin
196.         IF Windows(b).Zorder = 1 THEN EXIT FOR
197.     NEXT b
198.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
199.     DrawAllWin
200. END SUB
201.  
202.  
203. SUB DoAction (Act AS INTEGER)
204.     SHARED Windows() AS wChild, OldW() AS wChild
205.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
206.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
207.  
208.     SELECT CASE Act
209.         CASE aQuit
210.             END
211.  
212.         CASE Maxim
213.             _FULLSCREEN
214.  
215.         CASE Minim
216.             _FULLSCREEN _OFF
217.  
218.         CASE mLeft
219.             mX = _MOUSEX
220.             mY = _MOUSEY
221.  
222.             ' search where and what mouse has touched by leftclick
223.             OldA = 0
224.             OldActio = 0
225.             FOR a = 1 TO wMin ' windows(0) is out of action
226.                 Actio = IsInWindow(mX, mY, Windows(a))
227.                 IF Actio THEN
228.                     IF OldA <= 0 THEN
229.                         OldA = a
230.                         OldActio = Actio
231.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN
232.                         OldA = a
233.                         OldActio = Actio
234.                     END IF
235.                 END IF
236.             NEXT a
237.             IF a > OldA THEN
238.                 a = OldA ' restore the last windows interacting
239.                 Actio = OldActio
240.             END IF
241.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB
242.  
243.  
244.             Focus a 'set zorder on the (a) window that gets the input
245.  
246.  
247.             SELECT CASE Actio
248.                 CASE cMinim
249.                     ' here restore to  standard (bar + area of window) status of child window
250.                     IF Windows(a).Status = Closed + Maxim THEN
251.                         ' if windows is a closed maximized window
252.                         ' we restore its status of maximized
253.                         Windows(a).Status = Maxim
254.                     ELSEIF Windows(a).Status = Closed + Minim THEN
255.                         ' if windows is a closed minimized window
256.                         ' we restore its status of minimized
257.                         Windows(a).Status = Minim
258.                     ELSEIF Windows(a).Status = Maxim THEN
259.                         ' if is a window maximized it gets back all info setting
260.                         ' we restore its status of minimized
261.                         RestoreWin a
262.                         Windows(a).Status = Minim
263.                     END IF
264.  
265.  
266.                 CASE cMaxim
267.                     ' here convert the window to full size of main window of the program
268.                     ' OR gives 1 if both parameter are true or al last one is true
269.                     IF (Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim) THEN
270.                         ' it acts if windows if not still maximized
271.                         ' it is minimized window opened or closed
272.                         ' memorize window's data when it is not maximized
273.                         '                        IF Windows(a).Width < _WIDTH THEN
274.                         AdjournWin a
275.                         ' it sets maximized status
276.                         Windows(a).Width = _WIDTH
277.                         Windows(a).Height = _HEIGHT
278.                         Windows(a).X = 1
279.                         Windows(a).Y = 1
280.                         ' change status
281.                         Windows(a).Status = Maxim
282.                     END IF
283.  
284.                 CASE cClosed
285.                     ' here minimize the child window to its window bar
286.                     IF NOT Windows(a).Status > Closed THEN
287.                         Windows(a).Status = Windows(a).Status + Closed
288.                     END IF
289.  
290.                 CASE Dragging
291.                     ' dragging is possible for all status of windows
292.                     '
293.                     ' if minimized or Closed and minimized window we save data info
294.                     IF Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim THEN AdjournWin a
295.                     ' it sets variables for dragging
296.                     OldW(0).X = Windows(a).X
297.                     OldW(0).Y = Windows(a).Y
298.                     OldW(0).Width = Windows(a).Width
299.                     OldW(0).Height = Windows(a).Height
300.  
301.                     OmX = _MOUSEX - OldW(0).X
302.                     OmY = _MOUSEY - OldW(0).Y
303.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
304.                     DO WHILE _MOUSEBUTTON(1)
305.                         IF _MOUSEINPUT THEN
306.                             CLS , Orange
307.  
308.                             OldW(0).X = (_MOUSEX - OmX)
309.                             OldW(0).Y = (_MOUSEY - OmY)
310.                             DrawAllWin
311.                             dragWindow OldW(0)
312.                         END IF
313.                     LOOP
314.                     ' new position of window
315.                     Windows(a).X = OldW(0).X
316.                     Windows(a).Y = OldW(0).Y
317.                     OldW(a).X = Windows(a).X
318.                     OldW(a).Y = Windows(a).Y
319.  
320.                 CASE Focusing
321.                     Focus a
322.  
323.                 CASE cResize
324.                     ' resizing is possible only for minimized opened child windows
325.                     IF Windows(a).Status = Minim THEN
326.                         Windows(a).Status = cResize
327.                         DO WHILE _MOUSEBUTTON(1) OR _MOUSEINPUT: LOOP
328.                         DO WHILE Windows(a).Status = cResize
329.                             CLS , Orange
330.                             DrawAllWin
331.                             ShowDimension Windows(a)
332.  
333.  
334.                             IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN
335.                                 DO WHILE _MOUSEINPUT: LOOP ' clear mouse buffer
336.                                 IsResizing Windows(a), _MOUSEX, _MOUSEY
337.                             END IF
338.                             _DISPLAY
339.                         LOOP
340.                     END IF
341.  
342.             END SELECT
343.         CASE ELSE
344.     END SELECT
345. END SUB
346.  
347. SUB IsResizing (Win AS wChild, mX AS INTEGER, mY AS INTEGER)
348.     SHARED Windows() AS wChild, OldW() AS wChild
349.     DIM Actio AS INTEGER, OldmX AS INTEGER, OldmY AS INTEGER
350.     Actio = 0
351.  
352.     IF IsInTheRange%(mX, Win.X, Win.X + Win.Width) THEN
353.         IF IsInTheRange%(mY, Win.Y, Win.Y + Win.Height) THEN
354.             ' do nothing if is in the range of window
355.         ELSE
356.             ' user click out of area  of window to resize
357.             Actio = StopResize
358.         END IF
359.     ELSE
360.         ' user click out of area  of window to resize
361.         Actio = StopResize
362.     END IF
363.  
364.  
365.  
366.  
367.  
368.     IF IsInTheRange%(mX, Win.X, Win.X + 10) THEN
369.         IF IsInTheRange%(mY, Win.Y, Win.Y + 10) THEN
370.             ' user click on lefttop square to resize
371.             Actio = LResize
372.         END IF
373.     END IF
374.  
375.     IF IsInTheRange%(mX, Win.X + Win.Width - 10, Win.X + Win.Width) THEN
376.         IF IsInTheRange%(mY, Win.Y + Win.Height - 10, Win.Y + Win.Height) THEN
377.             ' user click on the rightbottom square to resize
378.             Actio = RResize
379.         END IF
380.     END IF
381.  
382.     IF Actio = 0 THEN
383.         ' no action done
384.     ELSEIF Actio = LResize THEN
385.         ' choosen LeftTop buttom to resize
386.         OldW(0).X = Win.X
387.         OldW(0).Y = Win.Y
388.         OldW(0).Width = Win.Width
389.         OldW(0).Height = Win.Height
390.         OldmX = _MOUSEX
391.         OldmY = _MOUSEY
392.         DO WHILE Actio = LResize
393.             IF _MOUSEINPUT THEN
394.                 IF (OldW(0).X + OldW(0).Width - OldmX) >= 50 THEN OldW(0).Width = OldW(0).X + OldW(0).Width - OldmX
395.                 IF (OldW(0).Y + OldW(0).Height - OldmY) >= 30 THEN OldW(0).Height = OldW(0).Y + OldW(0).Height - OldmY
396.                 CLS , Orange
397.                 DrawAllWin
398.                 ShowDimension OldW(0)
399.                 OldW(0).X = OldmX
400.                 OldW(0).Y = OldmY
401.  
402.                 OldmX = _MOUSEX
403.                 OldmY = _MOUSEY
404.             ELSE
405.                 IF _MOUSEBUTTON(1) THEN Actio = 0
406.             END IF
407.         LOOP
408.         Win.X = OldW(0).X
409.         Win.Y = OldW(0).Y
410.         Win.Width = OldW(0).Width
411.         Win.Height = OldW(0).Height
412.  
413.  
414.     ELSEIF Actio = RResize THEN
415.         ' choosen bottomright square
416.         OldW(0).X = Win.X
417.         OldW(0).Y = Win.Y
418.         OldW(0).Width = Win.Width
419.         OldW(0).Height = Win.Height
420.         OldmX = _MOUSEX
421.         OldmY = _MOUSEY
422.         DO WHILE Actio = RResize
423.             IF _MOUSEINPUT THEN
424.                 IF OldmX - OldW(0).X >= 50 THEN OldW(0).Width = OldmX - OldW(0).X
425.                 IF OldmY - OldW(0).Y >= 30 THEN OldW(0).Height = OldmY - OldW(0).Y
426.                 CLS , Orange
427.                 DrawAllWin
428.                 ShowDimension OldW(0)
429.                 OldmX = _MOUSEX
430.                 OldmY = _MOUSEY
431.             ELSE
432.                 IF _MOUSEBUTTON(1) THEN Actio = 0
433.             END IF
434.         LOOP
435.         Win.X = OldW(0).X
436.         Win.Y = OldW(0).Y
437.         Win.Width = OldW(0).Width
438.         Win.Height = OldW(0).Height
439.  
440.     ELSEIF Actio = StopResize THEN
441.         ' click out of window to stop resize action
442.         Win.Status = Minim
443.     END IF
444. END SUB
445.  
446. SUB ShowDimension (win AS wChild)
447.     LINE (win.X, win.Y)-(win.X + win.Width, win.Y + win.Height), White, B ' windows size
448.     LINE (win.X, win.Y)-(win.X + 10, win.Y + 10), White, BF 'button for resizing window
449.     LINE (win.X + win.Width - 10, win.Y + win.Height - 10)-(win.X + win.Width, win.Y + win.Height), White, BF 'button for resizing window
450.     _DISPLAY
451. END SUB
452.  
453. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
454.     IsInWindow = mFalse
455.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
456.         ' if window is closed to its bar it cannot get focus on the window area
457.         IF IsInTheRange%(X, Win.X, Win.X + Win.Width) AND (Win.Status < Closed) THEN IsInWindow = Focusing
458.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
459.         ' if is the window bar area
460.         IF IsInTheRange%(X, Win.X + 10, Win.X + Win.Width - 31) THEN
461.             ' if it is to the left of buttons on the bar
462.             IsInWindow = Dragging
463.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 30, Win.X + Win.Width - 21) THEN
464.             ' if it is on the leftest button on the bar
465.             IsInWindow = cMinim ' icon minimize--> restore to child default
466.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 20, Win.X + Win.Width - 11) THEN
467.             ' if it is on the middle button on the bar
468.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
469.         ELSEIF IsInTheRange%(X, Win.X + Win.Width - 10, Win.X + Win.Width) THEN
470.             ' if is on the rightest button on the bar
471.             IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
472.         ELSEIF IsInTheRange%(X, Win.X, Win.X + 10) THEN
473.             IsInWindow = cResize
474.         END IF
475.     END IF
476. END FUNCTION
477.  
478. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
479.     IF Min > Max THEN SWAP Min, Max
480.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
481. END FUNCTION
482.  
483. SUB dragWindow (Win AS wChild)
484.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), White, B ' windows size
485.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), White, BF 'title bar for dragging window
486.     _DISPLAY
487. END SUB
488.  
489. SUB wClosed (Win AS wChild)
490.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
491.     LINE (Win.X + Win.Width - 10, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Black, B
492.     LINE (Win.X + Win.Width - 7, Win.Y + 3)-(Win.X + Win.Width - 3, Win.Y + 7), Black
493.     LINE (Win.X + Win.Width - 7, Win.Y + 7)-(Win.X + Win.Width - 3, Win.Y + 3), Black
494. END SUB
495.  
496. SUB wMaxim (win AS wChild)
497.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Pink, BF 'title bar for restore to original dimensions
498.     LINE (win.X + win.Width - 20, win.Y)-(win.X + win.Width - 10, win.Y + 10), Black, B
499.     LINE (win.X + win.Width - 17, win.Y + 3)-(win.X + win.Width - 13, win.Y + 7), Black, B
500. END SUB
501.  
502. SUB wMinim (Win AS wChild)
503.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
504.     LINE (Win.X + Win.Width - 30, Win.Y)-(Win.X + Win.Width - 20, Win.Y + 10), Black, B
505.     LINE (Win.X + Win.Width - 27, Win.Y + 7)-(Win.X + Win.Width - 23, Win.Y + 7), Black
506. END SUB
507.  
508. SUB wResize (Win AS wChild)
509.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
510.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Black, B
511.     LINE (Win.X + 2, Win.Y + 2)-(Win.X + 7, Win.Y + 7), Black, B , &B1010101010101010
512. END SUB
513.  
514. SUB DrawWindow (Win AS wChild)
515.     ' the window
516.     IF Win.Status = Minim OR Win.Status = Maxim THEN
517.         LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Win.Color, BF
518.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.Width, Win.Y + Win.Height), Black
519.         LINE (Win.X + Win.Width, Win.Y)-(Win.X + Win.Width, Win.Y + Win.Height), Black
520.     END IF
521.     ' the status bar
522.     LINE (Win.X, Win.Y)-(Win.X + Win.Width, Win.Y + 10), Pink, BF 'title bar for dragging window
523.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.Width, Win.Y + 10), Black
524.     wMinim Win
525.     wMaxim Win
526.     wClosed Win
527.     wResize Win
528. END SUB
529.  
530. SUB GetInput (Act AS INTEGER)
531.     DIM mInput AS INTEGER
532.  
533.  
534.     ' keyboard input
535.     a$ = INKEY$
536.     IF a$ = CHR$(27) THEN Act = aQuit
537.  
538.     'mouse input
539.     mInput = mFalse
540.     IF _MOUSEINPUT THEN mInput = mTrue
541.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
542.     LOOP
543.     IF mInput THEN
544.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
545.             mInput = mLR
546.         ELSEIF _MOUSEBUTTON(1) THEN
547.             mInput = mLeft
548.         ELSEIF _MOUSEBUTTON(2) THEN
549.             mInput = mRight
550.         ELSEIF _MOUSEBUTTON(3) THEN
551.             mInput = mMiddle
552.         END IF
553.     END IF
554.  
555.     IF mInput = mLR THEN
556.         Act = aQuit
557.     ELSEIF mInput = mMiddle THEN
558.         Act = Minim
559.     ELSEIF mInput = mRight THEN
560.         Act = Maxim
561.     ELSEIF mInput = mLeft THEN
562.         Act = mInput
563.     END IF
564. END SUB

here 2 screenshot
  [ This attachment cannot be displayed inline in 'Print Page' view ]  
 [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: child windows into window of the program: a demonstration
Post by: keybone on February 14, 2020, 04:11:42 pm

Looks like it's coming along nicely...
One question though, where do you drag the window from for resizing?
I try dragging it from the lower right corner but it doesnt seem to work.

Anyways, nice job so far. It's nice to see someone else working on this :-)

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 14, 2020, 06:24:49 pm

Hi keybone
thanks for feedback and the fine words...

sorry I haven't been very clear: in resizing I have build up a system of click move and click to confirm. No dragging action.
So after you activate the resizing mode by leftclick on the alone and the leftest button on the window's bar, you'll see a white big square, that has at origin the same dimensions of the window,  and two little full white squares... LeftTop square and RightBottom square. To resize you must click by left button of mouse on one of these two buttons and then  you move the mouse to the desidered position, no more press leftbutton, , and you see the white square adapting  its shape to pointer of mouse. When you like the new shape you must left click  and the window changes to acquire that shape.

  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Title: Re: child windows into window of the program: a demonstration
Post by: keybone on February 15, 2020, 04:03:53 am

Quote from: TempodiBasic on February 14, 2020, 06:24:49 pm

Hi keybone
thanks for feedback and the fine words...

sorry I haven't been very clear: in resizing I have build up a system of click move and click to confirm. No dragging action.
So after you activate the resizing mode by leftclick on the alone and the leftest button on the window's bar, you'll see a white big square, that has at origin the same dimensions of the window,  and two little full white squares... LeftTop square and RightBottom square. To resize you must click by left button of mouse on one of these two buttons and then  you move the mouse to the desidered position, no more press leftbutton, , and you see the white square adapting  its shape to pointer of mouse. When you like the new shape you must left click  and the window changes to acquire that shape.

 

Its not working for me, I click on the resize button and the white box appears.
There is no response when i click one of the corner white boxes but when i click outside the window it turns back to normal.

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 15, 2020, 11:50:33 am

Ok we must define what is that makes the difference between our experience with this code.

To be sure I have taken the code from codebox (so it is the same that you have )
I have compiled it both by QB1.4 both by QB1.3 and I get the same program that works...
I'm using QB64 in Windows 10

.... to give a different feedback  when resizing is active I have made this little mod for output.

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8. ' 2020 02 12  with the power of the second array we implement the feature
9. '             of resizable of child window
10.  
11. ' 2020 02 09  with the power of the second array we implement a different
12. '             child windows' system:
13. '             all child windows can be Closed to window's bar
14. '             all child windows can be dragged on the screen
15.  
16. ' 2020 02 08  using a second array we store windows information indipendently so
17. '             now each window can be modified and restored
18.  
19.  
20. ' 2020 02 06  after dragging or maximize a window, restoring it we gives
21. '             to it the last value used in windows(0) so the info of the last
22. '             window that is dragged or maximize when we use Minimize button on
23. '             another child window
24. '             the fix can be got using a shadow array that stores windows informations
25. '             or windows(0) as the child window that takes the information of the
26. '             child window that must be acted (Minimize, Maximize and Closed)
27. '             and we use it as template to make graphic output
28.  
29. ' 2020 02 05 fixed a minor bug on mouse click events
30. '            activated events Maxim Minim and Closed
31.  
32.  
33. ' 2020 02 03 increasing the windows managed and close initialization to SUB
34. '            removed vMax SHARED variable
35. '            added 3 buttons on the rightest site of the bar of the child window
36. '            SUB wClosed, wMaxim, wMinim
37. '            In this version the user can maximize one child window to the application window
38. '            In the status of Maxim the child window has the focus and can be only
39. '            reduced to status Minim, it cannot be dragging or Closed to bar of window
40.  
41.  
42. ' 2020 01 30 fixed bug on focusing a child window
43. '
44.  
45. ' 2020 01 25  A program with child windows into it
46. ' we need a system to manage multiple windows
47. ' and a system to manage input/output
48. ' and a system to make graphic report
49.  
50. ' settings-------------------------------------------------------
51. SCREEN _NEWIMAGE(800, 600, 32)
52. _TITLE "Child windows"
53. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
54. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
55. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
56. CONST Minim = 10, Maxim = 20, Closed = 100
57. CONST wMin = 5, aNull = 0, aQuit = 9999
58. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
59. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
60. CONST cResize = 700, LResize = 710, RResize = 720, StopResize = 730
61.  
62. _FULLSCREEN
63.  
64.  
65. 'dataset  -----------------------------------------------
66. TYPE person
67.     NAME AS STRING * 10
68.     age AS INTEGER
69.     weight AS INTEGER
70.     height AS INTEGER
71.     BMI AS INTEGER
72. END TYPE
73.  
74. TYPE wChild
75.     X AS INTEGER
76.     Y AS INTEGER
77.     WIDTH AS INTEGER
78.     Height AS INTEGER
79.     Zorder AS INTEGER
80.     Status AS INTEGER
81.     COLOR AS _UNSIGNED LONG
82. END TYPE
83.  
84. REDIM Windows(1 TO wMin) AS wChild, OldW(0 TO wMin) AS wChild
85.  
86. InitWin
87.  
88. DIM Action AS INTEGER
89.  
90.  
91. ' main loop -----------------------------------------------
92.  
93. DO
94.     ' set the main window
95.     Action = aNull
96.     CLS , Orange
97.     DrawAllWin
98.     GetInput Action
99.     DoAction Action
100.     _DISPLAY
101.     _LIMIT 30
102. LOOP
103. END
104.  
105. ' SUBs and FUNCTIONs --------------------------------------
106. SUB InitWin
107.     SHARED Windows() AS wChild, OldW() AS wChild
108.     DIM a AS INTEGER
109.  
110.     Windows(1).X = 1
111.     Windows(1).Y = 1
112.     Windows(1).WIDTH = 300
113.     Windows(1).Height = 400
114.     Windows(1).Zorder = 1
115.     Windows(1).Status = Minim
116.     Windows(1).COLOR = Blu
117.  
118.     Windows(2).X = 100
119.     Windows(2).Y = 1
120.     Windows(2).WIDTH = 300
121.     Windows(2).Height = 400
122.     Windows(2).Zorder = 2
123.     Windows(2).Status = Minim
124.     Windows(2).COLOR = Yellow
125.  
126.     Windows(3).X = 200
127.     Windows(3).Y = 1
128.     Windows(3).WIDTH = 300
129.     Windows(3).Height = 400
130.     Windows(3).Zorder = 3
131.     Windows(3).Status = Minim
132.     Windows(3).COLOR = Green
133.  
134.     Windows(4).X = 300
135.     Windows(4).Y = 1
136.     Windows(4).WIDTH = 300
137.     Windows(4).Height = 400
138.     Windows(4).Zorder = 4
139.     Windows(4).Status = Minim
140.     Windows(4).COLOR = Red
141.  
142.     Windows(5).X = 400
143.     Windows(5).Y = 1
144.     Windows(5).WIDTH = 300
145.     Windows(5).Height = 400
146.     Windows(5).Zorder = 5
147.     Windows(5).Status = Minim
148.     Windows(5).COLOR = Cyan
149.  
150.     FOR a = 1 TO wMin STEP 1
151.         AdjournWin a
152.     NEXT a
153. END SUB
154.  
155. SUB RestoreWin (a AS INTEGER)
156.     SHARED Windows() AS wChild, OldW() AS wChild
157.  
158.     Windows(a).X = OldW(a).X
159.     Windows(a).Y = OldW(a).Y
160.     Windows(a).WIDTH = OldW(a).WIDTH
161.     Windows(a).Height = OldW(a).Height
162.     Windows(a).Zorder = OldW(a).Zorder
163.     Windows(a).COLOR = OldW(a).COLOR
164. END SUB
165.  
166. SUB AdjournWin (a AS INTEGER)
167.     SHARED Windows() AS wChild, OldW() AS wChild
168.  
169.     OldW(a).X = Windows(a).X
170.     OldW(a).Y = Windows(a).Y
171.     OldW(a).WIDTH = Windows(a).WIDTH
172.     OldW(a).Height = Windows(a).Height
173.     OldW(a).Zorder = Windows(a).Zorder
174.     OldW(a).COLOR = Windows(a).COLOR
175. END SUB
176.  
177. SUB DrawAllWin
178.     SHARED Windows() AS wChild
179.     DIM Finished AS INTEGER
180.     Finished = wMin
181.     DO
182.         FOR a = 1 TO wMin
183.             IF Windows(a).Zorder = Finished THEN
184.                 DrawWindow Windows(a)
185.                 Finished = Finished - 1
186.                 EXIT FOR
187.             END IF
188.         NEXT a
189.     LOOP UNTIL Finished = 0
190. END SUB
191.  
192. SUB Focus (Index AS INTEGER)
193.     SHARED Windows() AS wChild
194.     DIM b AS INTEGER
195.     FOR b = 1 TO wMin
196.         IF Windows(b).Zorder = 1 THEN EXIT FOR
197.     NEXT b
198.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
199.     DrawAllWin
200. END SUB
201.  
202.  
203. SUB DoAction (Act AS INTEGER)
204.     SHARED Windows() AS wChild, OldW() AS wChild
205.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
206.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
207.  
208.     SELECT CASE Act
209.         CASE aQuit
210.             END
211.  
212.         CASE Maxim
213.             _FULLSCREEN
214.  
215.         CASE Minim
216.             _FULLSCREEN _OFF
217.  
218.         CASE mLeft
219.             mX = _MOUSEX
220.             mY = _MOUSEY
221.  
222.             ' search where and what mouse has touched by leftclick
223.             OldA = 0
224.             OldActio = 0
225.             FOR a = 1 TO wMin ' windows(0) is out of action
226.                 Actio = IsInWindow(mX, mY, Windows(a))
227.                 IF Actio THEN
228.                     IF OldA <= 0 THEN
229.                         OldA = a
230.                         OldActio = Actio
231.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN
232.                         OldA = a
233.                         OldActio = Actio
234.                     END IF
235.                 END IF
236.             NEXT a
237.             IF a > OldA THEN
238.                 a = OldA ' restore the last windows interacting
239.                 Actio = OldActio
240.             END IF
241.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB
242.  
243.  
244.             Focus a 'set zorder on the (a) window that gets the input
245.  
246.  
247.             SELECT CASE Actio
248.                 CASE cMinim
249.                     ' here restore to  standard (bar + area of window) status of child window
250.                     IF Windows(a).Status = Closed + Maxim THEN
251.                         ' if windows is a closed maximized window
252.                         ' we restore its status of maximized
253.                         Windows(a).Status = Maxim
254.                     ELSEIF Windows(a).Status = Closed + Minim THEN
255.                         ' if windows is a closed minimized window
256.                         ' we restore its status of minimized
257.                         Windows(a).Status = Minim
258.                     ELSEIF Windows(a).Status = Maxim THEN
259.                         ' if is a window maximized it gets back all info setting
260.                         ' we restore its status of minimized
261.                         RestoreWin a
262.                         Windows(a).Status = Minim
263.                     END IF
264.  
265.  
266.                 CASE cMaxim
267.                     ' here convert the window to full size of main window of the program
268.                     ' OR gives 1 if both parameter are true or al last one is true
269.                     IF (Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim) THEN
270.                         ' it acts if windows if not still maximized
271.                         ' it is minimized window opened or closed
272.                         ' memorize window's data when it is not maximized
273.                         '                        IF Windows(a).Width < _WIDTH THEN
274.                         AdjournWin a
275.                         ' it sets maximized status
276.                         Windows(a).WIDTH = _WIDTH
277.                         Windows(a).Height = _HEIGHT
278.                         Windows(a).X = 1
279.                         Windows(a).Y = 1
280.                         ' change status
281.                         Windows(a).Status = Maxim
282.                     END IF
283.  
284.                 CASE cClosed
285.                     ' here minimize the child window to its window bar
286.                     IF NOT Windows(a).Status > Closed THEN
287.                         Windows(a).Status = Windows(a).Status + Closed
288.                     END IF
289.  
290.                 CASE Dragging
291.                     ' dragging is possible for all status of windows
292.                     '
293.                     ' if minimized or Closed and minimized window we save data info
294.                     IF Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim THEN AdjournWin a
295.                     ' it sets variables for dragging
296.                     OldW(0).X = Windows(a).X
297.                     OldW(0).Y = Windows(a).Y
298.                     OldW(0).WIDTH = Windows(a).WIDTH
299.                     OldW(0).Height = Windows(a).Height
300.  
301.                     OmX = _MOUSEX - OldW(0).X
302.                     OmY = _MOUSEY - OldW(0).Y
303.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
304.                     DO WHILE _MOUSEBUTTON(1)
305.                         IF _MOUSEINPUT THEN
306.                             CLS , Orange
307.  
308.                             OldW(0).X = (_MOUSEX - OmX)
309.                             OldW(0).Y = (_MOUSEY - OmY)
310.                             DrawAllWin
311.                             dragWindow OldW(0)
312.                         END IF
313.                     LOOP
314.                     ' new position of window
315.                     Windows(a).X = OldW(0).X
316.                     Windows(a).Y = OldW(0).Y
317.                     OldW(a).X = Windows(a).X
318.                     OldW(a).Y = Windows(a).Y
319.  
320.                 CASE Focusing
321.                     Focus a
322.  
323.                 CASE cResize
324.                     ' resizing is possible only for minimized opened child windows
325.                     IF Windows(a).Status = Minim THEN
326.                         Windows(a).Status = cResize
327.                         DO WHILE _MOUSEBUTTON(1) OR _MOUSEINPUT: LOOP
328.                         DO WHILE Windows(a).Status = cResize
329.                             CLS , Orange
330.                             DrawAllWin
331.                             ShowDimension Windows(a), 0
332.  
333.  
334.                             IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN
335.                                 DO WHILE _MOUSEINPUT: LOOP ' clear mouse buffer
336.                                 IsResizing Windows(a), _MOUSEX, _MOUSEY
337.                             END IF
338.                             _DISPLAY
339.                         LOOP
340.                     END IF
341.  
342.             END SELECT
343.         CASE ELSE
344.     END SELECT
345. END SUB
346.  
347. SUB IsResizing (Win AS wChild, mX AS INTEGER, mY AS INTEGER)
348.     SHARED Windows() AS wChild, OldW() AS wChild
349.     DIM Actio AS INTEGER, OldmX AS INTEGER, OldmY AS INTEGER
350.     Actio = 0
351.  
352.     IF IsInTheRange%(mX, Win.X, Win.X + Win.WIDTH) THEN
353.         IF IsInTheRange%(mY, Win.Y, Win.Y + Win.Height) THEN
354.             ' do nothing if is in the range of window
355.         ELSE
356.             ' user click out of area  of window to resize
357.             Actio = StopResize
358.         END IF
359.     ELSE
360.         ' user click out of area  of window to resize
361.         Actio = StopResize
362.     END IF
363.  
364.  
365.  
366.  
367.  
368.     IF IsInTheRange%(mX, Win.X, Win.X + 10) THEN
369.         IF IsInTheRange%(mY, Win.Y, Win.Y + 10) THEN
370.             ' user click on lefttop square to resize
371.             Actio = LResize
372.         END IF
373.     END IF
374.  
375.     IF IsInTheRange%(mX, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
376.         IF IsInTheRange%(mY, Win.Y + Win.Height - 10, Win.Y + Win.Height) THEN
377.             ' user click on the rightbottom square to resize
378.             Actio = RResize
379.         END IF
380.     END IF
381.  
382.     IF Actio = 0 THEN
383.         ' no action done
384.     ELSEIF Actio = LResize THEN
385.         ' choosen LeftTop buttom to resize
386.         OldW(0).X = Win.X
387.         OldW(0).Y = Win.Y
388.         OldW(0).WIDTH = Win.WIDTH
389.         OldW(0).Height = Win.Height
390.         OldmX = _MOUSEX
391.         OldmY = _MOUSEY
392.         DO WHILE Actio = LResize
393.             IF _MOUSEINPUT THEN
394.                 IF (OldW(0).X + OldW(0).WIDTH - OldmX) >= 50 THEN OldW(0).WIDTH = OldW(0).X + OldW(0).WIDTH - OldmX
395.                 IF (OldW(0).Y + OldW(0).Height - OldmY) >= 30 THEN OldW(0).Height = OldW(0).Y + OldW(0).Height - OldmY
396.                 CLS , Orange
397.                 DrawAllWin
398.                 ShowDimension OldW(0), Actio
399.                 OldW(0).X = OldmX
400.                 OldW(0).Y = OldmY
401.  
402.                 OldmX = _MOUSEX
403.                 OldmY = _MOUSEY
404.             ELSE
405.                 IF _MOUSEBUTTON(1) THEN Actio = 0
406.             END IF
407.         LOOP
408.         Win.X = OldW(0).X
409.         Win.Y = OldW(0).Y
410.         Win.WIDTH = OldW(0).WIDTH
411.         Win.Height = OldW(0).Height
412.  
413.  
414.     ELSEIF Actio = RResize THEN
415.         ' choosen bottomright square
416.         OldW(0).X = Win.X
417.         OldW(0).Y = Win.Y
418.         OldW(0).WIDTH = Win.WIDTH
419.         OldW(0).Height = Win.Height
420.         OldmX = _MOUSEX
421.         OldmY = _MOUSEY
422.         DO WHILE Actio = RResize
423.             IF _MOUSEINPUT THEN
424.                 IF OldmX - OldW(0).X >= 50 THEN OldW(0).WIDTH = OldmX - OldW(0).X
425.                 IF OldmY - OldW(0).Y >= 30 THEN OldW(0).Height = OldmY - OldW(0).Y
426.                 CLS , Orange
427.                 DrawAllWin
428.                 ShowDimension OldW(0), Actio
429.                 OldmX = _MOUSEX
430.                 OldmY = _MOUSEY
431.             ELSE
432.                 IF _MOUSEBUTTON(1) THEN Actio = 0
433.             END IF
434.         LOOP
435.         Win.X = OldW(0).X
436.         Win.Y = OldW(0).Y
437.         Win.WIDTH = OldW(0).WIDTH
438.         Win.Height = OldW(0).Height
439.  
440.     ELSEIF Actio = StopResize THEN
441.         ' click out of window to stop resize action
442.         Win.Status = Minim
443.     END IF
444. END SUB
445.  
446. SUB ShowDimension (win AS wChild, Actio AS INTEGER)
447.     IF win.Status = cResize AND Actio = 0 THEN
448.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B ' windows size
449.     ELSEIF Actio = LResize THEN
450.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 45 ' windows size
451.     ELSEIF Actio = RResize THEN
452.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 200 ' windows size
453.     END IF
454.     LINE (win.X, win.Y)-(win.X + 10, win.Y + 10), White, BF 'button for resizing window
455.     LINE (win.X + win.WIDTH - 10, win.Y + win.Height - 10)-(win.X + win.WIDTH, win.Y + win.Height), White, BF 'button for resizing window
456.     _DISPLAY
457. END SUB
458.  
459. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
460.     IsInWindow = mFalse
461.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
462.         ' if window is closed to its bar it cannot get focus on the window area
463.         IF IsInTheRange%(X, Win.X, Win.X + Win.WIDTH) AND (Win.Status < Closed) THEN IsInWindow = Focusing
464.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
465.         ' if is the window bar area
466.         IF IsInTheRange%(X, Win.X + 10, Win.X + Win.WIDTH - 31) THEN
467.             ' if it is to the left of buttons on the bar
468.             IsInWindow = Dragging
469.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 30, Win.X + Win.WIDTH - 21) THEN
470.             ' if it is on the leftest button on the bar
471.             IsInWindow = cMinim ' icon minimize--> restore to child default
472.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 20, Win.X + Win.WIDTH - 11) THEN
473.             ' if it is on the middle button on the bar
474.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
475.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
476.             ' if is on the rightest button on the bar
477.             IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
478.         ELSEIF IsInTheRange%(X, Win.X, Win.X + 10) THEN
479.             IsInWindow = cResize
480.         END IF
481.     END IF
482. END FUNCTION
483.  
484. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
485.     IF Min > Max THEN SWAP Min, Max
486.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
487. END FUNCTION
488.  
489. SUB dragWindow (Win AS wChild)
490.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), White, B ' windows size
491.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), White, BF 'title bar for dragging window
492.     _DISPLAY
493. END SUB
494.  
495. SUB wClosed (Win AS wChild)
496.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
497.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Black, B
498.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 3)-(Win.X + Win.WIDTH - 3, Win.Y + 7), Black
499.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 7)-(Win.X + Win.WIDTH - 3, Win.Y + 3), Black
500. END SUB
501.  
502. SUB wMaxim (win AS wChild)
503.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Pink, BF 'title bar for restore to original dimensions
504.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Black, B
505.     LINE (win.X + win.WIDTH - 17, win.Y + 3)-(win.X + win.WIDTH - 13, win.Y + 7), Black, B
506. END SUB
507.  
508. SUB wMinim (Win AS wChild)
509.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
510.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Black, B
511.     LINE (Win.X + Win.WIDTH - 27, Win.Y + 7)-(Win.X + Win.WIDTH - 23, Win.Y + 7), Black
512. END SUB
513.  
514. SUB wResize (Win AS wChild)
515.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
516.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Black, B
517.     LINE (Win.X + 2, Win.Y + 2)-(Win.X + 7, Win.Y + 7), Black, B , &B1010101010101010
518. END SUB
519.  
520. SUB DrawWindow (Win AS wChild)
521.     ' the window
522.     IF Win.Status = Minim OR Win.Status = Maxim THEN
523.         LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Win.COLOR, BF
524.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
525.         LINE (Win.X + Win.WIDTH, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
526.     END IF
527.     ' the status bar
528.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF 'title bar for dragging window
529.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.WIDTH, Win.Y + 10), Black
530.     wMinim Win
531.     wMaxim Win
532.     wClosed Win
533.     wResize Win
534. END SUB
535.  
536. SUB GetInput (Act AS INTEGER)
537.     DIM mInput AS INTEGER
538.  
539.  
540.     ' keyboard input
541.     a$ = INKEY$
542.     IF a$ = CHR$(27) THEN Act = aQuit
543.  
544.     'mouse input
545.     mInput = mFalse
546.     IF _MOUSEINPUT THEN mInput = mTrue
547.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
548.     LOOP
549.     IF mInput THEN
550.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
551.             mInput = mLR
552.         ELSEIF _MOUSEBUTTON(1) THEN
553.             mInput = mLeft
554.         ELSEIF _MOUSEBUTTON(2) THEN
555.             mInput = mRight
556.         ELSEIF _MOUSEBUTTON(3) THEN
557.             mInput = mMiddle
558.         END IF
559.     END IF
560.  
561.     IF mInput = mLR THEN
562.         Act = aQuit
563.     ELSEIF mInput = mMiddle THEN
564.         Act = Minim
565.     ELSEIF mInput = mRight THEN
566.         Act = Maxim
567.     ELSEIF mInput = mLeft THEN
568.         Act = mInput
569.     END IF
570. END SUB
571.  

Now the border of the big white square (the shadow of the window in resizing) is different if  no click on resizing squares, or left mouse button on left square or on right square.
Waiting your and others feedback
Thanks for time and energy spent

Title: Re: child windows into window of the program: a demonstration
Post by: keybone on February 17, 2020, 05:48:44 am

Quote from: TempodiBasic on February 15, 2020, 11:50:33 am

Ok we must define what is that makes the difference between our experience with this code.

To be sure I have taken the code from codebox (so it is the same that you have )
I have compiled it both by QB1.4 both by QB1.3 and I get the same program that works...
I'm using QB64 in Windows 10

.... to give a different feedback  when resizing is active I have made this little mod for output.

Code: QB64: [Select]

1. ' Question of QB64Forum
2. ' Basically I want to write a program to input data, store the data,  <-- this is DATABASE
3. ' retrieve the data, add to it, etc.
4. ' I would like the ability to have a new window/app, run concurrently <-- this is a graphic plotter
5. ' with the main window/app, but be able to display/plot the data
6. ' I retrieved from the main window/app.
7.  
8. ' 2020 02 12  with the power of the second array we implement the feature
9. '             of resizable of child window
10.  
11. ' 2020 02 09  with the power of the second array we implement a different
12. '             child windows' system:
13. '             all child windows can be Closed to window's bar
14. '             all child windows can be dragged on the screen
15.  
16. ' 2020 02 08  using a second array we store windows information indipendently so
17. '             now each window can be modified and restored
18.  
19.  
20. ' 2020 02 06  after dragging or maximize a window, restoring it we gives
21. '             to it the last value used in windows(0) so the info of the last
22. '             window that is dragged or maximize when we use Minimize button on
23. '             another child window
24. '             the fix can be got using a shadow array that stores windows informations
25. '             or windows(0) as the child window that takes the information of the
26. '             child window that must be acted (Minimize, Maximize and Closed)
27. '             and we use it as template to make graphic output
28.  
29. ' 2020 02 05 fixed a minor bug on mouse click events
30. '            activated events Maxim Minim and Closed
31.  
32.  
33. ' 2020 02 03 increasing the windows managed and close initialization to SUB
34. '            removed vMax SHARED variable
35. '            added 3 buttons on the rightest site of the bar of the child window
36. '            SUB wClosed, wMaxim, wMinim
37. '            In this version the user can maximize one child window to the application window
38. '            In the status of Maxim the child window has the focus and can be only
39. '            reduced to status Minim, it cannot be dragging or Closed to bar of window
40.  
41.  
42. ' 2020 01 30 fixed bug on focusing a child window
43. '
44.  
45. ' 2020 01 25  A program with child windows into it
46. ' we need a system to manage multiple windows
47. ' and a system to manage input/output
48. ' and a system to make graphic report
49.  
50. ' settings-------------------------------------------------------
51. SCREEN _NEWIMAGE(800, 600, 32)
52. _TITLE "Child windows"
53. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
54. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
55. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
56. CONST Minim = 10, Maxim = 20, Closed = 100
57. CONST wMin = 5, aNull = 0, aQuit = 9999
58. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
59. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
60. CONST cResize = 700, LResize = 710, RResize = 720, StopResize = 730
61.  
62. _FULLSCREEN
63.  
64.  
65. 'dataset  -----------------------------------------------
66. TYPE person
67.     NAME AS STRING * 10
68.     age AS INTEGER
69.     weight AS INTEGER
70.     height AS INTEGER
71.     BMI AS INTEGER
72. END TYPE
73.  
74. TYPE wChild
75.     X AS INTEGER
76.     Y AS INTEGER
77.     WIDTH AS INTEGER
78.     Height AS INTEGER
79.     Zorder AS INTEGER
80.     Status AS INTEGER
81.     COLOR AS _UNSIGNED LONG
82. END TYPE
83.  
84. REDIM Windows(1 TO wMin) AS wChild, OldW(0 TO wMin) AS wChild
85.  
86. InitWin
87.  
88. DIM Action AS INTEGER
89.  
90.  
91. ' main loop -----------------------------------------------
92.  
93. DO
94.     ' set the main window
95.     Action = aNull
96.     CLS , Orange
97.     DrawAllWin
98.     GetInput Action
99.     DoAction Action
100.     _DISPLAY
101.     _LIMIT 30
102. LOOP
103. END
104.  
105. ' SUBs and FUNCTIONs --------------------------------------
106. SUB InitWin
107.     SHARED Windows() AS wChild, OldW() AS wChild
108.     DIM a AS INTEGER
109.  
110.     Windows(1).X = 1
111.     Windows(1).Y = 1
112.     Windows(1).WIDTH = 300
113.     Windows(1).Height = 400
114.     Windows(1).Zorder = 1
115.     Windows(1).Status = Minim
116.     Windows(1).COLOR = Blu
117.  
118.     Windows(2).X = 100
119.     Windows(2).Y = 1
120.     Windows(2).WIDTH = 300
121.     Windows(2).Height = 400
122.     Windows(2).Zorder = 2
123.     Windows(2).Status = Minim
124.     Windows(2).COLOR = Yellow
125.  
126.     Windows(3).X = 200
127.     Windows(3).Y = 1
128.     Windows(3).WIDTH = 300
129.     Windows(3).Height = 400
130.     Windows(3).Zorder = 3
131.     Windows(3).Status = Minim
132.     Windows(3).COLOR = Green
133.  
134.     Windows(4).X = 300
135.     Windows(4).Y = 1
136.     Windows(4).WIDTH = 300
137.     Windows(4).Height = 400
138.     Windows(4).Zorder = 4
139.     Windows(4).Status = Minim
140.     Windows(4).COLOR = Red
141.  
142.     Windows(5).X = 400
143.     Windows(5).Y = 1
144.     Windows(5).WIDTH = 300
145.     Windows(5).Height = 400
146.     Windows(5).Zorder = 5
147.     Windows(5).Status = Minim
148.     Windows(5).COLOR = Cyan
149.  
150.     FOR a = 1 TO wMin STEP 1
151.         AdjournWin a
152.     NEXT a
153. END SUB
154.  
155. SUB RestoreWin (a AS INTEGER)
156.     SHARED Windows() AS wChild, OldW() AS wChild
157.  
158.     Windows(a).X = OldW(a).X
159.     Windows(a).Y = OldW(a).Y
160.     Windows(a).WIDTH = OldW(a).WIDTH
161.     Windows(a).Height = OldW(a).Height
162.     Windows(a).Zorder = OldW(a).Zorder
163.     Windows(a).COLOR = OldW(a).COLOR
164. END SUB
165.  
166. SUB AdjournWin (a AS INTEGER)
167.     SHARED Windows() AS wChild, OldW() AS wChild
168.  
169.     OldW(a).X = Windows(a).X
170.     OldW(a).Y = Windows(a).Y
171.     OldW(a).WIDTH = Windows(a).WIDTH
172.     OldW(a).Height = Windows(a).Height
173.     OldW(a).Zorder = Windows(a).Zorder
174.     OldW(a).COLOR = Windows(a).COLOR
175. END SUB
176.  
177. SUB DrawAllWin
178.     SHARED Windows() AS wChild
179.     DIM Finished AS INTEGER
180.     Finished = wMin
181.     DO
182.         FOR a = 1 TO wMin
183.             IF Windows(a).Zorder = Finished THEN
184.                 DrawWindow Windows(a)
185.                 Finished = Finished - 1
186.                 EXIT FOR
187.             END IF
188.         NEXT a
189.     LOOP UNTIL Finished = 0
190. END SUB
191.  
192. SUB Focus (Index AS INTEGER)
193.     SHARED Windows() AS wChild
194.     DIM b AS INTEGER
195.     FOR b = 1 TO wMin
196.         IF Windows(b).Zorder = 1 THEN EXIT FOR
197.     NEXT b
198.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
199.     DrawAllWin
200. END SUB
201.  
202.  
203. SUB DoAction (Act AS INTEGER)
204.     SHARED Windows() AS wChild, OldW() AS wChild
205.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
206.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
207.  
208.     SELECT CASE Act
209.         CASE aQuit
210.             END
211.  
212.         CASE Maxim
213.             _FULLSCREEN
214.  
215.         CASE Minim
216.             _FULLSCREEN _OFF
217.  
218.         CASE mLeft
219.             mX = _MOUSEX
220.             mY = _MOUSEY
221.  
222.             ' search where and what mouse has touched by leftclick
223.             OldA = 0
224.             OldActio = 0
225.             FOR a = 1 TO wMin ' windows(0) is out of action
226.                 Actio = IsInWindow(mX, mY, Windows(a))
227.                 IF Actio THEN
228.                     IF OldA <= 0 THEN
229.                         OldA = a
230.                         OldActio = Actio
231.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN
232.                         OldA = a
233.                         OldActio = Actio
234.                     END IF
235.                 END IF
236.             NEXT a
237.             IF a > OldA THEN
238.                 a = OldA ' restore the last windows interacting
239.                 Actio = OldActio
240.             END IF
241.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB
242.  
243.  
244.             Focus a 'set zorder on the (a) window that gets the input
245.  
246.  
247.             SELECT CASE Actio
248.                 CASE cMinim
249.                     ' here restore to  standard (bar + area of window) status of child window
250.                     IF Windows(a).Status = Closed + Maxim THEN
251.                         ' if windows is a closed maximized window
252.                         ' we restore its status of maximized
253.                         Windows(a).Status = Maxim
254.                     ELSEIF Windows(a).Status = Closed + Minim THEN
255.                         ' if windows is a closed minimized window
256.                         ' we restore its status of minimized
257.                         Windows(a).Status = Minim
258.                     ELSEIF Windows(a).Status = Maxim THEN
259.                         ' if is a window maximized it gets back all info setting
260.                         ' we restore its status of minimized
261.                         RestoreWin a
262.                         Windows(a).Status = Minim
263.                     END IF
264.  
265.  
266.                 CASE cMaxim
267.                     ' here convert the window to full size of main window of the program
268.                     ' OR gives 1 if both parameter are true or al last one is true
269.                     IF (Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim) THEN
270.                         ' it acts if windows if not still maximized
271.                         ' it is minimized window opened or closed
272.                         ' memorize window's data when it is not maximized
273.                         '                        IF Windows(a).Width < _WIDTH THEN
274.                         AdjournWin a
275.                         ' it sets maximized status
276.                         Windows(a).WIDTH = _WIDTH
277.                         Windows(a).Height = _HEIGHT
278.                         Windows(a).X = 1
279.                         Windows(a).Y = 1
280.                         ' change status
281.                         Windows(a).Status = Maxim
282.                     END IF
283.  
284.                 CASE cClosed
285.                     ' here minimize the child window to its window bar
286.                     IF NOT Windows(a).Status > Closed THEN
287.                         Windows(a).Status = Windows(a).Status + Closed
288.                     END IF
289.  
290.                 CASE Dragging
291.                     ' dragging is possible for all status of windows
292.                     '
293.                     ' if minimized or Closed and minimized window we save data info
294.                     IF Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim THEN AdjournWin a
295.                     ' it sets variables for dragging
296.                     OldW(0).X = Windows(a).X
297.                     OldW(0).Y = Windows(a).Y
298.                     OldW(0).WIDTH = Windows(a).WIDTH
299.                     OldW(0).Height = Windows(a).Height
300.  
301.                     OmX = _MOUSEX - OldW(0).X
302.                     OmY = _MOUSEY - OldW(0).Y
303.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
304.                     DO WHILE _MOUSEBUTTON(1)
305.                         IF _MOUSEINPUT THEN
306.                             CLS , Orange
307.  
308.                             OldW(0).X = (_MOUSEX - OmX)
309.                             OldW(0).Y = (_MOUSEY - OmY)
310.                             DrawAllWin
311.                             dragWindow OldW(0)
312.                         END IF
313.                     LOOP
314.                     ' new position of window
315.                     Windows(a).X = OldW(0).X
316.                     Windows(a).Y = OldW(0).Y
317.                     OldW(a).X = Windows(a).X
318.                     OldW(a).Y = Windows(a).Y
319.  
320.                 CASE Focusing
321.                     Focus a
322.  
323.                 CASE cResize
324.                     ' resizing is possible only for minimized opened child windows
325.                     IF Windows(a).Status = Minim THEN
326.                         Windows(a).Status = cResize
327.                         DO WHILE _MOUSEBUTTON(1) OR _MOUSEINPUT: LOOP
328.                         DO WHILE Windows(a).Status = cResize
329.                             CLS , Orange
330.                             DrawAllWin
331.                             ShowDimension Windows(a), 0
332.  
333.  
334.                             IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN
335.                                 DO WHILE _MOUSEINPUT: LOOP ' clear mouse buffer
336.                                 IsResizing Windows(a), _MOUSEX, _MOUSEY
337.                             END IF
338.                             _DISPLAY
339.                         LOOP
340.                     END IF
341.  
342.             END SELECT
343.         CASE ELSE
344.     END SELECT
345. END SUB
346.  
347. SUB IsResizing (Win AS wChild, mX AS INTEGER, mY AS INTEGER)
348.     SHARED Windows() AS wChild, OldW() AS wChild
349.     DIM Actio AS INTEGER, OldmX AS INTEGER, OldmY AS INTEGER
350.     Actio = 0
351.  
352.     IF IsInTheRange%(mX, Win.X, Win.X + Win.WIDTH) THEN
353.         IF IsInTheRange%(mY, Win.Y, Win.Y + Win.Height) THEN
354.             ' do nothing if is in the range of window
355.         ELSE
356.             ' user click out of area  of window to resize
357.             Actio = StopResize
358.         END IF
359.     ELSE
360.         ' user click out of area  of window to resize
361.         Actio = StopResize
362.     END IF
363.  
364.  
365.  
366.  
367.  
368.     IF IsInTheRange%(mX, Win.X, Win.X + 10) THEN
369.         IF IsInTheRange%(mY, Win.Y, Win.Y + 10) THEN
370.             ' user click on lefttop square to resize
371.             Actio = LResize
372.         END IF
373.     END IF
374.  
375.     IF IsInTheRange%(mX, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
376.         IF IsInTheRange%(mY, Win.Y + Win.Height - 10, Win.Y + Win.Height) THEN
377.             ' user click on the rightbottom square to resize
378.             Actio = RResize
379.         END IF
380.     END IF
381.  
382.     IF Actio = 0 THEN
383.         ' no action done
384.     ELSEIF Actio = LResize THEN
385.         ' choosen LeftTop buttom to resize
386.         OldW(0).X = Win.X
387.         OldW(0).Y = Win.Y
388.         OldW(0).WIDTH = Win.WIDTH
389.         OldW(0).Height = Win.Height
390.         OldmX = _MOUSEX
391.         OldmY = _MOUSEY
392.         DO WHILE Actio = LResize
393.             IF _MOUSEINPUT THEN
394.                 IF (OldW(0).X + OldW(0).WIDTH - OldmX) >= 50 THEN OldW(0).WIDTH = OldW(0).X + OldW(0).WIDTH - OldmX
395.                 IF (OldW(0).Y + OldW(0).Height - OldmY) >= 30 THEN OldW(0).Height = OldW(0).Y + OldW(0).Height - OldmY
396.                 CLS , Orange
397.                 DrawAllWin
398.                 ShowDimension OldW(0), Actio
399.                 OldW(0).X = OldmX
400.                 OldW(0).Y = OldmY
401.  
402.                 OldmX = _MOUSEX
403.                 OldmY = _MOUSEY
404.             ELSE
405.                 IF _MOUSEBUTTON(1) THEN Actio = 0
406.             END IF
407.         LOOP
408.         Win.X = OldW(0).X
409.         Win.Y = OldW(0).Y
410.         Win.WIDTH = OldW(0).WIDTH
411.         Win.Height = OldW(0).Height
412.  
413.  
414.     ELSEIF Actio = RResize THEN
415.         ' choosen bottomright square
416.         OldW(0).X = Win.X
417.         OldW(0).Y = Win.Y
418.         OldW(0).WIDTH = Win.WIDTH
419.         OldW(0).Height = Win.Height
420.         OldmX = _MOUSEX
421.         OldmY = _MOUSEY
422.         DO WHILE Actio = RResize
423.             IF _MOUSEINPUT THEN
424.                 IF OldmX - OldW(0).X >= 50 THEN OldW(0).WIDTH = OldmX - OldW(0).X
425.                 IF OldmY - OldW(0).Y >= 30 THEN OldW(0).Height = OldmY - OldW(0).Y
426.                 CLS , Orange
427.                 DrawAllWin
428.                 ShowDimension OldW(0), Actio
429.                 OldmX = _MOUSEX
430.                 OldmY = _MOUSEY
431.             ELSE
432.                 IF _MOUSEBUTTON(1) THEN Actio = 0
433.             END IF
434.         LOOP
435.         Win.X = OldW(0).X
436.         Win.Y = OldW(0).Y
437.         Win.WIDTH = OldW(0).WIDTH
438.         Win.Height = OldW(0).Height
439.  
440.     ELSEIF Actio = StopResize THEN
441.         ' click out of window to stop resize action
442.         Win.Status = Minim
443.     END IF
444. END SUB
445.  
446. SUB ShowDimension (win AS wChild, Actio AS INTEGER)
447.     IF win.Status = cResize AND Actio = 0 THEN
448.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B ' windows size
449.     ELSEIF Actio = LResize THEN
450.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 45 ' windows size
451.     ELSEIF Actio = RResize THEN
452.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 200 ' windows size
453.     END IF
454.     LINE (win.X, win.Y)-(win.X + 10, win.Y + 10), White, BF 'button for resizing window
455.     LINE (win.X + win.WIDTH - 10, win.Y + win.Height - 10)-(win.X + win.WIDTH, win.Y + win.Height), White, BF 'button for resizing window
456.     _DISPLAY
457. END SUB
458.  
459. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild)
460.     IsInWindow = mFalse
461.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
462.         ' if window is closed to its bar it cannot get focus on the window area
463.         IF IsInTheRange%(X, Win.X, Win.X + Win.WIDTH) AND (Win.Status < Closed) THEN IsInWindow = Focusing
464.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
465.         ' if is the window bar area
466.         IF IsInTheRange%(X, Win.X + 10, Win.X + Win.WIDTH - 31) THEN
467.             ' if it is to the left of buttons on the bar
468.             IsInWindow = Dragging
469.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 30, Win.X + Win.WIDTH - 21) THEN
470.             ' if it is on the leftest button on the bar
471.             IsInWindow = cMinim ' icon minimize--> restore to child default
472.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 20, Win.X + Win.WIDTH - 11) THEN
473.             ' if it is on the middle button on the bar
474.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
475.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
476.             ' if is on the rightest button on the bar
477.             IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
478.         ELSEIF IsInTheRange%(X, Win.X, Win.X + 10) THEN
479.             IsInWindow = cResize
480.         END IF
481.     END IF
482. END FUNCTION
483.  
484. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
485.     IF Min > Max THEN SWAP Min, Max
486.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
487. END FUNCTION
488.  
489. SUB dragWindow (Win AS wChild)
490.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), White, B ' windows size
491.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), White, BF 'title bar for dragging window
492.     _DISPLAY
493. END SUB
494.  
495. SUB wClosed (Win AS wChild)
496.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
497.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Black, B
498.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 3)-(Win.X + Win.WIDTH - 3, Win.Y + 7), Black
499.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 7)-(Win.X + Win.WIDTH - 3, Win.Y + 3), Black
500. END SUB
501.  
502. SUB wMaxim (win AS wChild)
503.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Pink, BF 'title bar for restore to original dimensions
504.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Black, B
505.     LINE (win.X + win.WIDTH - 17, win.Y + 3)-(win.X + win.WIDTH - 13, win.Y + 7), Black, B
506. END SUB
507.  
508. SUB wMinim (Win AS wChild)
509.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
510.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Black, B
511.     LINE (Win.X + Win.WIDTH - 27, Win.Y + 7)-(Win.X + Win.WIDTH - 23, Win.Y + 7), Black
512. END SUB
513.  
514. SUB wResize (Win AS wChild)
515.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Pink, BF 'title bar for restore to original dimensions
516.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Black, B
517.     LINE (Win.X + 2, Win.Y + 2)-(Win.X + 7, Win.Y + 7), Black, B , &B1010101010101010
518. END SUB
519.  
520. SUB DrawWindow (Win AS wChild)
521.     ' the window
522.     IF Win.Status = Minim OR Win.Status = Maxim THEN
523.         LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Win.COLOR, BF
524.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
525.         LINE (Win.X + Win.WIDTH, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
526.     END IF
527.     ' the status bar
528.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF 'title bar for dragging window
529.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.WIDTH, Win.Y + 10), Black
530.     wMinim Win
531.     wMaxim Win
532.     wClosed Win
533.     wResize Win
534. END SUB
535.  
536. SUB GetInput (Act AS INTEGER)
537.     DIM mInput AS INTEGER
538.  
539.  
540.     ' keyboard input
541.     a$ = INKEY$
542.     IF a$ = CHR$(27) THEN Act = aQuit
543.  
544.     'mouse input
545.     mInput = mFalse
546.     IF _MOUSEINPUT THEN mInput = mTrue
547.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
548.     LOOP
549.     IF mInput THEN
550.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
551.             mInput = mLR
552.         ELSEIF _MOUSEBUTTON(1) THEN
553.             mInput = mLeft
554.         ELSEIF _MOUSEBUTTON(2) THEN
555.             mInput = mRight
556.         ELSEIF _MOUSEBUTTON(3) THEN
557.             mInput = mMiddle
558.         END IF
559.     END IF
560.  
561.     IF mInput = mLR THEN
562.         Act = aQuit
563.     ELSEIF mInput = mMiddle THEN
564.         Act = Minim
565.     ELSEIF mInput = mRight THEN
566.         Act = Maxim
567.     ELSEIF mInput = mLeft THEN
568.         Act = mInput
569.     END IF
570. END SUB
571.  

Now the border of the big white square (the shadow of the window in resizing) is different if  no click on resizing squares, or left mouse button on left square or on right square.
Waiting your and others feedback
Thanks for time and energy spent

I tried it on version 1.3 and 1.4 and same result. It compiles fine and everything works except for the resizing.
Im using Linux to compile, i dont have a windows machine to test on. Who knows, maybe im just doing it wrong.

Title: Re: child windows into window of the program: a demonstration
Post by: Dimster on February 17, 2020, 09:20:40 am

Hi Tempodi ..what a great way to display multiple windows. Thanks for this. I have a lot of different menu options for the program I have been messing with and my program is very large. Is there a limit to the data each window can display? For example, I can display a lot more in 1000,800,32 than I can in 500,250,32. Also can each window have it's own size (like 750,250,32 & 1000,750,500,32 & 1600,800,32 etc.) or do they all need to be the same size? And lastly, when a window is resized, does the data in the window automatically resize?

I realize I should just try it all out myself and learn something but it's just so time consuming to do it only to find out "you can't do that". I'm into the instant gratification this digital world is providing rather that the "live and learn by trial and error" of last year.

Title: Re: child windows into window of the program: a demonstration
Post by: bplus on February 17, 2020, 11:54:55 am

Hi TempodiBasic,

Feedback from Win 10-64: I am also having troubles with response when I click white square, rarely does the outline of window come up for me to resize it.

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 19, 2020, 09:58:58 am

@Keybone
I'll try to run my demo app in Ubuntu in VirtualMachine , see later

@Bplus
please tell me, after you have done a left click on the resize button on the bar of window, have you no response after a single left click on both the little white boxes or only with one?
In my experience there is sometimes a latency of response of a second but I have no found the reason for now.

@Dimster
Thanks for kind words.
It is an application demonstration to use child window into the main window like it did Windows 3.1!

The application for now uses only a minimum limit to the dimension of a window opened (showed) but the size possible is ranging from minimum set to main window of program.

For now there is no routines to show data or graphics into each child window, for me it is a work in progress as I gain more time to use for this I'll go on. However I remember 4-5 routines-demonstrations posted by clever QB64 coders to show text and graphic in size and resizable area of the screen.
 
About the amount of data the limiti is the output routine and the RAM of PC.

Thans to all for feedbacks

Title: Re: child windows into window of the program: a demonstration
Post by: bplus on February 19, 2020, 10:27:28 am

Quote

@Bplus
please tell me, after you have done a left click on the resize button on the bar of window, have you no response after a single left click on both the little white boxes or only with one?
In my experience there is sometimes a latency of response of a second but I have no found the reason for now.

After I click the right top corner, the two white boxes come up reliably, but when I click either white box it seems totally random whether they decide to do the white outline for resizing. Sometimes it works right off (either white box) sometimes I click and click and click... nothing happens. The resizing, once the outlines are showing, also seems to work reliably.

Title: Re: child windows into window of the program: a demonstration
Post by: TerryRitchie on February 19, 2020, 02:57:06 pm

I was tinkering around with GUI structures a few years back. Here is the code. It may give you some ideas for your code. You can resize the windows by clicking and holding the bottom right corner of the window, just like Windows.

Code: QB64: [Select]

1. 'GUI 02/27/16
2.  
3. CONST BYWINDOW = 0
4. CONST BYSCREEN = -1
5. CONST ALLWINDOWS = 0
6.  
7. TYPE MOUSEFLAGS
8.     OnWindow AS INTEGER '              current window pointer is hovering over
9.     Icon AS INTEGER '                  current mouse pointer icon
10.     X AS INTEGER '                     current desktop mouse x coordinate
11.     Y AS INTEGER '                     current desktop mouse y coordinate
12.     PX AS INTEGER '                    previous desktop mouse x coordinate
13.     PY AS INTEGER '                    previous desktop mouse y coordinate
14.     WindowX AS INTEGER '               current window mouse x coordinate
15.     WindowY AS INTEGER '               current window mouse y coordinate
16.     SurfaceX AS INTEGER '              current work space mouse x coordinate
17.     SurfaceY AS INTEGER '              current work space mouse y coordinate
18.     OnSurface AS INTEGER '      [BOOL] mouse currently hovering over surface?
19.     OnTitlebar AS INTEGER '     [BOOL] mouse currently hovering over title bar?
20.     OnBorder AS INTEGER '       [BOOL] mouse currently hovering over a border?
21.     Border AS INTEGER '                border(s) mouse hovering (1-top, 2-right, 4-bottom, 8-left ... i.e. 6 = bottom right corner)
22.     LeftClick AS INTEGER '      [BOOL] mouse left button currently pressed?
23.     RightClick AS INTEGER '     [BOOL] mouse right button currently pressed?
24.     Move AS INTEGER '                  window currently in the process of being moved
25.     Resize AS INTEGER '                current window being resized
26.     LeftReleased AS INTEGER '   [BOOL] left mouse button released?
27.     RightReleased AS INTEGER '  [BOOL] right mouse button released?
28.  
29.     OnButton AS INTEGER '              current button pointer is hovering over
30.     ButtonPressed AS INTEGER '         current button being held down
31.     ButtonClicked AS INTEGER '         button that was clicked then released
32.  
33.  
34. END TYPE
35.  
36. TYPE WINDOWFLAGS
37.     X AS INTEGER '                     x location of current window
38.     Y AS INTEGER '                     y location of current window
39.     Width AS INTEGER '                 width of current window
40.     Height AS INTEGER '                height of current window
41.     Surface AS LONG '            [IMG]  window surface image
42.     SurfaceX AS INTEGER '              x location of current work space
43.     SurfaceY AS INTEGER '              y location of current workspace
44.     SWidth AS INTEGER '                width of current surface
45.     SHeight AS INTEGER '               height of current surface
46.     Focus AS INTEGER '                 the window that has focus
47.     HasFocus AS INTEGER '       [BOOL] current window has focus?
48. END TYPE
49.  
50. TYPE WIN
51.     Width AS INTEGER '                 overall window width
52.     Height AS INTEGER '                overall window height
53.  
54.     OWidth AS INTEGER '                original width
55.     OHeight AS INTEGER
56.  
57.     SWidth AS INTEGER '                surface width
58.     SHeight AS INTEGER '               surface height
59.  
60.     SIWidth AS INTEGER '               surface image width
61.     SIHeight AS INTEGER '              surface image height
62.  
63.     MinWidth AS INTEGER
64.     MaxWidth AS INTEGER
65.     MinHeight AS INTEGER
66.     MaxHeight AS INTEGER
67.  
68.  
69.     X AS INTEGER '                     window x location
70.     Y AS INTEGER '                     window y location
71.     SurfaceX AS INTEGER '              surface x location
72.     SurfaceY AS INTEGER '              surface y location
73.     Font AS LONG '              [FONT] window font
74.     InUse AS INTEGER '          [BOOL] window in use?
75.     Window AS LONG '            [IMG]  window image
76.     Surface AS LONG '           [IMG]  surface image
77.     BGImage AS LONG '           [IMG]  background image under window
78.     TBFImage AS LONG '          [IMG]  title bar image when window has focus
79.     TBNFImage AS LONG '         [IMG]  title bar image when window has lost focus
80.     Shadow AS INTEGER '         [BOOL] shadow present
81.     BWidth AS INTEGER '                border width
82.     TBHeight AS INTEGER '              title bar height
83.     WColor AS _UNSIGNED LONG '  [CLR]  window color
84.     Wred AS INTEGER '           [CLR]  red component of Wcolor
85.     Wgreen AS INTEGER '         [CLR]  green component of Wcolor
86.     Wblue AS INTEGER '          [CLR]  blue component of Wcolor
87.     TBColor AS _UNSIGNED LONG ' [CLR]  title bar color
88.     TTColor AS _UNSIGNED LONG ' [CLR]  title text color
89.     Title AS STRING * 128 '            window title
90.     Visible AS INTEGER '        [BOOL] window on screen?
91.     Focus AS INTEGER '          [BOOL] window has focus?
92.  
93.     'ByMethod AS INTEGER '       [BOOL] -1 = window dimensions by surface, 0 = dimensions by window
94.  
95.     Move AS INTEGER '           [BOOL] window currently being moved?
96.     Resize AS INTEGER '         [BOOL] window currently being resized
97.     Lighter AS _UNSIGNED LONG ' [CLR]  border colors
98.     Light AS _UNSIGNED LONG '   [CLR]
99.     Dark AS _UNSIGNED LONG '    [CLR]
100.     Darker AS _UNSIGNED LONG '  [CLR]
101.     Darkest AS _UNSIGNED LONG ' [CLR]
102.     Icon AS LONG '              [IMG]  window icon
103.     TBSolid AS INTEGER '        [BOOL] solid title bar?
104.     Size AS INTEGER '           [BOOL] window resizable?
105.  
106.     CloseButton AS INTEGER '           0 = no button, >0 = button handle number
107.     MaxButton AS INTEGER
108.     MinButton AS INTEGER
109.     RestoreButton AS INTEGER
110.     SUButton AS INTEGER
111.     SDButton AS INTEGER
112.     SLButton AS INTEGER
113.     SRButton AS INTEGER
114.  
115.     Maximized AS INTEGER '             -1 window currently maximized, 0 = normal  (use 'state' instead for max/min/normal?)
116.     Minimized AS INTEGER '             -1 window currently minimized
117.  
118.     Rwidth AS INTEGER '                restore width  (when max or min - values to restore window size)
119.     Rheight AS INTEGER '               restore height
120.  
121. END TYPE
122.  
123. TYPE BUTTON
124.     InUse AS INTEGER '          [BOOL] button in use?
125.     X AS INTEGER
126.     Y AS INTEGER
127.     Width AS INTEGER
128.     Height AS INTEGER
129.     State AS INTEGER '                 state of button: -1 = pressed, 0 = normal, 1 = disabled
130.     Normal AS LONG '            [IMG]  normal button
131.     Pressed AS LONG '           [IMG]  pressed button
132.     Disabled AS LONG '          [IMG]  disabled button
133.     Window AS INTEGER '                window button belongs to
134.     WinButton AS INTEGER '      [BOOL] indicates a button for window use only (scroll bar buttons, etc..)
135. END TYPE
136.  
137. TYPE MOUSEPOINTERS
138.     Icon AS LONG '              [IMG]  mouse pointer image
139.     X AS INTEGER '                     x offset of pointer
140.     Y AS INTEGER '                     y offset of pointer
141. END TYPE
142.  
143. REDIM WIN(1) AS WIN
144. REDIM BUT(1) AS BUTTON
145. REDIM WinOrder%(0)
146. DIM POINTER(15) AS MOUSEPOINTERS
147. DIM QB64Icon&
148. DIM WIN AS WINDOWFLAGS
149. DIM MOUSE AS MOUSEFLAGS
150.  
151. DIM DeskTop&
152.  
153. DIM untitled%(10)
154.  
155.  
156. POINTERS
157.  
158. WINDOW_DESKTOP 1024, 768, 0, ""
159.  
160.  
161. _FONT 14
162.  
163. _MOUSEHIDE
164.  
165. 'FOR i% = 1 TO 10
166. '    untitled%(i%) = WINDOW_NEW(320, 240)
167. '    WINDOW_SETTITLE untitled%(i%), "Untitled-" + LTRIM$(STR$(i%))
168. '    WIN(untitled%(i%)).TBSolid = 0
169. '    WINDOW_MAKE untitled%(i%)
170. '    WINDOW_SHOW untitled%(i%)
171. '    WINDOW_PUT untitled%(i%), 140 + i% * 25, 20 + i% * 25, BYWINDOW
172. '    WIN(untitled%(i%)).Size = -1
173. 'NEXT i%
174.  
175.  
176. untitled1% = WINDOW_NEW(640, 480)
177. untitled2% = WINDOW_NEW(320, 240)
178. untitled3% = WINDOW_NEW(160, 120)
179.  
180. WINDOW_SETTITLE untitled1%, "Untitled-1"
181. WINDOW_SETTITLE untitled2%, "Untitled-2"
182. WINDOW_SETTITLE untitled3%, "Untitled-3"
183.  
184. WIN(untitled2%).TBSolid = 0 '                    need to create library command for this
185.  
186.  
187. WINDOW_MAKE untitled3%
188. WINDOW_MAKE untitled2%
189. WINDOW_MAKE untitled1%
190.  
191. WINDOW_SHOW untitled1%
192. WINDOW_SHOW untitled2%
193. WINDOW_SHOW untitled3%
194.  
195. WINDOW_PUT untitled3%, 150, 25, BYWINDOW
196. WINDOW_PUT untitled2%, 200, 100, BYWINDOW
197. WINDOW_PUT untitled1%, 300, 200, BYWINDOW
198.  
199.  
200. WIN(untitled1%).Size = -1 '                      need to create library command for this
201. WIN(untitled2%).Size = -1 '                      need to create library command for this
202. WIN(untitled3%).Size = -1 '                      need to create library command for this
203.  
204.  
205. DO
206.     IF _MOUSEINPUT THEN WINDOW_MOUSE
207.     WINDOW_REFRESH
208.     LOCATE 1, 1
209.     PRINT " Focus ------> "; WinOrder%(1)
210.     PRINT " Mouse X ----> "; MOUSE.X
211.     PRINT " Mouse Y ----> "; MOUSE.Y
212.     PRINT " On Window --> "; MOUSE.OnWindow
213.     PRINT " Window X ---> "; MOUSE.WindowX
214.     PRINT " Window Y ---> "; MOUSE.WindowY
215.     PRINT " On Surface -> "; MOUSE.OnSurface
216.     PRINT " Surface X---> "; MOUSE.SurfaceX
217.     PRINT " Surface Y --> "; MOUSE.SurfaceY
218.     PRINT " On TitleBar > "; MOUSE.OnTitlebar
219.     PRINT " On Border --> "; MOUSE.OnBorder
220.     PRINT " Border -----> "; MOUSE.Border
221.     PRINT " Left Click -> "; MOUSE.LeftClick
222.     PRINT " Right Click > "; MOUSE.RightClick
223.     PRINT " Moving -----> "; MOUSE.Move
224.     PRINT " Resizing ---> "; MOUSE.Resize
225.     PRINT " On Button --> "; MOUSE.OnButton
226.     PRINT " Button Press> "; MOUSE.ButtonPressed
227.     PRINT " Button Click> "; MOUSE.ButtonClicked
228.     _DISPLAY
229. LOOP UNTIL _KEYDOWN(27)
230.  
231.  
232.  
233.  
234.  
235. '--------------------------------------------------------------------------------------------------------------------------------
236. '                                                                                                                         TBIMAGE
237. SUB TBIMAGE (h%, f%)
238.  
239. ' h% = window handle
240. ' f% = focus 1, no focus 0
241.  
242. SHARED WIN() AS WIN ' window array
243. SHARED BUT() AS BUTTON
244.  
245. DIM c% '                  generic counter
246. DIM Red!, Green!, Blue!
247. DIM Redinc!, Greeninc!, Blueinc!
248.  
249. IF f% THEN
250.     _DEST WIN(h%).TBFImage '                                                                draw on title bar focus image
251.     _FONT WIN(h%).Font '                                                                    set title bar font
252.     _PRINTMODE _KEEPBACKGROUND '                                                            font will be transparent
253.     COLOR WIN(h%).TTColor '                                                                 set font color
254.     CLS , WIN(h%).TBColor '                                                             yes, color title bar
255.     IF NOT WIN(h%).TBSolid THEN
256.         Red! = _RED(WIN(h%).TBColor) '                                                      get title bar color components
257.         Green! = _GREEN(WIN(h%).TBColor)
258.         Blue! = _BLUE(WIN(h%).TBColor)
259.         Redinc! = (255 - Red!) / WIN(h%).SWidth / 2 '                                       calculate color fade values
260.         Greeninc! = (255 - Green!) / WIN(h%).SWidth / 2
261.         Blueinc! = (255 - Blue!) / WIN(h%).SWidth / 2
262.     END IF
263. ELSE
264.     _DEST WIN(h%).TBNFImage
265.     _FONT WIN(h%).Font
266.     _PRINTMODE _KEEPBACKGROUND
267.     COLOR _RGB32(212, 208, 200)
268.     CLS , _RGB32(128, 128, 128)
269.     IF NOT WIN(h%).TBSolid THEN
270.         Red! = 128
271.         Green! = 128
272.         Blue! = 128
273.         Redinc! = 63 / WIN(h%).SWidth
274.         Greeninc! = 63 / WIN(h%).SWidth
275.         Blueinc! = 63 / WIN(h%).SWidth
276.     END IF
277. END IF
278. IF NOT WIN(h%).TBSolid THEN
279.     FOR c% = 0 TO WIN(h%).SWidth - 1
280.         LINE (c%, 0)-(c%, WIN(h%).TBHeight - 1), _RGB32(Red!, Green!, Blue!)
281.         Red! = Red! + Redinc!
282.         Green! = Green! + Greeninc!
283.         Blue! = Blue! + Blueinc!
284.     NEXT c%
285. END IF
286. w% = _PRINTWIDTH("#") + 6
287.  
288. IF WIN(h%).CloseButton THEN w% = w% + BUT(WIN(h%).CloseButton).Width
289. IF WIN(h%).MaxButton THEN w% = w% + BUT(WIN(h%).MaxButton).Width
290. IF WIN(h%).MinButton THEN w% = w% + BUT(WIN(h%).MinButton).Width
291.  
292. mw% = WIN(h%).SWidth - (WIN(h%).TBHeight + 2) - w%
293. t$ = RTRIM$(WIN(h%).Title)
294. WIN(h%).MinWidth = _PRINTWIDTH(LEFT$(t$, 3) + "...") + WIN(h%).TBHeight + 2 + w%
295. nt$ = t$
296. WHILE _PRINTWIDTH(nt$) > mw%
297.     t$ = LEFT$(t$, LEN(t$) - 1)
298.     nt$ = t$ + "..."
299. WEND
300. _PRINTSTRING (WIN(h%).TBHeight + 2, 4), nt$ '                         print title on title bar
301. _PUTIMAGE (2, 1)-(WIN(h%).TBHeight - 1, WIN(h%).TBHeight - 2), WIN(h%).Icon '           place icon on title bar
302.  
303. END SUB
304.  
305. '--------------------------------------------------------------------------------------------------------------------------------
306. '                                                                                                                          WITHIN
307. FUNCTION WITHIN (x%, y%, x2%, y2%)
308.  
309. '*
310. '* Returns true if mouse pointer within given coordinate pairs.
311. '*
312.  
313. SHARED MOUSE AS MOUSEFLAGS
314.  
315. IF MOUSE.X >= x% THEN '              mouse pointer inside given rectangle?
316.     IF MOUSE.X <= x2% THEN
317.         IF MOUSE.Y >= y% THEN
318.             IF MOUSE.Y <= y2% THEN
319.                 WITHIN = -1 '        yes, return true
320.             END IF
321.         END IF
322.     END IF
323. END IF
324.  
325. END FUNCTION
326.  
327. '--------------------------------------------------------------------------------------------------------------------------------
328. '                                                                                                                      BUTTON_PUT
329. SUB BUTTON_PUT (b%, x%, y%, state%) ' state% needed?
330.  
331. SHARED WIN() AS WIN
332. SHARED BUT() AS BUTTON
333.  
334. IF BUT(b%).WinButton THEN '                                                                  is button for window use only?
335.     SELECT CASE BUT(b%).State '                                                              which state is title bar button in?
336.         CASE -1 '                                                                            pressed state
337.             _PUTIMAGE (BUT(b%).X, BUT(b%).Y), BUT(b%).Pressed, WIN(BUT(b%).Window).Window '  draw pressed button on window
338.         CASE 0 '                                                                             normal (depressed) state
339.             _PUTIMAGE (BUT(b%).X, BUT(b%).Y), BUT(b%).Normal, WIN(BUT(b%).Window).Window '   draw normal button on window
340.         CASE 1 '                                                                             disabled state
341.             _PUTIMAGE (BUT(b%).X, BUT(b%).Y), BUT(b%).Disabled, WIN(BUT(b%).Window).Window ' draw disabled button on window
342.     END SELECT
343. ELSE
344.  
345.     '*
346.     '* Custom made buttons here
347.     '*
348.  
349. END IF
350.  
351. END SUB
352.  
353. '--------------------------------------------------------------------------------------------------------------------------------
354. '                                                                                                                      BUTTON_NEW
355. FUNCTION BUTTON_NEW (win%, w%, h%, t$, f&, c~&, t~&)
356. '*
357. '* win% - window button belongs to (negative value sent in means a title bar button is being created)
358. '* w%   - width of button (ignored if title bar button is being created)
359. '* h%   - height of button (ignored if title bar button is being created)
360. '* t$   - text to be placed on button (if title bar button then "CLOSE", "MAXIMIZE", "MINIMIZE', and "RESTORE")
361. '* f&   - text font (ignored if title bar button is being created)
362. '* c~&  - button color (if 0 then window color is used)
363. '* t~&  - text color (if 0 then balck is used)
364. '*
365. SHARED WIN() AS WIN
366. SHARED BUT() AS BUTTON
367.  
368. DIM i% ' next available button array index
369. DIM c% ' generic counter
370.  
371. i% = UBOUND(BUT) '                                                              get last button index
372. WHILE NOT BUT(i%).InUse AND i% > 1 '                                            is button in use?
373.     REDIM _PRESERVE BUT(i% - 1) AS BUTTON '                                     no, remove it
374.     i% = i% - 1 '                                                               go to previous index
375. WEND '                                                                          leave when last button still being used
376. i% = 0 '                                                                        start at beginning
377. c% = 1
378. DO '                                                                            cycle through button indexes
379.     IF NOT BUT(c%).InUse THEN '                                                 button in use?
380.         i% = c% '                                                               no, use this index
381.     ELSE '                                                                      yes
382.         c% = c% + 1 '                                                           increment index counter
383.         IF c% > UBOUND(BUT) THEN '                                              reached end of buttons?
384.             REDIM _PRESERVE BUT(c%) AS BUTTON '                                 yes, create a new button
385.             i% = c% '                                                           use this index
386.         END IF
387.     END IF
388. LOOP UNTIL i% '                                                                 leave when available index found
389. IF win% < 0 THEN '                                                              button belong to a title bar?
390.     win% = -win% '                                                              yes, correct window handle
391.     BUT(i%).WinButton = -1 '                                                    mark button as belonging to a title bar
392. END IF
393. BUT(i%).Window = win% '                                                         button belongs to window (0 for desktop)
394. BUT(i%).InUse = -1 '                                                            mark index as used
395. BUT(i%).State = 0 '                                                             default to normal
396. BUT(i%).X = 0 '                                                                 reset x coordinate
397. BUT(i%).Y = 0 '                                                                 reset y coordinate
398. IF BUT(i%).WinButton THEN '                                                     creating a title bar button?
399.     BUT(i%).Height = WIN(win%).TBHeight - 4 '                                   calculate button height
400.     BUT(i%).Width = INT(BUT(i%).Height * 1.14286) '                             calculate button width
401.     IF w% THEN BUT(i%).Height = BUT(i%).Width '                                 yes, height=width
402.     x2% = BUT(i%).Width - 1 '                                                   calculate right bottom corner button X
403.     y2% = BUT(i%).Height - 1 '                                                  calculate right bottom corner button Y
404.     BUT(i%).State = 0 '                                                         set button as normal (depressed)
405.     BUT(i%).Normal = _NEWIMAGE(BUT(i%).Width, BUT(i%).Height, 32) '             create normal image holder
406.     _DEST BUT(i%).Normal '                                                      draw on image
407.     CLS , WIN(win%).Darkest '                                                   create common button image
408.     LINE (0, 0)-(x2% - 1, y2% - 1), WIN(win%).Lighter, B '                      draw background
409.     LINE (1, 1)-(x2% - 1, y2% - 1), WIN(win%).Darker, B
410.     LINE (1, 1)-(x2% - 2, y2% - 2), WIN(win%).WColor, BF
411.     BUT(i%).Pressed = _NEWIMAGE(BUT(i%).Width, BUT(i%).Height, 32) '            create pressed image holder
412.     _DEST BUT(i%).Pressed '                                                     draw on image
413.     CLS , WIN(win%).Lighter '                                                   create common button image
414.     LINE (0, 0)-(x2% - 1, y2% - 1), WIN(win%).Darkest, B '                      draw background
415.     LINE (1, 1)-(x2% - 1, y2% - 1), WIN(win%).WColor, B
416.     LINE (1, 1)-(x2% - 2, y2% - 2), WIN(win%).Darker, B
417.     LINE (2, 2)-(x2% - 1, y2% - 1), WIN(win%).WColor, BF
418.     BUT(i%).Disabled = _NEWIMAGE(BUT(i%).Width, BUT(i%).Height, 32) '           create disabled image holder
419.     IF NOT w% THEN '                                                            title bar button?
420.         _DEST BUT(i%).Disabled '                                                yes, draw on image
421.         CLS , WIN(win%).Darkest '                                               create common button image
422.         LINE (0, 0)-(x2% - 1, y2% - 1), WIN(win%).Lighter, B '                  draw background
423.         LINE (1, 1)-(x2% - 1, y2% - 1), WIN(win%).Darker, B
424.         LINE (1, 1)-(x2% - 2, y2% - 2), WIN(win%).WColor, BF
425.     END IF
426.     SELECT CASE t$ '                                                            yes, which window button being created?
427.         CASE "CLOSE" '                                                          close button
428.             _DEST BUT(i%).Normal '                                              work on normal
429.             LINE (4, 3)-(x2% - 5, y2% - 4), _RGB32(0, 0, 0) '                   draw depressed button
430.             LINE (5, 3)-(x2% - 4, y2% - 4), _RGB32(0, 0, 0)
431.             LINE (4, y2% - 4)-(x2% - 5, 3), _RGB32(0, 0, 0)
432.             LINE (5, y2% - 4)-(x2% - 4, 3), _RGB32(0, 0, 0)
433.             _DEST BUT(i%).Pressed '                                             work on pressed
434.             LINE (5, 4)-(x2% - 4, y2% - 3), _RGB32(0, 0, 0) '                   draw pressed button
435.             LINE (6, 4)-(x2% - 3, y2% - 3), _RGB32(0, 0, 0)
436.             LINE (5, y2% - 3)-(x2% - 4, 4), _RGB32(0, 0, 0)
437.             LINE (6, y2% - 3)-(x2% - 3, 4), _RGB32(0, 0, 0)
438.             _DEST BUT(i%).Disabled '                                            work on disabled
439.             LINE (5, y2% - 4)-(x2% - 4, 4), _RGB32(255, 255, 255) '             draw disabled button
440.             LINE (6, y2% - 4)-(x2% - 3, 4), _RGB32(255, 255, 255)
441.             LINE (x2% - 4, y2% - 3)-(x2% - 3, y2% - 3), _RGB32(255, 255, 255) '
442.             LINE (4, 3)-(x2% - 5, y2% - 4), _RGB32(128, 128, 128)
443.             LINE (5, 3)-(x2% - 4, y2% - 4), _RGB32(128, 128, 128)
444.             LINE (4, y2% - 4)-(x2% - 5, 3), _RGB32(128, 128, 128)
445.             LINE (5, y2% - 4)-(x2% - 4, 3), _RGB32(128, 128, 128)
446.         CASE "MAXIMIZE" '                                                       maximize button
447.             _DEST BUT(i%).Normal '                                              work on normal
448.             LINE (3, 3)-(x2% - 4, y2% - 3), _RGB32(0, 0, 0), B '                draw depressed button
449.             LINE (3, 2)-(x2% - 4, 2), _RGB32(0, 0, 0)
450.             _DEST BUT(i%).Pressed '                                             work on pressed
451.             LINE (4, 4)-(x2% - 3, y2% - 2), _RGB32(0, 0, 0), B '                draw pressed button
452.             LINE (4, 3)-(x2% - 3, 3), _RGB32(0, 0, 0)
453.             _DEST BUT(i%).Disabled '                                            work on disabled
454.             LINE (4, 4)-(x2% - 3, y2% - 2), _RGB32(255, 255, 255), B '          draw disabled button
455.             PSET (x2% - 3, 3), _RGB32(255, 255, 255)
456.             LINE (3, 3)-(x2% - 4, y2% - 3), _RGB32(128, 128, 128), B
457.             LINE (3, 2)-(x2% - 4, 2), _RGB32(128, 128, 128)
458.         CASE "MINIMIZE" '                                                       minimize button
459.             _DEST BUT(i%).Normal '                                              work on normal
460.             LINE (4, y2% - 4)-(x2% - 6, y2% - 3), _RGB32(0, 0, 0), B '          draw depressed button
461.             _DEST BUT(i%).Pressed '                                             work on pressed
462.             LINE (5, y2% - 3)-(x2% - 5, y2% - 2), _RGB32(0, 0, 0), B '          draw pressed button
463.             _DEST BUT(i%).Disabled '                                            work on disabled
464.             LINE (5, y2% - 3)-(x2% - 5, y2% - 2), _RGB32(255, 255, 255), B '    draw disabled button
465.             LINE (4, y2% - 4)-(x2% - 6, y2% - 3), _RGB32(128, 128, 128), B
466.         CASE "RESTORE" '                                                        restore button
467.             _DEST BUT(i%).Normal '                                              work on normal
468.             LINE (3, 6)-(x2% - 7, y2% - 3), _RGB32(0, 0, 0), B '                draw depressed button
469.             LINE (3, 5)-(x2% - 7, 5), _RGB32(0, 0, 0)
470.             PSET (5, 4), _RGB32(0, 0, 0)
471.             PSET (x2% - 6, y2% - 6), _RGB32(0, 0, 0)
472.             LINE (5, 2)-(x2% - 5, 3), _RGB32(0, 0, 0), B
473.             LINE (x2% - 5, 4)-(x2% - 5, y2% - 6), _RGB32(0, 0, 0)
474.             _DEST BUT(i%).Pressed '                                             work on pressed
475.             LINE (4, 7)-(x2% - 6, y2% - 2), _RGB32(0, 0, 0), B '                draw pressed button
476.             LINE (4, 6)-(x2% - 6, 6), _RGB32(0, 0, 0)
477.             PSET (6, 5), _RGB32(0, 0, 0)
478.             PSET (x2% - 5, y2% - 5), _RGB32(0, 0, 0)
479.             LINE (6, 3)-(x2% - 4, 4), _RGB32(0, 0, 0), B
480.             LINE (x2% - 4, 5)-(x2% - 4, y2% - 5), _RGB32(0, 0, 0)
481.             _DEST BUT(i%).Disabled '                                            work on disabled
482.             LINE (4, 7)-(x2% - 6, y2% - 2), _RGB32(255, 255, 255), B '          draw disabled button
483.             LINE (6, 4)-(x2% - 6, 4), _RGB32(255, 255, 255)
484.             LINE (x2% - 5, 3)-(x2% - 4, y2% - 5), _RGB32(255, 255, 255), B
485.             LINE (3, 6)-(x2% - 7, y2% - 3), _RGB32(128, 128, 128), B
486.             LINE (3, 5)-(x2% - 7, 5), _RGB32(128, 128, 128)
487.             PSET (5, 4), _RGB32(128, 128, 128)
488.             PSET (x2% - 6, y2% - 6), _RGB32(128, 128, 128)
489.             LINE (5, 2)-(x2% - 5, 3), _RGB32(128, 128, 128), B
490.             LINE (x2% - 5, 4)-(x2% - 5, y2% - 6), _RGB32(128, 128, 128)
491.         CASE "SCROLLUP"
492.             _DEST BUT(i%).Normal
493.             LINE (BUT(i%).Width \ 2, 6)-(4, y2% - 6), _RGB32(0, 0, 0)
494.             LINE -(x2% - 4, y2% - 6), _RGB32(0, 0, 0)
495.             LINE -(BUT(i%).Width \ 2, 6), _RGB32(0, 0, 0)
496.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
497.             _DEST BUT(i%).Pressed
498.             LINE (BUT(i%).Width \ 2 + 1, 7)-(5, y2% - 5), _RGB32(0, 0, 0)
499.             LINE -(x2% - 3, y2% - 5), _RGB32(0, 0, 0)
500.             LINE -(BUT(i%).Width \ 2 + 1, 7), _RGB32(0, 0, 0)
501.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
502.         CASE "SCROLLDOWN"
503.             _DEST BUT(i%).Normal
504.             LINE (BUT(i%).Width \ 2, y2% - 6)-(4, 6), _RGB32(0, 0, 0)
505.             LINE -(y2% - 4, 6), _RGB32(0, 0, 0)
506.             LINE -(BUT(i%).Width \ 2, y2% - 6), _RGB32(0, 0, 0)
507.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
508.             _DEST BUT(i%).Pressed
509.             LINE (BUT(i%).Width \ 2 + 1, y2% - 5)-(5, 7), _RGB32(0, 0, 0)
510.             LINE -(x2% - 3, 7), _RGB32(0, 0, 0)
511.             LINE -(BUT(i%).Width \ 2 + 1, y2% - 5), _RGB32(0, 0, 0)
512.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
513.         CASE "SCROLLLEFT"
514.             _DEST BUT(i%).Normal
515.             LINE (5, BUT(i%).Height \ 2)-(x2% - 7, 4), _RGB32(0, 0, 0)
516.             LINE -(x2% - 7, y2% - 5), _RGB32(0, 0, 0)
517.             LINE -(5, BUT(i%).Height \ 2), _RGB32(0, 0, 0)
518.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
519.             _DEST BUT(i%).Pressed
520.             LINE (6, BUT(i%).Height \ 2 + 1)-(x2% - 6, 5), _RGB32(0, 0, 0)
521.             LINE -(x2% - 6, y2% - 4), _RGB32(0, 0, 0)
522.             LINE -(6, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0)
523.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
524.         CASE "SCROLLRIGHT"
525.             _DEST BUT(i%).Normal
526.             LINE (x2% - 6, BUT(i%).Height \ 2)-(6, 4), _RGB32(0, 0, 0)
527.             LINE -(6, y2% - 5), _RGB32(0, 0, 0)
528.             LINE -(x2% - 6, BUT(i%).Height \ 2), _RGB32(0, 0, 0)
529.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
530.             _DEST BUT(i%).Pressed
531.             LINE (x2% - 5, BUT(i%).Height \ 2 + 1)-(7, 5), _RGB32(0, 0, 0)
532.             LINE -(7, y2% - 4), _RGB32(0, 0, 0)
533.             LINE -(x2% - 5, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0)
534.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
535.     END SELECT
536. ELSE
537.  
538.     '*
539.     '* custom made buttons here
540.     '*
541.  
542. END IF
543.  
544. BUTTON_NEW = i%
545.  
546. END FUNCTION
547.  
548. '--------------------------------------------------------------------------------------------------------------------------------
549. '                                                                                                                    WINDOW_MOUSE
550. SUB WINDOW_MOUSE ()
551. '
552. ' work in progress (only called when there has been mouse activity)
553. '
554. SHARED WIN() AS WIN
555. SHARED WinOrder%()
556. SHARED WIN AS WINDOWFLAGS
557. SHARED MOUSE AS MOUSEFLAGS
558. SHARED BUT() AS BUTTON
559.  
560. DIM c% ' current window being checked for mouse hover
561. DIM o% ' order of windows
562. DIM x% ' x offset movement of mouse
563. DIM y% ' y offset movement of mouse
564. DIM tx%
565. DIM ty%
566.  
567. MOUSE.PX = MOUSE.X '                                                                         save last mouse x position
568. MOUSE.PY = MOUSE.Y '                                                                         save last mouse y position
569. WHILE _MOUSEINPUT: WEND '                                                                    get latest mouse status
570. MOUSE.X = _MOUSEX '                                                                          set desktop x coordinate flag
571. MOUSE.Y = _MOUSEY '                                                                          set desktop y coordinate flag
572. MOUSE.LeftClick = _MOUSEBUTTON(1) '                                                          set left mouse button status
573. MOUSE.RightClick = _MOUSEBUTTON(2) '                                                         set right mouse button status
574. IF NOT MOUSE.LeftClick THEN
575.     MOUSE.LeftReleased = -1 '                                                                left mouse button has been released?
576.     WIN(MOUSE.Move).Move = 0 '                                                               yes, window no longer being moved
577.     MOUSE.Move = 0 '                                                                         end window movement
578.     WIN(MOUSE.Resize).Resize = 0 '                                                           window no longer being resized
579.     MOUSE.Resize = 0 '                                                                       end window resizing
580.     MOUSE.Icon = 0 '                                                                         mouse pointer to default
581.     IF MOUSE.ButtonPressed THEN '                                                            was a button being held down?
582.         MOUSE.ButtonClicked = MOUSE.ButtonPressed '                                          yes, this button has now been clicked
583.         MOUSE.ButtonPressed = 0 '                                                            button no longer being held down
584.         BUT(MOUSE.ButtonClicked).State = 0 '                                                 set button state back to normal
585.     END IF
586. ELSE
587.     IF MOUSE.Move THEN '                                                                     window currently being moved?
588.         WINDOW_PUT MOUSE.move, WIN(MOUSE.move).X + MOUSEMOVEMENTX,_
589.                               WIN(MOUSE.move).Y + MOUSEMOVEMENTY,_
590.                               BYWINDOW '                                                     yes, update window position
591.     ELSEIF MOUSE.Resize THEN '                                                               window currently being resized?
592.         x% = MOUSEMOVEMENTX '                                                                yes, get change in x position
593.         y% = MOUSEMOVEMENTY '                                                                get change in y position
594.         IF MOUSE.Border AND 1 THEN '                                                         mouse on top border?
595.             ty% = WIN(MOUSE.Resize).Height - y% '                                            yes, calculate possible y value
596.             IF ty% >= WIN(MOUSE.Resize).MinHeight AND ty% <= WIN(MOUSE.Resize).MaxHeight THEN ' outside limits?
597.                 WIN(MOUSE.Resize).Y = WIN(MOUSE.Resize).Y + y% '                             no, adjust window y location
598.                 WIN(MOUSE.Resize).Height = ty% '                                             adjust overall window height
599.  
600.                 WIN(MOUSE.Resize).SHeight = WIN(MOUSE.Resize).SHeight - y% '                 adjust window screen height
601.  
602.             ELSE '                                                                           yes, minimum reached
603.                 _MOUSEMOVE MOUSE.X, MOUSE.PY '                                               force pointer back       (not working correctly in GL)
604.                 MOUSE.Y = MOUSE.PY '                                                         update mouse y position
605.                 MOUSE.PY = MOUSEMOVEMENTY '                                                  seed new y offset position
606.             END IF
607.         ELSEIF MOUSE.Border AND 4 THEN '                                                     no, mouse on bottom border?
608.             ty% = WIN(MOUSE.Resize).Height + y% '                                            calculate possible y value
609.             IF ty% >= WIN(MOUSE.Resize).MinHeight AND ty% <= WIN(MOUSE.Resize).MaxHeight THEN ' outside limits?
610.                 WIN(MOUSE.Resize).Height = ty% '                                             no, adjust overall window height
611.  
612.                 WIN(MOUSE.Resize).SHeight = WIN(MOUSE.Resize).SHeight + y% '                 adjust window screen height
613.  
614.             ELSE '                                                                           yes, minimum reached
615.                 _MOUSEMOVE MOUSE.X, MOUSE.PY '                                               force pointer back       (not working correclty in GL)
616.                 MOUSE.Y = MOUSE.PY '                                                         update mouse y position
617.                 MOUSE.PY = MOUSEMOVEMENTY '                                                  seed new y offset position
618.             END IF
619.         END IF
620.         IF MOUSE.Border AND 2 THEN '                                                         mouse on right border?
621.             tx% = WIN(MOUSE.Resize).Width + x% '                                             yes, calculate possible x value
622.             IF tx% >= WIN(MOUSE.Resize).MinWidth AND tx% <= WIN(MOUSE.Resize).MaxWidth THEN ' outside limits?
623.                 WIN(MOUSE.Resize).Width = tx% '                                              no, adjust overall window width
624.  
625.                 WIN(MOUSE.Resize).SWidth = WIN(MOUSE.Resize).SWidth + x% '                   adjust window screen width
626.  
627.             ELSE '                                                                           yes, minimum reached
628.                 _MOUSEMOVE MOUSE.PX, MOUSE.Y '                                               force pointer back       (not working correclty in GL)
629.                 MOUSE.X = MOUSE.PX '                                                         update mouse x position
630.                 MOUSE.PX = MOUSEMOVEMENTX '                                                  seed new x offset position
631.             END IF
632.         ELSEIF MOUSE.Border AND 8 THEN '                                                     no, mouse on left border?
633.             tx% = WIN(MOUSE.Resize).Width - x% '                                             calculate possible x value
634.             IF tx% >= WIN(MOUSE.Resize).MinWidth AND tx% <= WIN(MOUSE.Resize).MaxWidth THEN ' outside limits?
635.                 WIN(MOUSE.Resize).X = WIN(MOUSE.Resize).X + x% '                             no, adjust window x location
636.                 WIN(MOUSE.Resize).Width = tx% '                                              adjust overall window width
637.  
638.                 WIN(MOUSE.Resize).SWidth = WIN(MOUSE.Resize).SWidth - x% '                   adjust window screen width
639.  
640.             ELSE '                                                                           yes, minimum reached
641.                 _MOUSEMOVE MOUSE.PX, MOUSE.Y '                                               force pointer back       (not working correctly in GL)
642.                 MOUSE.X = MOUSE.PX '                                                         update mouse x position
643.                 MOUSE.PX = MOUSEMOVEMENTX '                                                  seed new x offset position
644.             END IF
645.         END IF
646.         WINDOW_MAKE MOUSE.Resize '                                                           redraw window
647.     ELSE
648.         MOUSE.WindowX = MOUSE.X - WIN(MOUSE.OnWindow).X '                                    set window x coordinate flag
649.         MOUSE.WindowY = MOUSE.Y - WIN(MOUSE.OnWindow).Y '                                    set window y coordinate flag
650.         MOUSE.SurfaceX = MOUSE.WindowX - WIN(MOUSE.OnWindow).SurfaceX '                        yes, set work space x flag
651.         MOUSE.SurfaceY = MOUSE.WindowY - WIN(MOUSE.OnWindow).SurfaceY '                        set work space y flag
652.     END IF
653. END IF
654.  
655. IF NOT MOUSE.LeftReleased THEN EXIT SUB '                                                    don't interact if left button being held down
656.  
657. WIN.X = 0 '                                                                                  reset window flags
658. WIN.Y = 0
659. WIN.Width = 0
660. WIN.Height = 0
661. WIN.Surface = 0
662. WIN.SurfaceX = 0
663. WIN.SurfaceY = 0
664. WIN.SWidth = 0
665. WIN.SHeight = 0
666. WIN.HasFocus = 0
667. MOUSE.Icon = 0
668. MOUSE.OnWindow = 0 '                                                                         reset remaining mouse flags
669. MOUSE.WindowX = 0
670. MOUSE.WindowY = 0
671. MOUSE.OnSurface = 0
672. MOUSE.SurfaceX = 0
673. MOUSE.SurfaceY = 0
674. MOUSE.OnTitlebar = 0
675. MOUSE.OnBorder = 0
676. MOUSE.Border = 0
677. MOUSE.OnButton = 0
678. DO '                                                                                         loop through window order array
679.     c% = c% + 1 '                                                                            increment array index
680.     o% = WinOrder%(c%) '                                                                     next window to check
681.     IF WIN(o%).Visible THEN '                                                                is window visible on screen?
682.         IF WITHIN(WIN(o%).X,_
683.                   WIN(o%).Y,_
684.                   WIN(o%).X + WIN(o%).Width - 1,_
685.                   WIN(o%).Y + WIN(o%).Height - 1) THEN '                                     yes, mouse within window coordinates?
686.             MOUSE.OnWindow = o% '                                                            yes, set pointer flag to hovered window
687.             MOUSE.WindowX = MOUSE.X - WIN(o%).X '                                            set window x coordinate flag
688.             MOUSE.WindowY = MOUSE.Y - WIN(o%).Y '                                            set window y coordinate flag
689.  
690.             WIN.X = WIN(o%).X
691.             WIN.Y = WIN(o%).Y
692.             WIN.Width = WIN(o%).Width '                                                      set window width flag
693.             WIN.Height = WIN(o%).Height '                                                    set window height flag
694.             WIN.Surface = WIN(o%).Surface
695.             WIN.SurfaceX = WIN(o%).SurfaceX
696.             WIN.SurfaceY = WIN(o%).SurfaceY
697.             WIN.SWidth = WIN(o%).SWidth '                                                    set window work space width flag
698.             WIN.SHeight = WIN(o%).SHeight '                                                  set window work space height flag
699.             WIN.HasFocus = WIN(o%).Focus
700.  
701.             IF WITHIN(WIN(o%).X + WIN(o%).SurfaceX,_
702.                       WIN(o%).Y + WIN(o%).SurfaceY,_
703.                       WIN(o%).X + WIN(o%).SurfaceX + WIN(o%).SWidth - 1,_
704.                       WIN(o%).Y + WIN(o%).SurfaceY + WIN(o%).SHeight - 1) THEN '              mouse within screen coordinates?
705.                 MOUSE.SurfaceX = MOUSE.WindowX - WIN(o%).SurfaceX '                            yes, set screen x flag
706.                 MOUSE.SurfaceY = MOUSE.WindowY - WIN(o%).SurfaceY '                            set screen y flag
707.                 MOUSE.OnSurface = -1 '                                                        set screen flag
708.             ELSEIF WITHIN(WIN(o%).X + WIN(o%).SurfaceX,_
709.                           WIN(o%).Y + WIN(o%).BWidth,_
710.                           WIN(o%).X + WIN(o%).SurfaceX + WIN(o%).SWidth - 1,_
711.                           WIN(o%).Y + WIN(o%).BWidth + WIN(o%).TBHeight - 1) THEN '          no, mouse within title bar?
712.                 IF WIN(o%).CloseButton THEN '                                                yes, does this window have a close button?
713.                     IF WITHIN(WIN(o%).X + BUT(WIN(o%).CloseButton).X,_
714.                               WIN(o%).Y + BUT(WIN(o%).CloseButton).Y,_
715.                               WIN(o%).X + BUT(WIN(o%).CloseButton).X + BUT(WIN(o%).CloseButton).Width - 1,_
716.                               WIN(o%).Y + BUT(WIN(o%).CloseButton).Y + BUT(WIN(o%).CloseButton).Height - 1) THEN ' yes, on button?
717.                         MOUSE.OnButton = WIN(o%).CloseButton '                               yes, set flag
718.                     END IF
719.                 END IF
720.                 IF WIN(o%).MaxButton THEN '                                                  does this window have a maximize button?
721.                     IF WITHIN(WIN(o%).X + BUT(WIN(o%).MaxButton).X,_
722.                               WIN(o%).Y + BUT(WIN(o%).MaxButton).Y,_
723.                               WIN(o%).X + BUT(WIN(o%).MaxButton).X + BUT(WIN(o%).MaxButton).Width - 1,_
724.                               WIN(o%).Y + BUT(WIN(o%).MaxButton).Y + BUT(WIN(o%).MaxButton).Height - 1) THEN ' yes, on button?
725.                         MOUSE.OnButton = WIN(o%).MaxButton '                                 yes, set flag
726.                     END IF
727.                 END IF
728.                 IF WIN(o%).MinButton THEN '                                                  does this window have a minimize button?
729.                     IF WITHIN(WIN(o%).X + BUT(WIN(o%).MinButton).X,_
730.                               WIN(o%).Y + BUT(WIN(o%).MinButton).Y,_
731.                               WIN(o%).X + BUT(WIN(o%).MinButton).X + BUT(WIN(o%).MinButton).Width - 1,_
732.                               WIN(o%).Y + BUT(WIN(o%).MinButton).Y + BUT(WIN(o%).MinButton).Height - 1) THEN ' yes, on button?
733.                         MOUSE.OnButton = WIN(o%).MinButton '                                 yes, set flag
734.                     END IF
735.                 END IF
736.                 IF MOUSE.OnButton = 0 THEN MOUSE.OnTitlebar = -1 '                           if not on button then must be on title bar
737.             END IF
738.             IF WIN(o%).Size THEN '                                                           is window resizable?
739.                 IF MOUSE.OnSurface + MOUSE.OnTitlebar + MOUSE.OnButton = 0 THEN '             yes, mouse on anything?
740.                     MOUSE.OnBorder = -1 '                                                    no, mouse must be on a border
741.                     IF MOUSE.Y <= WIN(o%).Y + WIN(o%).BWidth - 1 THEN '                      on top border?
742.                         MOUSE.Border = 1 '                                                   yes, set border value
743.                     ELSEIF MOUSE.Y >= WIN(o%).Y + WIN(o%).Height - WIN(o%).BWidth - 1 THEN ' no, on bottom border?
744.                         MOUSE.Border = MOUSE.Border + 4 '                                    yes, add border value
745.                     END IF
746.                     IF MOUSE.X >= WIN(o%).X + WIN(o%).Width - WIN(o%).BWidth - 1 THEN '      on right border?
747.                         MOUSE.Border = MOUSE.Border + 2 '                                    yes, add border value
748.                     ELSEIF MOUSE.X <= WIN(o%).X + WIN(o%).BWidth - 1 THEN '                  no, on left border?
749.                         MOUSE.Border = MOUSE.Border + 8 '                                    yes, add border value
750.                     END IF
751.                     MOUSE.Icon = MOUSE.Border '                                              mouse icon to resize
752.                 END IF
753.             END IF
754.         END IF
755.     END IF
756. LOOP UNTIL MOUSE.OnWindow OR c% = UBOUND(WinOrder%) '                                        leave when hovering or entire array scanned
757. IF MOUSE.LeftClick THEN MOUSE.LeftReleased = 0 '                                             left mouse button currently held down
758. IF MOUSE.OnWindow AND MOUSE.LeftClick THEN '                                                 is pointer on a window and left button pressed?
759.     WINDOW_SETFOCUS MOUSE.OnWindow '                                                         yes, this window now has focus
760.     c% = MOUSEMOVEMENTX '                                                                    seed mouse x offset function
761.     c% = MOUSEMOVEMENTY '                                                                    seed mouse y offset function
762.     IF MOUSE.OnTitlebar AND MOUSE.Move = 0 THEN '                                            is pointer on title bar and window not moving?
763.         MOUSE.Move = MOUSE.OnWindow '                                                        yes, this window can now be moved
764.         WIN(MOUSE.Move).Move = -1 '                                                          set window state to moving
765.     ELSEIF MOUSE.OnBorder AND MOUSE.Resize = 0 THEN '                                        is mouse on border and not resizing?
766.         MOUSE.Resize = MOUSE.OnWindow '                                                      yes, this window can now be resized
767.         WIN(MOUSE.Resize).Resize = -1 '                                                      set window state to resizing
768.     ELSEIF MOUSE.OnButton THEN '                                                             pointer on button?
769.         MOUSE.ButtonPressed = MOUSE.OnButton '                                               yes, button is currently being pressed
770.         BUT(MOUSE.ButtonPressed).State = -1 '                                                set button state to pressed
771.     END IF
772. END IF
773.  
774. END SUB
775.  
776. '--------------------------------------------------------------------------------------------------------------------------------
777. '                                                                                                                 WINDOW_SETFOCUS
778. SUB WINDOW_SETFOCUS (h%)
779. '
780. ' h% = handle of window to set focus ******************** NEEDS FIXED for only 1 window
781. '
782. SHARED WIN() AS WIN
783. SHARED WinOrder%()
784.  
785. DIM c%
786. DIM o%
787.  
788. IF h% < 1 THEN EXIT SUB '                                                       leave if no window selected
789. IF WIN(h%).Focus THEN EXIT SUB '                                                leave if window already in focus
790. IF NOT WIN(h%).Visible THEN EXIT SUB '                                          leave if window is not on screen
791. DO '                                                                            loop through window order array
792.     c% = c% + 1 '                                                               increment array index
793. LOOP UNTIL h% = WinOrder%(c%) OR c% = UBOUND(WinOrder%) '                       leave if window found or end of array reached
794. IF c% = UBOUND(WinOrder%) AND WinOrder%(c%) <> h% THEN EXIT SUB '               window does not exist, leave subroutine
795. FOR o% = c% - 1 TO 1 STEP -1 '                                                  cycle through array
796.     WinOrder%(o% + 1) = WinOrder%(o%) '                                         move windows above h% down one
797. NEXT o%
798. WinOrder%(1) = h% '                                                             make this window the new focus
799. c% = WinOrder%(2)
800. WIN(h%).Focus = -1 '                                                            this window now has focus
801.  
802. _PUTIMAGE (WIN(h%).BWidth, WIN(h%).BWidth), WIN(h%).TBFImage, WIN(h%).Window '  place focused title bar image on window
803.  
804. WIN(WinOrder%(2)).Focus = 0 '                                                   previous window lost focus
805.  
806. _PUTIMAGE (WIN(c%).BWidth, WIN(c%).BWidth), WIN(c%).TBNFImage, WIN(c%).Window ' unfocused
807.  
808. END SUB
809.  
810. '--------------------------------------------------------------------------------------------------------------------------------
811. '                                                                                                                  WINDOW_DESKTOP
812. SUB WINDOW_DESKTOP (w%, h%, c~&, i$)
813. '
814. ' w%  = desktop width  (0 for default 640 or to use optional desktop image width)
815. ' h%  = desktop height (0 for default 480 or to use optional desktop image height)
816. ' c~& = desktop color  (0 for none)
817. ' i$  = desktop image  (null for none)
818. '
819. ' If width and height are supplied then desktop is created with those dimensions and optional desktop image stretched across
820. '
821. SHARED DeskTop&
822.  
823. DIM Back& ' desktop background image
824.  
825. IF w% <> 0 AND h% <> 0 THEN '                                 dimensions supplied?
826.     DeskTop& = _NEWIMAGE(w%, h%, 32) '                        yes, create desktop screen with dimensions
827.     IF _FILEEXISTS(i$) THEN '                                 does background image exist?
828.         Back& = _LOADIMAGE(i$, 32) '                          yes, load background image
829.         _PUTIMAGE , Back&, DeskTop& '                         put background image on desktop screen
830.         _FREEIMAGE Back& '                                    background image no longer needed
831.     ELSE '                                                    no, background image does not exist
832.         _DEST DeskTop& '                                      draw on desktop screen
833.         IF c~& <> 0 THEN CLS , c~& ELSE CLS '                 color desktop background
834.     END IF
835. ELSE '                                                        no dimensions supplied
836.     IF _FILEEXISTS(i$) THEN '                                 does background image exist?
837.         DeskTop& = _LOADIMAGE(i$, 32) '                       yes, use this as the desktop
838.     ELSE '                                                    no, background image does not exist
839.         DeskTop& = _NEWIMAGE(640, 480, 32) '                  create default 640x480 desktop screen
840.         _DEST DeskTop& '                                      draw on desktop screen
841.         IF c~& <> 0 THEN CLS , c~& ELSE CLS '                 color desktop background
842.     END IF
843. END IF
844. SCREEN _NEWIMAGE(_WIDTH(DeskTop&), _HEIGHT(DeskTop&), 32) '   make main screen that matches desktop dimensions
845. CLS '                                                         clear screen (remove transparency)
846. _SCREENMOVE _MIDDLE '                                         move screen to the center of the programmer's desktop
847.  
848. END SUB
849.  
850. '--------------------------------------------------------------------------------------------------------------------------------
851. '                                                                                                                  WINDOW_REFRESH
852. SUB WINDOW_REFRESH ()
853.  
854. SHARED WIN() AS WIN ' window array
855. SHARED BUT() AS BUTTON
856. SHARED DeskTop&
857. SHARED WinOrder%()
858. SHARED POINTER() AS MOUSEPOINTERS
859. SHARED MOUSE AS MOUSEFLAGS
860.  
861. DIM o%
862. DIM h%
863.  
864. IF DeskTop& THEN _PUTIMAGE (0, 0), DeskTop& '                                               place background image if exist
865. FOR o% = UBOUND(WinOrder%) TO 1 STEP -1 '                                                   cycle through window order eversed
866.     h% = WinOrder%(o%) '                                                                    get next window handle
867.     IF WIN(h%).Visible THEN '                                                               is this window visible?
868.  
869.         IF WIN(h%).CloseButton THEN BUTTON_PUT WIN(h%).CloseButton, 0, 0, 0 '               draw close button if exist
870.         IF WIN(h%).MaxButton THEN BUTTON_PUT WIN(h%).MaxButton, 0, 0, 0 '                   draw maximize button if exist
871.         IF WIN(h%).MinButton THEN BUTTON_PUT WIN(h%).MinButton, 0, 0, 0 '                   draw minimize button if exist
872.  
873.         _PUTIMAGE (WIN(h%).X, WIN(h%).Y), WIN(h%).Window '                                  place window onto desktop
874.     END IF
875. NEXT o%
876. _PUTIMAGE (MOUSE.X + POINTER(MOUSE.Icon).X, MOUSE.Y + POINTER(MOUSE.Icon).Y), POINTER(MOUSE.Icon).Icon ' place mouse pointer
877.  
878. END SUB
879.  
880. '--------------------------------------------------------------------------------------------------------------------------------
881. '                                                                                                                      WINDOW_PUT
882. SUB WINDOW_PUT (h%, x%, y%, m%)
883. '
884. ' h% - handle of window to move
885. ' x% - new window x coordinate
886. ' y% - new window y coordinate
887. ' m% - method of move (by work space origin coordinates (BYSCREEN) or by entire window origin coordinates (BYWINDOW))
888. '
889. SHARED WIN() AS WIN ' window array
890.  
891. IF m% THEN '                                                BYSCREEN
892.     WIN(h%).X = x% - WIN(h%).BWidth
893.     WIN(h%).Y = y% - WIN(h%).BWidth - WIN(h%).TBHeight
894. ELSE '                                                      BYWINDOW
895.     WIN(h%).X = x%
896.     WIN(h%).Y = y%
897. END IF
898.  
899. 'IF WIN(h%).Visible THEN WINDOW_SETFOCUS h% ' *************************************** focus routine needs fixing for only 1 window
900.  
901. END SUB
902.  
903. '--------------------------------------------------------------------------------------------------------------------------------
904. '                                                                                                                     WINDOW_MAKE
905. SUB WINDOW_MAKE (h%)
906. '
907. ' h% - handle of window to create
908. '
909. SHARED WIN() AS WIN ' window array
910. SHARED MOUSE AS MOUSEFLAGS
911. SHARED BUT() AS BUTTON '             needed?
912.  
913. DIM p&(1)
914. DIM c% '                  generic counter
915. DIM Red!, Green!, Blue!
916. DIM Redinc!, Greeninc!, Blueinc!
917. DIM x%, y%
918.  
919. DIM CurrentDest&
920.  
921. p&(0) = 43690 '                                                                             scroll bar background pattern 1
922. p&(1) = 21845 '                                                                             scroll bar background pattern 2
923.  
924. CurrentDest& = _DEST '                                                                      remember calling destination
925.  
926. IF WIN(h%).Resize THEN '                                                                    window being resized?
927.     _FREEIMAGE WIN(h%).Window '                                                             remove window image from RAM
928.     IF (MOUSE.Border AND 2) OR (MOUSE.Border AND 8) THEN '                                  resizing right or left border?
929.         _FREEIMAGE WIN(h%).TBFImage '                                                       yes, remove title bar focus image
930.         _FREEIMAGE WIN(h%).TBNFImage '                                                      remove title bar no focus image
931.     END IF
932. ELSE '                                                                                      no, window being created
933.     CALCULATECOLORS h% '                                                                    calculate window color shades
934.     WIN(h%).TBHeight = _FONTHEIGHT(WIN(h%).Font) + 8 '                                      calculate title bar height
935.     WIN(h%).Width = WIN(h%).SWidth + WIN(h%).BWidth * 2 '                                   yes, calculate window width
936.     WIN(h%).Height = WIN(h%).SHeight + WIN(h%).BWidth * 2 + WIN(h%).TBHeight + 1 '          calculate window height
937.     WIN(h%).OWidth = WIN(h%).Width
938.     WIN(h%).OHeight = WIN(h%).Height
939.     WIN(h%).MaxWidth = WIN(h%).OWidth '                                                     save maximim width of window
940.     WIN(h%).MaxHeight = WIN(h%).OHeight '                                                   save maximim height of window
941.     WIN(h%).SurfaceX = WIN(h%).BWidth '                                                      calculate screen x location
942.     WIN(h%).SurfaceY = WIN(h%).BWidth + WIN(h%).TBHeight '                                   calculate screen y location
943.  
944.  
945.     WIN(h%).CloseButton = BUTTON_NEW(-h%, 0, 0, "CLOSE", 0, 0, 0) '                         create close title bar button
946.     WIN(h%).MaxButton = BUTTON_NEW(-h%, 0, 0, "MAXIMIZE", 0, 0, 0) '                        create maximize title bar button
947.     WIN(h%).MinButton = BUTTON_NEW(-h%, 0, 0, "MINIMIZE", 0, 0, 0) '                        create minimize title bar button
948.     WIN(h%).RestoreButton = BUTTON_NEW(-h%, 0, 0, "RESTORE", 0, 0, 0) '                     create restore title bar button
949.     WIN(h%).SUButton = BUTTON_NEW(-h%, 1, 0, "SCROLLUP", 0, 0, 0) '                         create scroll bar up button
950.     WIN(h%).SDButton = BUTTON_NEW(-h%, 1, 0, "SCROLLDOWN", 0, 0, 0) '                       create scroll bar down button
951.     WIN(h%).SLButton = BUTTON_NEW(-h%, 1, 0, "SCROLLLEFT", 0, 0, 0) '                       create scroll bar left button
952.     WIN(h%).SRButton = BUTTON_NEW(-h%, 1, 0, "SCROLLRIGHT", 0, 0, 0) '                      create scroll bar right button
953.     WIN(h%).MinHeight = WIN(h%).TBHeight + WIN(h%).BWidth * 2 + BUT(WIN(h%).SUButton).Height * 4 ' calculate min window height
954.  
955.     WIN(h%).TBFImage = _NEWIMAGE(WIN(h%).SWidth, WIN(h%).TBHeight, 32) '                    create title bar with focus
956.     WIN(h%).TBNFImage = _COPYIMAGE(WIN(h%).TBFImage) '                                      create title bar without focus
957.     WIN(h%).Surface = _NEWIMAGE(WIN(h%).SWidth, WIN(h%).SHeight, 32) '                       create screen image container
958.  
959.  
960.     BUT(WIN(h%).CloseButton).Y = WIN(h%).BWidth + 2 '                                       close button Y location
961.     BUT(WIN(h%).MaxButton).Y = WIN(h%).BWidth + 2 '                                         maximize buttun Y location
962.     BUT(WIN(h%).MinButton).Y = WIN(h%).BWidth + 2 '                                         minimize button Y location
963.     BUT(WIN(h%).RestoreButton).Y = WIN(h%).BWidth + 2 '                                     restore button Y location
964.     BUT(WIN(h%).SUButton).Y = WIN(h%).BWidth + WIN(h%).TBHeight + 1 '                       scroll up button Y location
965.     BUT(WIN(h%).SLButton).X = WIN(h%).BWidth '                                              scroll left button X location
966.  
967.  
968. END IF
969. WIN(h%).Window = _NEWIMAGE(WIN(h%).Width, WIN(h%).Height, 32) '                             create window image container
970.  
971.  
972. BUT(WIN(h%).CloseButton).X = WIN(h%).Width - WIN(h%).BWidth - BUT(WIN(h%).CloseButton).Width - 2 ' close button X location
973. BUT(WIN(h%).MaxButton).X = BUT(WIN(h%).CloseButton).X - BUT(WIN(h%).MaxButton).Width - 2 '  maximize button X location
974. BUT(WIN(h%).MinButton).X = BUT(WIN(h%).MaxButton).X - BUT(WIN(h%).MinButton).Width '        minimize button X location
975. BUT(WIN(h%).RestoreButton).X = BUT(WIN(h%).MaxButton).X '                                   restore button X location
976.  
977.  
978. BUT(WIN(h%).SUButton).X = BUT(WIN(h%).CloseButton).X '                                      scroll up buttom X location
979. BUT(WIN(h%).SDButton).X = BUT(WIN(h%).CloseButton).X '                                      scroll down button X location
980. BUT(WIN(h%).SRButton).X = BUT(WIN(h%).CloseButton).X '                                      scroll right button X location
981. BUT(WIN(h%).SDButton).Y = WIN(h%).Height - WIN(h%).BWidth - BUT(WIN(h%).SDButton).Height '  scroll down button Y location
982. BUT(WIN(h%).SLButton).Y = WIN(h%).Height - WIN(h%).BWidth - BUT(WIN(h%).SDButton).Height '  scroll left button Y location
983. BUT(WIN(h%).SRButton).Y = BUT(WIN(h%).SLButton).Y '                                         scroll left button X location
984.  
985.  
986. IF NOT (WIN(h%).Resize AND ((MOUSE.Border = 1) OR (MOUSE.Border = 4))) THEN '               resizing right or left border?
987.     WIN(h%).TBFImage = _NEWIMAGE(WIN(h%).SWidth, WIN(h%).TBHeight, 32) '                    yes, create title bar with focus
988.     WIN(h%).TBNFImage = _COPYIMAGE(WIN(h%).TBFImage) '                                      create title bar without focus
989.     TBIMAGE h%, 0 '                                                                         draw focused image
990.     TBIMAGE h%, 1 '                                                                         draw unfocused image
991. END IF
992.  
993.  
994. _DEST WIN(h%).Window '                                                                      draw on window image
995. CLS , WIN(h%).Lighter '                                                                     clear window image
996. IF WIN(h%).Focus THEN '                                                             does this window have focus?
997.     _PUTIMAGE (WIN(h%).BWidth, WIN(h%).BWidth), WIN(h%).TBFImage, WIN(h%).Window '  yes, draw focused title bar
998. ELSE '                                                                              no
999.     _PUTIMAGE (WIN(h%).BWidth, WIN(h%).BWidth), WIN(h%).TBNFImage, WIN(h%).Window ' draw unfocused title bar
1000. END IF
1001.  
1002.  
1003.  
1004.  
1005.  
1006. IF WIN(h%).SWidth < WIN(h%).SIWidth THEN
1007.  
1008.     BUT(WIN(h%).SDButton).Y = BUT(WIN(h%).SDButton).Y - BUT(WIN(h%).SDButton).Height '      yes, adjust scroll down button Y
1009.  
1010.     LINE (BUT(WIN(h%).SLButton).X + BUT(WIN(h%).SLButton).Width - 1, BUT(WIN(h%).SLButton).Y)-(BUT(WIN(h%).SRButton).X, BUT(WIN(h%).SRButton).Y + BUT(WIN(h%).SRButton).Height - 1), _RGB32(255, 255, 255), BF
1011.     FOR y% = BUT(WIN(h%).SLButton).Y TO BUT(WIN(h%).SLButton).Y + BUT(WIN(h%).SLButton).Height - 1
1012.         LINE (BUT(WIN(h%).SLButton).X + BUT(WIN(h%).SLButton).Width - 1, y%)-(BUT(WIN(h%).SRButton).X, y%), _RGB32(212, 208, 200), , p&(y% AND 1) ' alternate odd/even pattern
1013.     NEXT y%
1014.     BUTTON_PUT WIN(h%).SLButton, 0, 0, 0
1015.     BUTTON_PUT WIN(h%).SRButton, 0, 0, 0
1016. END IF
1017.  
1018. IF WIN(h%).SHeight < WIN(h%).SIHeight THEN
1019.  
1020.     BUT(WIN(h%).SRButton).X = BUT(WIN(h%).SRButton).X - BUT(WIN(h%).SRButton).Width '       yes, adjust scroll right button X
1021.  
1022.     LINE (BUT(WIN(h%).SUButton).X, BUT(WIN(h%).SUButton).Y + BUT(WIN(h%).SUButton).Height)-(BUT(WIN(h%).SDButton).X + BUT(WIN(h%).SDButton).Width - 1, BUT(WIN(h%).SDButton).Y), _RGB32(255, 255, 255), BF
1023.     FOR x% = BUT(WIN(h%).SUButton).X TO BUT(WIN(h%).SUButton).X + BUT(WIN(h%).SUButton).Width - 1
1024.         LINE (x%, BUT(WIN(h%).SUButton).Y + BUT(WIN(h%).SUButton).Height)-(x%, BUT(WIN(h%).SDButton).Y), _RGB32(212, 208, 200), , p&(x% AND 1)
1025.     NEXT x%
1026.     BUTTON_PUT WIN(h%).SUButton, 0, 0, 0
1027.     BUTTON_PUT WIN(h%).SDButton, 0, 0, 0
1028.  
1029. END IF
1030.  
1031.  
1032. '**
1033. '** Calculate where screen needs to sit inside viewport
1034. '**
1035. '** place window at viewport
1036. '**
1037.  
1038.  
1039.  
1040.  
1041.  
1042.  
1043. IF WIN(h%).BWidth THEN '                                                                    draw a border?
1044.     IF WIN(h%).BWidth = 1 THEN '                                                            yes, 1 pixel border?
1045.         LINE (WIN(h%).Width - 1, 0)-(WIN(h%).Width - 1, WIN(h%).Height - 1), WIN(h%).Dark ' yes, draw border
1046.         LINE -(0, WIN(h%).Height - 1), WIN(h%).Dark
1047.     END IF
1048.     IF WIN(h%).BWidth = 2 THEN '                                                            2 pixel border?
1049.         LINE (0, 0)-(WIN(h%).Width - 1, WIN(h%).Height - 1), WIN(h%).Dark, B '              yes, draw bottom and right border
1050.         LINE (0, 0)-(WIN(h%).Width - 2, WIN(h%).Height - 2), WIN(h%).Light, B '             draw top and left border
1051.     END IF
1052.     IF WIN(h%).BWidth > 2 THEN '                                                            more than 2 pixel border?
1053.         LINE (0, 0)-(WIN(h%).Width - 1, WIN(h%).Height - 1), WIN(h%).Darker, B '            yes, draw bottom and right border
1054.         LINE (0, 0)-(WIN(h%).Width - 2, WIN(h%).Height - 2), WIN(h%).Lighter, B '           draw top and left border
1055.         LINE (1, 1)-(WIN(h%).Width - 2, WIN(h%).Height - 2), WIN(h%).Dark, B '              draw bottom and right middle border
1056.         LINE (1, 1)-(WIN(h%).Width - 3, WIN(h%).Height - 3), WIN(h%).Light, B '             draw top and left middle border
1057.         LINE (2, 2)-(WIN(h%).Width - 3, WIN(h%).Height - 3), WIN(h%).WColor, B
1058.     END IF
1059.     IF WIN(h%).BWidth > 3 THEN '                                                            more than 3 pixel border?
1060.         LINE (WIN(h%).BWidth - 1, WIN(h%).BWidth - 1)-(WIN(h%).Width - WIN(h%).BWidth, WIN(h%).Height - WIN(h%).BWidth), WIN(h%).Light, B
1061.         LINE (WIN(h%).BWidth - 1, WIN(h%).BWidth - 1)-(WIN(h%).Width - WIN(h%).BWidth - 1, WIN(h%).Height - WIN(h%).BWidth - 1), WIN(h%).Dark, B
1062.     END IF
1063.  
1064.     LINE (WIN(h%).BWidth, WIN(h%).BWidth + WIN(h%).TBHeight)-(WIN(h%).Width - WIN(h%).BWidth - 1, WIN(h%).BWidth + WIN(h%).TBHeight), _RGB32(0, 0, 0)
1065.  
1066. END IF
1067.  
1068.  
1069. _DEST CurrentDest&
1070.  
1071. END SUB
1072.  
1073. '--------------------------------------------------------------------------------------------------------------------------------
1074. '                                                                                                                      WINDOW_NEW
1075. FUNCTION WINDOW_NEW (w%, h%)
1076. '
1077. ' w% = width of window work space
1078. ' h% = height of window work space
1079. '
1080. ' returns = integer handle number to reference window with
1081. '
1082. SHARED WIN() AS WIN ' window array
1083. SHARED WinOrder%()
1084. SHARED QB64Icon&
1085.  
1086. DIM i% ' next available window array index
1087. DIM c% ' generic counter
1088.  
1089. i% = UBOUND(WIN) '                                 get last window index
1090. WHILE NOT WIN(i%).InUse AND i% > 1 '               is window in use?
1091.     REDIM _PRESERVE WIN(i% - 1) AS WIN '           no, remove it
1092.     i% = i% - 1 '                                  go to previous index
1093. WEND
1094. i% = 0 '                                           start at beginning
1095. c% = 1
1096. DO '                                               cycle through window indexes
1097.     IF NOT WIN(c%).InUse THEN '                    window is use?
1098.         i% = c% '                                  no, use this index
1099.     ELSE '                                         yes
1100.         c% = c% + 1 '                              increment index counter
1101.         IF c% > UBOUND(WIN) THEN '                 reached end of windows?
1102.             REDIM _PRESERVE WIN(c%) AS WIN '       yes, create a new window
1103.             i% = c% '                              use this index
1104.         END IF
1105.     END IF
1106. LOOP UNTIL i% '                                    leave when available index found
1107. WIN(i%).InUse = -1 '                               mark index as used
1108. WIN(i%).Visible = 0 '                              set window invisible
1109.  
1110. WIN(i%).SIWidth = w% '                             set screen image width
1111. WIN(i%).SIHeight = h% '                            set screen image height
1112. WIN(i%).SWidth = w% '                              set window screen width
1113. WIN(i%).SHeight = h% '                             set window screen  height
1114.  
1115. WIN(i%).X = 0 '                                    set window x location
1116. WIN(i%).Y = 0 '                                    set window y location
1117. WIN(i%).BWidth = 3 '                               set border width
1118. WIN(i%).Font = _FONT
1119. WIN(i%).Title = ""
1120. WIN(i%).Icon = QB64Icon&
1121. WIN(i%).WColor = _RGB32(212, 208, 200) '           set window color
1122. WIN(i%).TBColor = _RGB32(10, 40, 100) '            set title bar color
1123. WIN(i%).TTColor = _RGB32(255, 255, 255) '          set title bar text color
1124. WIN(i%).TBSolid = -1
1125. WIN(i%).Shadow = 0 '                               set window shadow (off)
1126. WIN(i%).Focus = 0 '                                set window without focus
1127. WIN(i%).Move = 0
1128. WIN(i%).Resize = 0
1129. WIN(i%).Size = 0
1130. WIN(i%).CloseButton = 0
1131. WIN(i%).MaxButton = 0
1132. WIN(i%).MinButton = 0
1133. WIN(i%).RestoreButton = 0
1134. WIN(i%).SUButton = 0
1135. WIN(i%).SDButton = 0
1136. WIN(i%).SLButton = 0
1137. WIN(i%).SRButton = 0
1138. WIN(i%).Maximized = 0
1139. WIN(i%).Minimized = 0
1140. REDIM _PRESERVE WinOrder%(UBOUND(WinOrder%) + 1) ' increase window order array
1141. WinOrder%(UBOUND(WinOrder%)) = i% '                add window to order array
1142. WINDOW_NEW = i% '                                  return window handle
1143.  
1144.  
1145. END FUNCTION
1146.  
1147. '--------------------------------------------------------------------------------------------------------------------------------
1148. '                                                                                                                 WINDOW_SETTITLE
1149. SUB WINDOW_SETTITLE (h%, t$)
1150.  
1151. SHARED WIN() AS WIN ' window array
1152.  
1153. WIN(h%).Title = t$ '                                                               set title of window
1154.  
1155. END SUB
1156.  
1157. '--------------------------------------------------------------------------------------------------------------------------------
1158. '                                                                                                                  WINDOW_SETFONT
1159. SUB WINDOW_SETFONT (h%, f&)
1160.  
1161. SHARED WIN() AS WIN ' window array
1162.  
1163. WIN(h%).Font = f& '                                                                set window font
1164.  
1165. END SUB
1166.  
1167. '--------------------------------------------------------------------------------------------------------------------------------
1168. '                                                                                                                WINDOW_SETBORDER
1169. SUB WINDOW_SETBORDER (h%, w%)
1170.  
1171. SHARED WIN() AS WIN ' window array
1172.  
1173. WIN(h%).BWidth = w%
1174.  
1175. END SUB
1176.  
1177. '--------------------------------------------------------------------------------------------------------------------------------
1178. '                                                                                                                 WINDOW_SETCOLOR
1179. SUB WINDOW_SETCOLOR (h%, c~&)
1180.  
1181. SHARED WIN() AS WIN ' window array
1182.  
1183. WIN(h%).WColor = c~& '                                              set window color
1184.  
1185. END SUB
1186.  
1187. '--------------------------------------------------------------------------------------------------------------------------------
1188. '                                                                                                         WINDOW_SETTITLEBARCOLOR
1189. SUB WINDOW_SETTITLEBARCOLOR (h%, c~&)
1190.  
1191. SHARED WIN() AS WIN ' window array
1192.  
1193. WIN(h%).TBColor = c~& '                                               set title bar color
1194.  
1195. END SUB
1196.  
1197. '--------------------------------------------------------------------------------------------------------------------------------
1198. '                                                                                                                     WINDOW_SHOW
1199. SUB WINDOW_SHOW (h%)
1200.  
1201. SHARED WIN() AS WIN ' window array
1202.  
1203. WIN(h%).Visible = -1
1204.  
1205. END SUB
1206.  
1207. '--------------------------------------------------------------------------------------------------------------------------------
1208. '                                                                                                                     WINDOW_HIDE
1209. SUB WINDOW_HIDE (h%)
1210.  
1211. SHARED WIN() AS WIN ' window array
1212.  
1213. WIN(h%).Visible = 0
1214.  
1215. END SUB
1216.  
1217. '--------------------------------------------------------------------------------------------------------------------------------
1218. '                                                                                                                        POINTERS
1219. SUB POINTERS ()
1220.  
1221. SHARED POINTER() AS MOUSEPOINTERS
1222.  
1223. DIM Icon$
1224.  
1225. Icon$ = "b           bb          bwb         bwwb        bwwwb       bwwwwb      bwwwwwb     bwwwwwwb    "+_
1226.         "bwwwwwwwb   bwwwwwwwwb  bwwwwwwwwwb bwwwwwwbbbbbbwwwbwwb    bwwbbwwb    bwb  bwwb   bb   bwwb   "+_
1227.         "b     bwwb        bwwb         bwwb        bwwb         bb  "
1228. MAKEICON 0, Icon$, 12, 21, 0, 0 ' default - 12x21 - offset 0,0
1229. Icon$ = "    w       wbw     wbbbw   wbbbbbw wbbbbbbbwwwwwbwwww   wbw      wbw      wbw      wbw   "+_
1230.         "   wbw      wbw      wbw      wbw      wbw   wwwwbwwwwwbbbbbbbw wbbbbbw   wbbbw     wbw       w    "
1231. MAKEICON 1, Icon$, 9, 21, -4, -10 ' NS resize - 9x21 - offset 5,11
1232. Icon$ = "    ww         ww       wbw         wbw     wbbw         wbbw   wbbbwwwwwwwwwwwbbbw wbbbbbbbbbbbbbbbbbbbw"+_
1233.         " wbbbwwwwwwwwwwwbbbw   wbbw         wbbw     wbw         wbw       ww         ww    "
1234. MAKEICON 2, Icon$, 21, 9, -10, -4 ' EW resize - 21x9 - offset 11,5
1235. Icon$ = "        wwwwwww        wbbbbbw         wbbbbw          wbbbw         wbwbbw        wbw wbw"+_
1236.         "       wbw   ww      wbw      ww   wbw       wbw wbw        wbbwbw         wbbbw          "+_
1237.         "wbbbbw         wbbbbbw        wwwwwww        "
1238. MAKEICON 3, Icon$, 15, 15, -7, -7 ' NESW resize - 15x15 - offset 8,8
1239. Icon$ = "     bb              bwwb             bwwb             bwwb             bwwb             bwwbbb       "+_
1240.         "    bwwbwwbbb        bwwbwwbwwbb      bwwbwwbwwbwb bbb bwwbwwbwwbwwbbwwbbwwwwwwwwbwwbbwwwbwwwwwwwwwwwb"+_
1241.         " bwwbwwwwwwwwwwwb  bwbwwwwwwwwwwwb  bwwwwwwwwwwwwwb   bwwwwwwwwwwwwb   bwwwwwwwwwwwb     bwwwwwwwwwwb "+_
1242.         "    bwwwwwwwwwwb      bwwwwwwwwb       bwwwwwwwwb       bbbbbbbbbb  "
1243. MAKEICON 5, Icon$, 17, 22, -5, 0 ' pointer (hand) - 17x22 - offset 6,0
1244. Icon$ = "wwwwwww        wbbbbbw        wbbbbw         wbbbw          wbbwbw         wbw wbw        "+_
1245.         "ww   wbw             wbw             wbw   ww        wbw wbw         wbwbbw          wbbbw"+_
1246.         "         wbbbbw        wbbbbbw        wwwwwww"
1247. MAKEICON 6, Icon$, 15, 15, -7, -7 ' NWSE resize - 15x15 - offset 8,8
1248. Icon$ = "bbbbbbbbbbbbbbbwwwwwwwwwbbbbbbbbbbbbbbb bwwwwwwwwwb  bwwwwwwwwwb  bwwbwbwbwwb  bwwwbwbwwwb "+_
1249.         " bbwwwbwwwbb   bbwwwwwbb     bbwbwbb       bbwbb        bbwbb       bbwwwbb     bbwwbwwbb  "+_
1250.         " bbwwwwwwwbb  bwwwwbwwwwb  bwwwbwbwwwb  bwwbwbwbwwb  bwbwbwbwbwb bbbbbbbbbbbbbbbwwwwwwwwwbbbbbbbbbbbbbbb"
1251. MAKEICON 7, Icon$, 13, 22, -6, -10 ' wait - 13x22 - offset 7,11
1252. Icon$ = "          w                   wbw                 wbbbw               wbbbbbw             wbbbbbbbw      "+_
1253.         "      wwwwbwwww          ww   wbw   ww       wbw   wbw   wbw     wbbw   wbw   wbbw   wbbbwwwwwbwwwwwbbbw "+_
1254.         "wbbbbbbbbbbbbbbbbbbbw wbbbwwwwwbwwwwwbbbw   wbbw   wbw   wbbw     wbw   wbw   wbw       ww   wbw   ww    "+_
1255.         "      wwwwbwwww            wbbbbbbbw             wbbbbbw               wbbbw                 wbw         "+_
1256.         "          w          "
1257. MAKEICON 10, Icon$, 21, 21, -10, -10 ' move - 21x21 - offset 11,11
1258. Icon$ = "        www                wbw                wbw                wbw                wbw        "+_
1259.         "        wbw                wbw                wbw        wwwwwwwwwbwwwwwwwwwwbbbbbbbbbbbbbbbbbw"+_
1260.         "wwwwwwwwwbwwwwwwwww        wbw                wbw                wbw                wbw        "+_
1261.         "        wbw                wbw                wbw                www        "
1262. MAKEICON 11, Icon$, 19, 19, -9, -9 ' crosshair - 19x19 - offset 10,10
1263. Icon$ = "wwww wwwwwbbbwbbbwwwwwbwwww   wbw      wbw      wbw      wbw      wbw      wbw      wbw   "+_
1264.         "   wbw      wbw      wbw      wbw      wbw   wwwwbwwwwwbbbwbbbwwwww wwww"
1265. MAKEICON 13, Icon$, 9, 18, -4, -8 ' text - 9x18 - offset 5,9
1266. Icon$ = "       wwwwww            wwbbbbbbww         wbbbbbbbbbbw       wbbbbwwwwbbbbw     wbbbww    wwbbbw  "+_
1267.         " wbbbbbw      wbbbw  wbbwbbbw      wbbw wbbbwwbbbw     wbbbwwbbw  wbbbw     wbbwwbbw   wbbbw    wbbw"+_
1268.         "wbbw    wbbbw   wbbwwbbw     wbbbw  wbbwwbbbw     wbbbwwbbbw wbbw      wbbbwbbw  wbbbw      wbbbbbw "+_
1269.         "  wbbbww    wwbbbw     wbbbbwwwwbbbbw       wbbbbbbbbbbw         wwbbbbbbww            wwwwww       "
1270. MAKEICON 14, Icon$, 20, 20, -9, -9 ' not-allowed - 20x20 - offset 10,10
1271. Icon$ = "11111111111111111111121133333331144444444112113355533114455554411211335553311445555441121133555331144444441112"+_
1272.         "11335553311444444411121133555331144555544112113355533114455554411211333333311444444441121133333331144444444112"+_
1273.         "11113331111111111111121111111111111111111112116666666117711117711211661111111771111771121166111111177111177112"+_
1274.         "11666666611777777771121166666661177777777112116655566111111117711211665556611111111771121166666661111111177112"+_
1275.         "11111111111111111111122222222222222222222222"
1276. MAKEICON -1, Icon$, 22, 22, 0, 0 ' QB64 - 22x22
1277.  
1278. POINTER(4) = POINTER(1)
1279. POINTER(8) = POINTER(2)
1280. POINTER(9) = POINTER(6)
1281. POINTER(12) = POINTER(3)
1282.  
1283. END SUB
1284.  
1285.  
1286. '--------------------------------------------------------------------------------------------------------------------------------
1287. '                                                                                                                        MAKEICON
1288. SUB MAKEICON (n%, i$, w%, h%, xo%, yo%)
1289.  
1290. SHARED POINTER() AS MOUSEPOINTERS
1291. SHARED QB64Icon&
1292.  
1293. DIM x%
1294. DIM y%
1295. DIM p$
1296. DIM c%
1297.  
1298. IF n% = -1 THEN
1299.     QB64Icon& = _NEWIMAGE(22, 22, 32)
1300.     _DEST QB64Icon&
1301. ELSE
1302.     POINTER(n%).Icon = _NEWIMAGE(w%, h%, 32)
1303.     POINTER(n%).X = xo%
1304.     POINTER(n%).Y = yo%
1305.     _DEST POINTER(n%).Icon
1306. END IF
1307. FOR y% = 0 TO h% - 1
1308.     FOR x% = 0 TO w% - 1
1309.         c% = c% + 1
1310.         p$ = MID$(i$, c%, 1)
1311.         IF p$ = "b" THEN PSET (x%, y%), _RGB32(0, 0, 1)
1312.         IF p$ = "w" THEN PSET (x%, y%), _RGB32(255, 255, 255)
1313.         IF p$ = "1" THEN PSET (x%, y%), _RGB32(0, 0, 252)
1314.         IF p$ = "2" THEN PSET (x%, y%), _RGB32(0, 0, 112)
1315.         IF p$ = "3" THEN PSET (x%, y%), _RGB32(0, 188, 252)
1316.         IF p$ = "4" THEN PSET (x%, y%), _RGB32(0, 124, 252)
1317.         IF p$ = "5" THEN PSET (x%, y%), _RGB32(0, 0, 168)
1318.         IF p$ = "6" THEN PSET (x%, y%), _RGB32(252, 188, 0)
1319.         IF p$ = "7" THEN PSET (x%, y%), _RGB32(252, 124, 0)
1320.     NEXT x%
1321. NEXT y%
1322.  
1323. END SUB
1324.  
1325. '--------------------------------------------------------------------------------------------------------------------------------
1326. '                                                                                                                 CALCULATECOLORS
1327. SUB CALCULATECOLORS (h%)
1328.  
1329. SHARED WIN() AS WIN
1330.  
1331. WIN(h%).Wred = _RED(WIN(h%).WColor) '                                                     get RGB components of window color
1332. WIN(h%).Wgreen = _GREEN(WIN(h%).WColor)
1333. WIN(h%).Wblue = _BLUE(WIN(h%).WColor)
1334. WIN(h%).Lighter = _RGB32(WIN(h%).Wred * 1.5, WIN(h%).Wgreen * 1.5, WIN(h%).Wblue * 1.5) ' calculate window/border color shades
1335. WIN(h%).Light = _RGB32(WIN(h%).Wred * 1.25, WIN(h%).Wgreen * 1.25, WIN(h%).Wblue * 1.25)
1336. WIN(h%).Dark = _RGB32(WIN(h%).Wred / 1.25, WIN(h%).Wgreen / 1.25, WIN(h%).Wblue / 1.25)
1337. WIN(h%).Darker = _RGB32(WIN(h%).Wred / 1.5, WIN(h%).Wgreen / 1.5, WIN(h%).Wblue / 1.5)
1338. WIN(h%).Darkest = _RGB32(WIN(h%).Wred / 2, WIN(h%).Wgreen / 2, WIN(h%).Wblue / 2)
1339.  
1340. END SUB
1341.  
1342. '--------------------------------------------------------------------------------------------------------------------------------
1343. '                                                                                                                  MOUSEMOVEMENTY
1344. FUNCTION MOUSEMOVEMENTY ()
1345. '
1346. ' returns the mouse y coordinate difference between calls
1347. '
1348. SHARED MOUSE AS MOUSEFLAGS
1349.  
1350. STATIC y% ' previous call's mouse y coordinate (saved between calls)
1351.  
1352. MOUSEMOVEMENTY = MOUSE.Y - y% ' calculate mouse y offset from previous call
1353. y% = MOUSE.Y '                  save current mouse y coordinate
1354.  
1355. END FUNCTION
1356.  
1357. '--------------------------------------------------------------------------------------------------------------------------------
1358. '                                                                                                                  MOUSEMOVEMENTX
1359. FUNCTION MOUSEMOVEMENTX ()
1360. '
1361. ' returns the mouse x coordinate difference between calls
1362. '
1363. SHARED MOUSE AS MOUSEFLAGS
1364.  
1365. STATIC x% ' previous call's mouse x coordinate (saved between calls)
1366.  
1367. MOUSEMOVEMENTX = MOUSE.X - x% ' calculate mouse x offset from previous call
1368. x% = MOUSE.X '                  save current mouse x coordinate
1369.  
1370. END FUNCTION
1371.  
1372.  
1373.  

Title: Re: child windows into window of the program: a demonstration
Post by: keybone on February 19, 2020, 03:19:59 pm

Quote from: TerryRitchie on February 19, 2020, 02:57:06 pm

I was tinkering around with GUI structures a few years back. Here is the code. It may give you some ideas for your code. You can resize the windows by clicking and holding the bottom right corner of the window, just like Windows.

Code: QB64: [Select]

1. 'GUI 02/27/16
2.  
3. CONST BYWINDOW = 0
4. CONST BYSCREEN = -1
5. CONST ALLWINDOWS = 0
6.  
7. TYPE MOUSEFLAGS
8.     OnWindow AS INTEGER '              current window pointer is hovering over
9.     Icon AS INTEGER '                  current mouse pointer icon
10.     X AS INTEGER '                     current desktop mouse x coordinate
11.     Y AS INTEGER '                     current desktop mouse y coordinate
12.     PX AS INTEGER '                    previous desktop mouse x coordinate
13.     PY AS INTEGER '                    previous desktop mouse y coordinate
14.     WindowX AS INTEGER '               current window mouse x coordinate
15.     WindowY AS INTEGER '               current window mouse y coordinate
16.     SurfaceX AS INTEGER '              current work space mouse x coordinate
17.     SurfaceY AS INTEGER '              current work space mouse y coordinate
18.     OnSurface AS INTEGER '      [BOOL] mouse currently hovering over surface?
19.     OnTitlebar AS INTEGER '     [BOOL] mouse currently hovering over title bar?
20.     OnBorder AS INTEGER '       [BOOL] mouse currently hovering over a border?
21.     Border AS INTEGER '                border(s) mouse hovering (1-top, 2-right, 4-bottom, 8-left ... i.e. 6 = bottom right corner)
22.     LeftClick AS INTEGER '      [BOOL] mouse left button currently pressed?
23.     RightClick AS INTEGER '     [BOOL] mouse right button currently pressed?
24.     Move AS INTEGER '                  window currently in the process of being moved
25.     Resize AS INTEGER '                current window being resized
26.     LeftReleased AS INTEGER '   [BOOL] left mouse button released?
27.     RightReleased AS INTEGER '  [BOOL] right mouse button released?
28.  
29.     OnButton AS INTEGER '              current button pointer is hovering over
30.     ButtonPressed AS INTEGER '         current button being held down
31.     ButtonClicked AS INTEGER '         button that was clicked then released
32.  
33.  
34. END TYPE
35.  
36. TYPE WINDOWFLAGS
37.     X AS INTEGER '                     x location of current window
38.     Y AS INTEGER '                     y location of current window
39.     Width AS INTEGER '                 width of current window
40.     Height AS INTEGER '                height of current window
41.     Surface AS LONG '            [IMG]  window surface image
42.     SurfaceX AS INTEGER '              x location of current work space
43.     SurfaceY AS INTEGER '              y location of current workspace
44.     SWidth AS INTEGER '                width of current surface
45.     SHeight AS INTEGER '               height of current surface
46.     Focus AS INTEGER '                 the window that has focus
47.     HasFocus AS INTEGER '       [BOOL] current window has focus?
48. END TYPE
49.  
50. TYPE WIN
51.     Width AS INTEGER '                 overall window width
52.     Height AS INTEGER '                overall window height
53.  
54.     OWidth AS INTEGER '                original width
55.     OHeight AS INTEGER
56.  
57.     SWidth AS INTEGER '                surface width
58.     SHeight AS INTEGER '               surface height
59.  
60.     SIWidth AS INTEGER '               surface image width
61.     SIHeight AS INTEGER '              surface image height
62.  
63.     MinWidth AS INTEGER
64.     MaxWidth AS INTEGER
65.     MinHeight AS INTEGER
66.     MaxHeight AS INTEGER
67.  
68.  
69.     X AS INTEGER '                     window x location
70.     Y AS INTEGER '                     window y location
71.     SurfaceX AS INTEGER '              surface x location
72.     SurfaceY AS INTEGER '              surface y location
73.     Font AS LONG '              [FONT] window font
74.     InUse AS INTEGER '          [BOOL] window in use?
75.     Window AS LONG '            [IMG]  window image
76.     Surface AS LONG '           [IMG]  surface image
77.     BGImage AS LONG '           [IMG]  background image under window
78.     TBFImage AS LONG '          [IMG]  title bar image when window has focus
79.     TBNFImage AS LONG '         [IMG]  title bar image when window has lost focus
80.     Shadow AS INTEGER '         [BOOL] shadow present
81.     BWidth AS INTEGER '                border width
82.     TBHeight AS INTEGER '              title bar height
83.     WColor AS _UNSIGNED LONG '  [CLR]  window color
84.     Wred AS INTEGER '           [CLR]  red component of Wcolor
85.     Wgreen AS INTEGER '         [CLR]  green component of Wcolor
86.     Wblue AS INTEGER '          [CLR]  blue component of Wcolor
87.     TBColor AS _UNSIGNED LONG ' [CLR]  title bar color
88.     TTColor AS _UNSIGNED LONG ' [CLR]  title text color
89.     Title AS STRING * 128 '            window title
90.     Visible AS INTEGER '        [BOOL] window on screen?
91.     Focus AS INTEGER '          [BOOL] window has focus?
92.  
93.     'ByMethod AS INTEGER '       [BOOL] -1 = window dimensions by surface, 0 = dimensions by window
94.  
95.     Move AS INTEGER '           [BOOL] window currently being moved?
96.     Resize AS INTEGER '         [BOOL] window currently being resized
97.     Lighter AS _UNSIGNED LONG ' [CLR]  border colors
98.     Light AS _UNSIGNED LONG '   [CLR]
99.     Dark AS _UNSIGNED LONG '    [CLR]
100.     Darker AS _UNSIGNED LONG '  [CLR]
101.     Darkest AS _UNSIGNED LONG ' [CLR]
102.     Icon AS LONG '              [IMG]  window icon
103.     TBSolid AS INTEGER '        [BOOL] solid title bar?
104.     Size AS INTEGER '           [BOOL] window resizable?
105.  
106.     CloseButton AS INTEGER '           0 = no button, >0 = button handle number
107.     MaxButton AS INTEGER
108.     MinButton AS INTEGER
109.     RestoreButton AS INTEGER
110.     SUButton AS INTEGER
111.     SDButton AS INTEGER
112.     SLButton AS INTEGER
113.     SRButton AS INTEGER
114.  
115.     Maximized AS INTEGER '             -1 window currently maximized, 0 = normal  (use 'state' instead for max/min/normal?)
116.     Minimized AS INTEGER '             -1 window currently minimized
117.  
118.     Rwidth AS INTEGER '                restore width  (when max or min - values to restore window size)
119.     Rheight AS INTEGER '               restore height
120.  
121. END TYPE
122.  
123. TYPE BUTTON
124.     InUse AS INTEGER '          [BOOL] button in use?
125.     X AS INTEGER
126.     Y AS INTEGER
127.     Width AS INTEGER
128.     Height AS INTEGER
129.     State AS INTEGER '                 state of button: -1 = pressed, 0 = normal, 1 = disabled
130.     Normal AS LONG '            [IMG]  normal button
131.     Pressed AS LONG '           [IMG]  pressed button
132.     Disabled AS LONG '          [IMG]  disabled button
133.     Window AS INTEGER '                window button belongs to
134.     WinButton AS INTEGER '      [BOOL] indicates a button for window use only (scroll bar buttons, etc..)
135. END TYPE
136.  
137. TYPE MOUSEPOINTERS
138.     Icon AS LONG '              [IMG]  mouse pointer image
139.     X AS INTEGER '                     x offset of pointer
140.     Y AS INTEGER '                     y offset of pointer
141. END TYPE
142.  
143. REDIM WIN(1) AS WIN
144. REDIM BUT(1) AS BUTTON
145. REDIM WinOrder%(0)
146. DIM POINTER(15) AS MOUSEPOINTERS
147. DIM QB64Icon&
148. DIM WIN AS WINDOWFLAGS
149. DIM MOUSE AS MOUSEFLAGS
150.  
151. DIM DeskTop&
152.  
153. DIM untitled%(10)
154.  
155.  
156. POINTERS
157.  
158. WINDOW_DESKTOP 1024, 768, 0, ""
159.  
160.  
161. _FONT 14
162.  
163. _MOUSEHIDE
164.  
165. 'FOR i% = 1 TO 10
166. '    untitled%(i%) = WINDOW_NEW(320, 240)
167. '    WINDOW_SETTITLE untitled%(i%), "Untitled-" + LTRIM$(STR$(i%))
168. '    WIN(untitled%(i%)).TBSolid = 0
169. '    WINDOW_MAKE untitled%(i%)
170. '    WINDOW_SHOW untitled%(i%)
171. '    WINDOW_PUT untitled%(i%), 140 + i% * 25, 20 + i% * 25, BYWINDOW
172. '    WIN(untitled%(i%)).Size = -1
173. 'NEXT i%
174.  
175.  
176. untitled1% = WINDOW_NEW(640, 480)
177. untitled2% = WINDOW_NEW(320, 240)
178. untitled3% = WINDOW_NEW(160, 120)
179.  
180. WINDOW_SETTITLE untitled1%, "Untitled-1"
181. WINDOW_SETTITLE untitled2%, "Untitled-2"
182. WINDOW_SETTITLE untitled3%, "Untitled-3"
183.  
184. WIN(untitled2%).TBSolid = 0 '                    need to create library command for this
185.  
186.  
187. WINDOW_MAKE untitled3%
188. WINDOW_MAKE untitled2%
189. WINDOW_MAKE untitled1%
190.  
191. WINDOW_SHOW untitled1%
192. WINDOW_SHOW untitled2%
193. WINDOW_SHOW untitled3%
194.  
195. WINDOW_PUT untitled3%, 150, 25, BYWINDOW
196. WINDOW_PUT untitled2%, 200, 100, BYWINDOW
197. WINDOW_PUT untitled1%, 300, 200, BYWINDOW
198.  
199.  
200. WIN(untitled1%).Size = -1 '                      need to create library command for this
201. WIN(untitled2%).Size = -1 '                      need to create library command for this
202. WIN(untitled3%).Size = -1 '                      need to create library command for this
203.  
204.  
205. DO
206.     IF _MOUSEINPUT THEN WINDOW_MOUSE
207.     WINDOW_REFRESH
208.     LOCATE 1, 1
209.     PRINT " Focus ------> "; WinOrder%(1)
210.     PRINT " Mouse X ----> "; MOUSE.X
211.     PRINT " Mouse Y ----> "; MOUSE.Y
212.     PRINT " On Window --> "; MOUSE.OnWindow
213.     PRINT " Window X ---> "; MOUSE.WindowX
214.     PRINT " Window Y ---> "; MOUSE.WindowY
215.     PRINT " On Surface -> "; MOUSE.OnSurface
216.     PRINT " Surface X---> "; MOUSE.SurfaceX
217.     PRINT " Surface Y --> "; MOUSE.SurfaceY
218.     PRINT " On TitleBar > "; MOUSE.OnTitlebar
219.     PRINT " On Border --> "; MOUSE.OnBorder
220.     PRINT " Border -----> "; MOUSE.Border
221.     PRINT " Left Click -> "; MOUSE.LeftClick
222.     PRINT " Right Click > "; MOUSE.RightClick
223.     PRINT " Moving -----> "; MOUSE.Move
224.     PRINT " Resizing ---> "; MOUSE.Resize
225.     PRINT " On Button --> "; MOUSE.OnButton
226.     PRINT " Button Press> "; MOUSE.ButtonPressed
227.     PRINT " Button Click> "; MOUSE.ButtonClicked
228.     _DISPLAY
229. LOOP UNTIL _KEYDOWN(27)
230.  
231.  
232.  
233.  
234.  
235. '--------------------------------------------------------------------------------------------------------------------------------
236. '                                                                                                                         TBIMAGE
237. SUB TBIMAGE (h%, f%)
238.  
239. ' h% = window handle
240. ' f% = focus 1, no focus 0
241.  
242. SHARED WIN() AS WIN ' window array
243. SHARED BUT() AS BUTTON
244.  
245. DIM c% '                  generic counter
246. DIM Red!, Green!, Blue!
247. DIM Redinc!, Greeninc!, Blueinc!
248.  
249. IF f% THEN
250.     _DEST WIN(h%).TBFImage '                                                                draw on title bar focus image
251.     _FONT WIN(h%).Font '                                                                    set title bar font
252.     _PRINTMODE _KEEPBACKGROUND '                                                            font will be transparent
253.     COLOR WIN(h%).TTColor '                                                                 set font color
254.     CLS , WIN(h%).TBColor '                                                             yes, color title bar
255.     IF NOT WIN(h%).TBSolid THEN
256.         Red! = _RED(WIN(h%).TBColor) '                                                      get title bar color components
257.         Green! = _GREEN(WIN(h%).TBColor)
258.         Blue! = _BLUE(WIN(h%).TBColor)
259.         Redinc! = (255 - Red!) / WIN(h%).SWidth / 2 '                                       calculate color fade values
260.         Greeninc! = (255 - Green!) / WIN(h%).SWidth / 2
261.         Blueinc! = (255 - Blue!) / WIN(h%).SWidth / 2
262.     END IF
263. ELSE
264.     _DEST WIN(h%).TBNFImage
265.     _FONT WIN(h%).Font
266.     _PRINTMODE _KEEPBACKGROUND
267.     COLOR _RGB32(212, 208, 200)
268.     CLS , _RGB32(128, 128, 128)
269.     IF NOT WIN(h%).TBSolid THEN
270.         Red! = 128
271.         Green! = 128
272.         Blue! = 128
273.         Redinc! = 63 / WIN(h%).SWidth
274.         Greeninc! = 63 / WIN(h%).SWidth
275.         Blueinc! = 63 / WIN(h%).SWidth
276.     END IF
277. END IF
278. IF NOT WIN(h%).TBSolid THEN
279.     FOR c% = 0 TO WIN(h%).SWidth - 1
280.         LINE (c%, 0)-(c%, WIN(h%).TBHeight - 1), _RGB32(Red!, Green!, Blue!)
281.         Red! = Red! + Redinc!
282.         Green! = Green! + Greeninc!
283.         Blue! = Blue! + Blueinc!
284.     NEXT c%
285. END IF
286. w% = _PRINTWIDTH("#") + 6
287.  
288. IF WIN(h%).CloseButton THEN w% = w% + BUT(WIN(h%).CloseButton).Width
289. IF WIN(h%).MaxButton THEN w% = w% + BUT(WIN(h%).MaxButton).Width
290. IF WIN(h%).MinButton THEN w% = w% + BUT(WIN(h%).MinButton).Width
291.  
292. mw% = WIN(h%).SWidth - (WIN(h%).TBHeight + 2) - w%
293. t$ = RTRIM$(WIN(h%).Title)
294. WIN(h%).MinWidth = _PRINTWIDTH(LEFT$(t$, 3) + "...") + WIN(h%).TBHeight + 2 + w%
295. nt$ = t$
296. WHILE _PRINTWIDTH(nt$) > mw%
297.     t$ = LEFT$(t$, LEN(t$) - 1)
298.     nt$ = t$ + "..."
299. WEND
300. _PRINTSTRING (WIN(h%).TBHeight + 2, 4), nt$ '                         print title on title bar
301. _PUTIMAGE (2, 1)-(WIN(h%).TBHeight - 1, WIN(h%).TBHeight - 2), WIN(h%).Icon '           place icon on title bar
302.  
303. END SUB
304.  
305. '--------------------------------------------------------------------------------------------------------------------------------
306. '                                                                                                                          WITHIN
307. FUNCTION WITHIN (x%, y%, x2%, y2%)
308.  
309. '*
310. '* Returns true if mouse pointer within given coordinate pairs.
311. '*
312.  
313. SHARED MOUSE AS MOUSEFLAGS
314.  
315. IF MOUSE.X >= x% THEN '              mouse pointer inside given rectangle?
316.     IF MOUSE.X <= x2% THEN
317.         IF MOUSE.Y >= y% THEN
318.             IF MOUSE.Y <= y2% THEN
319.                 WITHIN = -1 '        yes, return true
320.             END IF
321.         END IF
322.     END IF
323. END IF
324.  
325. END FUNCTION
326.  
327. '--------------------------------------------------------------------------------------------------------------------------------
328. '                                                                                                                      BUTTON_PUT
329. SUB BUTTON_PUT (b%, x%, y%, state%) ' state% needed?
330.  
331. SHARED WIN() AS WIN
332. SHARED BUT() AS BUTTON
333.  
334. IF BUT(b%).WinButton THEN '                                                                  is button for window use only?
335.     SELECT CASE BUT(b%).State '                                                              which state is title bar button in?
336.         CASE -1 '                                                                            pressed state
337.             _PUTIMAGE (BUT(b%).X, BUT(b%).Y), BUT(b%).Pressed, WIN(BUT(b%).Window).Window '  draw pressed button on window
338.         CASE 0 '                                                                             normal (depressed) state
339.             _PUTIMAGE (BUT(b%).X, BUT(b%).Y), BUT(b%).Normal, WIN(BUT(b%).Window).Window '   draw normal button on window
340.         CASE 1 '                                                                             disabled state
341.             _PUTIMAGE (BUT(b%).X, BUT(b%).Y), BUT(b%).Disabled, WIN(BUT(b%).Window).Window ' draw disabled button on window
342.     END SELECT
343. ELSE
344.  
345.     '*
346.     '* Custom made buttons here
347.     '*
348.  
349. END IF
350.  
351. END SUB
352.  
353. '--------------------------------------------------------------------------------------------------------------------------------
354. '                                                                                                                      BUTTON_NEW
355. FUNCTION BUTTON_NEW (win%, w%, h%, t$, f&, c~&, t~&)
356. '*
357. '* win% - window button belongs to (negative value sent in means a title bar button is being created)
358. '* w%   - width of button (ignored if title bar button is being created)
359. '* h%   - height of button (ignored if title bar button is being created)
360. '* t$   - text to be placed on button (if title bar button then "CLOSE", "MAXIMIZE", "MINIMIZE', and "RESTORE")
361. '* f&   - text font (ignored if title bar button is being created)
362. '* c~&  - button color (if 0 then window color is used)
363. '* t~&  - text color (if 0 then balck is used)
364. '*
365. SHARED WIN() AS WIN
366. SHARED BUT() AS BUTTON
367.  
368. DIM i% ' next available button array index
369. DIM c% ' generic counter
370.  
371. i% = UBOUND(BUT) '                                                              get last button index
372. WHILE NOT BUT(i%).InUse AND i% > 1 '                                            is button in use?
373.     REDIM _PRESERVE BUT(i% - 1) AS BUTTON '                                     no, remove it
374.     i% = i% - 1 '                                                               go to previous index
375. WEND '                                                                          leave when last button still being used
376. i% = 0 '                                                                        start at beginning
377. c% = 1
378. DO '                                                                            cycle through button indexes
379.     IF NOT BUT(c%).InUse THEN '                                                 button in use?
380.         i% = c% '                                                               no, use this index
381.     ELSE '                                                                      yes
382.         c% = c% + 1 '                                                           increment index counter
383.         IF c% > UBOUND(BUT) THEN '                                              reached end of buttons?
384.             REDIM _PRESERVE BUT(c%) AS BUTTON '                                 yes, create a new button
385.             i% = c% '                                                           use this index
386.         END IF
387.     END IF
388. LOOP UNTIL i% '                                                                 leave when available index found
389. IF win% < 0 THEN '                                                              button belong to a title bar?
390.     win% = -win% '                                                              yes, correct window handle
391.     BUT(i%).WinButton = -1 '                                                    mark button as belonging to a title bar
392. END IF
393. BUT(i%).Window = win% '                                                         button belongs to window (0 for desktop)
394. BUT(i%).InUse = -1 '                                                            mark index as used
395. BUT(i%).State = 0 '                                                             default to normal
396. BUT(i%).X = 0 '                                                                 reset x coordinate
397. BUT(i%).Y = 0 '                                                                 reset y coordinate
398. IF BUT(i%).WinButton THEN '                                                     creating a title bar button?
399.     BUT(i%).Height = WIN(win%).TBHeight - 4 '                                   calculate button height
400.     BUT(i%).Width = INT(BUT(i%).Height * 1.14286) '                             calculate button width
401.     IF w% THEN BUT(i%).Height = BUT(i%).Width '                                 yes, height=width
402.     x2% = BUT(i%).Width - 1 '                                                   calculate right bottom corner button X
403.     y2% = BUT(i%).Height - 1 '                                                  calculate right bottom corner button Y
404.     BUT(i%).State = 0 '                                                         set button as normal (depressed)
405.     BUT(i%).Normal = _NEWIMAGE(BUT(i%).Width, BUT(i%).Height, 32) '             create normal image holder
406.     _DEST BUT(i%).Normal '                                                      draw on image
407.     CLS , WIN(win%).Darkest '                                                   create common button image
408.     LINE (0, 0)-(x2% - 1, y2% - 1), WIN(win%).Lighter, B '                      draw background
409.     LINE (1, 1)-(x2% - 1, y2% - 1), WIN(win%).Darker, B
410.     LINE (1, 1)-(x2% - 2, y2% - 2), WIN(win%).WColor, BF
411.     BUT(i%).Pressed = _NEWIMAGE(BUT(i%).Width, BUT(i%).Height, 32) '            create pressed image holder
412.     _DEST BUT(i%).Pressed '                                                     draw on image
413.     CLS , WIN(win%).Lighter '                                                   create common button image
414.     LINE (0, 0)-(x2% - 1, y2% - 1), WIN(win%).Darkest, B '                      draw background
415.     LINE (1, 1)-(x2% - 1, y2% - 1), WIN(win%).WColor, B
416.     LINE (1, 1)-(x2% - 2, y2% - 2), WIN(win%).Darker, B
417.     LINE (2, 2)-(x2% - 1, y2% - 1), WIN(win%).WColor, BF
418.     BUT(i%).Disabled = _NEWIMAGE(BUT(i%).Width, BUT(i%).Height, 32) '           create disabled image holder
419.     IF NOT w% THEN '                                                            title bar button?
420.         _DEST BUT(i%).Disabled '                                                yes, draw on image
421.         CLS , WIN(win%).Darkest '                                               create common button image
422.         LINE (0, 0)-(x2% - 1, y2% - 1), WIN(win%).Lighter, B '                  draw background
423.         LINE (1, 1)-(x2% - 1, y2% - 1), WIN(win%).Darker, B
424.         LINE (1, 1)-(x2% - 2, y2% - 2), WIN(win%).WColor, BF
425.     END IF
426.     SELECT CASE t$ '                                                            yes, which window button being created?
427.         CASE "CLOSE" '                                                          close button
428.             _DEST BUT(i%).Normal '                                              work on normal
429.             LINE (4, 3)-(x2% - 5, y2% - 4), _RGB32(0, 0, 0) '                   draw depressed button
430.             LINE (5, 3)-(x2% - 4, y2% - 4), _RGB32(0, 0, 0)
431.             LINE (4, y2% - 4)-(x2% - 5, 3), _RGB32(0, 0, 0)
432.             LINE (5, y2% - 4)-(x2% - 4, 3), _RGB32(0, 0, 0)
433.             _DEST BUT(i%).Pressed '                                             work on pressed
434.             LINE (5, 4)-(x2% - 4, y2% - 3), _RGB32(0, 0, 0) '                   draw pressed button
435.             LINE (6, 4)-(x2% - 3, y2% - 3), _RGB32(0, 0, 0)
436.             LINE (5, y2% - 3)-(x2% - 4, 4), _RGB32(0, 0, 0)
437.             LINE (6, y2% - 3)-(x2% - 3, 4), _RGB32(0, 0, 0)
438.             _DEST BUT(i%).Disabled '                                            work on disabled
439.             LINE (5, y2% - 4)-(x2% - 4, 4), _RGB32(255, 255, 255) '             draw disabled button
440.             LINE (6, y2% - 4)-(x2% - 3, 4), _RGB32(255, 255, 255)
441.             LINE (x2% - 4, y2% - 3)-(x2% - 3, y2% - 3), _RGB32(255, 255, 255) '
442.             LINE (4, 3)-(x2% - 5, y2% - 4), _RGB32(128, 128, 128)
443.             LINE (5, 3)-(x2% - 4, y2% - 4), _RGB32(128, 128, 128)
444.             LINE (4, y2% - 4)-(x2% - 5, 3), _RGB32(128, 128, 128)
445.             LINE (5, y2% - 4)-(x2% - 4, 3), _RGB32(128, 128, 128)
446.         CASE "MAXIMIZE" '                                                       maximize button
447.             _DEST BUT(i%).Normal '                                              work on normal
448.             LINE (3, 3)-(x2% - 4, y2% - 3), _RGB32(0, 0, 0), B '                draw depressed button
449.             LINE (3, 2)-(x2% - 4, 2), _RGB32(0, 0, 0)
450.             _DEST BUT(i%).Pressed '                                             work on pressed
451.             LINE (4, 4)-(x2% - 3, y2% - 2), _RGB32(0, 0, 0), B '                draw pressed button
452.             LINE (4, 3)-(x2% - 3, 3), _RGB32(0, 0, 0)
453.             _DEST BUT(i%).Disabled '                                            work on disabled
454.             LINE (4, 4)-(x2% - 3, y2% - 2), _RGB32(255, 255, 255), B '          draw disabled button
455.             PSET (x2% - 3, 3), _RGB32(255, 255, 255)
456.             LINE (3, 3)-(x2% - 4, y2% - 3), _RGB32(128, 128, 128), B
457.             LINE (3, 2)-(x2% - 4, 2), _RGB32(128, 128, 128)
458.         CASE "MINIMIZE" '                                                       minimize button
459.             _DEST BUT(i%).Normal '                                              work on normal
460.             LINE (4, y2% - 4)-(x2% - 6, y2% - 3), _RGB32(0, 0, 0), B '          draw depressed button
461.             _DEST BUT(i%).Pressed '                                             work on pressed
462.             LINE (5, y2% - 3)-(x2% - 5, y2% - 2), _RGB32(0, 0, 0), B '          draw pressed button
463.             _DEST BUT(i%).Disabled '                                            work on disabled
464.             LINE (5, y2% - 3)-(x2% - 5, y2% - 2), _RGB32(255, 255, 255), B '    draw disabled button
465.             LINE (4, y2% - 4)-(x2% - 6, y2% - 3), _RGB32(128, 128, 128), B
466.         CASE "RESTORE" '                                                        restore button
467.             _DEST BUT(i%).Normal '                                              work on normal
468.             LINE (3, 6)-(x2% - 7, y2% - 3), _RGB32(0, 0, 0), B '                draw depressed button
469.             LINE (3, 5)-(x2% - 7, 5), _RGB32(0, 0, 0)
470.             PSET (5, 4), _RGB32(0, 0, 0)
471.             PSET (x2% - 6, y2% - 6), _RGB32(0, 0, 0)
472.             LINE (5, 2)-(x2% - 5, 3), _RGB32(0, 0, 0), B
473.             LINE (x2% - 5, 4)-(x2% - 5, y2% - 6), _RGB32(0, 0, 0)
474.             _DEST BUT(i%).Pressed '                                             work on pressed
475.             LINE (4, 7)-(x2% - 6, y2% - 2), _RGB32(0, 0, 0), B '                draw pressed button
476.             LINE (4, 6)-(x2% - 6, 6), _RGB32(0, 0, 0)
477.             PSET (6, 5), _RGB32(0, 0, 0)
478.             PSET (x2% - 5, y2% - 5), _RGB32(0, 0, 0)
479.             LINE (6, 3)-(x2% - 4, 4), _RGB32(0, 0, 0), B
480.             LINE (x2% - 4, 5)-(x2% - 4, y2% - 5), _RGB32(0, 0, 0)
481.             _DEST BUT(i%).Disabled '                                            work on disabled
482.             LINE (4, 7)-(x2% - 6, y2% - 2), _RGB32(255, 255, 255), B '          draw disabled button
483.             LINE (6, 4)-(x2% - 6, 4), _RGB32(255, 255, 255)
484.             LINE (x2% - 5, 3)-(x2% - 4, y2% - 5), _RGB32(255, 255, 255), B
485.             LINE (3, 6)-(x2% - 7, y2% - 3), _RGB32(128, 128, 128), B
486.             LINE (3, 5)-(x2% - 7, 5), _RGB32(128, 128, 128)
487.             PSET (5, 4), _RGB32(128, 128, 128)
488.             PSET (x2% - 6, y2% - 6), _RGB32(128, 128, 128)
489.             LINE (5, 2)-(x2% - 5, 3), _RGB32(128, 128, 128), B
490.             LINE (x2% - 5, 4)-(x2% - 5, y2% - 6), _RGB32(128, 128, 128)
491.         CASE "SCROLLUP"
492.             _DEST BUT(i%).Normal
493.             LINE (BUT(i%).Width \ 2, 6)-(4, y2% - 6), _RGB32(0, 0, 0)
494.             LINE -(x2% - 4, y2% - 6), _RGB32(0, 0, 0)
495.             LINE -(BUT(i%).Width \ 2, 6), _RGB32(0, 0, 0)
496.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
497.             _DEST BUT(i%).Pressed
498.             LINE (BUT(i%).Width \ 2 + 1, 7)-(5, y2% - 5), _RGB32(0, 0, 0)
499.             LINE -(x2% - 3, y2% - 5), _RGB32(0, 0, 0)
500.             LINE -(BUT(i%).Width \ 2 + 1, 7), _RGB32(0, 0, 0)
501.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
502.         CASE "SCROLLDOWN"
503.             _DEST BUT(i%).Normal
504.             LINE (BUT(i%).Width \ 2, y2% - 6)-(4, 6), _RGB32(0, 0, 0)
505.             LINE -(y2% - 4, 6), _RGB32(0, 0, 0)
506.             LINE -(BUT(i%).Width \ 2, y2% - 6), _RGB32(0, 0, 0)
507.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
508.             _DEST BUT(i%).Pressed
509.             LINE (BUT(i%).Width \ 2 + 1, y2% - 5)-(5, 7), _RGB32(0, 0, 0)
510.             LINE -(x2% - 3, 7), _RGB32(0, 0, 0)
511.             LINE -(BUT(i%).Width \ 2 + 1, y2% - 5), _RGB32(0, 0, 0)
512.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
513.         CASE "SCROLLLEFT"
514.             _DEST BUT(i%).Normal
515.             LINE (5, BUT(i%).Height \ 2)-(x2% - 7, 4), _RGB32(0, 0, 0)
516.             LINE -(x2% - 7, y2% - 5), _RGB32(0, 0, 0)
517.             LINE -(5, BUT(i%).Height \ 2), _RGB32(0, 0, 0)
518.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
519.             _DEST BUT(i%).Pressed
520.             LINE (6, BUT(i%).Height \ 2 + 1)-(x2% - 6, 5), _RGB32(0, 0, 0)
521.             LINE -(x2% - 6, y2% - 4), _RGB32(0, 0, 0)
522.             LINE -(6, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0)
523.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
524.         CASE "SCROLLRIGHT"
525.             _DEST BUT(i%).Normal
526.             LINE (x2% - 6, BUT(i%).Height \ 2)-(6, 4), _RGB32(0, 0, 0)
527.             LINE -(6, y2% - 5), _RGB32(0, 0, 0)
528.             LINE -(x2% - 6, BUT(i%).Height \ 2), _RGB32(0, 0, 0)
529.             PAINT (BUT(i%).Width \ 2, BUT(i%).Height \ 2), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
530.             _DEST BUT(i%).Pressed
531.             LINE (x2% - 5, BUT(i%).Height \ 2 + 1)-(7, 5), _RGB32(0, 0, 0)
532.             LINE -(7, y2% - 4), _RGB32(0, 0, 0)
533.             LINE -(x2% - 5, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0)
534.             PAINT (BUT(i%).Width \ 2 + 1, BUT(i%).Height \ 2 + 1), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
535.     END SELECT
536. ELSE
537.  
538.     '*
539.     '* custom made buttons here
540.     '*
541.  
542. END IF
543.  
544. BUTTON_NEW = i%
545.  
546. END FUNCTION
547.  
548. '--------------------------------------------------------------------------------------------------------------------------------
549. '                                                                                                                    WINDOW_MOUSE
550. SUB WINDOW_MOUSE ()
551. '
552. ' work in progress (only called when there has been mouse activity)
553. '
554. SHARED WIN() AS WIN
555. SHARED WinOrder%()
556. SHARED WIN AS WINDOWFLAGS
557. SHARED MOUSE AS MOUSEFLAGS
558. SHARED BUT() AS BUTTON
559.  
560. DIM c% ' current window being checked for mouse hover
561. DIM o% ' order of windows
562. DIM x% ' x offset movement of mouse
563. DIM y% ' y offset movement of mouse
564. DIM tx%
565. DIM ty%
566.  
567. MOUSE.PX = MOUSE.X '                                                                         save last mouse x position
568. MOUSE.PY = MOUSE.Y '                                                                         save last mouse y position
569. WHILE _MOUSEINPUT: WEND '                                                                    get latest mouse status
570. MOUSE.X = _MOUSEX '                                                                          set desktop x coordinate flag
571. MOUSE.Y = _MOUSEY '                                                                          set desktop y coordinate flag
572. MOUSE.LeftClick = _MOUSEBUTTON(1) '                                                          set left mouse button status
573. MOUSE.RightClick = _MOUSEBUTTON(2) '                                                         set right mouse button status
574. IF NOT MOUSE.LeftClick THEN
575.     MOUSE.LeftReleased = -1 '                                                                left mouse button has been released?
576.     WIN(MOUSE.Move).Move = 0 '                                                               yes, window no longer being moved
577.     MOUSE.Move = 0 '                                                                         end window movement
578.     WIN(MOUSE.Resize).Resize = 0 '                                                           window no longer being resized
579.     MOUSE.Resize = 0 '                                                                       end window resizing
580.     MOUSE.Icon = 0 '                                                                         mouse pointer to default
581.     IF MOUSE.ButtonPressed THEN '                                                            was a button being held down?
582.         MOUSE.ButtonClicked = MOUSE.ButtonPressed '                                          yes, this button has now been clicked
583.         MOUSE.ButtonPressed = 0 '                                                            button no longer being held down
584.         BUT(MOUSE.ButtonClicked).State = 0 '                                                 set button state back to normal
585.     END IF
586. ELSE
587.     IF MOUSE.Move THEN '                                                                     window currently being moved?
588.         WINDOW_PUT MOUSE.move, WIN(MOUSE.move).X + MOUSEMOVEMENTX,_
589.                               WIN(MOUSE.move).Y + MOUSEMOVEMENTY,_
590.                               BYWINDOW '                                                     yes, update window position
591.     ELSEIF MOUSE.Resize THEN '                                                               window currently being resized?
592.         x% = MOUSEMOVEMENTX '                                                                yes, get change in x position
593.         y% = MOUSEMOVEMENTY '                                                                get change in y position
594.         IF MOUSE.Border AND 1 THEN '                                                         mouse on top border?
595.             ty% = WIN(MOUSE.Resize).Height - y% '                                            yes, calculate possible y value
596.             IF ty% >= WIN(MOUSE.Resize).MinHeight AND ty% <= WIN(MOUSE.Resize).MaxHeight THEN ' outside limits?
597.                 WIN(MOUSE.Resize).Y = WIN(MOUSE.Resize).Y + y% '                             no, adjust window y location
598.                 WIN(MOUSE.Resize).Height = ty% '                                             adjust overall window height
599.  
600.                 WIN(MOUSE.Resize).SHeight = WIN(MOUSE.Resize).SHeight - y% '                 adjust window screen height
601.  
602.             ELSE '                                                                           yes, minimum reached
603.                 _MOUSEMOVE MOUSE.X, MOUSE.PY '                                               force pointer back       (not working correctly in GL)
604.                 MOUSE.Y = MOUSE.PY '                                                         update mouse y position
605.                 MOUSE.PY = MOUSEMOVEMENTY '                                                  seed new y offset position
606.             END IF
607.         ELSEIF MOUSE.Border AND 4 THEN '                                                     no, mouse on bottom border?
608.             ty% = WIN(MOUSE.Resize).Height + y% '                                            calculate possible y value
609.             IF ty% >= WIN(MOUSE.Resize).MinHeight AND ty% <= WIN(MOUSE.Resize).MaxHeight THEN ' outside limits?
610.                 WIN(MOUSE.Resize).Height = ty% '                                             no, adjust overall window height
611.  
612.                 WIN(MOUSE.Resize).SHeight = WIN(MOUSE.Resize).SHeight + y% '                 adjust window screen height
613.  
614.             ELSE '                                                                           yes, minimum reached
615.                 _MOUSEMOVE MOUSE.X, MOUSE.PY '                                               force pointer back       (not working correclty in GL)
616.                 MOUSE.Y = MOUSE.PY '                                                         update mouse y position
617.                 MOUSE.PY = MOUSEMOVEMENTY '                                                  seed new y offset position
618.             END IF
619.         END IF
620.         IF MOUSE.Border AND 2 THEN '                                                         mouse on right border?
621.             tx% = WIN(MOUSE.Resize).Width + x% '                                             yes, calculate possible x value
622.             IF tx% >= WIN(MOUSE.Resize).MinWidth AND tx% <= WIN(MOUSE.Resize).MaxWidth THEN ' outside limits?
623.                 WIN(MOUSE.Resize).Width = tx% '                                              no, adjust overall window width
624.  
625.                 WIN(MOUSE.Resize).SWidth = WIN(MOUSE.Resize).SWidth + x% '                   adjust window screen width
626.  
627.             ELSE '                                                                           yes, minimum reached
628.                 _MOUSEMOVE MOUSE.PX, MOUSE.Y '                                               force pointer back       (not working correclty in GL)
629.                 MOUSE.X = MOUSE.PX '                                                         update mouse x position
630.                 MOUSE.PX = MOUSEMOVEMENTX '                                                  seed new x offset position
631.             END IF
632.         ELSEIF MOUSE.Border AND 8 THEN '                                                     no, mouse on left border?
633.             tx% = WIN(MOUSE.Resize).Width - x% '                                             calculate possible x value
634.             IF tx% >= WIN(MOUSE.Resize).MinWidth AND tx% <= WIN(MOUSE.Resize).MaxWidth THEN ' outside limits?
635.                 WIN(MOUSE.Resize).X = WIN(MOUSE.Resize).X + x% '                             no, adjust window x location
636.                 WIN(MOUSE.Resize).Width = tx% '                                              adjust overall window width
637.  
638.                 WIN(MOUSE.Resize).SWidth = WIN(MOUSE.Resize).SWidth - x% '                   adjust window screen width
639.  
640.             ELSE '                                                                           yes, minimum reached
641.                 _MOUSEMOVE MOUSE.PX, MOUSE.Y '                                               force pointer back       (not working correctly in GL)
642.                 MOUSE.X = MOUSE.PX '                                                         update mouse x position
643.                 MOUSE.PX = MOUSEMOVEMENTX '                                                  seed new x offset position
644.             END IF
645.         END IF
646.         WINDOW_MAKE MOUSE.Resize '                                                           redraw window
647.     ELSE
648.         MOUSE.WindowX = MOUSE.X - WIN(MOUSE.OnWindow).X '                                    set window x coordinate flag
649.         MOUSE.WindowY = MOUSE.Y - WIN(MOUSE.OnWindow).Y '                                    set window y coordinate flag
650.         MOUSE.SurfaceX = MOUSE.WindowX - WIN(MOUSE.OnWindow).SurfaceX '                        yes, set work space x flag
651.         MOUSE.SurfaceY = MOUSE.WindowY - WIN(MOUSE.OnWindow).SurfaceY '                        set work space y flag
652.     END IF
653. END IF
654.  
655. IF NOT MOUSE.LeftReleased THEN EXIT SUB '                                                    don't interact if left button being held down
656.  
657. WIN.X = 0 '                                                                                  reset window flags
658. WIN.Y = 0
659. WIN.Width = 0
660. WIN.Height = 0
661. WIN.Surface = 0
662. WIN.SurfaceX = 0
663. WIN.SurfaceY = 0
664. WIN.SWidth = 0
665. WIN.SHeight = 0
666. WIN.HasFocus = 0
667. MOUSE.Icon = 0
668. MOUSE.OnWindow = 0 '                                                                         reset remaining mouse flags
669. MOUSE.WindowX = 0
670. MOUSE.WindowY = 0
671. MOUSE.OnSurface = 0
672. MOUSE.SurfaceX = 0
673. MOUSE.SurfaceY = 0
674. MOUSE.OnTitlebar = 0
675. MOUSE.OnBorder = 0
676. MOUSE.Border = 0
677. MOUSE.OnButton = 0
678. DO '                                                                                         loop through window order array
679.     c% = c% + 1 '                                                                            increment array index
680.     o% = WinOrder%(c%) '                                                                     next window to check
681.     IF WIN(o%).Visible THEN '                                                                is window visible on screen?
682.         IF WITHIN(WIN(o%).X,_
683.                   WIN(o%).Y,_
684.                   WIN(o%).X + WIN(o%).Width - 1,_
685.                   WIN(o%).Y + WIN(o%).Height - 1) THEN '                                     yes, mouse within window coordinates?
686.             MOUSE.OnWindow = o% '                                                            yes, set pointer flag to hovered window
687.             MOUSE.WindowX = MOUSE.X - WIN(o%).X '                                            set window x coordinate flag
688.             MOUSE.WindowY = MOUSE.Y - WIN(o%).Y '                                            set window y coordinate flag
689.  
690.             WIN.X = WIN(o%).X
691.             WIN.Y = WIN(o%).Y
692.             WIN.Width = WIN(o%).Width '                                                      set window width flag
693.             WIN.Height = WIN(o%).Height '                                                    set window height flag
694.             WIN.Surface = WIN(o%).Surface
695.             WIN.SurfaceX = WIN(o%).SurfaceX
696.             WIN.SurfaceY = WIN(o%).SurfaceY
697.             WIN.SWidth = WIN(o%).SWidth '                                                    set window work space width flag
698.             WIN.SHeight = WIN(o%).SHeight '                                                  set window work space height flag
699.             WIN.HasFocus = WIN(o%).Focus
700.  
701.             IF WITHIN(WIN(o%).X + WIN(o%).SurfaceX,_
702.                       WIN(o%).Y + WIN(o%).SurfaceY,_
703.                       WIN(o%).X + WIN(o%).SurfaceX + WIN(o%).SWidth - 1,_
704.                       WIN(o%).Y + WIN(o%).SurfaceY + WIN(o%).SHeight - 1) THEN '              mouse within screen coordinates?
705.                 MOUSE.SurfaceX = MOUSE.WindowX - WIN(o%).SurfaceX '                            yes, set screen x flag
706.                 MOUSE.SurfaceY = MOUSE.WindowY - WIN(o%).SurfaceY '                            set screen y flag
707.                 MOUSE.OnSurface = -1 '                                                        set screen flag
708.             ELSEIF WITHIN(WIN(o%).X + WIN(o%).SurfaceX,_
709.                           WIN(o%).Y + WIN(o%).BWidth,_
710.                           WIN(o%).X + WIN(o%).SurfaceX + WIN(o%).SWidth - 1,_
711.                           WIN(o%).Y + WIN(o%).BWidth + WIN(o%).TBHeight - 1) THEN '          no, mouse within title bar?
712.                 IF WIN(o%).CloseButton THEN '                                                yes, does this window have a close button?
713.                     IF WITHIN(WIN(o%).X + BUT(WIN(o%).CloseButton).X,_
714.                               WIN(o%).Y + BUT(WIN(o%).CloseButton).Y,_
715.                               WIN(o%).X + BUT(WIN(o%).CloseButton).X + BUT(WIN(o%).CloseButton).Width - 1,_
716.                               WIN(o%).Y + BUT(WIN(o%).CloseButton).Y + BUT(WIN(o%).CloseButton).Height - 1) THEN ' yes, on button?
717.                         MOUSE.OnButton = WIN(o%).CloseButton '                               yes, set flag
718.                     END IF
719.                 END IF
720.                 IF WIN(o%).MaxButton THEN '                                                  does this window have a maximize button?
721.                     IF WITHIN(WIN(o%).X + BUT(WIN(o%).MaxButton).X,_
722.                               WIN(o%).Y + BUT(WIN(o%).MaxButton).Y,_
723.                               WIN(o%).X + BUT(WIN(o%).MaxButton).X + BUT(WIN(o%).MaxButton).Width - 1,_
724.                               WIN(o%).Y + BUT(WIN(o%).MaxButton).Y + BUT(WIN(o%).MaxButton).Height - 1) THEN ' yes, on button?
725.                         MOUSE.OnButton = WIN(o%).MaxButton '                                 yes, set flag
726.                     END IF
727.                 END IF
728.                 IF WIN(o%).MinButton THEN '                                                  does this window have a minimize button?
729.                     IF WITHIN(WIN(o%).X + BUT(WIN(o%).MinButton).X,_
730.                               WIN(o%).Y + BUT(WIN(o%).MinButton).Y,_
731.                               WIN(o%).X + BUT(WIN(o%).MinButton).X + BUT(WIN(o%).MinButton).Width - 1,_
732.                               WIN(o%).Y + BUT(WIN(o%).MinButton).Y + BUT(WIN(o%).MinButton).Height - 1) THEN ' yes, on button?
733.                         MOUSE.OnButton = WIN(o%).MinButton '                                 yes, set flag
734.                     END IF
735.                 END IF
736.                 IF MOUSE.OnButton = 0 THEN MOUSE.OnTitlebar = -1 '                           if not on button then must be on title bar
737.             END IF
738.             IF WIN(o%).Size THEN '                                                           is window resizable?
739.                 IF MOUSE.OnSurface + MOUSE.OnTitlebar + MOUSE.OnButton = 0 THEN '             yes, mouse on anything?
740.                     MOUSE.OnBorder = -1 '                                                    no, mouse must be on a border
741.                     IF MOUSE.Y <= WIN(o%).Y + WIN(o%).BWidth - 1 THEN '                      on top border?
742.                         MOUSE.Border = 1 '                                                   yes, set border value
743.                     ELSEIF MOUSE.Y >= WIN(o%).Y + WIN(o%).Height - WIN(o%).BWidth - 1 THEN ' no, on bottom border?
744.                         MOUSE.Border = MOUSE.Border + 4 '                                    yes, add border value
745.                     END IF
746.                     IF MOUSE.X >= WIN(o%).X + WIN(o%).Width - WIN(o%).BWidth - 1 THEN '      on right border?
747.                         MOUSE.Border = MOUSE.Border + 2 '                                    yes, add border value
748.                     ELSEIF MOUSE.X <= WIN(o%).X + WIN(o%).BWidth - 1 THEN '                  no, on left border?
749.                         MOUSE.Border = MOUSE.Border + 8 '                                    yes, add border value
750.                     END IF
751.                     MOUSE.Icon = MOUSE.Border '                                              mouse icon to resize
752.                 END IF
753.             END IF
754.         END IF
755.     END IF
756. LOOP UNTIL MOUSE.OnWindow OR c% = UBOUND(WinOrder%) '                                        leave when hovering or entire array scanned
757. IF MOUSE.LeftClick THEN MOUSE.LeftReleased = 0 '                                             left mouse button currently held down
758. IF MOUSE.OnWindow AND MOUSE.LeftClick THEN '                                                 is pointer on a window and left button pressed?
759.     WINDOW_SETFOCUS MOUSE.OnWindow '                                                         yes, this window now has focus
760.     c% = MOUSEMOVEMENTX '                                                                    seed mouse x offset function
761.     c% = MOUSEMOVEMENTY '                                                                    seed mouse y offset function
762.     IF MOUSE.OnTitlebar AND MOUSE.Move = 0 THEN '                                            is pointer on title bar and window not moving?
763.         MOUSE.Move = MOUSE.OnWindow '                                                        yes, this window can now be moved
764.         WIN(MOUSE.Move).Move = -1 '                                                          set window state to moving
765.     ELSEIF MOUSE.OnBorder AND MOUSE.Resize = 0 THEN '                                        is mouse on border and not resizing?
766.         MOUSE.Resize = MOUSE.OnWindow '                                                      yes, this window can now be resized
767.         WIN(MOUSE.Resize).Resize = -1 '                                                      set window state to resizing
768.     ELSEIF MOUSE.OnButton THEN '                                                             pointer on button?
769.         MOUSE.ButtonPressed = MOUSE.OnButton '                                               yes, button is currently being pressed
770.         BUT(MOUSE.ButtonPressed).State = -1 '                                                set button state to pressed
771.     END IF
772. END IF
773.  
774. END SUB
775.  
776. '--------------------------------------------------------------------------------------------------------------------------------
777. '                                                                                                                 WINDOW_SETFOCUS
778. SUB WINDOW_SETFOCUS (h%)
779. '
780. ' h% = handle of window to set focus ******************** NEEDS FIXED for only 1 window
781. '
782. SHARED WIN() AS WIN
783. SHARED WinOrder%()
784.  
785. DIM c%
786. DIM o%
787.  
788. IF h% < 1 THEN EXIT SUB '                                                       leave if no window selected
789. IF WIN(h%).Focus THEN EXIT SUB '                                                leave if window already in focus
790. IF NOT WIN(h%).Visible THEN EXIT SUB '                                          leave if window is not on screen
791. DO '                                                                            loop through window order array
792.     c% = c% + 1 '                                                               increment array index
793. LOOP UNTIL h% = WinOrder%(c%) OR c% = UBOUND(WinOrder%) '                       leave if window found or end of array reached
794. IF c% = UBOUND(WinOrder%) AND WinOrder%(c%) <> h% THEN EXIT SUB '               window does not exist, leave subroutine
795. FOR o% = c% - 1 TO 1 STEP -1 '                                                  cycle through array
796.     WinOrder%(o% + 1) = WinOrder%(o%) '                                         move windows above h% down one
797. NEXT o%
798. WinOrder%(1) = h% '                                                             make this window the new focus
799. c% = WinOrder%(2)
800. WIN(h%).Focus = -1 '                                                            this window now has focus
801.  
802. _PUTIMAGE (WIN(h%).BWidth, WIN(h%).BWidth), WIN(h%).TBFImage, WIN(h%).Window '  place focused title bar image on window
803.  
804. WIN(WinOrder%(2)).Focus = 0 '                                                   previous window lost focus
805.  
806. _PUTIMAGE (WIN(c%).BWidth, WIN(c%).BWidth), WIN(c%).TBNFImage, WIN(c%).Window ' unfocused
807.  
808. END SUB
809.  
810. '--------------------------------------------------------------------------------------------------------------------------------
811. '                                                                                                                  WINDOW_DESKTOP
812. SUB WINDOW_DESKTOP (w%, h%, c~&, i$)
813. '
814. ' w%  = desktop width  (0 for default 640 or to use optional desktop image width)
815. ' h%  = desktop height (0 for default 480 or to use optional desktop image height)
816. ' c~& = desktop color  (0 for none)
817. ' i$  = desktop image  (null for none)
818. '
819. ' If width and height are supplied then desktop is created with those dimensions and optional desktop image stretched across
820. '
821. SHARED DeskTop&
822.  
823. DIM Back& ' desktop background image
824.  
825. IF w% <> 0 AND h% <> 0 THEN '                                 dimensions supplied?
826.     DeskTop& = _NEWIMAGE(w%, h%, 32) '                        yes, create desktop screen with dimensions
827.     IF _FILEEXISTS(i$) THEN '                                 does background image exist?
828.         Back& = _LOADIMAGE(i$, 32) '                          yes, load background image
829.         _PUTIMAGE , Back&, DeskTop& '                         put background image on desktop screen
830.         _FREEIMAGE Back& '                                    background image no longer needed
831.     ELSE '                                                    no, background image does not exist
832.         _DEST DeskTop& '                                      draw on desktop screen
833.         IF c~& <> 0 THEN CLS , c~& ELSE CLS '                 color desktop background
834.     END IF
835. ELSE '                                                        no dimensions supplied
836.     IF _FILEEXISTS(i$) THEN '                                 does background image exist?
837.         DeskTop& = _LOADIMAGE(i$, 32) '                       yes, use this as the desktop
838.     ELSE '                                                    no, background image does not exist
839.         DeskTop& = _NEWIMAGE(640, 480, 32) '                  create default 640x480 desktop screen
840.         _DEST DeskTop& '                                      draw on desktop screen
841.         IF c~& <> 0 THEN CLS , c~& ELSE CLS '                 color desktop background
842.     END IF
843. END IF
844. SCREEN _NEWIMAGE(_WIDTH(DeskTop&), _HEIGHT(DeskTop&), 32) '   make main screen that matches desktop dimensions
845. CLS '                                                         clear screen (remove transparency)
846. _SCREENMOVE _MIDDLE '                                         move screen to the center of the programmer's desktop
847.  
848. END SUB
849.  
850. '--------------------------------------------------------------------------------------------------------------------------------
851. '                                                                                                                  WINDOW_REFRESH
852. SUB WINDOW_REFRESH ()
853.  
854. SHARED WIN() AS WIN ' window array
855. SHARED BUT() AS BUTTON
856. SHARED DeskTop&
857. SHARED WinOrder%()
858. SHARED POINTER() AS MOUSEPOINTERS
859. SHARED MOUSE AS MOUSEFLAGS
860.  
861. DIM o%
862. DIM h%
863.  
864. IF DeskTop& THEN _PUTIMAGE (0, 0), DeskTop& '                                               place background image if exist
865. FOR o% = UBOUND(WinOrder%) TO 1 STEP -1 '                                                   cycle through window order eversed
866.     h% = WinOrder%(o%) '                                                                    get next window handle
867.     IF WIN(h%).Visible THEN '                                                               is this window visible?
868.  
869.         IF WIN(h%).CloseButton THEN BUTTON_PUT WIN(h%).CloseButton, 0, 0, 0 '               draw close button if exist
870.         IF WIN(h%).MaxButton THEN BUTTON_PUT WIN(h%).MaxButton, 0, 0, 0 '                   draw maximize button if exist
871.         IF WIN(h%).MinButton THEN BUTTON_PUT WIN(h%).MinButton, 0, 0, 0 '                   draw minimize button if exist
872.  
873.         _PUTIMAGE (WIN(h%).X, WIN(h%).Y), WIN(h%).Window '                                  place window onto desktop
874.     END IF
875. NEXT o%
876. _PUTIMAGE (MOUSE.X + POINTER(MOUSE.Icon).X, MOUSE.Y + POINTER(MOUSE.Icon).Y), POINTER(MOUSE.Icon).Icon ' place mouse pointer
877.  
878. END SUB
879.  
880. '--------------------------------------------------------------------------------------------------------------------------------
881. '                                                                                                                      WINDOW_PUT
882. SUB WINDOW_PUT (h%, x%, y%, m%)
883. '
884. ' h% - handle of window to move
885. ' x% - new window x coordinate
886. ' y% - new window y coordinate
887. ' m% - method of move (by work space origin coordinates (BYSCREEN) or by entire window origin coordinates (BYWINDOW))
888. '
889. SHARED WIN() AS WIN ' window array
890.  
891. IF m% THEN '                                                BYSCREEN
892.     WIN(h%).X = x% - WIN(h%).BWidth
893.     WIN(h%).Y = y% - WIN(h%).BWidth - WIN(h%).TBHeight
894. ELSE '                                                      BYWINDOW
895.     WIN(h%).X = x%
896.     WIN(h%).Y = y%
897. END IF
898.  
899. 'IF WIN(h%).Visible THEN WINDOW_SETFOCUS h% ' *************************************** focus routine needs fixing for only 1 window
900.  
901. END SUB
902.  
903. '--------------------------------------------------------------------------------------------------------------------------------
904. '                                                                                                                     WINDOW_MAKE
905. SUB WINDOW_MAKE (h%)
906. '
907. ' h% - handle of window to create
908. '
909. SHARED WIN() AS WIN ' window array
910. SHARED MOUSE AS MOUSEFLAGS
911. SHARED BUT() AS BUTTON '             needed?
912.  
913. DIM p&(1)
914. DIM c% '                  generic counter
915. DIM Red!, Green!, Blue!
916. DIM Redinc!, Greeninc!, Blueinc!
917. DIM x%, y%
918.  
919. DIM CurrentDest&
920.  
921. p&(0) = 43690 '                                                                             scroll bar background pattern 1
922. p&(1) = 21845 '                                                                             scroll bar background pattern 2
923.  
924. CurrentDest& = _DEST '                                                                      remember calling destination
925.  
926. IF WIN(h%).Resize THEN '                                                                    window being resized?
927.     _FREEIMAGE WIN(h%).Window '                                                             remove window image from RAM
928.     IF (MOUSE.Border AND 2) OR (MOUSE.Border AND 8) THEN '                                  resizing right or left border?
929.         _FREEIMAGE WIN(h%).TBFImage '                                                       yes, remove title bar focus image
930.         _FREEIMAGE WIN(h%).TBNFImage '                                                      remove title bar no focus image
931.     END IF
932. ELSE '                                                                                      no, window being created
933.     CALCULATECOLORS h% '                                                                    calculate window color shades
934.     WIN(h%).TBHeight = _FONTHEIGHT(WIN(h%).Font) + 8 '                                      calculate title bar height
935.     WIN(h%).Width = WIN(h%).SWidth + WIN(h%).BWidth * 2 '                                   yes, calculate window width
936.     WIN(h%).Height = WIN(h%).SHeight + WIN(h%).BWidth * 2 + WIN(h%).TBHeight + 1 '          calculate window height
937.     WIN(h%).OWidth = WIN(h%).Width
938.     WIN(h%).OHeight = WIN(h%).Height
939.     WIN(h%).MaxWidth = WIN(h%).OWidth '                                                     save maximim width of window
940.     WIN(h%).MaxHeight = WIN(h%).OHeight '                                                   save maximim height of window
941.     WIN(h%).SurfaceX = WIN(h%).BWidth '                                                      calculate screen x location
942.     WIN(h%).SurfaceY = WIN(h%).BWidth + WIN(h%).TBHeight '                                   calculate screen y location
943.  
944.  
945.     WIN(h%).CloseButton = BUTTON_NEW(-h%, 0, 0, "CLOSE", 0, 0, 0) '                         create close title bar button
946.     WIN(h%).MaxButton = BUTTON_NEW(-h%, 0, 0, "MAXIMIZE", 0, 0, 0) '                        create maximize title bar button
947.     WIN(h%).MinButton = BUTTON_NEW(-h%, 0, 0, "MINIMIZE", 0, 0, 0) '                        create minimize title bar button
948.     WIN(h%).RestoreButton = BUTTON_NEW(-h%, 0, 0, "RESTORE", 0, 0, 0) '                     create restore title bar button
949.     WIN(h%).SUButton = BUTTON_NEW(-h%, 1, 0, "SCROLLUP", 0, 0, 0) '                         create scroll bar up button
950.     WIN(h%).SDButton = BUTTON_NEW(-h%, 1, 0, "SCROLLDOWN", 0, 0, 0) '                       create scroll bar down button
951.     WIN(h%).SLButton = BUTTON_NEW(-h%, 1, 0, "SCROLLLEFT", 0, 0, 0) '                       create scroll bar left button
952.     WIN(h%).SRButton = BUTTON_NEW(-h%, 1, 0, "SCROLLRIGHT", 0, 0, 0) '                      create scroll bar right button
953.     WIN(h%).MinHeight = WIN(h%).TBHeight + WIN(h%).BWidth * 2 + BUT(WIN(h%).SUButton).Height * 4 ' calculate min window height
954.  
955.     WIN(h%).TBFImage = _NEWIMAGE(WIN(h%).SWidth, WIN(h%).TBHeight, 32) '                    create title bar with focus
956.     WIN(h%).TBNFImage = _COPYIMAGE(WIN(h%).TBFImage) '                                      create title bar without focus
957.     WIN(h%).Surface = _NEWIMAGE(WIN(h%).SWidth, WIN(h%).SHeight, 32) '                       create screen image container
958.  
959.  
960.     BUT(WIN(h%).CloseButton).Y = WIN(h%).BWidth + 2 '                                       close button Y location
961.     BUT(WIN(h%).MaxButton).Y = WIN(h%).BWidth + 2 '                                         maximize buttun Y location
962.     BUT(WIN(h%).MinButton).Y = WIN(h%).BWidth + 2 '                                         minimize button Y location
963.     BUT(WIN(h%).RestoreButton).Y = WIN(h%).BWidth + 2 '                                     restore button Y location
964.     BUT(WIN(h%).SUButton).Y = WIN(h%).BWidth + WIN(h%).TBHeight + 1 '                       scroll up button Y location
965.     BUT(WIN(h%).SLButton).X = WIN(h%).BWidth '                                              scroll left button X location
966.  
967.  
968. END IF
969. WIN(h%).Window = _NEWIMAGE(WIN(h%).Width, WIN(h%).Height, 32) '                             create window image container
970.  
971.  
972. BUT(WIN(h%).CloseButton).X = WIN(h%).Width - WIN(h%).BWidth - BUT(WIN(h%).CloseButton).Width - 2 ' close button X location
973. BUT(WIN(h%).MaxButton).X = BUT(WIN(h%).CloseButton).X - BUT(WIN(h%).MaxButton).Width - 2 '  maximize button X location
974. BUT(WIN(h%).MinButton).X = BUT(WIN(h%).MaxButton).X - BUT(WIN(h%).MinButton).Width '        minimize button X location
975. BUT(WIN(h%).RestoreButton).X = BUT(WIN(h%).MaxButton).X '                                   restore button X location
976.  
977.  
978. BUT(WIN(h%).SUButton).X = BUT(WIN(h%).CloseButton).X '                                      scroll up buttom X location
979. BUT(WIN(h%).SDButton).X = BUT(WIN(h%).CloseButton).X '                                      scroll down button X location
980. BUT(WIN(h%).SRButton).X = BUT(WIN(h%).CloseButton).X '                                      scroll right button X location
981. BUT(WIN(h%).SDButton).Y = WIN(h%).Height - WIN(h%).BWidth - BUT(WIN(h%).SDButton).Height '  scroll down button Y location
982. BUT(WIN(h%).SLButton).Y = WIN(h%).Height - WIN(h%).BWidth - BUT(WIN(h%).SDButton).Height '  scroll left button Y location
983. BUT(WIN(h%).SRButton).Y = BUT(WIN(h%).SLButton).Y '                                         scroll left button X location
984.  
985.  
986. IF NOT (WIN(h%).Resize AND ((MOUSE.Border = 1) OR (MOUSE.Border = 4))) THEN '               resizing right or left border?
987.     WIN(h%).TBFImage = _NEWIMAGE(WIN(h%).SWidth, WIN(h%).TBHeight, 32) '                    yes, create title bar with focus
988.     WIN(h%).TBNFImage = _COPYIMAGE(WIN(h%).TBFImage) '                                      create title bar without focus
989.     TBIMAGE h%, 0 '                                                                         draw focused image
990.     TBIMAGE h%, 1 '                                                                         draw unfocused image
991. END IF
992.  
993.  
994. _DEST WIN(h%).Window '                                                                      draw on window image
995. CLS , WIN(h%).Lighter '                                                                     clear window image
996. IF WIN(h%).Focus THEN '                                                             does this window have focus?
997.     _PUTIMAGE (WIN(h%).BWidth, WIN(h%).BWidth), WIN(h%).TBFImage, WIN(h%).Window '  yes, draw focused title bar
998. ELSE '                                                                              no
999.     _PUTIMAGE (WIN(h%).BWidth, WIN(h%).BWidth), WIN(h%).TBNFImage, WIN(h%).Window ' draw unfocused title bar
1000. END IF
1001.  
1002.  
1003.  
1004.  
1005.  
1006. IF WIN(h%).SWidth < WIN(h%).SIWidth THEN
1007.  
1008.     BUT(WIN(h%).SDButton).Y = BUT(WIN(h%).SDButton).Y - BUT(WIN(h%).SDButton).Height '      yes, adjust scroll down button Y
1009.  
1010.     LINE (BUT(WIN(h%).SLButton).X + BUT(WIN(h%).SLButton).Width - 1, BUT(WIN(h%).SLButton).Y)-(BUT(WIN(h%).SRButton).X, BUT(WIN(h%).SRButton).Y + BUT(WIN(h%).SRButton).Height - 1), _RGB32(255, 255, 255), BF
1011.     FOR y% = BUT(WIN(h%).SLButton).Y TO BUT(WIN(h%).SLButton).Y + BUT(WIN(h%).SLButton).Height - 1
1012.         LINE (BUT(WIN(h%).SLButton).X + BUT(WIN(h%).SLButton).Width - 1, y%)-(BUT(WIN(h%).SRButton).X, y%), _RGB32(212, 208, 200), , p&(y% AND 1) ' alternate odd/even pattern
1013.     NEXT y%
1014.     BUTTON_PUT WIN(h%).SLButton, 0, 0, 0
1015.     BUTTON_PUT WIN(h%).SRButton, 0, 0, 0
1016. END IF
1017.  
1018. IF WIN(h%).SHeight < WIN(h%).SIHeight THEN
1019.  
1020.     BUT(WIN(h%).SRButton).X = BUT(WIN(h%).SRButton).X - BUT(WIN(h%).SRButton).Width '       yes, adjust scroll right button X
1021.  
1022.     LINE (BUT(WIN(h%).SUButton).X, BUT(WIN(h%).SUButton).Y + BUT(WIN(h%).SUButton).Height)-(BUT(WIN(h%).SDButton).X + BUT(WIN(h%).SDButton).Width - 1, BUT(WIN(h%).SDButton).Y), _RGB32(255, 255, 255), BF
1023.     FOR x% = BUT(WIN(h%).SUButton).X TO BUT(WIN(h%).SUButton).X + BUT(WIN(h%).SUButton).Width - 1
1024.         LINE (x%, BUT(WIN(h%).SUButton).Y + BUT(WIN(h%).SUButton).Height)-(x%, BUT(WIN(h%).SDButton).Y), _RGB32(212, 208, 200), , p&(x% AND 1)
1025.     NEXT x%
1026.     BUTTON_PUT WIN(h%).SUButton, 0, 0, 0
1027.     BUTTON_PUT WIN(h%).SDButton, 0, 0, 0
1028.  
1029. END IF
1030.  
1031.  
1032. '**
1033. '** Calculate where screen needs to sit inside viewport
1034. '**
1035. '** place window at viewport
1036. '**
1037.  
1038.  
1039.  
1040.  
1041.  
1042.  
1043. IF WIN(h%).BWidth THEN '                                                                    draw a border?
1044.     IF WIN(h%).BWidth = 1 THEN '                                                            yes, 1 pixel border?
1045.         LINE (WIN(h%).Width - 1, 0)-(WIN(h%).Width - 1, WIN(h%).Height - 1), WIN(h%).Dark ' yes, draw border
1046.         LINE -(0, WIN(h%).Height - 1), WIN(h%).Dark
1047.     END IF
1048.     IF WIN(h%).BWidth = 2 THEN '                                                            2 pixel border?
1049.         LINE (0, 0)-(WIN(h%).Width - 1, WIN(h%).Height - 1), WIN(h%).Dark, B '              yes, draw bottom and right border
1050.         LINE (0, 0)-(WIN(h%).Width - 2, WIN(h%).Height - 2), WIN(h%).Light, B '             draw top and left border
1051.     END IF
1052.     IF WIN(h%).BWidth > 2 THEN '                                                            more than 2 pixel border?
1053.         LINE (0, 0)-(WIN(h%).Width - 1, WIN(h%).Height - 1), WIN(h%).Darker, B '            yes, draw bottom and right border
1054.         LINE (0, 0)-(WIN(h%).Width - 2, WIN(h%).Height - 2), WIN(h%).Lighter, B '           draw top and left border
1055.         LINE (1, 1)-(WIN(h%).Width - 2, WIN(h%).Height - 2), WIN(h%).Dark, B '              draw bottom and right middle border
1056.         LINE (1, 1)-(WIN(h%).Width - 3, WIN(h%).Height - 3), WIN(h%).Light, B '             draw top and left middle border
1057.         LINE (2, 2)-(WIN(h%).Width - 3, WIN(h%).Height - 3), WIN(h%).WColor, B
1058.     END IF
1059.     IF WIN(h%).BWidth > 3 THEN '                                                            more than 3 pixel border?
1060.         LINE (WIN(h%).BWidth - 1, WIN(h%).BWidth - 1)-(WIN(h%).Width - WIN(h%).BWidth, WIN(h%).Height - WIN(h%).BWidth), WIN(h%).Light, B
1061.         LINE (WIN(h%).BWidth - 1, WIN(h%).BWidth - 1)-(WIN(h%).Width - WIN(h%).BWidth - 1, WIN(h%).Height - WIN(h%).BWidth - 1), WIN(h%).Dark, B
1062.     END IF
1063.  
1064.     LINE (WIN(h%).BWidth, WIN(h%).BWidth + WIN(h%).TBHeight)-(WIN(h%).Width - WIN(h%).BWidth - 1, WIN(h%).BWidth + WIN(h%).TBHeight), _RGB32(0, 0, 0)
1065.  
1066. END IF
1067.  
1068.  
1069. _DEST CurrentDest&
1070.  
1071. END SUB
1072.  
1073. '--------------------------------------------------------------------------------------------------------------------------------
1074. '                                                                                                                      WINDOW_NEW
1075. FUNCTION WINDOW_NEW (w%, h%)
1076. '
1077. ' w% = width of window work space
1078. ' h% = height of window work space
1079. '
1080. ' returns = integer handle number to reference window with
1081. '
1082. SHARED WIN() AS WIN ' window array
1083. SHARED WinOrder%()
1084. SHARED QB64Icon&
1085.  
1086. DIM i% ' next available window array index
1087. DIM c% ' generic counter
1088.  
1089. i% = UBOUND(WIN) '                                 get last window index
1090. WHILE NOT WIN(i%).InUse AND i% > 1 '               is window in use?
1091.     REDIM _PRESERVE WIN(i% - 1) AS WIN '           no, remove it
1092.     i% = i% - 1 '                                  go to previous index
1093. WEND
1094. i% = 0 '                                           start at beginning
1095. c% = 1
1096. DO '                                               cycle through window indexes
1097.     IF NOT WIN(c%).InUse THEN '                    window is use?
1098.         i% = c% '                                  no, use this index
1099.     ELSE '                                         yes
1100.         c% = c% + 1 '                              increment index counter
1101.         IF c% > UBOUND(WIN) THEN '                 reached end of windows?
1102.             REDIM _PRESERVE WIN(c%) AS WIN '       yes, create a new window
1103.             i% = c% '                              use this index
1104.         END IF
1105.     END IF
1106. LOOP UNTIL i% '                                    leave when available index found
1107. WIN(i%).InUse = -1 '                               mark index as used
1108. WIN(i%).Visible = 0 '                              set window invisible
1109.  
1110. WIN(i%).SIWidth = w% '                             set screen image width
1111. WIN(i%).SIHeight = h% '                            set screen image height
1112. WIN(i%).SWidth = w% '                              set window screen width
1113. WIN(i%).SHeight = h% '                             set window screen  height
1114.  
1115. WIN(i%).X = 0 '                                    set window x location
1116. WIN(i%).Y = 0 '                                    set window y location
1117. WIN(i%).BWidth = 3 '                               set border width
1118. WIN(i%).Font = _FONT
1119. WIN(i%).Title = ""
1120. WIN(i%).Icon = QB64Icon&
1121. WIN(i%).WColor = _RGB32(212, 208, 200) '           set window color
1122. WIN(i%).TBColor = _RGB32(10, 40, 100) '            set title bar color
1123. WIN(i%).TTColor = _RGB32(255, 255, 255) '          set title bar text color
1124. WIN(i%).TBSolid = -1
1125. WIN(i%).Shadow = 0 '                               set window shadow (off)
1126. WIN(i%).Focus = 0 '                                set window without focus
1127. WIN(i%).Move = 0
1128. WIN(i%).Resize = 0
1129. WIN(i%).Size = 0
1130. WIN(i%).CloseButton = 0
1131. WIN(i%).MaxButton = 0
1132. WIN(i%).MinButton = 0
1133. WIN(i%).RestoreButton = 0
1134. WIN(i%).SUButton = 0
1135. WIN(i%).SDButton = 0
1136. WIN(i%).SLButton = 0
1137. WIN(i%).SRButton = 0
1138. WIN(i%).Maximized = 0
1139. WIN(i%).Minimized = 0
1140. REDIM _PRESERVE WinOrder%(UBOUND(WinOrder%) + 1) ' increase window order array
1141. WinOrder%(UBOUND(WinOrder%)) = i% '                add window to order array
1142. WINDOW_NEW = i% '                                  return window handle
1143.  
1144.  
1145. END FUNCTION
1146.  
1147. '--------------------------------------------------------------------------------------------------------------------------------
1148. '                                                                                                                 WINDOW_SETTITLE
1149. SUB WINDOW_SETTITLE (h%, t$)
1150.  
1151. SHARED WIN() AS WIN ' window array
1152.  
1153. WIN(h%).Title = t$ '                                                               set title of window
1154.  
1155. END SUB
1156.  
1157. '--------------------------------------------------------------------------------------------------------------------------------
1158. '                                                                                                                  WINDOW_SETFONT
1159. SUB WINDOW_SETFONT (h%, f&)
1160.  
1161. SHARED WIN() AS WIN ' window array
1162.  
1163. WIN(h%).Font = f& '                                                                set window font
1164.  
1165. END SUB
1166.  
1167. '--------------------------------------------------------------------------------------------------------------------------------
1168. '                                                                                                                WINDOW_SETBORDER
1169. SUB WINDOW_SETBORDER (h%, w%)
1170.  
1171. SHARED WIN() AS WIN ' window array
1172.  
1173. WIN(h%).BWidth = w%
1174.  
1175. END SUB
1176.  
1177. '--------------------------------------------------------------------------------------------------------------------------------
1178. '                                                                                                                 WINDOW_SETCOLOR
1179. SUB WINDOW_SETCOLOR (h%, c~&)
1180.  
1181. SHARED WIN() AS WIN ' window array
1182.  
1183. WIN(h%).WColor = c~& '                                              set window color
1184.  
1185. END SUB
1186.  
1187. '--------------------------------------------------------------------------------------------------------------------------------
1188. '                                                                                                         WINDOW_SETTITLEBARCOLOR
1189. SUB WINDOW_SETTITLEBARCOLOR (h%, c~&)
1190.  
1191. SHARED WIN() AS WIN ' window array
1192.  
1193. WIN(h%).TBColor = c~& '                                               set title bar color
1194.  
1195. END SUB
1196.  
1197. '--------------------------------------------------------------------------------------------------------------------------------
1198. '                                                                                                                     WINDOW_SHOW
1199. SUB WINDOW_SHOW (h%)
1200.  
1201. SHARED WIN() AS WIN ' window array
1202.  
1203. WIN(h%).Visible = -1
1204.  
1205. END SUB
1206.  
1207. '--------------------------------------------------------------------------------------------------------------------------------
1208. '                                                                                                                     WINDOW_HIDE
1209. SUB WINDOW_HIDE (h%)
1210.  
1211. SHARED WIN() AS WIN ' window array
1212.  
1213. WIN(h%).Visible = 0
1214.  
1215. END SUB
1216.  
1217. '--------------------------------------------------------------------------------------------------------------------------------
1218. '                                                                                                                        POINTERS
1219. SUB POINTERS ()
1220.  
1221. SHARED POINTER() AS MOUSEPOINTERS
1222.  
1223. DIM Icon$
1224.  
1225. Icon$ = "b           bb          bwb         bwwb        bwwwb       bwwwwb      bwwwwwb     bwwwwwwb    "+_
1226.         "bwwwwwwwb   bwwwwwwwwb  bwwwwwwwwwb bwwwwwwbbbbbbwwwbwwb    bwwbbwwb    bwb  bwwb   bb   bwwb   "+_
1227.         "b     bwwb        bwwb         bwwb        bwwb         bb  "
1228. MAKEICON 0, Icon$, 12, 21, 0, 0 ' default - 12x21 - offset 0,0
1229. Icon$ = "    w       wbw     wbbbw   wbbbbbw wbbbbbbbwwwwwbwwww   wbw      wbw      wbw      wbw   "+_
1230.         "   wbw      wbw      wbw      wbw      wbw   wwwwbwwwwwbbbbbbbw wbbbbbw   wbbbw     wbw       w    "
1231. MAKEICON 1, Icon$, 9, 21, -4, -10 ' NS resize - 9x21 - offset 5,11
1232. Icon$ = "    ww         ww       wbw         wbw     wbbw         wbbw   wbbbwwwwwwwwwwwbbbw wbbbbbbbbbbbbbbbbbbbw"+_
1233.         " wbbbwwwwwwwwwwwbbbw   wbbw         wbbw     wbw         wbw       ww         ww    "
1234. MAKEICON 2, Icon$, 21, 9, -10, -4 ' EW resize - 21x9 - offset 11,5
1235. Icon$ = "        wwwwwww        wbbbbbw         wbbbbw          wbbbw         wbwbbw        wbw wbw"+_
1236.         "       wbw   ww      wbw      ww   wbw       wbw wbw        wbbwbw         wbbbw          "+_
1237.         "wbbbbw         wbbbbbw        wwwwwww        "
1238. MAKEICON 3, Icon$, 15, 15, -7, -7 ' NESW resize - 15x15 - offset 8,8
1239. Icon$ = "     bb              bwwb             bwwb             bwwb             bwwb             bwwbbb       "+_
1240.         "    bwwbwwbbb        bwwbwwbwwbb      bwwbwwbwwbwb bbb bwwbwwbwwbwwbbwwbbwwwwwwwwbwwbbwwwbwwwwwwwwwwwb"+_
1241.         " bwwbwwwwwwwwwwwb  bwbwwwwwwwwwwwb  bwwwwwwwwwwwwwb   bwwwwwwwwwwwwb   bwwwwwwwwwwwb     bwwwwwwwwwwb "+_
1242.         "    bwwwwwwwwwwb      bwwwwwwwwb       bwwwwwwwwb       bbbbbbbbbb  "
1243. MAKEICON 5, Icon$, 17, 22, -5, 0 ' pointer (hand) - 17x22 - offset 6,0
1244. Icon$ = "wwwwwww        wbbbbbw        wbbbbw         wbbbw          wbbwbw         wbw wbw        "+_
1245.         "ww   wbw             wbw             wbw   ww        wbw wbw         wbwbbw          wbbbw"+_
1246.         "         wbbbbw        wbbbbbw        wwwwwww"
1247. MAKEICON 6, Icon$, 15, 15, -7, -7 ' NWSE resize - 15x15 - offset 8,8
1248. Icon$ = "bbbbbbbbbbbbbbbwwwwwwwwwbbbbbbbbbbbbbbb bwwwwwwwwwb  bwwwwwwwwwb  bwwbwbwbwwb  bwwwbwbwwwb "+_
1249.         " bbwwwbwwwbb   bbwwwwwbb     bbwbwbb       bbwbb        bbwbb       bbwwwbb     bbwwbwwbb  "+_
1250.         " bbwwwwwwwbb  bwwwwbwwwwb  bwwwbwbwwwb  bwwbwbwbwwb  bwbwbwbwbwb bbbbbbbbbbbbbbbwwwwwwwwwbbbbbbbbbbbbbbb"
1251. MAKEICON 7, Icon$, 13, 22, -6, -10 ' wait - 13x22 - offset 7,11
1252. Icon$ = "          w                   wbw                 wbbbw               wbbbbbw             wbbbbbbbw      "+_
1253.         "      wwwwbwwww          ww   wbw   ww       wbw   wbw   wbw     wbbw   wbw   wbbw   wbbbwwwwwbwwwwwbbbw "+_
1254.         "wbbbbbbbbbbbbbbbbbbbw wbbbwwwwwbwwwwwbbbw   wbbw   wbw   wbbw     wbw   wbw   wbw       ww   wbw   ww    "+_
1255.         "      wwwwbwwww            wbbbbbbbw             wbbbbbw               wbbbw                 wbw         "+_
1256.         "          w          "
1257. MAKEICON 10, Icon$, 21, 21, -10, -10 ' move - 21x21 - offset 11,11
1258. Icon$ = "        www                wbw                wbw                wbw                wbw        "+_
1259.         "        wbw                wbw                wbw        wwwwwwwwwbwwwwwwwwwwbbbbbbbbbbbbbbbbbw"+_
1260.         "wwwwwwwwwbwwwwwwwww        wbw                wbw                wbw                wbw        "+_
1261.         "        wbw                wbw                wbw                www        "
1262. MAKEICON 11, Icon$, 19, 19, -9, -9 ' crosshair - 19x19 - offset 10,10
1263. Icon$ = "wwww wwwwwbbbwbbbwwwwwbwwww   wbw      wbw      wbw      wbw      wbw      wbw      wbw   "+_
1264.         "   wbw      wbw      wbw      wbw      wbw   wwwwbwwwwwbbbwbbbwwwww wwww"
1265. MAKEICON 13, Icon$, 9, 18, -4, -8 ' text - 9x18 - offset 5,9
1266. Icon$ = "       wwwwww            wwbbbbbbww         wbbbbbbbbbbw       wbbbbwwwwbbbbw     wbbbww    wwbbbw  "+_
1267.         " wbbbbbw      wbbbw  wbbwbbbw      wbbw wbbbwwbbbw     wbbbwwbbw  wbbbw     wbbwwbbw   wbbbw    wbbw"+_
1268.         "wbbw    wbbbw   wbbwwbbw     wbbbw  wbbwwbbbw     wbbbwwbbbw wbbw      wbbbwbbw  wbbbw      wbbbbbw "+_
1269.         "  wbbbww    wwbbbw     wbbbbwwwwbbbbw       wbbbbbbbbbbw         wwbbbbbbww            wwwwww       "
1270. MAKEICON 14, Icon$, 20, 20, -9, -9 ' not-allowed - 20x20 - offset 10,10
1271. Icon$ = "11111111111111111111121133333331144444444112113355533114455554411211335553311445555441121133555331144444441112"+_
1272.         "11335553311444444411121133555331144555544112113355533114455554411211333333311444444441121133333331144444444112"+_
1273.         "11113331111111111111121111111111111111111112116666666117711117711211661111111771111771121166111111177111177112"+_
1274.         "11666666611777777771121166666661177777777112116655566111111117711211665556611111111771121166666661111111177112"+_
1275.         "11111111111111111111122222222222222222222222"
1276. MAKEICON -1, Icon$, 22, 22, 0, 0 ' QB64 - 22x22
1277.  
1278. POINTER(4) = POINTER(1)
1279. POINTER(8) = POINTER(2)
1280. POINTER(9) = POINTER(6)
1281. POINTER(12) = POINTER(3)
1282.  
1283. END SUB
1284.  
1285.  
1286. '--------------------------------------------------------------------------------------------------------------------------------
1287. '                                                                                                                        MAKEICON
1288. SUB MAKEICON (n%, i$, w%, h%, xo%, yo%)
1289.  
1290. SHARED POINTER() AS MOUSEPOINTERS
1291. SHARED QB64Icon&
1292.  
1293. DIM x%
1294. DIM y%
1295. DIM p$
1296. DIM c%
1297.  
1298. IF n% = -1 THEN
1299.     QB64Icon& = _NEWIMAGE(22, 22, 32)
1300.     _DEST QB64Icon&
1301. ELSE
1302.     POINTER(n%).Icon = _NEWIMAGE(w%, h%, 32)
1303.     POINTER(n%).X = xo%
1304.     POINTER(n%).Y = yo%
1305.     _DEST POINTER(n%).Icon
1306. END IF
1307. FOR y% = 0 TO h% - 1
1308.     FOR x% = 0 TO w% - 1
1309.         c% = c% + 1
1310.         p$ = MID$(i$, c%, 1)
1311.         IF p$ = "b" THEN PSET (x%, y%), _RGB32(0, 0, 1)
1312.         IF p$ = "w" THEN PSET (x%, y%), _RGB32(255, 255, 255)
1313.         IF p$ = "1" THEN PSET (x%, y%), _RGB32(0, 0, 252)
1314.         IF p$ = "2" THEN PSET (x%, y%), _RGB32(0, 0, 112)
1315.         IF p$ = "3" THEN PSET (x%, y%), _RGB32(0, 188, 252)
1316.         IF p$ = "4" THEN PSET (x%, y%), _RGB32(0, 124, 252)
1317.         IF p$ = "5" THEN PSET (x%, y%), _RGB32(0, 0, 168)
1318.         IF p$ = "6" THEN PSET (x%, y%), _RGB32(252, 188, 0)
1319.         IF p$ = "7" THEN PSET (x%, y%), _RGB32(252, 124, 0)
1320.     NEXT x%
1321. NEXT y%
1322.  
1323. END SUB
1324.  
1325. '--------------------------------------------------------------------------------------------------------------------------------
1326. '                                                                                                                 CALCULATECOLORS
1327. SUB CALCULATECOLORS (h%)
1328.  
1329. SHARED WIN() AS WIN
1330.  
1331. WIN(h%).Wred = _RED(WIN(h%).WColor) '                                                     get RGB components of window color
1332. WIN(h%).Wgreen = _GREEN(WIN(h%).WColor)
1333. WIN(h%).Wblue = _BLUE(WIN(h%).WColor)
1334. WIN(h%).Lighter = _RGB32(WIN(h%).Wred * 1.5, WIN(h%).Wgreen * 1.5, WIN(h%).Wblue * 1.5) ' calculate window/border color shades
1335. WIN(h%).Light = _RGB32(WIN(h%).Wred * 1.25, WIN(h%).Wgreen * 1.25, WIN(h%).Wblue * 1.25)
1336. WIN(h%).Dark = _RGB32(WIN(h%).Wred / 1.25, WIN(h%).Wgreen / 1.25, WIN(h%).Wblue / 1.25)
1337. WIN(h%).Darker = _RGB32(WIN(h%).Wred / 1.5, WIN(h%).Wgreen / 1.5, WIN(h%).Wblue / 1.5)
1338. WIN(h%).Darkest = _RGB32(WIN(h%).Wred / 2, WIN(h%).Wgreen / 2, WIN(h%).Wblue / 2)
1339.  
1340. END SUB
1341.  
1342. '--------------------------------------------------------------------------------------------------------------------------------
1343. '                                                                                                                  MOUSEMOVEMENTY
1344. FUNCTION MOUSEMOVEMENTY ()
1345. '
1346. ' returns the mouse y coordinate difference between calls
1347. '
1348. SHARED MOUSE AS MOUSEFLAGS
1349.  
1350. STATIC y% ' previous call's mouse y coordinate (saved between calls)
1351.  
1352. MOUSEMOVEMENTY = MOUSE.Y - y% ' calculate mouse y offset from previous call
1353. y% = MOUSE.Y '                  save current mouse y coordinate
1354.  
1355. END FUNCTION
1356.  
1357. '--------------------------------------------------------------------------------------------------------------------------------
1358. '                                                                                                                  MOUSEMOVEMENTX
1359. FUNCTION MOUSEMOVEMENTX ()
1360. '
1361. ' returns the mouse x coordinate difference between calls
1362. '
1363. SHARED MOUSE AS MOUSEFLAGS
1364.  
1365. STATIC x% ' previous call's mouse x coordinate (saved between calls)
1366.  
1367. MOUSEMOVEMENTX = MOUSE.X - x% ' calculate mouse x offset from previous call
1368. x% = MOUSE.X '                  save current mouse x coordinate
1369.  
1370. END FUNCTION
1371.  
1372.  
1373.  

I remember that thing, awesome! Thanks for posting it again. :-)

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 19, 2020, 07:14:08 pm

Thanks Terry for your code!

Surely there is so much to study and understand to port in some other system!

PS Do you think that I need just to oversize my demonstration from about 560 lines to your about 1300 lines of code to get your wonderful results? Or do you think that I need to develop more and better skills to project and in second time to code applications?
It is always fine to see your works!

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 19, 2020, 07:22:00 pm

Hi Bplus
about

Quote

but when I click either white box it seems totally random whether they decide to do the white outline for resizing

it is a less precision managment of data.... if you see in the code there are some cases that are no managed: ie the distance between mouse pointer and original border of window in resizing, another is when the user try to reduce the dimension of the window under the minimum setting, in that case the no managment of the data let flickering the white border or move window in the direction of the movement of the mouse pointer...
Going on with the development of this demonstration these issues can be solved. So the displaying data into the windows.
Thanks for more feedback.

Title: Re: child windows into window of the program: a demonstration
Post by: bplus on February 19, 2020, 07:38:10 pm

Hi TempodiBasic,

It is my understanding to resize a window in your code:
1) Click top right box and that activates the 2 white resize boxes
2) Click one of those and that tells your code which corner is anchor and which corner will be moved, this activatees the dashed outline border
3) then you mouse down and drag that box to desired position and release.

or am I operating under the wrong directions?



Hi Terry,

As keybone says "awesome!" I have a question about the resizing, when making a new window instance, is there some limit put on how big the window can be made? I ask because the smallest window in your demo doesn't allow getting bigger but is willing to get smaller easy enough.




These are very ambitious projects! Don't worry TempodiBasic, Terry has 1300 lines and no code yet for clicking a button action ;-)) I imagine with this sort of project you never get the feeling you are finished. :) Except for Fellippe of course. ;-))

Title: Re: child windows into window of the program: a demonstration
Post by: TerryRitchie on February 19, 2020, 07:57:32 pm

Quote from: TempodiBasic on February 19, 2020, 07:14:08 pm

Thanks Terry for your code!

Surely there is so much to study and understand to port in some other system!

PS Do you think that I need just to oversize my demonstration from about 560 lines to your about 1300 lines of code to get your wonderful results? Or do you think that I need to develop more and better skills to project and in second time to code applications?
It is always fine to see your works!

Tempo, I tinkered with GUI systems for a few years and came to this conclusion: They are damned difficult to design. The code I posted here was the closest I ever got to making a GUI similar to Windows within QB64. As much as I loathe OOP programming I believe that is the kind of language needed to write an effective GUI. Don't get me wrong, I'm sure it can be done in a functional language such as QB64 (Galleon made a demo that simply blew me away, I have since lost it) but I simply don't have the time nor patience to correctly lay out the means to do so.

Don't give up trying though Tempo. When I first learned of QB64 back in 2010 my coding was MUCH less proficient than yours. I just kept playing, tinkering, and plugging away.

Title: Re: child windows into window of the program: a demonstration
Post by: TerryRitchie on February 19, 2020, 08:12:32 pm

Quote from: bplus on February 19, 2020, 07:38:10 pm

Hi Terry,

As keybone says "awesome!" I have a question about the resizing, when making a new window instance, is there some limit put on how big the window can be made? I ask because the smallest window in your demo doesn't allow getting bigger but is willing to get smaller easy enough.

I have not played with this code in over 4 years. I would need to go back through the code and read my comments to get a feel for it again.

Title: Re: child windows into window of the program: a demonstration
Post by: TerryRitchie on February 19, 2020, 08:14:56 pm

Would anyone happen to have the GUI demo Galleon posted on [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] back around 2012?

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 19, 2020, 08:18:22 pm

@Bplus
so

Quote

It is my understanding to resize a window in your code:
1) Click top right box and that activates the 2 white resize boxes
2) Click one of those and that tells your code which corner is anchor and which corner will be moved, this activatees the dashed outline border

these 2 steps are ok (dashed lines are added only to give more feedback to user, each anchor has its dashed line)
after got dashed line you must
3) move the pointer of mouse without any mouse button pressed (like mouse was locked in dragging mode)
4) left click another time to escape from this situation of dragging anchor without any mouse button pressed
now you get the new dimensioned window.


@Terry
Thanks
and thanks for this http://qb64sourcecode.com/ (http://qb64sourcecode.com/)

Title: Re: child windows into window of the program: a demonstration
Post by: TerryRitchie on February 19, 2020, 09:12:01 pm

Quote from: TempodiBasic on February 19, 2020, 08:18:22 pm

and thanks for this http://qb64sourcecode.com/ (http://qb64sourcecode.com/)

I never did finish the last 4 lessons on that site. When the school I was working for forced me to start teaching Python I never found the time to finish.

I'm glad you like it and you are welcome. I've had quite a few people tell me that it helped them get a start in QB64.

Title: Re: child windows into window of the program: a demonstration
Post by: bplus on February 19, 2020, 09:34:59 pm

Quote from: TempodiBasic on February 19, 2020, 08:18:22 pm

@Bplus
sothese 2 steps are ok (dashed lines are added only to give more feedback to user, each anchor has its dashed line)
after got dashed line you must
3) move the pointer of mouse without any mouse button pressed (like mouse was locked in dragging mode)
4) left click another time to escape from this situation of dragging anchor without any mouse button pressed
now you get the new dimensioned window.

...

Ah... It does work better, when I click the white box and if it does not respond, it usually responds with a 2nd try after I click the interior of box. I am in such a habit of mouse down and drag to resize, it's hard to test a different way.

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 20, 2020, 08:38:17 am

Hi

@Keybone
I have tried my code in QB64 1.3 in Lubuntu 16.4 and I have had your same experience!
I don't know why the click is not detected in the little white boxes.... the same code works on Windows 10.

Please try this
1. go in the code to the line 334 of the code

Code: QB64: [Select]

1.                             IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN  'this one line
2.                                 DO WHILE _MOUSEINPUT: LOOP ' clear mouse buffer
3.                                 IsResizing Windows(a), _MOUSEX, _MOUSEY
4.                             END IF

and cancel the second condition of the IF, you'll find the resizing but with the issue to not be able to choose the bottomright white square.

Please gimme feedback when you can do it.

@Bplus
thanks, this is a problem of bad communication from me...

@QB64 coders
who can give me feedback on MacOs?
Thanks

Title: Re: child windows into window of the program: a demonstration
Post by: keybone on February 20, 2020, 01:21:08 pm

Quote from: TempodiBasic on February 20, 2020, 08:38:17 am

Hi

@Keybone
I have tried my code in QB64 1.3 in Lubuntu 16.4 and I have had your same experience!
I don't know why the click is not detected in the little white boxes.... the same code works on Windows 10.

Please try this
1. go in the code to the line 334 of the code

Code: QB64: [Select]

1.                             IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN  'this one line
2.                                 DO WHILE _MOUSEINPUT: LOOP ' clear mouse buffer
3.                                 IsResizing Windows(a), _MOUSEX, _MOUSEY
4.                             END IF

and cancel the second condition of the IF, you'll find the resizing but with the issue to not be able to choose the bottomright white square.

Please gimme feedback when you can do it.

@Bplus
thanks, this is a problem of bad communication from me...

@QB64 coders
who can give me feedback on MacOs?
Thanks

Yeah thats kind odd that it works on windows and not linux.
I have no idea why it's not working. Maybe you need to simplify your mouse input routines.
Other than the mouse not working properly, it looks pretty decent.

I'm going to say though that the way this window manager works is pretty unstandard.
It is very different from how it would be expected to work compared to others.

For example the minimize button restores the window from maximized, and the close button minimizes it.
You might want to rethink it a little bit, but not saying its bad or anything, just different. :-)

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on February 21, 2020, 04:35:39 pm

@keybone

I'm thinking that the only difference between the executable compiled in Windows 10 and that compiled in Lubuntu 16.04 is QB64 !
Yes  the translator from QB to C++ to compile with GCC.
So about this

Quote

Yeah thats kind odd that it works on windows and not linux.
I have no idea why it's not working. Maybe you need to simplify your mouse input routines.

I think that the same QB64 code is translated into 2 different ways in the 2 different OSes.
in fact if you cut out 

Code: QB64: [Select]

1.      AND _MOUSEBUTTON(1)

  from line
 

Code: QB64: [Select]

1.                      IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN  'this one line

the code works with the original glicth that you can use only the leftest white square of the resizing tool.

about

Quote

For example the minimize button restores the window from maximized, and the close button minimizes it.
You might want to rethink it a little bit, but not saying its bad or anything, just different. :-)

yes the will to build something just different is behind this demonstration...
1. the X to close to the minimum size (the only bar of window) 
2. the maximize button not switching between maximize and restore to normal size
3. the dotted square for resize the window

I agree that the button to restore the area of the window brings a picture that is not intuitive! I'll change this picture with another more clear.

About resizing routine: it is a choice to not use the continue state of left button of mouse down as signal to resize but to use a lock system that can be disactivated clicking outer of the shape of resizing.

Thanks for your feedbacks


Good hearing

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on April 18, 2020, 06:22:47 am

Hy guys
just a little feedback

I have found as to fix the issue on Linux!
it seems that the translation in C++ on Linux's ship makes faster the execution of code...
so if you put a delay not littler than .1 you got the code working well

Code: QB64: [Select]

1. _DELAY 0.1

under the .1 ( as .08 .05 .02)  the issue comes back!
What fine thing....

As i can recover the rest of fixing I'll post the code with no scattering of window resized and a demo of a module with input in a window and output into another.
Thanks to read

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on May 08, 2020, 04:30:07 am

Hi guys
here a first fixed version of wchild demonstration with its original method for  get resizing, fullscreen, fullwindow and normalwindow child windows into a main window program.

  [ This attachment cannot be displayed inline in 'Print Page' view ]  

  [ This attachment cannot be displayed inline in 'Print Page' view ]  

Here the code 

Code: QB64: [Select]

1. ' HELP:
2. ' click by left button of mouse on the title bar and drag and drop to move a child window
3. ' click by left button of mouse on the leftest button on the title bar of a child window to resize window
4. '   and then click on one of two white squares  and when white border  of window is changed
5. '   move mouse and the border follow pointerofmouse resizing window.
6. '   To stop resizing and fix the new dimensions click again on white square
7. ' click by left button of mouse on the rightest button on the title bar  of window to minimize window to its title bar
8. ' click by left button of mouse on the second rightest button on the title bar  to maximize window occupying the whole main window
9. '      in fullscreen mode you get the fullscreen area with wchild choosen
10. ' click by left button of mouse on the third rightest button on the title bar  to restore the window from minimized_to_bar  to previous status Normal or Maximized
11. ' click by third (wheel) button of mouse to pass from fullscreen to window status of main window of the program
12. ' click by second (right) button of mouse to pass from window to fullscreen status of main window of the program
13.  
14.  
15.  
16. ' settings-------------------------------------------------------
17. SCREEN _NEWIMAGE(800, 600, 32)
18. _TITLE "Child windows"
19. ' the CONST with colors is better to declare after screen definition
20. ' also if _RGBA32 is indipendent form screen definition
21. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
22. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
23. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
24.  
25. ' these constants have the role of commands to execute from windows' engine
26. CONST Minim = 10, Maxim = 20, Closed = 100
27. CONST wMin = 5, aNull = 0, aQuit = 9999
28. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
29. CONST cResize = 700, LResize = 710, RResize = 720, StopResize = 730
30. ' these constants are universal
31. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
32.  
33. _FULLSCREEN ' app starts at fullscreen state
34. RANDOMIZE TIMER ' to support randomizing
35.  
36. 'dataset  -----------------------------------------------
37. ' components' type
38. REM here declaration for components used into wchild
39. REM  for large components you can use an $include file
40.  
41. ' window's type
42. TYPE wChild
43.     X AS INTEGER ' x of window
44.     Y AS INTEGER 'y of window
45.     WIDTH AS INTEGER ' width of window
46.     Height AS INTEGER 'height of window
47.     Zorder AS INTEGER 'order along z axis 1 = on top , lower value = at bottom
48.     Status AS INTEGER 'status maximized/fullscreen, minimized/normal or StatusBar/Closed
49.     COLOR AS _UNSIGNED LONG ' color of background of window
50.     Name AS STRING
51. END TYPE
52.  
53. ' 2 arrays one for windows and one for operation with windows
54. ' like to manage temporary data or store original data
55. REDIM Windows(1 TO wMin) AS wChild, OldW(0 TO wMin) AS wChild
56. DIM Action AS INTEGER ' flag of actions for engine
57.  
58.  
59. InitWin ' it creates some windows
60.  
61.  
62.  
63. ' main loop -----------------------------------------------
64.  
65. DO
66.     ' set the main window's background
67.     CLS , Orange
68.     ' reset the flag of engine
69.     Action = aNull
70.  
71.     DrawAllWin ' output windows in Zorder
72.     GetInput Action ' this SUB takes keyboard and mouse input from user and translate it as engine's command
73.     DoAction Action ' it executes command of getinput
74.     _DISPLAY ' retracing the video
75.     _LIMIT 30 'fps 30
76. LOOP
77. END
78.  
79. ' SUBs and FUNCTIONs --------------------------------------
80.  
81.  
82. SUB InitWin ' it creates  windows and save their data in oldW
83.     SHARED Windows() AS wChild, OldW() AS wChild
84.     DIM a AS INTEGER
85.  
86.     Windows(1).X = 1
87.     Windows(1).Y = 1
88.     Windows(1).WIDTH = 300
89.     Windows(1).Height = 400
90.     Windows(1).Zorder = 1
91.     Windows(1).Status = Minim
92.     Windows(1).COLOR = Blu
93.     Windows(1).Name = "Blu"
94.  
95.     Windows(2).X = 100
96.     Windows(2).Y = 1
97.     Windows(2).WIDTH = 300
98.     Windows(2).Height = 400
99.     Windows(2).Zorder = 2
100.     Windows(2).Status = Minim
101.     Windows(2).COLOR = Yellow
102.     Windows(2).Name = "Yellow"
103.  
104.     Windows(3).X = 200
105.     Windows(3).Y = 1
106.     Windows(3).WIDTH = 300
107.     Windows(3).Height = 400
108.     Windows(3).Zorder = 3
109.     Windows(3).Status = Minim
110.     Windows(3).COLOR = Green
111.     Windows(3).Name = "Green"
112.  
113.     Windows(4).X = 300
114.     Windows(4).Y = 1
115.     Windows(4).WIDTH = 300
116.     Windows(4).Height = 400
117.     Windows(4).Zorder = 4
118.     Windows(4).Status = Minim
119.     Windows(4).COLOR = Red
120.     Windows(4).Name = "Red"
121.     Windows(5).X = 400
122.     Windows(5).Y = 1
123.     Windows(5).WIDTH = 300
124.     Windows(5).Height = 400
125.     Windows(5).Zorder = 5
126.     Windows(5).Status = Minim
127.     Windows(5).COLOR = Cyan
128.     Windows(5).Name = "Cyan"
129.  
130.     FOR a = 1 TO wMin STEP 1
131.         AdjournWin a 'it stores informations of  windows into OldW
132.     NEXT a
133. END SUB
134.  
135. SUB RestoreWin (a AS INTEGER) ' it restores data of a windows from OldW
136.     SHARED Windows() AS wChild, OldW() AS wChild
137.  
138.     Windows(a).X = OldW(a).X
139.     Windows(a).Y = OldW(a).Y
140.     Windows(a).WIDTH = OldW(a).WIDTH
141.     Windows(a).Height = OldW(a).Height
142.     Windows(a).Zorder = OldW(a).Zorder
143.     Windows(a).COLOR = OldW(a).COLOR
144. END SUB
145.  
146. SUB AdjournWin (a AS INTEGER) 'it saves data of a window into OldW
147.     SHARED Windows() AS wChild, OldW() AS wChild
148.  
149.     OldW(a).X = Windows(a).X
150.     OldW(a).Y = Windows(a).Y
151.     OldW(a).WIDTH = Windows(a).WIDTH
152.     OldW(a).Height = Windows(a).Height
153.     OldW(a).Zorder = Windows(a).Zorder
154.     OldW(a).COLOR = Windows(a).COLOR
155. END SUB
156.  
157. SUB DrawAllWin ' it draws all windows starting from bottom of Zorder stack
158.     SHARED Windows() AS wChild ' here parameters of wchild and components
159.     DIM Finished AS INTEGER 'target to draw
160.     DIM a AS INTEGER ' counter of FOR
161.     Finished = wMin ' it starts from the bottom of Zorder
162.     DO
163.         FOR a = 1 TO wMin 'for all windows created (wMin)
164.             IF Windows(a).Zorder = Finished THEN ' if the window is that we are searching
165.                 DrawWindow Windows(a), a 'we draw window
166.                 Finished = Finished - 1 'we decrease the pointer from bottom to up until the first window
167.                 EXIT FOR ' next window
168.             END IF
169.         NEXT a
170.     LOOP UNTIL Finished = 0
171. END SUB
172.  
173. SUB Focus (Index AS INTEGER) ' it puts a windows at top of Zorder and the previous top window to the bottom
174.     SHARED Windows() AS wChild
175.     DIM b AS INTEGER
176.     FOR b = 1 TO wMin
177.         IF Windows(b).Zorder = 1 THEN EXIT FOR
178.     NEXT b
179.     ' here it changes the position between the new Ontpo window and the last Ontop Window
180.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
181.     DrawAllWin
182. END SUB
183.  
184.  
185. SUB DoAction (Act AS INTEGER) ' it is the engine of the manager of windows
186.     SHARED Windows() AS wChild, OldW() AS wChild
187.     ' engine's variables
188.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
189.  
190.     ' mouse's variables
191.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
192.     ' it executes Act's content
193.     SELECT CASE Act
194.         CASE aQuit
195.             END
196.  
197.         CASE Maxim
198.             _FULLSCREEN
199.  
200.         CASE Minim
201.             _FULLSCREEN _OFF
202.  
203.         CASE mLeft ' Left Click of mouse
204.             mX = _MOUSEX ' we store the actual X and Y of mouse
205.             mY = _MOUSEY
206.  
207.             ' search where and what mouse has touched by leftclick
208.             OldA = 0
209.             OldActio = 0
210.             FOR a = 1 TO wMin ' windows(0) is out of action
211.                 Actio = IsInWindow(mX, mY, Windows(a)) ' what window on the top of stack is interacting with mouse
212.                 IF Actio THEN
213.                     IF OldA <= 0 THEN ' if no previous window has interact with mouse
214.                         OldA = a 'we memorize action and index of window
215.                         OldActio = Actio
216.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN ' if actual window has a Zorder less the previouse
217.                         OldA = a ' we memorize action and  index of window
218.                         OldActio = Actio
219.                     END IF
220.                 END IF
221.             NEXT a
222.             IF a > OldA THEN
223.                 a = OldA ' restore the last windows interacting
224.                 Actio = OldActio
225.             END IF
226.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB ' no action out of SUB
227.  
228.  
229.             Focus a 'set zorder on the (a) window that gets the input
230.  
231.  
232.             SELECT CASE Actio
233.                 CASE cMinim
234.                     ' here restore to  standard (bar + area of window) status of child window
235.                     IF Windows(a).Status = Closed + Maxim THEN
236.                         ' if windows is a closed maximized window
237.                         ' we restore its status of maximized
238.                         Windows(a).Status = Maxim
239.                     ELSEIF Windows(a).Status = Closed + Minim THEN
240.                         ' if windows is a closed minimized window
241.                         ' we restore its status of minimized
242.                         Windows(a).Status = Minim
243.                     ELSEIF Windows(a).Status = Maxim THEN
244.                         ' if is a window maximized it gets back all info setting
245.                         ' we restore its status of minimized
246.                         RestoreWin a
247.                         Windows(a).Status = Minim
248.                     END IF
249.  
250.  
251.                 CASE cMaxim
252.                     ' here convert the window to full size of main window of the program
253.                     ' OR gives 1 if both parameter are true or al last one is true
254.                     IF (Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim) THEN
255.                         ' it acts if windows if not still maximized
256.                         ' it is minimized window opened or closed
257.                         ' memorize window's data when it is not maximized
258.                         '                        IF Windows(a).Width < _WIDTH THEN
259.                         AdjournWin a
260.                         ' it sets maximized status
261.                         Windows(a).WIDTH = _WIDTH
262.                         Windows(a).Height = _HEIGHT
263.                         Windows(a).X = 1
264.                         Windows(a).Y = 1
265.                         ' change status
266.                         Windows(a).Status = Maxim
267.                     END IF
268.  
269.                 CASE cClosed
270.                     ' here minimize the child window to its window bar
271.                     IF NOT Windows(a).Status > Closed THEN
272.                         Windows(a).Status = Windows(a).Status + Closed
273.                     END IF
274.  
275.                 CASE Dragging
276.                     ' dragging is possible for all status of windows
277.                     '
278.                     ' if minimized or Closed and minimized window we save data info
279.                     IF Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim THEN AdjournWin a
280.                     ' it sets variables for dragging
281.                     OldW(0).X = Windows(a).X
282.                     OldW(0).Y = Windows(a).Y
283.                     OldW(0).WIDTH = Windows(a).WIDTH
284.                     OldW(0).Height = Windows(a).Height
285.  
286.                     OmX = _MOUSEX - OldW(0).X ' we store actual value of X and Y of mouse
287.                     OmY = _MOUSEY - OldW(0).Y
288.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
289.                     DO WHILE _MOUSEBUTTON(1) ' while left mouse is pressed down
290.                         IF _MOUSEINPUT THEN ' if there is a mouseinput
291.                             CLS , Orange 'reset background
292.  
293.                             OldW(0).X = (_MOUSEX - OmX) 'it adjourns window X and Y
294.                             OldW(0).Y = (_MOUSEY - OmY)
295.                             DrawAllWin ' it shows all windows
296.                             dragWindow OldW(0) ' it shows white skeleton of window
297.                         END IF
298.                     LOOP
299.                     ' new position of window
300.                     Windows(a).X = OldW(0).X
301.                     Windows(a).Y = OldW(0).Y
302.                     OldW(a).X = Windows(a).X
303.                     OldW(a).Y = Windows(a).Y
304.  
305.                 CASE Focusing
306.                     Focus a ' it puts at the top of stack of windows
307.  
308.                 CASE cResize
309.                     ' resizing is possible only for minimized opened child windows
310.                     IF Windows(a).Status = Minim THEN
311.                         Windows(a).Status = cResize
312.                         DO WHILE _MOUSEBUTTON(1) OR _MOUSEINPUT: LOOP ' it waits if there is a mouse input
313.                         DO WHILE Windows(a).Status = cResize ' while window is in resize mode
314.                             CLS , Orange ' it redraws background of main window
315.                             DrawAllWin ' it draws all mouse  windows
316.                             ShowDimension Windows(a), 0
317.  
318.                             ' if mouse move or left mouse button is down
319.                             IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN
320.                                 DO WHILE _MOUSEINPUT: LOOP ' clear mouse buffer
321.                                 _DELAY 0.1 ' <---- this fixs Linus issue
322.                                 IsResizing Windows(a), _MOUSEX, _MOUSEY
323.                             END IF
324.                             _DISPLAY
325.                         LOOP
326.                     END IF
327.  
328.             END SELECT
329.         CASE ELSE
330.     END SELECT
331. END SUB
332.  
333. SUB IsResizing (Win AS wChild, mX AS INTEGER, mY AS INTEGER) ' this resize window by mouse
334.     SHARED Windows() AS wChild, OldW() AS wChild
335.     DIM Actio AS INTEGER, OldmX AS INTEGER, OldmY AS INTEGER
336.     Actio = 0
337.     'if mouse X is in the X range of the window
338.     IF IsInTheRange%(mX, Win.X, Win.X + Win.WIDTH) THEN
339.         ' if mouse Y is in the y range of the window
340.         IF IsInTheRange%(mY, Win.Y, Win.Y + Win.Height) THEN
341.             ' do nothing if it is in the range of window
342.         ELSE
343.             ' user click out of area  of window to resize
344.             Actio = StopResize
345.         END IF
346.     ELSE
347.         ' user click out of area  of window to resize
348.         Actio = StopResize
349.     END IF
350.  
351.  
352.  
353.  
354.     ' if mouse X is in the x range  of the leftest button on the window's bar
355.     IF IsInTheRange%(mX, Win.X, Win.X + 10) THEN
356.         ' if mouse Y is in the y range of the window's bar
357.         IF IsInTheRange%(mY, Win.Y, Win.Y + 10) THEN
358.             ' user click on lefttop square to resize
359.             Actio = LResize
360.         END IF
361.     END IF
362.     ' if mouse X is in the range of rightest button of window's bar
363.     IF IsInTheRange%(mX, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
364.         ' if mouse Y is in the y range of the bottom of window
365.         IF IsInTheRange%(mY, Win.Y + Win.Height - 10, Win.Y + Win.Height) THEN
366.             ' user click on the rightbottom square to resize
367.             Actio = RResize
368.         END IF
369.     END IF
370.  
371.     IF Actio = 0 THEN
372.         ' no action done
373.     ELSEIF Actio = LResize THEN
374.         ' choosen LeftTop buttom to resize
375.         OldW(0).X = Win.X
376.         OldW(0).Y = Win.Y
377.         OldW(0).WIDTH = Win.WIDTH
378.         OldW(0).Height = Win.Height
379.         OldmX = _MOUSEX
380.         OldmY = _MOUSEY
381.         DO WHILE Actio = LResize
382.             IF _MOUSEINPUT THEN ' if mouse moves it adapts the dimension to the minimun default value for X and Y
383.                 IF (OldW(0).X + OldW(0).WIDTH - OldmX) >= 70 THEN OldW(0).WIDTH = OldW(0).X + OldW(0).WIDTH - OldmX ELSE OldW(0).WIDTH = 70: OldW(0).X = Win.X + Win.WIDTH - 70: OldmX = OldW(0).X
384.                 IF (OldW(0).Y + OldW(0).Height - OldmY) >= 30 THEN OldW(0).Height = OldW(0).Y + OldW(0).Height - OldmY ELSE OldW(0).Height = 30: OldW(0).Y = Win.Y + Win.Height - 30: OldmY = OldW(0).Y
385.                 CLS , Orange
386.                 DrawAllWin
387.                 ShowDimension OldW(0), Actio
388.                 OldW(0).X = OldmX ' it stores new Oldmx and OldmY
389.                 OldW(0).Y = OldmY
390.  
391.                 OldmX = _MOUSEX
392.                 OldmY = _MOUSEY
393.             ELSE
394.                 IF _MOUSEBUTTON(1) THEN Actio = 0 ' a second leftclick stops the resize action
395.             END IF
396.         LOOP
397.         Win.X = OldW(0).X 'the new dimension of windows are stored
398.         Win.Y = OldW(0).Y
399.         Win.WIDTH = OldW(0).WIDTH
400.         Win.Height = OldW(0).Height
401.  
402.  
403.     ELSEIF Actio = RResize THEN
404.         ' choosen bottomright square
405.         OldW(0).X = Win.X ' it gets the window dimensions
406.         OldW(0).Y = Win.Y
407.         OldW(0).WIDTH = Win.WIDTH
408.         OldW(0).Height = Win.Height
409.         OldmX = _MOUSEX 'actual mouse X and Y
410.         OldmY = _MOUSEY
411.         DO WHILE Actio = RResize ' while is active resize from right
412.             IF _MOUSEINPUT THEN ' if mouse moves it adapts the dimension of window to mouse position
413.                 IF OldmX - OldW(0).X >= 70 THEN OldW(0).WIDTH = OldmX - OldW(0).X
414.                 IF OldmY - OldW(0).Y >= 30 THEN OldW(0).Height = OldmY - OldW(0).Y
415.                 CLS , Orange
416.                 DrawAllWin
417.                 ShowDimension OldW(0), Actio
418.                 OldmX = _MOUSEX
419.                 OldmY = _MOUSEY
420.             ELSE
421.                 IF _MOUSEBUTTON(1) THEN Actio = 0 ' il mouse leftclick it stops resize
422.             END IF
423.         LOOP
424.         Win.X = OldW(0).X 'it adjusts the dimensions of window to the new status
425.         Win.Y = OldW(0).Y
426.         Win.WIDTH = OldW(0).WIDTH
427.         Win.Height = OldW(0).Height
428.  
429.     ELSEIF Actio = StopResize THEN
430.         ' click out of window to stop resize action
431.         Win.Status = Minim
432.     END IF
433. END SUB
434.  
435. SUB ShowDimension (win AS wChild, Actio AS INTEGER) ' it shows skeleton of window with 2 buttons for dimensioning
436.     IF win.Status = cResize AND Actio = 0 THEN
437.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B ' windows size
438.     ELSEIF Actio = LResize THEN
439.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 45 ' windows size
440.     ELSEIF Actio = RResize THEN
441.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 200 ' windows size
442.     END IF
443.     LINE (win.X, win.Y)-(win.X + 10, win.Y + 10), White, BF 'button for resizing window
444.     LINE (win.X + win.WIDTH - 10, win.Y + win.Height - 10)-(win.X + win.WIDTH, win.Y + win.Height), White, BF 'button for resizing window
445.     _DISPLAY
446. END SUB
447.  
448. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild) 'it searches if mouse is in window passed as Win
449.     IsInWindow = mFalse
450.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
451.         ' if window is closed to its bar it cannot get focus on the window area
452.         IF IsInTheRange%(X, Win.X, Win.X + Win.WIDTH) AND (Win.Status < Closed) THEN IsInWindow = Focusing
453.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
454.         ' if it is the window bar area
455.         IF IsInTheRange%(X, Win.X + 10, Win.X + Win.WIDTH - 31) THEN
456.             ' if it is to the left of buttons on the bar
457.             IsInWindow = Dragging
458.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 30, Win.X + Win.WIDTH - 21) THEN
459.             ' if it is on the leftest button on the bar
460.             IsInWindow = cMinim ' icon minimize--> restore to child default
461.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 20, Win.X + Win.WIDTH - 11) THEN
462.             ' if it is on the middle button on the bar
463.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
464.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
465.             ' if is on the rightest button on the bar
466.             IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
467.         ELSEIF IsInTheRange%(X, Win.X, Win.X + 10) THEN ' if is on the left side of bar on Resize button
468.             IsInWindow = cResize
469.         END IF
470.     END IF
471. END FUNCTION
472.  
473. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER) ' it tests if What is between Min and Max
474.     IF Min > Max THEN SWAP Min, Max
475.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
476. END FUNCTION
477.  
478. SUB dragWindow (Win AS wChild) ' this draw the white skeleton of a window
479.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), White, B ' windows size
480.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), White, BF 'title bar for dragging window
481.     _DISPLAY
482. END SUB
483.  
484. SUB wClosed (Win AS wChild) 'title bar button for show only title bar of window
485.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF
486.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Black, B
487.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 3)-(Win.X + Win.WIDTH - 3, Win.Y + 7), Black
488.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 7)-(Win.X + Win.WIDTH - 3, Win.Y + 3), Black
489. END SUB
490.  
491. SUB wMaxim (win AS wChild) 'title bar  button for maximize to the whole main window
492.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Pink, BF
493.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Black, B
494.     LINE (win.X + win.WIDTH - 17, win.Y + 3)-(win.X + win.WIDTH - 13, win.Y + 7), Black, B
495. END SUB
496.  
497. SUB wMinim (Win AS wChild) 'title bar button for restore to original dimensions
498.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Pink, BF
499.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Black, B
500.     LINE (Win.X + Win.WIDTH - 27, Win.Y + 3)-(Win.X + Win.WIDTH - 23, Win.Y + 4), Black, BF
501.     LINE (Win.X + Win.WIDTH - 27, Win.Y + 3)-(Win.X + Win.WIDTH - 23, Win.Y + 7), Black, B , &B1010101010101010
502. END SUB
503.  
504. SUB wResize (Win AS wChild) 'title bar button for resize  dimensions of window
505.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Pink, BF
506.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Black, B
507.     LINE (Win.X + 2, Win.Y + 2)-(Win.X + 7, Win.Y + 7), Black, B , &B1010101010101010
508. END SUB
509.  
510. SUB DrawWindow (Win AS wChild, a AS INTEGER) ' it draws a window aspect following its status
511.  
512.     ' the window
513.     IF Win.Status = Minim OR Win.Status = Maxim THEN
514.         LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Win.COLOR, BF
515.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
516.         LINE (Win.X + Win.WIDTH, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
517.     END IF
518.     ' the title bar
519.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF 'title bar for dragging window
520.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.WIDTH, Win.Y + 10), Black
521.     wMinim Win
522.     wMaxim Win
523.     wClosed Win
524.     wResize Win
525.  
526.     ' the content of the window
527.     REM here the draw routine of components
528.  
529.  
530. END SUB
531.  
532. SUB GetInput (Act AS INTEGER) ' manager of input by keyboard & mouse
533.     DIM mInput AS INTEGER ' flag of commands of mouse
534.  
535.  
536.     ' keyboard input
537.     a$ = INKEY$
538.     IF a$ = CHR$(27) THEN Act = aQuit 'keyboard's command in feedback by Act
539.  
540.     'mouse input
541.     mInput = mFalse
542.     IF _MOUSEINPUT THEN mInput = mTrue
543.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
544.     LOOP
545.     IF mInput THEN ' here flag of mouse gets the command's values
546.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
547.             mInput = mLR
548.         ELSEIF _MOUSEBUTTON(1) THEN
549.             mInput = mLeft
550.         ELSEIF _MOUSEBUTTON(2) THEN
551.             mInput = mRight
552.         ELSEIF _MOUSEBUTTON(3) THEN
553.             mInput = mMiddle
554.         END IF
555.     END IF
556.     'mouse's command in feedback by Act
557.     IF mInput = mLR THEN
558.         Act = aQuit
559.     ELSEIF mInput = mMiddle THEN
560.         Act = Minim
561.     ELSEIF mInput = mRight THEN
562.         Act = Maxim
563.     ELSEIF mInput = mLeft THEN
564.         Act = mInput
565.     END IF
566. END SUB
567.  
568.  
569.  

Title: Re: child windows into window of the program: a demonstration
Post by: TempodiBasic on May 11, 2020, 03:27:50 pm

Hi
it is just an update to show how to manage a content of child windows.
Here there is a simple label into windows... coming soon a BMI database for people

Code: QB64: [Select]

1. ' 2020 04 18  Fixed Linux issue about selection of resizing white buttons
2.  
3. ' 2020 04 03  creating label as component of window (label is from 1 to 100 characters on one line)
4. '             to be visible in a window it is printed only for the inner width of window
5.  
6. ' 2020 03 25  fixing  window undraggable if it has been put lefter  to
7. ' the left border of main window
8.  
9. ' 2020 02 17  fixing resize from left bug with scattering of window resized
10.  
11. ' 2020 02 12  with the power of the second array we implement the feature
12. '             of resizable of child window
13.  
14. ' 2020 02 09  with the power of the second array we implement a different
15. '             child windows' system:
16. '             all child windows can be Closed to window's bar
17. '             all child windows can be dragged on the screen
18.  
19. ' 2020 02 08  using a second array we store windows information indipendently so
20. '             now each window can be modified and restored
21.  
22.  
23. ' 2020 02 06  after dragging or maximize a window, restoring it we gives
24. '             to it the last value used in windows(0) so the info of the last
25. '             window that is dragged or maximize when we use Minimize button on
26. '             another child window
27. '             the fix can be got using a shadow array that stores windows informations
28. '             or windows(0) as the child window that takes the information of the
29. '             child window that must be acted (Minimize, Maximize and Closed)
30. '             and we use it as template to make graphic output
31.  
32. ' 2020 02 05 fixed a minor bug on mouse click events
33. '            activated events Maxim Minim and Closed
34.  
35.  
36. ' 2020 02 03 increasing the windows managed and close initialization to SUB
37. '            removed vMax SHARED variable
38. '            added 3 buttons on the rightest site of the bar of the child window
39. '            SUB wClosed, wMaxim, wMinim
40. '            In this version the user can maximize one child window to the application window
41. '            In the status of Maxim the child window has the focus and can be only
42. '            reduced to status Minim, it cannot be dragging or Closed to bar of window
43.  
44.  
45. ' 2020 01 30 fixed bug on focusing a child window
46. '
47.  
48. ' 2020 01 25  A program with child windows into it
49. ' we need a system to manage multiple windows
50. ' and a system to manage input/output
51. ' and a system to make graphic report
52.  
53.  
54. ' settings-------------------------------------------------------
55. SCREEN _NEWIMAGE(800, 600, 32)
56. _TITLE "Child windows"
57. ' the CONST with colors is better to declare after screen definition
58. ' also if _RGBA32 is indipendent form screen definition
59. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255)
60. CONST Green = _RGBA32(0, 200, 0, 255), Blu = _RGBA32(0, 0, 200, 255), Yellow = _RGBA32(200, 200, 20, 255)
61. CONST Cyan = _RGBA32(20, 140, 230, 255), Orange = _RGBA32(200, 100, 20, 255), Pink = _RGBA32(227, 80, 120, 255)
62.  
63. ' these constants have the role of commands to execute from windows' engine
64. CONST Minim = 10, Maxim = 20, Closed = 100
65. CONST wMin = 5, aNull = 0, aQuit = 9999
66. CONST Dragging = 300, Focusing = 200, cMinim = 400, cMaxim = 500, cClosed = 600
67. CONST cResize = 700, LResize = 710, RResize = 720, StopResize = 730
68. ' these constants are universal
69. CONST mTrue = 1, mFalse = 0, mLeft = 2, mRight = 3, mMiddle = 4, mLR = 5
70.  
71. _FULLSCREEN ' app starts at fullscreen state
72. RANDOMIZE TIMER ' to support randomizing
73.  
74. 'dataset  -----------------------------------------------
75. ' components type
76. TYPE Label
77.     X AS INTEGER ' x relative to x of parent window
78.     Y AS INTEGER ' y relative to y of parent window
79.     Parent AS STRING ' the name of window   if=" Desktop" it is the main window
80.     Lenght AS INTEGER ' lenght of label
81.     Caption AS STRING ' the text of label
82.     Color AS _UNSIGNED LONG ' foreground color of text of label
83.     font AS LONG ' it is handle of font
84. END TYPE
85.  
86. ' window's type
87. TYPE wChild
88.     X AS INTEGER ' x of window
89.     Y AS INTEGER 'y of window
90.     WIDTH AS INTEGER ' width of window
91.     Height AS INTEGER 'height of window
92.     Zorder AS INTEGER 'order along z axis 1 = on top , lower value = at bottom
93.     Status AS INTEGER 'status maximized/fullscreen, minimized/normal or StatusBar/Closed
94.     COLOR AS _UNSIGNED LONG ' color of background of window
95.     Name AS STRING
96. END TYPE
97. ' 2 arrays one for windows and one for operation with windows
98. ' like to manage temporary data or store original data
99. REDIM Windows(1 TO wMin) AS wChild, OldW(0 TO wMin) AS wChild
100. DIM L(1 TO wMin) AS Label
101. DIM Action AS INTEGER ' flag of actions for engine
102.  
103.  
104. InitWin ' it creates some windows
105. InitLabel L(), Windows()
106.  
107.  
108.  
109.  
110. ' main loop -----------------------------------------------
111.  
112. DO
113.     ' set the main window's background
114.     CLS , Orange
115.     ' reset the flag of engine
116.     Action = aNull
117.  
118.     DrawAllWin ' output windows in Zorder
119.     GetInput Action ' this SUB takes keyboard and mouse input from user and translate it as engine's command
120.     DoAction Action ' it executes command of getinput
121.     _DISPLAY ' retracing the video
122.     _LIMIT 30 'fps 30
123. LOOP
124. END
125.  
126. ' SUBs and FUNCTIONs --------------------------------------
127. SUB ShowString (L AS Label, Win AS wChild)
128.     IF Win.Status <> Minim AND Win.Status <> Maxim THEN EXIT SUB
129.     DIM VisibleString AS STRING, NumChar AS INTEGER
130.     IF _FONTHEIGHT(L.font) + L.Y >= Win.Height THEN EXIT SUB
131.     IF L.Lenght + L.X >= Win.WIDTH THEN
132.         NumChar = CINT((Win.WIDTH - L.X - 4) / _FONTWIDTH)
133.         VisibleString = LEFT$(L.Caption, NumChar)
134.     ELSE
135.         VisibleString = L.Caption
136.     END IF
137.     COLOR L.Color, Win.COLOR
138.     _PRINTSTRING (L.X + Win.X, L.Y + Win.Y + 10), VisibleString
139. END SUB
140.  
141. SUB InitLabel (L() AS Label, win() AS wChild)
142.     FOR a% = 1 TO wMin
143.         L(a%).X = 3 + (RND * (win(a%).Height / 2) - 10)
144.         L(a%).Y = 4 + (RND * (win(a%).WIDTH / 2) - 10)
145.         L(a%).Parent = win(a%).Name
146.         L(a%).Caption = "This is a demonstration of output"
147.         L(a%).Color = _RGBA32(133, 39, 177, 255)
148.         L(a%).font = _LOADFONT("cour.ttf", 12, "monospace")
149.         IF L(a%).font <= 0 THEN PRINT "error loading font ": SLEEP
150.         L(a%).Lenght = LEN(L(a%).Caption) * _FONTWIDTH
151.     NEXT a%
152. END SUB
153.  
154. SUB InitWin ' it creates  windows and save their data in oldW
155.     SHARED Windows() AS wChild, OldW() AS wChild
156.     DIM a AS INTEGER
157.  
158.     Windows(1).X = 1
159.     Windows(1).Y = 1
160.     Windows(1).WIDTH = 300
161.     Windows(1).Height = 400
162.     Windows(1).Zorder = 1
163.     Windows(1).Status = Minim
164.     Windows(1).COLOR = Blu
165.     Windows(1).Name = "Blu"
166.  
167.     Windows(2).X = 100
168.     Windows(2).Y = 1
169.     Windows(2).WIDTH = 300
170.     Windows(2).Height = 400
171.     Windows(2).Zorder = 2
172.     Windows(2).Status = Minim
173.     Windows(2).COLOR = Yellow
174.     Windows(2).Name = "Yellow"
175.  
176.     Windows(3).X = 200
177.     Windows(3).Y = 1
178.     Windows(3).WIDTH = 300
179.     Windows(3).Height = 400
180.     Windows(3).Zorder = 3
181.     Windows(3).Status = Minim
182.     Windows(3).COLOR = Green
183.     Windows(3).Name = "Green"
184.  
185.     Windows(4).X = 300
186.     Windows(4).Y = 1
187.     Windows(4).WIDTH = 300
188.     Windows(4).Height = 400
189.     Windows(4).Zorder = 4
190.     Windows(4).Status = Minim
191.     Windows(4).COLOR = Red
192.     Windows(4).Name = "Red"
193.     Windows(5).X = 400
194.     Windows(5).Y = 1
195.     Windows(5).WIDTH = 300
196.     Windows(5).Height = 400
197.     Windows(5).Zorder = 5
198.     Windows(5).Status = Minim
199.     Windows(5).COLOR = Cyan
200.     Windows(5).Name = "Cyan"
201.  
202.     FOR a = 1 TO wMin STEP 1
203.         AdjournWin a 'it stores informations of  windows into OldW
204.     NEXT a
205. END SUB
206.  
207. SUB RestoreWin (a AS INTEGER) ' it restores data of a windows from OldW
208.     SHARED Windows() AS wChild, OldW() AS wChild
209.  
210.     Windows(a).X = OldW(a).X
211.     Windows(a).Y = OldW(a).Y
212.     Windows(a).WIDTH = OldW(a).WIDTH
213.     Windows(a).Height = OldW(a).Height
214.     Windows(a).Zorder = OldW(a).Zorder
215.     Windows(a).COLOR = OldW(a).COLOR
216. END SUB
217.  
218. SUB AdjournWin (a AS INTEGER) 'it saves data of a window into OldW
219.     SHARED Windows() AS wChild, OldW() AS wChild
220.  
221.     OldW(a).X = Windows(a).X
222.     OldW(a).Y = Windows(a).Y
223.     OldW(a).WIDTH = Windows(a).WIDTH
224.     OldW(a).Height = Windows(a).Height
225.     OldW(a).Zorder = Windows(a).Zorder
226.     OldW(a).COLOR = Windows(a).COLOR
227. END SUB
228.  
229. SUB DrawAllWin ' it draws all windows starting from bottom of Zorder stack
230.     SHARED Windows() AS wChild, L AS Label
231.     DIM Finished AS INTEGER 'target to draw
232.     DIM a AS INTEGER ' counter of FOR
233.     Finished = wMin ' it starts from the bottom of Zorder
234.     DO
235.         FOR a = 1 TO wMin 'for all windows created (wMin)
236.             IF Windows(a).Zorder = Finished THEN ' if the window is that we are searching
237.                 DrawWindow Windows(a), a 'we draw window
238.                 Finished = Finished - 1 'we decrease the pointer from bottom to up until the first window
239.                 EXIT FOR ' next window
240.             END IF
241.         NEXT a
242.     LOOP UNTIL Finished = 0
243. END SUB
244.  
245. SUB Focus (Index AS INTEGER) ' it puts a windows at top of Zorder and the previous top window to the bottom
246.     SHARED Windows() AS wChild
247.     DIM b AS INTEGER
248.     FOR b = 1 TO wMin
249.         IF Windows(b).Zorder = 1 THEN EXIT FOR
250.     NEXT b
251.     ' here it changes the position between the new Ontpo window and the last Ontop Window
252.     IF Index <> b THEN SWAP Windows(Index).Zorder, Windows(b).Zorder
253.     DrawAllWin
254. END SUB
255.  
256.  
257. SUB DoAction (Act AS INTEGER) ' it is the engine of the manager of windows
258.     SHARED Windows() AS wChild, OldW() AS wChild
259.     ' engine's variables
260.     DIM a AS INTEGER, Actio AS INTEGER, OldA AS INTEGER, OldActio AS INTEGER
261.  
262.     ' mouse's variables
263.     DIM mX AS INTEGER, mY AS INTEGER, OmX AS INTEGER, OmY AS INTEGER
264.     ' it executes Act's content
265.     SELECT CASE Act
266.         CASE aQuit
267.             END
268.  
269.         CASE Maxim
270.             _FULLSCREEN
271.  
272.         CASE Minim
273.             _FULLSCREEN _OFF
274.  
275.         CASE mLeft ' Left Click of mouse
276.             mX = _MOUSEX ' we store the actual X and Y of mouse
277.             mY = _MOUSEY
278.  
279.             ' search where and what mouse has touched by leftclick
280.             OldA = 0
281.             OldActio = 0
282.             FOR a = 1 TO wMin ' windows(0) is out of action
283.                 Actio = IsInWindow(mX, mY, Windows(a)) ' what window on the top of stack is interacting with mouse
284.                 IF Actio THEN
285.                     IF OldA <= 0 THEN ' if no previous window has interact with mouse
286.                         OldA = a 'we memorize action and index of window
287.                         OldActio = Actio
288.                     ELSEIF Windows(a).Zorder < Windows(OldA).Zorder THEN ' if actual window has a Zorder less the previouse
289.                         OldA = a ' we memorize action and  index of window
290.                         OldActio = Actio
291.                     END IF
292.                 END IF
293.             NEXT a
294.             IF a > OldA THEN
295.                 a = OldA ' restore the last windows interacting
296.                 Actio = OldActio
297.             END IF
298.             IF OldA = 0 OR OldActio = 0 THEN EXIT SUB ' no action out of SUB
299.  
300.  
301.             Focus a 'set zorder on the (a) window that gets the input
302.  
303.  
304.             SELECT CASE Actio
305.                 CASE cMinim
306.                     ' here restore to  standard (bar + area of window) status of child window
307.                     IF Windows(a).Status = Closed + Maxim THEN
308.                         ' if windows is a closed maximized window
309.                         ' we restore its status of maximized
310.                         Windows(a).Status = Maxim
311.                     ELSEIF Windows(a).Status = Closed + Minim THEN
312.                         ' if windows is a closed minimized window
313.                         ' we restore its status of minimized
314.                         Windows(a).Status = Minim
315.                     ELSEIF Windows(a).Status = Maxim THEN
316.                         ' if is a window maximized it gets back all info setting
317.                         ' we restore its status of minimized
318.                         RestoreWin a
319.                         Windows(a).Status = Minim
320.                     END IF
321.  
322.  
323.                 CASE cMaxim
324.                     ' here convert the window to full size of main window of the program
325.                     ' OR gives 1 if both parameter are true or al last one is true
326.                     IF (Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim) THEN
327.                         ' it acts if windows if not still maximized
328.                         ' it is minimized window opened or closed
329.                         ' memorize window's data when it is not maximized
330.                         '                        IF Windows(a).Width < _WIDTH THEN
331.                         AdjournWin a
332.                         ' it sets maximized status
333.                         Windows(a).WIDTH = _WIDTH
334.                         Windows(a).Height = _HEIGHT
335.                         Windows(a).X = 1
336.                         Windows(a).Y = 1
337.                         ' change status
338.                         Windows(a).Status = Maxim
339.                     END IF
340.  
341.                 CASE cClosed
342.                     ' here minimize the child window to its window bar
343.                     IF NOT Windows(a).Status > Closed THEN
344.                         Windows(a).Status = Windows(a).Status + Closed
345.                     END IF
346.  
347.                 CASE Dragging
348.                     ' dragging is possible for all status of windows
349.                     '
350.                     ' if minimized or Closed and minimized window we save data info
351.                     IF Windows(a).Status = Minim OR Windows(a).Status = Closed + Minim THEN AdjournWin a
352.                     ' it sets variables for dragging
353.                     OldW(0).X = Windows(a).X
354.                     OldW(0).Y = Windows(a).Y
355.                     OldW(0).WIDTH = Windows(a).WIDTH
356.                     OldW(0).Height = Windows(a).Height
357.  
358.                     OmX = _MOUSEX - OldW(0).X ' we store actual value of X and Y of mouse
359.                     OmY = _MOUSEY - OldW(0).Y
360.                     DO WHILE _MOUSEINPUT: LOOP ' just clear mouse buffer
361.                     DO WHILE _MOUSEBUTTON(1) ' while left mouse is pressed down
362.                         IF _MOUSEINPUT THEN ' if there is a mouseinput
363.                             CLS , Orange 'reset background
364.  
365.                             OldW(0).X = (_MOUSEX - OmX) 'it adjourns window X and Y
366.                             OldW(0).Y = (_MOUSEY - OmY)
367.                             DrawAllWin ' it shows all windows
368.                             dragWindow OldW(0) ' it shows white skeleton of window
369.                         END IF
370.                     LOOP
371.                     ' new position of window
372.                     Windows(a).X = OldW(0).X
373.                     Windows(a).Y = OldW(0).Y
374.                     OldW(a).X = Windows(a).X
375.                     OldW(a).Y = Windows(a).Y
376.  
377.                 CASE Focusing
378.                     Focus a ' it puts at the top of stack of windows
379.  
380.                 CASE cResize
381.                     ' resizing is possible only for minimized opened child windows
382.                     IF Windows(a).Status = Minim THEN
383.                         Windows(a).Status = cResize
384.                         DO WHILE _MOUSEBUTTON(1) OR _MOUSEINPUT: LOOP ' it waits if there is a mouse input
385.                         DO WHILE Windows(a).Status = cResize ' while window is in resize mode
386.                             CLS , Orange ' it redraws background of main window
387.                             DrawAllWin ' it draws all mouse  windows
388.                             ShowDimension Windows(a), 0
389.  
390.                             ' if mouse move or left mouse button is down
391.                             IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN
392.                                 DO WHILE _MOUSEINPUT: LOOP ' clear mouse buffer
393.                                 _DELAY 0.1 ' this fixs Linus issue
394.                                 IsResizing Windows(a), _MOUSEX, _MOUSEY
395.                             END IF
396.                             _DISPLAY
397.                         LOOP
398.                     END IF
399.  
400.             END SELECT
401.         CASE ELSE
402.     END SELECT
403. END SUB
404.  
405. SUB IsResizing (Win AS wChild, mX AS INTEGER, mY AS INTEGER) ' this resize window by mouse
406.     SHARED Windows() AS wChild, OldW() AS wChild
407.     DIM Actio AS INTEGER, OldmX AS INTEGER, OldmY AS INTEGER
408.     Actio = 0
409.     'if mouse X is in the X range of the window
410.     IF IsInTheRange%(mX, Win.X, Win.X + Win.WIDTH) THEN
411.         ' if mouse Y is in the y range of the window
412.         IF IsInTheRange%(mY, Win.Y, Win.Y + Win.Height) THEN
413.             ' do nothing if it is in the range of window
414.         ELSE
415.             ' user click out of area  of window to resize
416.             Actio = StopResize
417.         END IF
418.     ELSE
419.         ' user click out of area  of window to resize
420.         Actio = StopResize
421.     END IF
422.  
423.  
424.  
425.  
426.     ' if mouse X is in the x range  of the leftest button on the window's bar
427.     IF IsInTheRange%(mX, Win.X, Win.X + 10) THEN
428.         ' if mouse Y is in the y range of the window's bar
429.         IF IsInTheRange%(mY, Win.Y, Win.Y + 10) THEN
430.             ' user click on lefttop square to resize
431.             Actio = LResize
432.         END IF
433.     END IF
434.     ' if mouse X is in the range of rightest button of window's bar
435.     IF IsInTheRange%(mX, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
436.         ' if mouse Y is in the y range of the bottom of window
437.         IF IsInTheRange%(mY, Win.Y + Win.Height - 10, Win.Y + Win.Height) THEN
438.             ' user click on the rightbottom square to resize
439.             Actio = RResize
440.         END IF
441.     END IF
442.  
443.     IF Actio = 0 THEN
444.         ' no action done
445.     ELSEIF Actio = LResize THEN
446.         ' choosen LeftTop buttom to resize
447.         OldW(0).X = Win.X
448.         OldW(0).Y = Win.Y
449.         OldW(0).WIDTH = Win.WIDTH
450.         OldW(0).Height = Win.Height
451.         OldmX = _MOUSEX
452.         OldmY = _MOUSEY
453.         DO WHILE Actio = LResize
454.             IF _MOUSEINPUT THEN ' if mouse moves it adapts the dimension to the minimun default value for X and Y
455.                 IF (OldW(0).X + OldW(0).WIDTH - OldmX) >= 70 THEN OldW(0).WIDTH = OldW(0).X + OldW(0).WIDTH - OldmX ELSE OldW(0).WIDTH = 70: OldW(0).X = Win.X + Win.WIDTH - 70: OldmX = OldW(0).X
456.                 IF (OldW(0).Y + OldW(0).Height - OldmY) >= 30 THEN OldW(0).Height = OldW(0).Y + OldW(0).Height - OldmY ELSE OldW(0).Height = 30: OldW(0).Y = Win.Y + Win.Height - 30: OldmY = OldW(0).Y
457.                 CLS , Orange
458.                 DrawAllWin
459.                 ShowDimension OldW(0), Actio
460.                 OldW(0).X = OldmX ' it stores new Oldmx and OldmY
461.                 OldW(0).Y = OldmY
462.  
463.                 OldmX = _MOUSEX
464.                 OldmY = _MOUSEY
465.             ELSE
466.                 IF _MOUSEBUTTON(1) THEN Actio = 0 ' a second leftclick stops the resize action
467.             END IF
468.         LOOP
469.         Win.X = OldW(0).X 'the new dimension of windows are stored
470.         Win.Y = OldW(0).Y
471.         Win.WIDTH = OldW(0).WIDTH
472.         Win.Height = OldW(0).Height
473.  
474.  
475.     ELSEIF Actio = RResize THEN
476.         ' choosen bottomright square
477.         OldW(0).X = Win.X ' it gets the window dimensions
478.         OldW(0).Y = Win.Y
479.         OldW(0).WIDTH = Win.WIDTH
480.         OldW(0).Height = Win.Height
481.         OldmX = _MOUSEX 'actual mouse X and Y
482.         OldmY = _MOUSEY
483.         DO WHILE Actio = RResize ' while is active resize from right
484.             IF _MOUSEINPUT THEN ' if mouse moves it adapts the dimension of window to mouse position
485.                 IF OldmX - OldW(0).X >= 70 THEN OldW(0).WIDTH = OldmX - OldW(0).X
486.                 IF OldmY - OldW(0).Y >= 30 THEN OldW(0).Height = OldmY - OldW(0).Y
487.                 CLS , Orange
488.                 DrawAllWin
489.                 ShowDimension OldW(0), Actio
490.                 OldmX = _MOUSEX
491.                 OldmY = _MOUSEY
492.             ELSE
493.                 IF _MOUSEBUTTON(1) THEN Actio = 0 ' il mouse leftclick it stops resize
494.             END IF
495.         LOOP
496.         Win.X = OldW(0).X 'it adjusts the dimensions of window to the new status
497.         Win.Y = OldW(0).Y
498.         Win.WIDTH = OldW(0).WIDTH
499.         Win.Height = OldW(0).Height
500.  
501.     ELSEIF Actio = StopResize THEN
502.         ' click out of window to stop resize action
503.         Win.Status = Minim
504.     END IF
505. END SUB
506.  
507. SUB ShowDimension (win AS wChild, Actio AS INTEGER) ' it shows skeleton of window with 2 buttons for dimensioning
508.     IF win.Status = cResize AND Actio = 0 THEN
509.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B ' windows size
510.     ELSEIF Actio = LResize THEN
511.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 45 ' windows size
512.     ELSEIF Actio = RResize THEN
513.         LINE (win.X, win.Y)-(win.X + win.WIDTH, win.Y + win.Height), White, B , 200 ' windows size
514.     END IF
515.     LINE (win.X, win.Y)-(win.X + 10, win.Y + 10), White, BF 'button for resizing window
516.     LINE (win.X + win.WIDTH - 10, win.Y + win.Height - 10)-(win.X + win.WIDTH, win.Y + win.Height), White, BF 'button for resizing window
517.     _DISPLAY
518. END SUB
519.  
520. FUNCTION IsInWindow (X AS INTEGER, Y AS INTEGER, Win AS wChild) 'it searches if mouse is in window passed as Win
521.     IsInWindow = mFalse
522.     IF IsInTheRange%(Y, Win.Y + 11, Win.Y + Win.Height) = mTrue THEN
523.         ' if window is closed to its bar it cannot get focus on the window area
524.         IF IsInTheRange%(X, Win.X, Win.X + Win.WIDTH) AND (Win.Status < Closed) THEN IsInWindow = Focusing
525.     ELSEIF IsInTheRange%(Y, Win.Y, Win.Y + 10) = mTrue THEN
526.         ' if it is the window bar area
527.         IF IsInTheRange%(X, Win.X + 10, Win.X + Win.WIDTH - 31) THEN
528.             ' if it is to the left of buttons on the bar
529.             IsInWindow = Dragging
530.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 30, Win.X + Win.WIDTH - 21) THEN
531.             ' if it is on the leftest button on the bar
532.             IsInWindow = cMinim ' icon minimize--> restore to child default
533.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 20, Win.X + Win.WIDTH - 11) THEN
534.             ' if it is on the middle button on the bar
535.             IsInWindow = cMaxim ' icon maximize--> expand to fullscreen
536.         ELSEIF IsInTheRange%(X, Win.X + Win.WIDTH - 10, Win.X + Win.WIDTH) THEN
537.             ' if is on the rightest button on the bar
538.             IsInWindow = cClosed ' icon close-->reduce to the  bar of child window
539.         ELSEIF IsInTheRange%(X, Win.X, Win.X + 10) THEN ' if is on the left side of bar on Resize button
540.             IsInWindow = cResize
541.         END IF
542.     END IF
543. END FUNCTION
544.  
545. FUNCTION IsInTheRange% (What AS INTEGER, Min AS INTEGER, Max AS INTEGER) ' it tests if What is between Min and Max
546.     IF Min > Max THEN SWAP Min, Max
547.     IF What > Min AND What < Max THEN IsInTheRange% = mTrue ELSE IsInTheRange% = mFalse
548. END FUNCTION
549.  
550. SUB dragWindow (Win AS wChild) ' this draw the white skeleton of a window
551.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), White, B ' windows size
552.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), White, BF 'title bar for dragging window
553.     _DISPLAY
554. END SUB
555.  
556. SUB wClosed (Win AS wChild) 'title bar button for show only title bar of window
557.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF
558.     LINE (Win.X + Win.WIDTH - 10, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Black, B
559.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 3)-(Win.X + Win.WIDTH - 3, Win.Y + 7), Black
560.     LINE (Win.X + Win.WIDTH - 7, Win.Y + 7)-(Win.X + Win.WIDTH - 3, Win.Y + 3), Black
561. END SUB
562.  
563. SUB wMaxim (win AS wChild) 'title bar  button for maximize to the whole main window
564.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Pink, BF
565.     LINE (win.X + win.WIDTH - 20, win.Y)-(win.X + win.WIDTH - 10, win.Y + 10), Black, B
566.     LINE (win.X + win.WIDTH - 17, win.Y + 3)-(win.X + win.WIDTH - 13, win.Y + 7), Black, B
567. END SUB
568.  
569. SUB wMinim (Win AS wChild) 'title bar button for restore to original dimensions
570.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Pink, BF
571.     LINE (Win.X + Win.WIDTH - 30, Win.Y)-(Win.X + Win.WIDTH - 20, Win.Y + 10), Black, B
572.     LINE (Win.X + Win.WIDTH - 27, Win.Y + 3)-(Win.X + Win.WIDTH - 23, Win.Y + 4), Black, BF
573.     LINE (Win.X + Win.WIDTH - 27, Win.Y + 3)-(Win.X + Win.WIDTH - 23, Win.Y + 7), Black, B , &B1010101010101010
574. END SUB
575.  
576. SUB wResize (Win AS wChild) 'title bar button for resize  dimensions of window
577.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Pink, BF
578.     LINE (Win.X, Win.Y)-(Win.X + 10, Win.Y + 10), Black, B
579.     LINE (Win.X + 2, Win.Y + 2)-(Win.X + 7, Win.Y + 7), Black, B , &B1010101010101010
580. END SUB
581.  
582. SUB DrawWindow (Win AS wChild, a AS INTEGER) ' it draws a window aspect following its status
583.     SHARED L() AS Label
584.     ' the window
585.     IF Win.Status = Minim OR Win.Status = Maxim THEN
586.         LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Win.COLOR, BF
587.         LINE (Win.X, Win.Y + Win.Height)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
588.         LINE (Win.X + Win.WIDTH, Win.Y)-(Win.X + Win.WIDTH, Win.Y + Win.Height), Black
589.     END IF
590.     ' the title bar
591.     LINE (Win.X, Win.Y)-(Win.X + Win.WIDTH, Win.Y + 10), Pink, BF 'title bar for dragging window
592.     LINE (Win.X, Win.Y + 10)-(Win.X + Win.WIDTH, Win.Y + 10), Black
593.     wMinim Win
594.     wMaxim Win
595.     wClosed Win
596.     wResize Win
597.  
598.     ' the content of the window
599.     IF Win.Name = L(a).Parent THEN ShowString L(a), Win
600.  
601.  
602. END SUB
603.  
604. SUB GetInput (Act AS INTEGER) ' manager of input by keyboard & mouse
605.     DIM mInput AS INTEGER ' flag of commands of mouse
606.  
607.  
608.     ' keyboard input
609.     a$ = INKEY$
610.     IF a$ = CHR$(27) THEN Act = aQuit 'keyboard's command in feedback by Act
611.  
612.     'mouse input
613.     mInput = mFalse
614.     IF _MOUSEINPUT THEN mInput = mTrue
615.     DO WHILE _MOUSEINPUT 'clear buffer of mouse
616.     LOOP
617.     IF mInput THEN ' here flag of mouse gets the command's values
618.         IF _MOUSEBUTTON(1) AND _MOUSEBUTTON(2) THEN
619.             mInput = mLR
620.         ELSEIF _MOUSEBUTTON(1) THEN
621.             mInput = mLeft
622.         ELSEIF _MOUSEBUTTON(2) THEN
623.             mInput = mRight
624.         ELSEIF _MOUSEBUTTON(3) THEN
625.             mInput = mMiddle
626.         END IF
627.     END IF
628.     'mouse's command in feedback by Act
629.     IF mInput = mLR THEN
630.         Act = aQuit
631.     ELSEIF mInput = mMiddle THEN
632.         Act = Minim
633.     ELSEIF mInput = mRight THEN
634.         Act = Maxim
635.     ELSEIF mInput = mLeft THEN
636.         Act = mInput
637.     END IF
638. END SUB
639.  

Thanks to try

Text Only | Text with Attachments