QB64.org Forum

Active Forums => Programs => Topic started by: Zeppelin on December 05, 2019, 05:51:00 pm

Title: _PUT Rotation Help
Post by: Zeppelin on December 05, 2019, 05:51:00 pm

Hey Everyone,
Here's a piece I've been working on for awhile now but in the Infinite sub I'm trying to get the 'sword' to make a full rotation and end up under the character during the jump, but it seems to just keep spinning and stopping at random points. Not too sure what I'm doing wrong.
 

Code: QB64: [Select]

1. '+-------------------+
2. '        SLAY
3. ' ZEPPELIN GAMES 2019
4. '+-------------------+
5.  
6. _TITLE "SLAY" 'SET TITLE
7. _FULLSCREEN 'SET FULLSCREEN
8. SCREEN _NEWIMAGE(1200, 800, 32)
9.  
10. 'DECLARE VARIABLES
11. 'SAVE DATA VARS
12. DIM SHARED save.point AS INTEGER
13. DIM SHARED saveData$(1000)
14.  
15. 'PLAYER VARS
16. DIM SHARED player%(100000)
17. DIM SHARED sword%(100000)
18. DIM SHARED player.name AS STRING
19. DIM SHARED player.health AS INTEGER
20. DIM SHARED player.basehealth AS INTEGER
21. DIM SHARED playerScale AS INTEGER
22. playerScale = 15
23.  
24. DIM SHARED pX
25.  
26. 'PLAYER STATS
27. DIM SHARED stats.enemyskilled AS INTEGER
28. DIM SHARED stats.totaldeaths AS INTEGER
29.  
30. 'SCREEN AND FORMATTING VARS
31. DIM SHARED w AS INTEGER
32. DIM SHARED h AS INTEGER
33.  
34. DIM SHARED fh AS INTEGER
35. DIM SHARED fw AS INTEGER
36.  
37. 'GET THE SCREEN DIMSENSIONS
38. w = _WIDTH
39. h = _HEIGHT
40.  
41. 'FONT DATA
42. fh = _FONTHEIGHT
43. fw = _FONTWIDTH
44.  
45. 'SET THE COLOR
46. col = _RGBA(255, 255, 255, 255)
47.  
48. 'START GAME
49. LoadData
50.  
51. SUB LoadData
52.     'LOAD SAVE DATA
53.  
54.     'LOAD PLAYER SPRITE
55.     LoadSprite player%(), playerScale
56.     LoadSprite sword%(), playerScale / 1.2
57.  
58.     IF _FILEEXISTS("SlayV4SaveData.txt") THEN 'SEE IF THE FILE EXISTS
59.         OPEN "SlayV4SaveData.txt" FOR INPUT AS #1
60.         DO UNTIL EOF(1) 'LOOP UNTIL END OF FILE
61.             _LIMIT 60
62.             filecount = filecount + 1 'COUNT AMOUNT OF LINES
63.             LINE INPUT #1, file$
64.             saveData$(filecount) = file$
65.         LOOP
66.         CLOSE #1
67.  
68.         IF filecount > 2 THEN
69.             'PLAYER
70.  
71.             'DECRYPT NAME
72.             name$ = ""
73.             FOR n = 1 TO LEN(saveData$(1)) STEP 2
74.                 name$ = name$ + CHR$(ASC(MID$(saveData$(1), n, 1)) - 4)
75.             NEXT n
76.  
77.             'DECRYPT STATS
78.             'HEALTH
79.             health$ = ""
80.             FOR n = 1 TO LEN(saveData$(2)) STEP 2
81.                 health$ = health$ + CHR$(ASC(MID$(saveData$(2), n, 1)) - 4)
82.             NEXT n
83.  
84.             player.name = UCASE$(name$) 'LOAD NAME
85.             player.basehealth = VAL(health$) 'LOAD BASE HEALTH
86.             player.health = player.basehealth 'SET PLAYER HEALTH
87.             'SAVE DATA
88.             save.point = VAL(saveData$(3)) 'LOAD SAVE POINT
89.             'STATS
90.             stats.enemyskilled = VAL(saveData$(4)) 'ENEMYS KILLED
91.             stats.totaldeaths = VAL(saveData$(5)) 'TOTAL DEATHS
92.         ELSE
93.             CreateNewSave
94.         END IF
95.     ELSE
96.         CreateNewSave
97.     END IF
98.  
99.     'START GAME
100.     _DELAY (1)
101.     DrawLogo
102. END SUB
103.  
104. SUB CreateNewSave
105.     'CREATE NEW SAVE FILE
106.     scaledText w / 2 - 65, h / 2 + 8, 16, _RGBA(255, 255, 255, 255), "Enter your name: "
107.     DO
108.         _LIMIT 60
109.         LOCATE (h / 2 - 248) / fh + hf, (w / 2 - 50) / fw + fw: INPUT "", name$
110.     LOOP UNTIL LEN(name$) > 1
111.     IF LEN(name$) > 16 THEN
112.         CLS
113.         _PRINTSTRING (w / 2 - 150, h / 2), "Name length should be less than 16 characters"
114.         _DELAY (2)
115.         CLS
116.         LoadData
117.     END IF
118.  
119.     'SET VARS
120.     player.name = UCASE$(name$)
121.     player.health = 100
122.  
123.     save.point = 0
124.     stats.enemyskilled = 0
125.     stats.totaldeaths = 0
126.  
127.     'ENCRYPT SAVE DATA
128.     'NAME
129.     DIM nameArray$(16)
130.     FOR n = 1 TO LEN(player.name)
131.         nameArray$(n) = MID$(player.name, n, 1)
132.     NEXT n
133.  
134.     FOR n = 1 TO LEN(player.name)
135.         tempName$ = tempName$ + CHR$(ASC(nameArray$(n)) + 4)
136.         tempName$ = tempName$ + CHR$(INT(RND * 100) + 100)
137.     NEXT n
138.  
139.     name$ = tempName$
140.  
141.     'ENCRYPT STATS
142.     'HEALTH
143.     DIM healthArray$(5)
144.     FOR n = 1 TO LEN(STR$(player.health))
145.         healthArray$(n) = MID$(STR$(player.health), n, 1)
146.     NEXT n
147.  
148.     FOR n = 1 TO LEN(STR$(player.health))
149.         tempHealth$ = tempHealth$ + CHR$(ASC(healthArray$(n)) + 4)
150.         tempHealth$ = tempHealth$ + CHR$(INT(RND * 100) + 100)
151.     NEXT n
152.  
153.     'SAVE VARS TO TXT
154.     OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
155.     'PLAYER
156.     PRINT #1, name$
157.     PRINT #1, tempHealth$
158.     'SAVE DATA
159.     PRINT #1, save.point
160.     'STATS
161.     PRINT #1, stats.enemyskilled
162.     PRINT #1, stats.totaldeaths
163.     CLOSE #1
164.     CLS
165. END SUB
166.  
167. SUB DrawLogo
168.     'FADE LOGO IN
169.     FOR n = 0 TO 255
170.         'LIMIT FPS
171.         _LIMIT 60
172.  
173.         LINE (w / 10 * 2, h / 10 * 7)-(w / 10 * 8, h / 10 * 8), _RGB(0, 0, 0), BF
174.         scaledText w / 2, h / 2, 500, _RGBA32(255, 255, 255, n), "Z"
175.         scaledText w / 2, h / 6 * 4.5, 50, _RGBA(255, 255, 255, n), "ZEPPELIN GAMES"
176.         _DISPLAY
177.     NEXT n
178.  
179.     scaledText w / 2, h / 2, 500, _RGBA32(255, 255, 255, 255), "Z"
180.     scaledText w / 2, h / 6 * 4.5, 50, _RGBA32(255, 255, 255, 255), "ZEPPELIN GAMES"
181.     _DISPLAY
182.     _DELAY (3) 'WAIT A BIT
183.  
184.     'FADE THE LOGO AND TEXT OUT
185.     FOR n = 0 TO 255
186.         'LIMIT FPS
187.         _LIMIT 60
188.  
189.         LINE (w / 10 * 2, h / 10 * 7)-(w / 10 * 8, h / 10 * 8), _RGB(0, 0, 0), BF
190.         scaledText w / 2, h / 2, 500, _RGBA32(255, 255, 255, 255 - n), "Z"
191.         scaledText w / 2, h / 6 * 4.5, 50, _RGBA(255, 255, 255, 255 - n), "ZEPPELIN GAMES"
192.         _DISPLAY
193.     NEXT n
194.     CLS
195.     _DISPLAY
196.     DrawMenu
197. END SUB
198.  
199. SUB DrawMenu
200.     'FADE IN MENU SCREEN
201.     DIM col AS LONG
202.     col = _RGBA(255, 255, 255, 255)
203.     'S
204.     LINE (w / 10 * 2.75, h / 10 * 1.5)-(w / 10 * 3.5, h / 10 * 1.75), col, BF '1ST ACROSS
205.     LINE (w / 10 * 2.75, h / 10 * 1.5)-(w / 10 * 3, h / 10 * 2.5), col, BF '1ST DOWN
206.     LINE (w / 10 * 2.75, h / 10 * 2.5)-(w / 10 * 3.45, h / 10 * 2.75), col, BF '2ND ACROSS
207.     LINE (w / 10 * 3.2, h / 10 * 2.75)-(w / 10 * 3.45, h / 10 * 2.9), col, BF '2ND DOWN
208.     LINE (w / 10 * 3.2, h / 10 * 3.35)-(w / 10 * 3.45, h / 10 * 3.75), col, BF 'EXTENDED 2ND DOWN
209.     LINE (w / 10 * 2.65, h / 10 * 3.75)-(w / 10 * 3.45, h / 10 * 4.1), col, BF '3RD ACROSS
210.  
211.     'L
212.     LINE (w / 10 * 3.8, h / 10 * 1.5)-(w / 10 * 4.05, h / 10 * 2.65), col, BF '1ST DOWN
213.     LINE (w / 10 * 3.8, h / 10 * 3.6)-(w / 10 * 4.05, h / 10 * 3.75), col, BF 'EXTENDED 1ST DOWN
214.     LINE (w / 10 * 3.8, h / 10 * 3.75)-(w / 10 * 4.6, h / 10 * 4.1), col, BF '1ST ACROSS
215.  
216.     'A
217.     LINE (w / 10 * 4.85, h / 10 * 1.5)-(w / 10 * 5.1, h / 10 * 2.7), col, BF 'LEFT DOWN
218.     LINE (w / 10 * 4.85, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 1.8), col, BF 'TOP LINE
219.     LINE (w / 10 * 5.5, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 2.7), col, BF 'RIGHT DOWN
220.     LINE (w / 10 * 5.55, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 2.9), col, BF 'RIGHT DOWN EDGE
221.     LINE (w / 10 * 4.85, h / 10 * 2.4)-(w / 10 * 5.75, h / 10 * 2.65), col, BF 'MIDDLE LINE
222.     LINE (w / 10 * 4.85, h / 10 * 3.5)-(w / 10 * 5.1, h / 10 * 4.1), col, BF 'EXTENDED LEFT DOWN
223.     LINE (w / 10 * 5.5, h / 10 * 3.5)-(w / 10 * 5.75, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN
224.     LINE (w / 10 * 5.55, h / 10 * 3.35)-(w / 10 * 5.75, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN EDGE
225.  
226.     'Y
227.     LINE (w / 10 * 6, h / 10 * 1.5)-(w / 10 * 6.25, h / 10 * 2.75), col, BF 'LEFT DOWN
228.     LINE (w / 10 * 6.75, h / 10 * 1.5)-(w / 10 * 7, h / 10 * 3), col, BF 'RIGHT DOWN
229.     LINE (w / 10 * 6, h / 10 * 2.5)-(w / 10 * 7, h / 10 * 2.85), col, BF '1ST ACROSS
230.     LINE (w / 10 * 6.75, h / 10 * 3.25)-(w / 10 * 7, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN
231.     LINE (w / 10 * 6, h / 10 * 3.8)-(w / 10 * 7, h / 10 * 4.1), col, BF 'BOTTOM LINE
232.  
233.     'SWORD
234.     LINE (w / 10 * 3, h / 10 * 3)-(w / 10 * 6.5, h / 10 * 3.25), col, BF 'HILT
235.     LINE (w / 10 * 3.5, h / 10 * 2.5)-(w / 10 * 3.75, h / 10 * 3.75), col, BF 'Hand Guard
236.     LINE (w / 10 * 3.75, h / 10 * 2.75)-(w / 10 * 4.75, h / 10 * 3.50), col, BF 'Blade First Layer
237.     LINE (w / 10 * 4.75, h / 10 * 2.85)-(w / 10 * 5.5, h / 10 * 3.4), col, BF 'Blade 2nd Layer
238.     LINE (w / 10 * 5.5, h / 10 * 3.10)-(w / 10 * 7, h / 10 * 3.15), col, BF 'Tip of Blade
239.  
240.     col = _RGBA(0, 0, 0, 255)
241.     LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
242.  
243.     'SHOW ACCOUNT
244.     _PRINTSTRING (5, 5), player.name
245.  
246.     'PRINT MENU OPTIONS
247.     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "SINGLE-PLAYER"
248.     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "MULTI-PLAYER"
249.     scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "OPTIONS"
250.     scaledText w / 2, h / 10 * 6.25, 25, _RGBA(255, 255, 255, 255), "QUIT"
251.     scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
252.  
253.     'PICK MENU OPTION
254.     opt = 0
255.     col = _RGBA(0, 0, 0, 255)
256.     DO
257.         _LIMIT 60
258.         LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
259.         _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
260.         _DISPLAY 'REDUCE FLICKERING
261.  
262.         SELECT CASE INKEY$
263.             CASE "s", "S" 'MOVE POINTER DOWN
264.                 IF opt + 1 = 4 THEN
265.                     opt = 0
266.                 ELSE
267.                     opt = opt + 1
268.                 END IF
269.  
270.             CASE "w", "W" 'MOVE POINTER UP
271.                 IF opt - 1 = -1 THEN
272.                     opt = 3
273.                 ELSE
274.                     opt = opt - 1
275.                 END IF
276.  
277.             CASE CHR$(13) 'ENTER KEY
278.                 'SINGLE-PLAYER SELECTED
279.                 IF opt = 0 THEN
280.                     SinglePlayerMenu
281.                 END IF
282.  
283.                 'MULTI-PLAYER SELECTED
284.                 IF opt = 1 THEN
285.                     MultiplayerGameMenu
286.                 END IF
287.  
288.                 'OPTIONS SELETED
289.                 IF opt = 2 THEN
290.                     OptionsMenu
291.                 END IF
292.  
293.                 'QUIT SELECTED
294.                 IF opt = 3 THEN
295.                     SYSTEM
296.                 END IF
297.         END SELECT
298.     LOOP
299. END SUB
300.  
301.  
302. SUB OptionsMenu
303.     LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
304.     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "INFO"
305.     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "RESET GAME"
306.     scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "BACK"
307.     scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
308.  
309.     opt = 0
310.     DO
311.         _LIMIT 60
312.         LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
313.         _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
314.  
315.         _DISPLAY 'REDUCE FLICKERING
316.  
317.         SELECT CASE INKEY$
318.             CASE "s", "S" 'MOVE POINTER DOWN
319.                 IF opt + 1 = 3 THEN
320.                     opt = 0
321.                 ELSE
322.                     opt = opt + 1
323.                 END IF
324.  
325.             CASE "w", "W" 'MOVE POINTER UP
326.                 IF opt - 1 = -1 THEN
327.                     opt = 2
328.                 ELSE
329.                     opt = opt - 1
330.                 END IF
331.             CASE CHR$(13) 'ENTER PRESSED
332.                 IF opt = 0 THEN 'GAME INFO
333.                     LINE (0, h / 10 * 4.7)-(w, h), col, BF 'CLEAR OPTIONS
334.                     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "ZEPPELIN GAMES 2018"
335.                     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "SLAY V4"
336.                     scaledText w / 2, h / 10 * 6.25, 25, _RGBA(255, 255, 255, 255), "ENEMIES KILLED: " + STR$(stats.enemyskilled)
337.                     scaledText w / 2, h / 10 * 6.75, 25, _RGBA(255, 255, 255, 255), "TOTAL DEATHS: " + STR$(stats.totaldeaths)
338.                     scaledText w / 2, h / 10 * 9.25, 14, _RGBA(255, 255, 255, 255), "PRESS ANY KEY TO CONTINUE"
339.  
340.                     _DISPLAY
341.                     DO WHILE INKEY$ = ""
342.                     LOOP
343.                     LINE (0, h / 10 * 4.7)-(w, h), col, BF 'CLEAR OPTIONS
344.                     OptionsMenu
345.                 END IF
346.                 IF opt = 1 THEN 'RESET GAME
347.                     OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
348.                     PRINT #1, ""
349.                     CLOSE #1
350.                     CLS
351.                     RUN "SLAY V4.exe"
352.                 END IF
353.                 IF opt = 2 THEN 'BACK
354.                     DrawMenu
355.                 END IF
356.         END SELECT
357.     LOOP
358. END SUB
359.  
360. SUB SinglePlayerMenu
361.     col = _RGBA(0, 0, 0, 255)
362.     LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
363.     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "CAMPAIGN"
364.     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "INFINITE"
365.     scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "BACK"
366.     scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
367.  
368.     opt = 0
369.     DO
370.         _LIMIT 60
371.         LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
372.         _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
373.  
374.         _DISPLAY 'REDUCE FLICKERING
375.  
376.         SELECT CASE INKEY$
377.             CASE "s", "S" 'MOVE POINTER DOWN
378.                 IF opt + 1 = 3 THEN
379.                     opt = 0
380.                 ELSE
381.                     opt = opt + 1
382.                 END IF
383.  
384.             CASE "w", "W" 'MOVE POINTER UP
385.                 IF opt - 1 = -1 THEN
386.                     opt = 2
387.                 ELSE
388.                     opt = opt - 1
389.                 END IF
390.             CASE CHR$(13) 'ENTER PRESSED
391.                 IF opt = 0 THEN
392.                     Campaign
393.                 END IF
394.                 IF opt = 1 THEN
395.                     Infinite
396.                 END IF
397.                 IF opt = 2 THEN
398.                     DrawMenu
399.                 END IF
400.         END SELECT
401.     LOOP
402. END SUB
403.  
404. 'CAMPAIGN - STORY
405. SUB Campaign
406.  
407. END SUB
408.  
409. 'PRACTICE - GAMEMODE
410. SUB Infinite
411.     CLS
412.     'DEFINE LOCAL VARS
413.  
414.     DIM health
415.     DIM deltaTime
416.  
417.     DIM swordX
418.     DIM swordY
419.  
420.     DIM swing
421.     DIM angle
422.  
423.     playerSpeed = 500
424.     jumpHeight = 150
425.     health = 100
426.     jump = 0
427.     pX = _WIDTH / 2 - (playerScale * 2.5)
428.     pY = _HEIGHT / 10 * 8
429.  
430.     swordX = pX
431.     swordY = pY + (playerScale * 5)
432.  
433.     sTime = TIMER
434.  
435.     DO
436.         _LIMIT 120
437.         sTime = TIMER(0.001)
438.         IF _KEYDOWN(100) THEN
439.             pX = pX + playerSpeed / 100
440.             IF pX > _WIDTH - (playerScale * 12) - 1 THEN pX = _WIDTH - (playerScale * 12) - 1
441.         END IF
442.         IF _KEYDOWN(97) THEN
443.             pX = pX - playerSpeed / 100
444.             IF pX < (playerScale * 12) THEN pX = (playerScale * 12)
445.         END IF
446.         IF _KEYDOWN(32) THEN
447.             IF jump = 0 THEN
448.                 jump = 1
449.             END IF
450.         END IF
451.  
452.         IF jump >= 1 THEN
453.             IF pY > ((_HEIGHT / 10) * 8) - jumpHeight AND NOT jump = 2 THEN
454.                 pY = pY - playerSpeed / 100
455.  
456.                 'Spin Sword
457.                 swing = 1
458.                 swordX = pX + ((playerScale * 6) * COS(_D2R(angle)))
459.                 swordY = pY + ((playerScale * 6) * SIN(_D2R(angle)))
460.             ELSE
461.  
462.                 IF pY <= (_HEIGHT / 10) * 8 THEN
463.                     jump = 2
464.                     pY = pY + playerSpeed / 100
465.  
466.                     'Spin Sword
467.                     swing = 1
468.                     swordX = pX + ((playerScale * 6) * COS(_D2R(angle)))
469.                     swordY = pY + ((playerScale * 6) * SIN(_D2R(angle)))
470.  
471.                 ELSE
472.                     jump = 0
473.                     swing = 0
474.                     pY = (_HEIGHT / 10) * 8
475.                 END IF
476.             END IF
477.         END IF
478.  
479.         IF swing = 1 THEN
480.             angle = angle + (jumpHeight / 100)
481.         END IF
482.  
483.         LINE (pX - (playerScale * 10) - 10, pY - (playerScale * 12) - 10)-(pX + ((playerScale * 10) * 2) + 10, pY + (playerScale * 10) + 10), _RGB(0, 0, 0), BF
484.  
485.         PUT (pX, pY), player%()
486.         PUT (swordX, swordY), sword%()
487.         _DISPLAY
488.  
489.         eTime = TIMER(0.001)
490.         deltaTime = eTime - sTime
491.  
492.     LOOP UNTIL health <= 0 OR INKEY$ = CHR$(27)
493.     CLS
494.     SaveGame
495.     DrawMenu
496. END SUB
497.  
498. 'MULTIPLAYER GAME MENU
499. SUB MultiplayerGameMenu
500.     LINE (w / 10, h / 10 * 4.7)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
501.     _PRINTSTRING (w / 2 - 40, h / 10 * 4.75), "LOCAL"
502.     _PRINTSTRING (w / 2 - 34, h / 10 * 5.25), "LAN"
503.     _PRINTSTRING (w / 2 - 37, h / 10 * 5.75), "BACK"
504.  
505.     opt = 0
506.     DO
507.         LINE (w / 2 - 58, h / 10 * 4.7)-(w / 2 - 70, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
508.         _PRINTSTRING (w / 2 - 65, h / 10 * (4.75 + (0.5 * opt))), ">" 'DISPLAY POINTER
509.  
510.         _DISPLAY 'REDUCE FLICKERING
511.  
512.         SELECT CASE INKEY$
513.             CASE "s" 'MOVE POINTER DOWN
514.                 IF opt + 1 = 3 THEN
515.                     opt = 0
516.                 ELSE
517.                     opt = opt + 1
518.                 END IF
519.  
520.             CASE "w" 'MOVE POINTER UP
521.                 IF opt - 1 = -1 THEN
522.                     opt = 2
523.                 ELSE
524.                     opt = opt - 1
525.                 END IF
526.             CASE CHR$(13) 'ENTER KEY
527.                 IF opt = 0 THEN
528.                     LocalMultiplayer
529.                 ELSEIF opt = 1 THEN
530.                     LANMultiplayer
531.                 ELSEIF opt = 2 THEN
532.                     DrawMenu
533.                 END IF
534.         END SELECT
535.     LOOP UNTIL INKEY$ = CHR$(13)
536. END SUB
537.  
538.  
539. 'MULTIPLAYER ON SAME DEVICE
540. SUB LocalMultiplayer
541.  
542. END SUB
543.  
544. 'MULTIPLAYER OVER WIFI CONNECTION
545. SUB LANMultiplayer
546.  
547.  
548. END SUB
549.  
550. SUB SaveGame
551.     'SAVE VARS TO TXT
552.     OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
553.     'PLAYER
554.     PRINT #1, name$
555.     PRINT #1, player.health
556.     'SAVE DATA
557.     PRINT #1, save.point
558.     'STATS
559.     PRINT #1, stats.enemyskilled
560.     PRINT #1, stats.totaldeaths
561.     CLOSE #1
562. END SUB
563.  
564. SUB LoadSprite (sp%(), scale)
565.     DIM sprite(4, 4)
566.     FOR y = 0 TO 4
567.         FOR x = 0 TO 4
568.             READ sprite(x, y) 'Read the data
569.         NEXT x
570.     NEXT y
571.  
572.     FOR y = 0 TO 4 * scale STEP scale 'Factor in the scale
573.         FOR x = 0 TO 4 * scale STEP scale
574.             spriteCol = sprite(x / scale, y / scale)
575.             LINE (x, y)-(x + scale, y + scale), _RGB(spriteCol * 255, spriteCol * 255, spriteCol * 255), BF 'Draw each pixel
576.         NEXT x
577.     NEXT y
578.  
579.     GET (0, 0)-(scale * 5, scale * 5), sp%()
580.     CLS
581.  
582.     'Player Data
583.     DATA 0,1,1,1,0
584.     DATA 0,1,1,1,0
585.     DATA 1,1,1,1,1
586.     DATA 0,1,1,1,0
587.     DATA 0,1,0,1,0
588.  
589.     'Sword Data
590.     DATA 0,0,1,0,0
591.     DATA 1,1,1,1,1
592.     DATA 0,1,1,1,0
593.     DATA 0,1,1,1,0
594.     DATA 0,0,1,0,0
595. END SUB
596.  
597. SUB scaledText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
598.     fg = _DEFAULTCOLOR
599.     'screen snapshot
600.     cur& = _DEST
601.     I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
602.     _DEST I&
603.     COLOR K, _RGBA32(0, 0, 0, 0)
604.     _PRINTSTRING (0, 0), txt$
605.     mult = textHeight / 16
606.     xlen = LEN(txt$) * 8 * mult
607.     _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
608.     COLOR fg
609.     _FREEIMAGE I&
610. END SUB

Thanks,
Zep

Title: Re: _PUT Rotation Help
Post by: bplus on December 06, 2019, 01:29:10 am

Hi Mark,

Never used GET and PUT but if you want to try more updated way to rotate images:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. scale = 10
3.  
4. DIM sprite(4, 4)
5. FOR y = 0 TO 4
6.     FOR x = 0 TO 4
7.         READ sprite(x, y) 'Read the data
8.     NEXT x
9. NEXT y
10.  
11. FOR y = 0 TO 4 * scale STEP scale 'Factor in the scale
12.     FOR x = 0 TO 4 * scale STEP scale
13.         spriteCol = sprite(x / scale, y / scale)
14.         LINE (x, y)-(x + scale, y + scale), _RGB32(spriteCol * 255, spriteCol * 255, spriteCol * 255), BF 'Draw each pixel
15.     NEXT x
16. NEXT y
17. sword& = _NEWIMAGE(50, 50, 32)
18. _PUTIMAGE , 0, sword&, (0, 0)-(scale * 5, scale * 5)
19. FOR a = 0 TO 360
20.     CLS
21.     x = _WIDTH / 2 + 100 * COS(_D2R(a + 90))
22.     y = _HEIGHT / 2 + 100 * SIN(_D2R(a + 90))
23.     RotoZoom2 x, y, sword&, 1, 1, 2 * a
24.     _DISPLAY
25.     _LIMIT 60
26. NEXT
27. FOR a = 0 TO 360
28.     CLS
29.     x = _WIDTH / 2 + 100 * COS(_D2R(a + 90))
30.     y = _HEIGHT / 2 + 100 * SIN(_D2R(a + 90))
31.     RotoZoom2 x, y, sword&, 1, a / 360, 4 * a
32.     _DISPLAY
33.     _LIMIT 60
34. NEXT
35.  
36. FOR a = 0 TO 360
37.     CLS
38.     x = _WIDTH / 2 + 100 * COS(_D2R(a + 90))
39.     y = _HEIGHT / 2 + 100 * SIN(_D2R(a + 90))
40.     RotoZoom2 x, y, sword&, 1 - a / 720, a / 360, 8 * a
41.     _DISPLAY
42.     _LIMIT 60
43. NEXT
44. d = 1: a = 0: l = 100
45. WHILE _KEYDOWN(27) = 0
46.     CLS
47.     a = a + d
48.     IF a > 360 THEN a = 360: d = -d
49.     IF a < 0 THEN a = 0: d = -d
50.     RotoZoom2 _WIDTH / 2, _HEIGHT / 2, sword&, (360 - a) / 360, 1, 1
51.     _DISPLAY
52.     IF l < 2000 THEN l = l * 1.5
53.     _LIMIT l
54. WEND
55.  
56. 'Sword Data
57. DATA 0,0,1,0,0
58. DATA 1,1,1,1,1
59. DATA 0,1,1,1,0
60. DATA 0,1,1,1,0
61. DATA 0,0,1,0,0
62.  
63. SUB RotoZoom2 (X AS LONG, Y AS LONG, Image AS LONG, xScale AS SINGLE, yScale, Rotation AS SINGLE)
64.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE
65.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
66.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
67.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
68.     sinr! = SIN(-Rotation / 57.2957795131): cosr! = COS(-Rotation / 57.2957795131)
69.     FOR i& = 0 TO 3
70.         x2& = (px(i&) * cosr! + sinr! * py(i&)) * xScale + X: y2& = (py(i&) * cosr! - px(i&) * sinr!) * yScale + Y
71.         px(i&) = x2&: py(i&) = y2&
72.     NEXT
73.     _MAPTRIANGLE (0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
74.     _MAPTRIANGLE (0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
75. END SUB
76.  
77.  

For Rotozoom2:
x, y places the image center
image is the handle&
On X scale: 0 to 1 and back to 0 spins on y axis,
ON Y scale: 0 to 1 and back to 0 spins on x axis
On Rotation (Degrees) : 0 to 360 and on spins on z axis
use negatives for opposite direction

Title: Re: _PUT Rotation Help
Post by: Zeppelin on December 06, 2019, 02:08:56 am

Thanks bPlus,
Your method seems alot more efficient.

Zep

Text Only | Text with Attachments