QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: romichess on December 02, 2019, 02:04:36 pm

Title: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 02, 2019, 02:04:36 pm

I am having a conniption because my code works when I don't think it should!

First I tried, IF  _MOUSEINPUT THEN : X = _MOUSEX : y = _MOUSEY : END IF.

That can't be used because it fills a buffer with input that takes time to empty. I looked for a clear mouse input buffer command but there does not seem to be one.

My game is to run in real time. My concern was interfering with the real time flow by getting stuck in a do loop while moving the mouse across the screen. But that does not happen and I don't know why. Can someone explain?

Code: QB64: [Select]

1. DIM sw AS INTEGER
2. DIM sh AS INTEGER
3. DIM x AS INTEGER
4. DIM y AS INTEGER
5. DIM repeat AS INTEGER
6.  
7. repeat = 1
8.  
9. sw = _DESKTOPWIDTH
10. sh = _DESKTOPHEIGHT
11.  
12. SCREEN _NEWIMAGE(sw, sh, 256)
13.  
14. _FULLSCREEN
15.  
16. WHILE repeat
17.  
18.     _LIMIT 60
19.  
20.     DO WHILE _MOUSEINPUT
21.  
22.         x = _MOUSEX
23.         y = _MOUSEY
24.  
25.     LOOP
26.  
27.     LOCATE 1, 1
28.     PRINT x, y
29.  
30.     _DISPLAY
31.  
32.     IF INKEY$ = CHR$(27) THEN repeat = 0
33.  
34. WEND
35.  
36. SYSTEM

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: bplus on December 02, 2019, 02:10:36 pm

Welcome romichess! just one little less than intuitive item

Code: QB64: [Select]

1. DIM sw AS INTEGER
2. DIM sh AS INTEGER
3. DIM x AS INTEGER
4. DIM y AS INTEGER
5. DIM repeat AS INTEGER
6.  
7. repeat = 1
8.  
9. sw = _DESKTOPWIDTH
10. sh = _DESKTOPHEIGHT
11.  
12. SCREEN _NEWIMAGE(sw, sh, 256)
13.  
14. _FULLSCREEN
15.  
16. WHILE repeat
17.  
18.     _LIMIT 60
19.  
20.     WHILE _MOUSEINPUT: WEND ' <<<<<<<<<< poll the mouse here in main game loop
21.     '
22.     x = _MOUSEX
23.     y = _MOUSEY
24.     mb = _MOUSEBUTTON(1) ' <<<<<<<<< is left mouse button down?
25.  
26.  
27.     LOCATE 1, 1
28.     PRINT x, y, mb
29.  
30.     _DISPLAY
31.  
32.     IF INKEY$ = CHR$(27) THEN repeat = 0
33.  
34. WEND
35.  
36. SYSTEM

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 02, 2019, 11:08:26 pm

Thank you bplus. I'll just accept the less than intuitive explanation.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: bplus on December 03, 2019, 12:29:34 am

Yeah, all I can say is this line

Code: QB64: [Select]

1. WHILE _MOUSEINPUT: WEND

updates all the mouse stuff like _MOUSEX and _MOUSEY and _MOUSEBUTTON(1) and the others, so put that line in your main loop and you will keep the mouse variables up to date.

The only time you need to do something inside that loop is to get the mousewheel updates as explained in the Wiki.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: SMcNeill on December 03, 2019, 02:38:42 am

Let’s see if I can help explain away the mystery.

A few things to establish first:  Your OS is actually what interacts with your hardware.  Windows/Mac/Linux all handle the drivers and such, and they read our input devices; QB64 doesn’t do this ourselves.  We just read the input buffers that the OS reserves for us, and use them to associate with the device they tell us they belong to.

Now, your OS is going to have a set speed that it polls the hardware at, to check device state at a certain frequency.  A keyboard might check changes 10 times a second, whereas a mouse might poll for updates 100 times a second.  Some of these settings you can tweak via the OS interface (such as keyboard repeat rate), some of them you can’t.  (At least not easily, that I know of.)

Now, how does this affect our programming inside QB64?  Let’s look at a few simple programs:

Code: [Select]

DO
    x = _MOUSEINPIT
LOOP
Now with the above, we might process that do loop 1000 times a second, while the hardware is polling the mouse 100 times a second.  We’re going to catch every mouse event, keep the buffer clear, and have no issues with anything.

Code: [Select]

DO
   x = _MOUSEINPUT
    _LIMIT 10
LOOP
Now, however, we’re just doing the do loop 10 times a second, while the hardware is polling the mouse 100 times a second.  We’re never going to clear that mouse buffer, so our program is always going to respond to mouse events that occurred in the past.  We set a limit to use less CPU and play nice with other programs, and we’re not looping as fast as the hardware is putting stuff into the buffer.

So what’s the solution??

Code: [Select]

DO
    WHILE _MOUSEINPUT: _WEND
     _LIMIT 10
LOOP
Now we’re running our loop 10 times a second.  The hardware is polling the mouse 100 times a second...

And we throw away 90% of that information!

What a real-time event log might look like is similar or this:

MILISECONDS
0 QB64 runs loop.  Mouse at 64, 128
1 Mouse at 64, 128.2
2 Mouse at 64, 128.4
3 Mouse at 64, 128.6
4 Mouse at 64, 128.8
5 Mouse at 64, 129.1
6 Mouse at 64, 129.3
7 Mouse at 64, 129.6
8 Mouse at 64, 129.8
9 Mouse at 64, 130.1
10 QB64 does loop.  Mouse at 64, 130.4

