QB64.org Forum

Active Forums => Programs => Topic started by: SierraKen on January 11, 2020, 05:39:49 pm

Title: Spilling Paint Non-Stop
Post by: SierraKen on January 11, 2020, 05:39:49 pm

Code: QB64: [Select]

1. _TITLE "Spilling Paint Non-Stop by SierraKen"
2. SCREEN _NEWIMAGE(800, 600, 32)
3. DO
4.     RANDOMIZE TIMER
5.     a = INT(RND * 300) + 60
6.     st = INT(RND * 1000)
7.     st = st / 900
8.     IF st < .1 THEN st = .1
9.     c1 = INT(RND * 200) + 54
10.     c2 = INT(RND * 200) + 54
11.     c3 = INT(RND * 200) + 54
12.     s = 0
13.     FOR d = 0 TO 250 STEP st
14.         _LIMIT 2000
15.         s = s + .5
16.         x = COS(s * 3.141592 / a) * d
17.         y = SIN(s * 3.151492 / a) * d
18.         CIRCLE (x + 400, y + 300), 30, _RGB32(c1, c2, c3)
19.         PAINT (x + 400, y + 300), _RGB32(c1, c2, c3)
20.     NEXT d
21. LOOP
22.  

Title: Re: Spilling Paint Non-Stop
Post by: johnno56 on January 12, 2020, 06:04:24 am

"Cleanup on aisle #3"... lol

Cool...

Title: Re: Spilling Paint Non-Stop
Post by: Petr on January 12, 2020, 10:42:38 am

Hi Sierraken, try it with Steve' s CircleFill:

Code: QB64: [Select]

1. _TITLE "Spilling Paint Non-Stop by SierraKen"
2. SCREEN _NEWIMAGE(800, 600, 32)
3. DO
4.     RANDOMIZE TIMER
5.     a = INT(RND * 300) + 60
6.     st = INT(RND * 1000)
7.     st = st / 900
8.     IF st < .1 THEN st = .1
9.     c1 = INT(RND * 200) + 54
10.     c2 = INT(RND * 200) + 54
11.     c3 = INT(RND * 200) + 54
12.     s = 0
13.     FOR d = 0 TO 250 STEP st
14.         _LIMIT 2000
15.         s = s + .5
16.         x = COS(s * 3.141592 / a) * d
17.         y = SIN(s * 3.151492 / a) * d
18.         '   CIRCLE (x + 400, y + 300), 30, _RGB32(c1, c2, c3)
19.         '   PAINT (x + 400, y + 300), _RGB32(c1, c2, c3)
20.         CircleFill x + 400, y + 300, 30, _RGB32(c1, c2, c3)
21.     NEXT d
22. LOOP
23.  
24.  
25. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
26.     ' CX = center x coordinate
27.     ' CY = center y coordinate
28.     '  R = radius
29.     '  C = fill color
30.     DIM Radius AS INTEGER, RadiusError AS INTEGER
31.     DIM X AS INTEGER, Y AS INTEGER
32.     Radius = ABS(R)
33.     RadiusError = -Radius
34.     X = Radius
35.     Y = 0
36.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
37.     LINE (CX - X, CY)-(CX + X, CY), C, BF
38.     WHILE X > Y
39.         RadiusError = RadiusError + Y * 2 + 1
40.         IF RadiusError >= 0 THEN
41.             IF X <> Y + 1 THEN
42.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
43.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
44.             END IF
45.             X = X - 1
46.             RadiusError = RadiusError - X * 2
47.         END IF
48.         Y = Y + 1
49.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
50.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
51.     WEND
52. END SUB
53.  
54.  
55.  

Title: Re: Spilling Paint Non-Stop
Post by: bplus on January 12, 2020, 05:07:03 pm

Here is my try at slinging paint, wear your goggles:

Code: QB64: [Select]