Now, do we *really* care where the mouse was in that fraction between fractional seconds of our DO..LOOP?  Or do we really only care about *where it’s at when QB64 loops back around to it again*??

We toss away a lot of the information, with the logic of:  “I don’t care where it was 0.002 seconds ago, I what to know where it is NOW.”

Think of it like trying to pace off 1000 feet while walking.  You don’t put your feet heel to toe and try and count every exact span of your foot.  You just care about each individual step taken, and what your steady stride is.  You ignore that fractional information, for the expediency of simply getting from Point A to Point B in a reasonable manner.

And that’s basically WHY bplus’s example works for us.  We’re only reacting to the mouse’s state when we poll it; not whatever it might be between those loops.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: Pete on December 03, 2019, 02:59:00 am

Nice example, Steve, but I would have gone with Schrodinger's mouse. Depending on when you observed it, Schrodinger's cat did or did not eat it.

Pete

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: TempodiBasic on December 03, 2019, 04:58:48 am

try this for mouse event cleaner...
https://www.qb64.org/forum/index.php?topic=1744.msg110135#msg110135 (https://www.qb64.org/forum/index.php?topic=1744.msg110135#msg110135)

and if you want to interact with keyboard also while you are  _MOUSEINPUT
you can move this line of your code

Code: QB64: [Select]

1. IF INKEY$ = CHR$(27) THEN repeat = 0

in the inner of the loop of mouse polling.

Welcome to QB64 forum

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: Richard on December 03, 2019, 05:46:54 am

Pete

You made a serious typo:-

o   should be replaced with   ö   (Alt 148   Code Page 437)

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 03, 2019, 10:17:08 am

Thanks guys. I get it now.

WHILE _MOUSEINPUT : WEND is a cat that eats up all the mice in the cage except the last one which it saves to play with!

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: bplus on December 03, 2019, 11:47:06 am

Hi romichess,

There is another conniption causing issue with the mouse you might want to be prepared for that TempodiBasic has alluded to.

This involves executing some code when the mouse is clicked.

The _MOUSEBUUTON(1) reading only tells you when the mouse button is being pressed and if you execute a block of code at that time, you are likely to execute it several times if the user is slow to release or the code is slow to read the mouse clear update, _Mousebutton(1) = 0.

I have only recently seen a best solution by Steve to be clear of mouse button down condition before executing a "Mouse Click Event" block of code.

I have only tested this in newly revised cSleep but looks good to me and you know Steve came up with it so it's got to be good (if it is bug free).

A demo of the technique:

Code: QB64: [Select]

1. OPTION _EXPLICIT 'B+ actually this might be better than old version of cSleep because handles time also
2.  
3. PRINT "Hello World, press key, click mouse or wait 5 secs for goodbye."
4. cSleep 5
5. PRINT "goodbye world"
6.  
7. 'c for click + SLEEP, this does force you to commit to a max time to wait
8. SUB cSleep (secsWait AS DOUBLE) 'wait for keypress or mouseclick, solves midnight problem nicely I think
9.     DIM wayt AS INTEGER, oldMouse AS INTEGER, k AS LONG, startTime AS DOUBLE
10.  
11.     startTime = TIMER
12.     wayt = 1
13.     _KEYCLEAR
14.     WHILE wayt
15.         WHILE _MOUSEINPUT: WEND
16.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN wayt = 0 ' <<<<<<<<<< execute Mouse Click Event
17.         oldMouse = _MOUSEBUTTON(1) ' <<< this is Steve's cool way to get clear of mouse click
18.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: wayt = 0  
19.         IF TIMER - startTime < 0 THEN 'past midnight
20.             IF TIMER + 24 * 60 * 60 - startTime > secsWait THEN wayt = 0
21.         ELSE
22.             IF TIMER - startTime >= secsWait THEN wayt = 0
23.         END IF
24.         _LIMIT 30
25.     WEND
26. END SUB
27.  
28. 'here is steve's   with midnight problem but really nice clear of mouse (and keypresses?)
29. SUB Pause (time AS _FLOAT)
30.     DIM ExitTime AS _FLOAT, k AS LONG, oldMouse AS INTEGER
31.     _KEYCLEAR 'clear the keyboard buffer so we don't automatically exit the routine
32.     IF time <= 0 THEN ExitTime = 1.18E+1000 ELSE ExitTime = time + TIMER
33.     DO
34.         WHILE _MOUSEINPUT: WEND
35.         IF _MOUSEBUTTON(1) AND NOT oldMouse THEN EXIT SUB
36.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: EXIT SUB 'clear any stray key events so they don't mess with code outside the Pause.
37.         oldMouse = _MOUSEBUTTON(1)
38.         _LIMIT 10
39.     LOOP UNTIL ExitTime < TIMER
40. END SUB
41.  
42.  

The oldMouse variable helps us get clear of the mouse down condition before we execute our mouse click code.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: MasterGy on December 03, 2019, 01:23:39 pm

Hi ! familiar problem, I used to say this:

do

    FOR ttt = 0 TO 1000: x = _MOUSEINPUT: NEXT ttt   
X = _MOUSEX
...

loop

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 03, 2019, 01:25:56 pm

Hi back bplus,

That looks simple enough! I have actually already put some thought into this. My imagined (not tested) solution was just to record the x,y coordinates of the button down and compare them to the button up x,y. If they are very close then do the action on mouse up. If the x/y are too different then assume the user changed his mind and moved the mouse while holding down the button. So then just ignore the mouse up event.

Edit: I forgot to mention that once the x,y of the button down event is saved a new x,y cannot be saved until the old x,y is cleared by a button up.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: SMcNeill on December 03, 2019, 02:04:42 pm

My simple idea for mouse presses is this one:

Code: QB64: [Select]

1. DIM SHARED mb(1 TO 3) AS INTEGER '3 variables to hold the buttons
2. DIM SHARED ms AS INTEGER 'a variable to hold the mouse scroll
3.  
4.  
5.  
6.  
7. 'Before the main loop, do once:
8. WHILE _MOUSEINPUT: WEND 'clear the mouse buffer once
9. FOR i = 1 TO 3: mb(i) = _MOUSEBUTTON(i): NEXT 'get the button status to start with, to make certain it isn't down to begin with.
10.  
11. 'main loop
12. DO
13.     WHILE _MOUSEINPUT: ms = ms + _MOUSEWHEEL: WEND 'track the changes to the mouse wheel up or down
14.     IF _MOUSEBUTTON(1) AND NOT mb(1) THEN LeftClick = LeftClick + 1 'if we press the button down, and it wasn't already down, then it's a click!
15.     IF _MOUSEBUTTON(2) AND NOT mb(2) THEN RightClick = RightClick + 1
16.     IF _MOUSEBUTTON(3) AND NOT mb(3) THEN MidClick = MidClick + 1
17.  
18.     CLS
19.     PRINT "Mouse X:"; _MOUSEX
20.     PRINT "Mouse Y:"; _MOUSEY
21.     PRINT "Left Clicks:"; LeftClick
22.     PRINT "Middle Clicks:"; MidClick
23.     PRINT "Right Clicks:"; RightClick
24.     PRINT
25.     PRINT "Mouse Wheel Scrolled:"; ms
26.  
27.     FOR i = 1 TO 3: mb(i) = _MOUSEBUTTON(i): NEXT 'get the button status to start with
28.     _LIMIT 60
29. LOOP

Use a variable to store the mouse button state, and only if it was UP on the last pass through the loop, do we count it as a successful click DOWN on this pass.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 03, 2019, 07:05:16 pm

Thanks! :)

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 03, 2019, 08:43:23 pm

Thanks everyone! I have achieved my first goal which is kind of a proof of concept moment. I think my code is not too big to post here. Next I will go over every line to clean it up. I'm trying to create a realtime game similar to Master OF Orion 1. Don't worry, :) , the graphics will be updated. First I want to get a working game before I worry about graphics or sound.

So far all the code does is create 100 stars. They have a name, color, size and location. The neat part so far is that when a star is moused over it prints the star name in the upper left corner. After cleaning up the code scaling for various graphics resolutions will be next. Then a hard one it would seem. Instead of printing the name of the star in the upper left corner it will place a panel on the screen next to the star. The panel will stay if the star is left clicked until it is clicked again. Otherwise the panel will disappear when the mouse moves off of the star. I could use a pointer or two as to how to print in the panel! And of course any pointers or comments at all are welcome! 

Code: QB64: [Select]