1. _TITLE "Splats" 'b+ 2020-01-12
2. ' from eRATication/cheese wedge tests/ multiple explosions.bas 2018-07-28 translated from
3. 'bomb.bas for SmallBASIC 0.12.2 [B+=MGA] 2016-05-09 from explosion study
4.  
5. CONST xmax = 1300, ymax = 760, pi2 = 6.283185
6. TYPE particle
7.     x AS SINGLE
8.     y AS SINGLE
9.     dx AS SINGLE
10.     dy AS SINGLE
11.     size AS SINGLE
12.     spread AS SINGLE
13.     'tf AS INTEGER
14. END TYPE
15. REDIM SHARED dots(1) AS particle
16. SCREEN _NEWIMAGE(xmax, ymax, 32)
17. _FULLSCREEN
18. RANDOMIZE TIMER
19. DIM kolor AS _UNSIGNED LONG
20.  
21. WHILE NOT _KEYDOWN(27)
22.     COLOR , _RGB32(RND * 255, RND * 255, RND * 255)
23.     CLS
24.     stopit = (RND * 100) \ 1 + 15
25.     FOR i = 1 TO stopit
26.         dx = RND * 60 - 30: dy = RND * 60 - 30: a = 7 * (RND * 10 - 5): b = 7 * (RND * 10 - 5)
27.         x = xmax * RND: y = ymax * RND
28.         kolor = _RGB32(RND * 255, RND * 255, RND * 255)
29.         WHILE x > -100 AND x < xmax + 100 AND y > -100 AND y < ymax + 100
30.             splat x, y, kolor
31.             x = x + dx: y = y + dy
32.             dx = dx + a: dy = dy + b
33.             _DISPLAY
34.             '_LIMIT 5
35.         WEND
36.         '_DELAY 1
37.     NEXT
38.     _DELAY 5
39. WEND
40. SYSTEM
41.  
42. SUB splat (x, y, kolor AS _UNSIGNED LONG)
43.     round = 5
44.     nRounds = (RND * 10) \ 1 + 1
45.     nDots = nRounds * round
46.  
47.     REDIM dots(1 TO nDots) AS particle
48.     FOR i = 1 TO round
49.         NewDot i, x, y
50.     NEXT
51.     rounds = round
52.     FOR loopCount = 0 TO 20
53.         IF _KEYDOWN(27) THEN END
54.         FOR i = 1 TO rounds
55.             dots(i).x = dots(i).x + dots(i).dx
56.             dots(i).y = dots(i).y + dots(i).dy
57.             dots(i).dx = dots(i).dx * dots(i).spread
58.             dots(i).dy = dots(i).dy * dots(i).spread
59.             fcirc dots(i).x, dots(i).y, dots(i).size / 2, kolor
60.             dots(i).size = dots(i).size * dots(i).spread
61.         NEXT
62.         IF rounds < nDots THEN
63.             FOR i = 1 TO round
64.                 NewDot i, x, y
65.             NEXT
66.             rounds = rounds + round
67.         END IF
68.         _DISPLAY
69.     NEXT
70. END SUB
71.  
72. SUB NewDot (i, x, y)
73.     angle = RND * pi2
74.     r = RND * 5
75.     dots(i).x = x + r * COS(angle)
76.     dots(i).y = y + r * SIN(angle)
77.     dots(i).size = RND * 15 + 5
78.     r = RND * 3
79.     dots(i).dx = r * (15 - dots(i).size) * COS(angle)
80.     dots(i).dy = r * (15 - dots(i).size) * SIN(angle)
81.     dots(i).spread = RND * .3 + .2
82. END SUB
83.  
84. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
85.     DIM Radius AS INTEGER, RadiusError AS INTEGER
86.     DIM X AS INTEGER, Y AS INTEGER
87.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
88.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
89.     LINE (CX - X, CY)-(CX + X, CY), C, BF
90.     WHILE X > Y
91.         RadiusError = RadiusError + Y * 2 + 1
92.         IF RadiusError >= 0 THEN
93.             IF X <> Y + 1 THEN
94.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
95.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
96.             END IF
97.             X = X - 1
98.             RadiusError = RadiusError - X * 2
99.         END IF
100.         Y = Y + 1
101.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
102.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
103.     WEND
104. END SUB
105.  
106.  
107.  

Title: Re: Spilling Paint Non-Stop
Post by: johnno56 on January 12, 2020, 05:28:16 pm

I don't think goggles are going to be enough! Cool...

Title: Re: Spilling Paint Non-Stop
Post by: SierraKen on January 12, 2020, 10:25:30 pm

Thanks Petr! I need to learn how to use that code.

LOL B+! Great job.

Title: Re: Spilling Paint Non-Stop
Post by: SMcNeill on January 13, 2020, 12:00:41 am

Quote from: SierraKen on January 12, 2020, 10:25:30 pm

Thanks Petr! I need to learn how to use that code.

LOL B+! Great job.

Code: [Select]

        ‘ CIRCLE (x + 400, y + 300), 30, _RGB32(c1, c2, c3)
        CircleFill x + 400, y + 300, 30, _RGB32(c1, c2, c3)
As you can see from Petr’s replacement above, it’s usually just as simple as using the sub name CircleFill instead of using Circle.  Just don’t put the X/Y coordinates in parentheses.

Title: Re: Spilling Paint Non-Stop
Post by: bplus on January 13, 2020, 02:44:24 am