1. TYPE stars
2.     n AS STRING * 10
3.     x AS INTEGER
4.     y AS INTEGER
5.     o AS INTEGER
6.     c AS INTEGER
7.     s AS INTEGER
8.     t AS INTEGER
9.     p AS INTEGER
10. END TYPE
11.  
12. DECLARE SUB NewGame
13. DECLARE SUB PutStars
14. DECLARE SUB GiveName
15. DECLARE SUB ShowPanel (i)
16.  
17. DIM SHARED sw AS INTEGER
18. DIM SHARED sh AS INTEGER
19. DIM SHARED x AS INTEGER
20. DIM SHARED y AS INTEGER
21. DIM dx AS INTEGER
22. DIM dy AS INTEGER
23. DIM repeat AS INTEGER
24. DIM SHARED star(100) AS stars
25. DIM SHARED i AS INTEGER
26. DIM SHARED j AS INTEGER
27. DIM ch AS STRING * 1
28. DIM SHARED names(200) AS STRING * 10
29.  
30. repeat = 1
31.  
32. sw = _DESKTOPWIDTH
33. sh = _DESKTOPHEIGHT
34.  
35. SCREEN _NEWIMAGE(sw, sh, 256)
36.  
37. _FULLSCREEN
38.  
39. GiveName
40.  
41. NewGame
42.  
43. WHILE repeat
44.  
45.     _LIMIT 60
46.  
47.     CLS
48.  
49.     PutStars
50.  
51.     WHILE _MOUSEINPUT: WEND
52.  
53.     x = _MOUSEX
54.     y = _MOUSEY
55.     mb = _MOUSEBUTTON(1)
56.  
57.     FOR i = 0 TO 99
58.         dx = star(i).x - x
59.         dy = star(i).y - y
60.         IF ABS(dx) <= star(i).s + 6 AND ABS(dy) <= star(i).s + 6 THEN
61.             ShowPanel (i)
62.         END IF
63.     NEXT
64.  
65.     _DISPLAY
66.  
67.     ch = INKEY$
68.     IF ch = CHR$(27) THEN repeat = 0
69.     IF ch = "n" THEN NewGame
70.     ch = ""
71.  
72. WEND
73.  
74. SYSTEM
75.  
76. SUB ShowPanel (i)
77.     PRINT star(i).n
78. END SUB
79.  
80. SUB PutStars
81.     FOR i = 0 TO 99
82.         CIRCLE (star(i).x, star(i).y), star(i).s + 6, star(i).c
83.     NEXT
84. END SUB
85.  
86. SUB NewGame
87.     DIM k AS INTEGER
88.     DIM r AS INTEGER
89.     DIM dx AS INTEGER
90.     DIM dy AS INTEGER
91.     DIM n AS STRING * 10
92.     RANDOMIZE TIMER
93.     star(0).n = "sol"
94.     star(0).x = RND * (sw - 80) + 40
95.     star(0).y = RND * (sh - 40) + 20
96.     star(0).c = 14
97.     star(0).s = 3
98.     FOR i = 1 TO 99
99.         k = 1
100.         WHILE k
101.             k = 0
102.             x = INT(RND * (sw - 120)) + 60
103.             y = INT(RND * (sh - 60)) + 30
104.             r = INT(RND * 200)
105.             n = names(r)
106.             FOR j = 0 TO i - 1
107.                 dx = x - star(j).x
108.                 dy = y - star(j).y
109.                 IF ABS(dx) < 60 AND ABS(dy) < 60 THEN
110.                     k = 1
111.                 END IF
112.                 IF n = star(j).n THEN
113.                     k = 1
114.                 END IF
115.             NEXT
116.         WEND
117.         star(i).n = n
118.         star(i).x = x
119.         star(i).y = y
120.         star(i).c = RND * 7 + 9
121.         star(i).s = RND * 5
122.     NEXT
123. END SUB
124.  
125. ' A lot of star names I made up
126.  
127. SUB GiveName
128.     names(0) = "Acamar"
129.     names(1) = "Arcab"
130.     names(2) = "Acrux"
131.     names(3) = "Adhara"
132.     names(4) = "Arneb"
133.     names(5) = "Antares"
134.     names(6) = "Arcturus"
135.     names(7) = "Atria"
136.     names(8) = "Beid"
137.     names(9) = "Betelgeuse"
138.     names(10) = "Botein"
139.     names(11) = "Beemim"
140.     names(12) = "Bellatrix"
141.     names(13) = "Bharani"
142.     names(14) = "Biham"
143.     names(15) = "Brachium"
144.     names(16) = "Canopus"
145.     names(17) = "Capella"
146.     names(18) = "Castor"
147.     names(19) = "Chara"
148.     names(20) = "Cursa"
149.     names(21) = "Copernicus"
150.     names(22) = "Chalawan"
151.     names(23) = "Chertan"
152.     names(24) = "Dabih"
153.     names(25) = "Dalim"
154.     names(26) = "Deneb"
155.     names(27) = "Denebola"
156.     names(28) = "Diadem"
157.     names(29) = "Diphda"
158.     names(30) = "Dschubba"
159.     names(31) = "Dziban"
160.     names(32) = "Edasich"
161.     names(33) = "Electra"
162.     names(34) = "Elgafar"
163.     names(35) = "Elkurud"
164.     names(36) = "Elnath"
165.     names(37) = "Eltanin"
166.     names(38) = "Enif"
167.     names(39) = "Errai"
168.     names(40) = "Fafnir"
169.     names(41) = "Fang"
170.     names(42) = "Fawaris"
171.     names(43) = "Felis"
172.     names(44) = "Fomalhaut"
173.     names(45) = "Fulu"
174.     names(46) = "Fumal"
175.     names(47) = "Furud"
176.     names(48) = "Garnet"
177.     names(49) = "Giausar"
178.     names(50) = "Gienah"
179.     names(51) = "Ginan"
180.     names(52) = "Gomeisa"
181.     names(53) = "Graffias"
182.     names(54) = "Grumium"
183.     names(55) = "Gudja"
184.     names(56) = "Hadar"
185.     names(57) = "Haedus"
186.     names(58) = "Hamal"
187.     names(59) = "Hassaleh"
188.     names(60) = "Hatysa"
189.     names(61) = "Helvetios"
190.     names(62) = "Heze"
191.     names(63) = "Homan"
192.     names(64) = "Iklil"
193.     names(65) = "Imai"
194.     names(66) = "Intercrus"
195.     names(67) = "Izar"
196.     names(68) = "Iccar"
197.     names(69) = "Inar"
198.     names(70) = "Iaeth"
199.     names(71) = "Imaous"
200.     names(72) = "Jabbah"
201.     names(73) = "Jishui"
202.     names(74) = "Jax"
203.     names(75) = "Jalae"
204.     names(76) = "Jewel"
205.     names(77) = "Jumbo"
206.     names(78) = "Jerue"
207.     names(79) = "Jabear"
208.     names(80) = "Kakkab"
209.     names(81) = "Kang"
210.     names(82) = "Kekouan"
211.     names(83) = "Keid"
212.     names(84) = "Kitalpha"
213.     names(85) = "Kochab"
214.     names(86) = "Kolob"
215.     names(87) = "Kobol"
216.     names(88) = "Larawag"
217.     names(89) = "Lesath"
218.     names(90) = "Libertas"
219.     names(91) = "Lich"
220.     names(92) = "Lilly"
221.     names(93) = "Laddel"
222.     names(94) = "Luminous"
223.     names(95) = "Lasacious"
224.     names(96) = "Mizar"
225.     names(97) = "Markab"
226.     names(98) = "Matar"
227.     names(99) = "Mintaka"
228.     names(100) = "Meleph"
229.     names(101) = "Menkar"
230.     names(102) = "Merga"
231.     names(103) = "Merope"
232.     names(104) = "Nahn"
233.     names(105) = "Naos"
234.     names(106) = "Nashira"
235.     names(107) = "Navi"
236.     names(108) = "Nekkar"
237.     names(109) = "Nembus"
238.     names(110) = "Nihal"
239.     names(111) = "Nunki"
240.     names(112) = "Ogma"
241.     names(113) = "Okab"
242.     names(114) = "Ohmy"
243.     names(115) = "Oragami"
244.     names(116) = "Origen"
245.     names(117) = "Omanii"
246.     names(118) = "Obytewa"
247.     names(119) = "Oglok"
248.     names(120) = "Phact"
249.     names(121) = "Pherkad"
250.     names(122) = "Pleione"
251.     names(122) = "Polaris"
252.     names(123) = "Pollux"
253.     names(124) = "Procyon"
254.     names(125) = "Proxima"
255.     names(126) = "Polis"
256.     names(127) = "Quaint"
257.     names(128) = "Quazzat"
258.     names(129) = "Quetzal"
259.     names(130) = "Qussol"
260.     names(131) = "Quella"
261.     names(132) = "Quyaeo"
262.     names(133) = "Ququdas"
263.     names(134) = "Quekak"
264.     names(135) = "Rasalas"
265.     names(136) = "Regor"
266.     names(137) = "Regulus"
267.     names(138) = "Rigel"
268.     names(139) = "Revati"
269.     names(140) = "Rotenev"
270.     names(141) = "Rukbat"
271.     names(142) = "Rastaban"
272.     names(143) = "Sabik"
273.     names(144) = "Sadr"
274.     names(145) = "Saiph"
275.     names(146) = "Sargas"
276.     names(147) = "Sarin"
277.     names(148) = "Syrma"
278.     names(149) = "Spica"
279.     names(150) = "Sirius"
280.     names(151) = "Tarazed"
281.     names(152) = "Taygeta"
282.     names(153) = "Tejat"
283.     names(154) = "Thabit"
284.     names(155) = "Thuban"
285.     names(156) = "Tiaki"
286.     names(157) = "Toliman"
287.     names(158) = "Torcular"
288.     names(157) = "Umala"
289.     names(158) = "Ulatte"
290.     names(159) = "Ubbessa"
291.     names(160) = "Unoless"
292.     names(161) = "Umaddem"
293.     names(162) = "Ummbra"
294.     names(162) = "Uniqu"
295.     names(163) = "Uzzaal"
296.     names(164) = "Vega"
297.     names(165) = "Veritate"
298.     names(166) = "Vindetrix"
299.     names(167) = "Vedas"
300.     names(168) = "Vergg"
301.     names(169) = "Vacant"
302.     names(170) = "Vucae"
303.     names(171) = "Vicar"
304.     names(172) = "Wasat"
305.     names(173) = "Wazn"
306.     names(174) = "Wezen"
307.     names(175) = "Waiten"
308.     names(176) = "Wachar"
309.     names(177) = "Wheelz"
310.     names(178) = "Whatsp"
311.     names(179) = "Wassand"
312.     names(180) = "Xenno"
313.     names(181) = "Xyphod"
314.     names(182) = "Xu"
315.     names(183) = "Xaal"
316.     names(184) = "Xyross"
317.     names(185) = "Xiggot"
318.     names(186) = "Xirrks"
319.     names(187) = "Yed"
320.     names(188) = "Yildun"
321.     names(189) = "yundun"
322.     names(190) = "Yavyo"
323.     names(191) = "Yotrac"
324.     names(192) = "Yxzoqu"
325.     names(193) = "Ynnot"
326.     names(194) = "Zaniah"
327.     names(195) = "Zaurak"
328.     names(196) = "Zhang"
329.     names(197) = "Zibal"
330.     names(198) = "Zosma"
331.     names(199) = "Zuben"
332. END SUB
333.  
334.  

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: bplus on December 03, 2019, 10:37:52 pm

Interesting project, not familiar with game but it looks like you can put up real star data and teach star gazing, ID stars.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 03, 2019, 11:01:31 pm

Yes! Maybe on a phone or tablet that people can take outside with them.

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 03, 2019, 11:34:48 pm

Scaling for different resolutions turned out to be rather trivial. It took about 5 minutes. Here is the new code. My monitors are only 1920 x 1080p. If anyone has 1440p or 4k please check it out and let me know if it scales ok. Thanks. Or maybe QB64 does not work at those resolutions? I forget. It's bedtime! gn :)

P.S. I will comment the code before doing much more.

Code: QB64: [Select]

1. TYPE stars
2.     n AS STRING * 10
3.     x AS INTEGER
4.     y AS INTEGER
5.     o AS INTEGER
6.     c AS INTEGER
7.     s AS INTEGER
8.     t AS INTEGER
9.     p AS INTEGER
10. END TYPE
11.  
12. DECLARE SUB NewGame
13. DECLARE SUB PutStars
14. DECLARE SUB GiveName
15. DECLARE SUB ShowPanel (i)
16.  
17. DIM SHARED sw AS INTEGER
18. DIM SHARED sh AS INTEGER
19. DIM SHARED sww AS INTEGER
20. DIM SHARED swn AS INTEGER
21. DIM SHARED shw AS INTEGER
22. DIM SHARED shn AS INTEGER
23. DIM SHARED nw AS INTEGER
24. DIM SHARED nh AS INTEGER
25. DIM SHARED ratio AS _FLOAT
26. DIM SHARED x AS INTEGER
27. DIM SHARED y AS INTEGER
28. DIM dx AS INTEGER
29. DIM dy AS INTEGER
30. DIM repeat AS INTEGER
31. DIM SHARED star(100) AS stars
32. DIM SHARED i AS INTEGER
33. DIM SHARED j AS INTEGER
34. DIM ch AS STRING * 1
35. DIM SHARED names(200) AS STRING * 10
36.  
37. repeat = 1
38.  
39. sw = _DESKTOPWIDTH
40. sww = sw / 24
41. swn = sw / 48
42. nw = 1920
43.  
44. ratio = sw / 1920
45.  
46. sh = _DESKTOPHEIGHT
47. shw = sh / 20
48. shn = sh / 40
49. nh = 1080
50.  
51. SCREEN _NEWIMAGE(sw, sh, 256)
52.  
53. _FULLSCREEN
54.  
55. GiveName
56.  
57. NewGame
58.  
59. WHILE repeat
60.  
61.     _LIMIT 60
62.  
63.     CLS
64.  
65.     PutStars
66.  
67.     WHILE _MOUSEINPUT: WEND
68.  
69.     x = _MOUSEX
70.     y = _MOUSEY
71.     mb = _MOUSEBUTTON(1)
72.  
73.     FOR i = 0 TO 99
74.         dx = star(i).x - x
75.         dy = star(i).y - y
76.         IF ABS(dx) <= star(i).s + 6 AND ABS(dy) <= star(i).s + 6 THEN
77.             ShowPanel (i)
78.         END IF
79.     NEXT
80.  
81.     _DISPLAY
82.  
83.     ch = INKEY$
84.     IF ch = CHR$(27) THEN repeat = 0
85.     IF ch = "n" THEN NewGame
86.     ch = ""
87.  
88. WEND
89.  
90. SYSTEM
91.  
92. SUB ShowPanel (i)
93.     PRINT star(i).n
94. END SUB
95.  
96. SUB PutStars
97.     FOR i = 0 TO 99
98.         CIRCLE (star(i).x, star(i).y), (star(i).s + 6) * ratio, star(i).c
99.     NEXT
100. END SUB
101.  
102. SUB NewGame
103.     DIM k AS INTEGER
104.     DIM r AS INTEGER
105.     DIM dx AS INTEGER
106.     DIM dy AS INTEGER
107.     DIM n AS STRING * 10
108.     RANDOMIZE TIMER
109.     star(0).n = "Sol"
110.     star(0).x = RND * (sw - sww) + swn
111.     star(0).y = RND * (sh - shw) + shn
112.     star(0).c = 14
113.     star(0).s = 3
114.     FOR i = 1 TO 99
115.         k = 1
116.         WHILE k
117.             k = 0
118.             x = RND * (sw - sww) + swn
119.             y = RND * (sh - shw) + shn
120.             r = INT(RND * 200)
121.             n = names(r)
122.             FOR j = 0 TO i - 1
123.                 dx = x - star(j).x
124.                 dy = y - star(j).y
125.                 IF ABS(dx) < sww AND ABS(dy) < shw THEN
126.                     k = 1
127.                 END IF
128.                 IF n = star(j).n THEN
129.                     k = 1
130.                 END IF
131.             NEXT
132.         WEND
133.         star(i).n = n
134.         star(i).x = x
135.         star(i).y = y
136.         star(i).c = RND * 7 + 9
137.         star(i).s = RND * 5
138.     NEXT
139. END SUB
140.  
141. ' A lot of star names I made up
142.  
143. SUB GiveName
144.     names(0) = "Acamar"
145.     names(1) = "Arcab"
146.     names(2) = "Acrux"
147.     names(3) = "Adhara"
148.     names(4) = "Arneb"
149.     names(5) = "Antares"
150.     names(6) = "Arcturus"
151.     names(7) = "Atria"
152.     names(8) = "Beid"
153.     names(9) = "Betelgeuse"
154.     names(10) = "Botein"
155.     names(11) = "Beemim"
156.     names(12) = "Bellatrix"
157.     names(13) = "Bharani"
158.     names(14) = "Biham"
159.     names(15) = "Brachium"
160.     names(16) = "Canopus"
161.     names(17) = "Capella"
162.     names(18) = "Castor"
163.     names(19) = "Chara"
164.     names(20) = "Cursa"
165.     names(21) = "Copernicus"
166.     names(22) = "Chalawan"
167.     names(23) = "Chertan"
168.     names(24) = "Dabih"
169.     names(25) = "Dalim"
170.     names(26) = "Deneb"
171.     names(27) = "Denebola"
172.     names(28) = "Diadem"
173.     names(29) = "Diphda"
174.     names(30) = "Dschubba"
175.     names(31) = "Dziban"
176.     names(32) = "Edasich"
177.     names(33) = "Electra"
178.     names(34) = "Elgafar"
179.     names(35) = "Elkurud"
180.     names(36) = "Elnath"
181.     names(37) = "Eltanin"
182.     names(38) = "Enif"
183.     names(39) = "Errai"
184.     names(40) = "Fafnir"
185.     names(41) = "Fang"
186.     names(42) = "Fawaris"
187.     names(43) = "Felis"
188.     names(44) = "Fomalhaut"
189.     names(45) = "Fulu"
190.     names(46) = "Fumal"
191.     names(47) = "Furud"
192.     names(48) = "Garnet"
193.     names(49) = "Giausar"
194.     names(50) = "Gienah"
195.     names(51) = "Ginan"
196.     names(52) = "Gomeisa"
197.     names(53) = "Graffias"
198.     names(54) = "Grumium"
199.     names(55) = "Gudja"
200.     names(56) = "Hadar"
201.     names(57) = "Haedus"
202.     names(58) = "Hamal"
203.     names(59) = "Hassaleh"
204.     names(60) = "Hatysa"
205.     names(61) = "Helvetios"
206.     names(62) = "Heze"
207.     names(63) = "Homan"
208.     names(64) = "Iklil"
209.     names(65) = "Imai"
210.     names(66) = "Intercrus"
211.     names(67) = "Izar"
212.     names(68) = "Iccar"
213.     names(69) = "Inar"
214.     names(70) = "Iaeth"
215.     names(71) = "Imaous"
216.     names(72) = "Jabbah"
217.     names(73) = "Jishui"
218.     names(74) = "Jax"
219.     names(75) = "Jalae"
220.     names(76) = "Jewel"
221.     names(77) = "Jumbo"
222.     names(78) = "Jerue"
223.     names(79) = "Jabear"
224.     names(80) = "Kakkab"
225.     names(81) = "Kang"
226.     names(82) = "Kekouan"
227.     names(83) = "Keid"
228.     names(84) = "Kitalpha"
229.     names(85) = "Kochab"
230.     names(86) = "Kolob"
231.     names(87) = "Kobol"
232.     names(88) = "Larawag"
233.     names(89) = "Lesath"
234.     names(90) = "Libertas"
235.     names(91) = "Lich"
236.     names(92) = "Lilly"
237.     names(93) = "Laddel"
238.     names(94) = "Luminous"
239.     names(95) = "Lasacious"
240.     names(96) = "Mizar"
241.     names(97) = "Markab"
242.     names(98) = "Matar"
243.     names(99) = "Mintaka"
244.     names(100) = "Meleph"
245.     names(101) = "Menkar"
246.     names(102) = "Merga"
247.     names(103) = "Merope"
248.     names(104) = "Nahn"
249.     names(105) = "Naos"
250.     names(106) = "Nashira"
251.     names(107) = "Navi"
252.     names(108) = "Nekkar"
253.     names(109) = "Nembus"
254.     names(110) = "Nihal"
255.     names(111) = "Nunki"
256.     names(112) = "Ogma"
257.     names(113) = "Okab"
258.     names(114) = "Ohmy"
259.     names(115) = "Oragami"
260.     names(116) = "Origen"
261.     names(117) = "Omanii"
262.     names(118) = "Obytewa"
263.     names(119) = "Oglok"
264.     names(120) = "Phact"
265.     names(121) = "Pherkad"
266.     names(122) = "Pleione"
267.     names(122) = "Polaris"
268.     names(123) = "Pollux"
269.     names(124) = "Procyon"
270.     names(125) = "Proxima"
271.     names(126) = "Polis"
272.     names(127) = "Quaint"
273.     names(128) = "Quazzat"
274.     names(129) = "Quetzal"
275.     names(130) = "Qussol"
276.     names(131) = "Quella"
277.     names(132) = "Quyaeo"
278.     names(133) = "Ququdas"
279.     names(134) = "Quekak"
280.     names(135) = "Rasalas"
281.     names(136) = "Regor"
282.     names(137) = "Regulus"
283.     names(138) = "Rigel"
284.     names(139) = "Revati"
285.     names(140) = "Rotenev"
286.     names(141) = "Rukbat"
287.     names(142) = "Rastaban"
288.     names(143) = "Sabik"
289.     names(144) = "Sadr"
290.     names(145) = "Saiph"
291.     names(146) = "Sargas"
292.     names(147) = "Sarin"
293.     names(148) = "Syrma"
294.     names(149) = "Spica"
295.     names(150) = "Sirius"
296.     names(151) = "Tarazed"
297.     names(152) = "Taygeta"
298.     names(153) = "Tejat"
299.     names(154) = "Thabit"
300.     names(155) = "Thuban"
301.     names(156) = "Tiaki"
302.     names(157) = "Toliman"
303.     names(158) = "Torcular"
304.     names(157) = "Umala"
305.     names(158) = "Ulatte"
306.     names(159) = "Ubbessa"
307.     names(160) = "Unoless"
308.     names(161) = "Umaddem"
309.     names(162) = "Ummbra"
310.     names(162) = "Uniqu"
311.     names(163) = "Uzzaal"
312.     names(164) = "Vega"
313.     names(165) = "Veritate"
314.     names(166) = "Vindetrix"
315.     names(167) = "Vedas"
316.     names(168) = "Vergg"
317.     names(169) = "Vacant"
318.     names(170) = "Vucae"
319.     names(171) = "Vicar"
320.     names(172) = "Wasat"
321.     names(173) = "Wazn"
322.     names(174) = "Wezen"
323.     names(175) = "Waiten"
324.     names(176) = "Wachar"
325.     names(177) = "Wheelz"
326.     names(178) = "Whatsp"
327.     names(179) = "Wassand"
328.     names(180) = "Xenno"
329.     names(181) = "Xyphod"
330.     names(182) = "Xu"
331.     names(183) = "Xaal"
332.     names(184) = "Xyross"
333.     names(185) = "Xiggot"
334.     names(186) = "Xirrks"
335.     names(187) = "Yed"
336.     names(188) = "Yildun"
337.     names(189) = "yundun"
338.     names(190) = "Yavyo"
339.     names(191) = "Yotrac"
340.     names(192) = "Yxzoqu"
341.     names(193) = "Ynnot"
342.     names(194) = "Zaniah"
343.     names(195) = "Zaurak"
344.     names(196) = "Zhang"
345.     names(197) = "Zibal"
346.     names(198) = "Zosma"
347.     names(199) = "Zuben"
348. END SUB
349.  
350.  

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: bplus on December 04, 2019, 10:42:05 am