I added a toggle with space bar to go between color and shades of gray fro white to black which looks better less color is more sometimes:

Code: QB64: [Select]

1. _TITLE "Splats" 'b+ 2020-01-12
2. ' from eRATication/cheese wedge tests/ multiple explosions.bas 2018-07-28 translated from
3. 'bomb.bas for SmallBASIC 0.12.2 [B+=MGA] 2016-05-09 from explosion study
4.  
5. CONST xmax = 1300, ymax = 760, pi2 = 6.283185
6. TYPE particle
7.     x AS SINGLE
8.     y AS SINGLE
9.     dx AS SINGLE
10.     dy AS SINGLE
11.     size AS SINGLE
12.     spread AS SINGLE
13.     'tf AS INTEGER
14. END TYPE
15. REDIM SHARED dots(1) AS particle
16. SCREEN _NEWIMAGE(xmax, ymax, 32)
17. _FULLSCREEN
18. RANDOMIZE TIMER
19. DIM kolor AS _UNSIGNED LONG
20.  
21. WHILE NOT _KEYDOWN(27)
22.     COLOR , _RGB32(RND * 255, RND * 255, RND * 255)
23.     CLS
24.     stopit = (RND * 100) \ 1 + 15
25.     FOR i = 1 TO stopit
26.         dx = RND * 60 - 30: dy = RND * 60 - 30: a = 7 * (RND * 10 - 5): b = 7 * (RND * 10 - 5)
27.         x = xmax * RND: y = ymax * RND
28.         r = RND * 255
29.         IF INKEY$ = " " THEN toggle = 1 - toggle
30.         IF toggle THEN
31.             kolor = _RGB32(r, r, r)
32.         ELSE
33.             kolor = _RGB32(RND * 255, RND * 255, RND * 255)
34.         END IF
35.         WHILE x > -100 AND x < xmax + 100 AND y > -100 AND y < ymax + 100
36.             splat x, y, kolor
37.             x = x + dx: y = y + dy
38.             dx = dx + a: dy = dy + b
39.             _DISPLAY
40.         WEND
41.     NEXT
42.     _DELAY 5
43. WEND
44. SYSTEM
45.  
46. SUB splat (x, y, kolor AS _UNSIGNED LONG)
47.     round = 5
48.     nRounds = (RND * 10) \ 1 + 1
49.     nDots = nRounds * round
50.  
51.     REDIM dots(1 TO nDots) AS particle
52.     FOR i = 1 TO round
53.         NewDot i, x, y
54.     NEXT
55.     rounds = round
56.     FOR loopCount = 0 TO 20
57.         IF _KEYDOWN(27) THEN END
58.         FOR i = 1 TO rounds
59.             dots(i).x = dots(i).x + dots(i).dx
60.             dots(i).y = dots(i).y + dots(i).dy
61.             dots(i).dx = dots(i).dx * dots(i).spread
62.             dots(i).dy = dots(i).dy * dots(i).spread
63.             fcirc dots(i).x, dots(i).y, dots(i).size / 2, kolor
64.             dots(i).size = dots(i).size * dots(i).spread
65.         NEXT
66.         IF rounds < nDots THEN
67.             FOR i = 1 TO round
68.                 NewDot i, x, y
69.             NEXT
70.             rounds = rounds + round
71.         END IF
72.         _DISPLAY
73.     NEXT
74. END SUB
75.  
76. SUB NewDot (i, x, y)
77.     angle = RND * pi2
78.     r = RND * 5
79.     dots(i).x = x + r * COS(angle)
80.     dots(i).y = y + r * SIN(angle)
81.     dots(i).size = RND * 15 + 5
82.     r = RND * 3
83.     dots(i).dx = r * (15 - dots(i).size) * COS(angle)
84.     dots(i).dy = r * (15 - dots(i).size) * SIN(angle)
85.     dots(i).spread = RND * .3 + .2
86. END SUB
87.  
88. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
89.     DIM Radius AS INTEGER, RadiusError AS INTEGER
90.     DIM X AS INTEGER, Y AS INTEGER
91.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
92.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
93.     LINE (CX - X, CY)-(CX + X, CY), C, BF
94.     WHILE X > Y
95.         RadiusError = RadiusError + Y * 2 + 1
96.         IF RadiusError >= 0 THEN
97.             IF X <> Y + 1 THEN
98.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
99.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
100.             END IF
101.             X = X - 1
102.             RadiusError = RadiusError - X * 2
103.         END IF
104.         Y = Y + 1
105.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
106.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
107.     WEND
108. END SUB
109.  
110.  
111.  

Text Only | Text with Attachments