Oh wouldn't that be something! to match users latitude and longitude and time and show them their night sky. :)

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 04, 2019, 01:35:47 pm

Quote from: bplus on December 04, 2019, 10:42:05 am

Oh wouldn't that be something! to match users latitude and longitude and time and show them their night sky. :)

Hi bplus,

I am not going in that direction. But if you want to go in that direction and my code will help then by all means proceed! :)

Title: Re: I'm new to QB64 and I'm having a conniption
Post by: romichess on December 05, 2019, 04:21:43 pm

Quote from: bplus on December 03, 2019, 11:47:06 am

Hi romichess,

There is another conniption causing issue with the mouse you might want to be prepared for that TempodiBasic has alluded to.

This involves executing some code when the mouse is clicked.

The _MOUSEBUUTON(1) reading only tells you when the mouse button is being pressed and if you execute a block of code at that time, you are likely to execute it several times if the user is slow to release or the code is slow to read the mouse clear update, _Mousebutton(1) = 0.

I have only recently seen a best solution by Steve to be clear of mouse button down condition before executing a "Mouse Click Event" block of code.

I have only tested this in newly revised cSleep but looks good to me and you know Steve came up with it so it's got to be good (if it is bug free).

A demo of the technique:

Code: QB64: [Select]

1. OPTION _EXPLICIT 'B+ actually this might be better than old version of cSleep because handles time also
2.  
3. PRINT "Hello World, press key, click mouse or wait 5 secs for goodbye."
4. cSleep 5
5. PRINT "goodbye world"
6.  
7. 'c for click + SLEEP, this does force you to commit to a max time to wait
8. SUB cSleep (secsWait AS DOUBLE) 'wait for keypress or mouseclick, solves midnight problem nicely I think
9.     DIM wayt AS INTEGER, oldMouse AS INTEGER, k AS LONG, startTime AS DOUBLE
10.  
11.     startTime = TIMER
12.     wayt = 1
13.     _KEYCLEAR
14.     WHILE wayt
15.         WHILE _MOUSEINPUT: WEND
16.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN wayt = 0 ' <<<<<<<<<< execute Mouse Click Event
17.         oldMouse = _MOUSEBUTTON(1) ' <<< this is Steve's cool way to get clear of mouse click
18.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: wayt = 0  
19.         IF TIMER - startTime < 0 THEN 'past midnight
20.             IF TIMER + 24 * 60 * 60 - startTime > secsWait THEN wayt = 0
21.         ELSE
22.             IF TIMER - startTime >= secsWait THEN wayt = 0
23.         END IF
24.         _LIMIT 30
25.     WEND
26. END SUB
27.  
28. 'here is steve's   with midnight problem but really nice clear of mouse (and keypresses?)
29. SUB Pause (time AS _FLOAT)
30.     DIM ExitTime AS _FLOAT, k AS LONG, oldMouse AS INTEGER
31.     _KEYCLEAR 'clear the keyboard buffer so we don't automatically exit the routine
32.     IF time <= 0 THEN ExitTime = 1.18E+1000 ELSE ExitTime = time + TIMER
33.     DO
34.         WHILE _MOUSEINPUT: WEND
35.         IF _MOUSEBUTTON(1) AND NOT oldMouse THEN EXIT SUB
36.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: EXIT SUB 'clear any stray key events so they don't mess with code outside the Pause.
37.         oldMouse = _MOUSEBUTTON(1)
38.         _LIMIT 10
39.     LOOP UNTIL ExitTime < TIMER
40. END SUB
41.  
42.  

The oldMouse variable helps us get clear of the mouse down condition before we execute our mouse click code.

The solution I had imagined works really well.

Code: QB64: [Select]

1.     WHILE _MOUSEINPUT: WEND '          Eat all the mice but keep last mouse to toy with
2.  
3.     x = _MOUSEX
4.     y = _MOUSEY
5.     mb = _MOUSEBUTTON(1)
6.     clk = 0 ' click, is just a one frame signal
7.  
8.     IF mb = -1 AND cx = sw THEN ' if clicked_x is off screen there is no clicked_x
9.         cx = x 'now we have a clicked_x
10.         cy = y 'and a clicked_y
11.     END IF
12.  
13.     IF mb = 0 AND cx < sw THEN ' and since we have a clicked_x
14.         IF ABS(x - cx) < 4 AND ABS(y - cy) < 4 THEN ' mouse jiggle tolerance
15.             clk = 1 ' we send a click signal for one frame
16.         END IF
17.         cx = sw ' and since the click signal is for x, y we move clicked_x off screen
18.     END IF
19.  

Text Only | Text with Attachments