Print Page - Click It!

Code: QB64: [Select]

CONST DefaultPort$ = "7993"
CONST DefaultIP$ = "172.93.60.23"
CONST True = -1, False = 0
CONST Verbose = True
_DEFINE A-Z AS _INTEGER64  'we're going to send/recieve int64s usually (8 bytes).  Deal with it.
DIM SHARED Host, Client, LastSeen
 
 
'REQUIRED SERVER CODE ABOVE
 
 
 
SCREEN _NEWIMAGE(800, 600, 32)
 
_TITLE "Click It!"
_CONTROLCHR OFF 'not necessary, but used here to help diagnose stray characters passed back and forth
 
PRINT "Connecting to Server..";
Client = ConnectAsClient(DefaultPort, DefaultIP$)
PRINT Verify$
PRINT
PRINT "Press <ANY KEY> to continue..."
SLEEP
_KEYCLEAR
 
 
CLS
PRINT "Are you a new player?  (Y/N)"
DO
    a$ = UCASE$(INPUT$(1))
LOOP UNTIL a$ = "Y" OR a$ = "N"
DO
    IF a$ = "Y" THEN
        INPUT "REGISTER NAME:"; n$
        INPUT "REGISTER PASSWORD:"; p$
        Send Client, "[REGISTER]" + n$ + "," + p$ 'Register a new account
    ELSE
        INPUT "LOGIN NAME:"; n$
        INPUT "LOGIN PASSWORD:"; p$
        Send Client, "[LOG IN]" + n$ + "," + p$ 'Login from an existing account
    END IF
    OK$ = Verify$
    PRINT OK$ 'don't just print the results here
LOOP UNTIL LEFT$(OK$, 4) = "[OK]" 'we want to actually make use of them.
PRINT
PRINT "Press <ANY KEY> to continue..."
SLEEP
_KEYCLEAR
 
Send Client, "[GAME SET]Click It" 'Let the server know what game we're playing.
PRINT Verify$
Send Client, "[GAME GET]Highscore.txt"
OK$ = Verify$ 'same deal as above.  We don't want to just print the results; we want to use them.
IF LEFT$(OK$, 4) = "[OK]" THEN highscore$ = MID$(OK$, 5) 'the server just sent us the whole highscore listing,
'all at once.  We can write it to our disk if we want (OPEN file$ FOR BINARY and PUT the whole file to drive),
'or we can parse it as we want, to make sense of who/what it is.
'What this file contains is what we sent to the server to store for us, so if we don't know how to decipher it
'for our game, the server sure as hell doesn't know what to do with it either!
PRINT "Highscore.txt retrieved."
PRINT
PRINT "Press <ANY KEY> to continue..."
SLEEP
_KEYCLEAR
 
'At this point, highscore.txt is either going to be one of two different things:
'1) It's going to be blank and have a file length of 0, as we haven't saved any highscores yet.
'2) It's going to be the whole highscore list.
 
'Regardless, let's go ahead and just save file this to our drive as file handle #1.  (Our only needed filehandle)
 
OPEN "highscore.txt" FOR OUTPUT AS #1: CLOSE 1 'blank any old highscore file.
OPEN "highscore.txt" FOR BINARY AS #1
PUT #1, , highscore$ 'and put the whole file to the drive all at once.
 
'AGAIN, You'll need to come up with your own method to handle however you process the file the server sent you.
'This is just the simple style which I chose to use for this demo.
 
SEEK #1, 1 'This isn't the most efficient way to get my high score list, but it's the one I'm using
DIM Player$(1000), Score(1000) 'Up to 1000 players, and their score.
DO UNTIL EOF(1) OR LOF(1) = 0
    players = players + 1
    LINE INPUT #1, Player$(players)
    LINE INPUT #1, junk$
    Score(players) = VAL(junk$)
    IF Player$(players) = n$ THEN click = Score(players): found = players
LOOP
CLOSE 1
 
COLOR , 0
DO
    CLS
    LINE (100, 100)-(300, 200), &HFF00FF00, BF
    LINE (100, 100)-(300, 200), -1, B
    _PRINTSTRING (110, 140), "<CLICKS:" + STR$(click) + ">"
    WHILE _MOUSEINPUT: WEND
    IF _MOUSEBUTTON(1) <> 0 AND oldmouse = 0 THEN 'mouse is clicked
        IF _MOUSEX >= 100 AND _MOUSEX <= 300 AND _MOUSEY >= 100 AND _MOUSEY <= 200 THEN 'it's a click in the box
            click = click + 1
        ELSE 'we clicked outside the box!  We have to quit!
            EXIT DO
        END IF
    END IF
    oldmouse = _MOUSEBUTTON(1)
    _DISPLAY
    _LIMIT 60
LOOP
 
IF found THEN
    Score(found) = click
ELSE
    players = players + 1
    Score(players) = click
    Player$(players) = n$
END IF
 
FOR i = 1 TO players - 1 'a lazy bubble sort to rank our players.
    FOR j = i TO players 'this is inefficient as heck, but I don't expect there will be millions of players to rank!
        IF Score(i) < Score(j) THEN SWAP Player$(i), Player$(j): SWAP Score(i), Score(j)
    NEXT
NEXT
 
OPEN "highscore.txt" FOR OUTPUT AS #1 'replace the old highscore file.
FOR i = 1 TO players
    PRINT #1, Player$(i)
    PRINT #1, Score(i)
NEXT
CLOSE 1
OPEN "highscore.txt" FOR BINARY AS #1
s$ = SPACE$(LOF(1))
GET #1, 1, s$ 'get that information into a single large string
CLOSE 1
 
 
CLS
 
'****************************************************************
'**
'**  NEXT COMMAND IS STRESSED FOR EMPHASIS!  READ IT!!!!
'**
'*****************************************************************
 
Send Client, "[GAME PUT]highscore.txt" + CHR$(0) + s$ 'NOTICE THE SEPARATOR BETWEEN OUR COMMAND AND THE FILE CONTENTS
'WITHOUT THAT SEPARATOR (CHR$(0)), YOU WILL GET ERRORS AND NOT SAVE YOUR FILE.
 
'****************************************************************
'**
'**  PREVIOUS COMMAND IS STRESSED FOR EMPHASIS!  READ IT!!!!
'**
'*****************************************************************
 
PRINT Verify$
PRINT
PRINT "PLAYER SCORELIST"
FOR i = 1 TO players 'just dump the player scores to the screen.
    'I'm not looking for pretty at this point, just trying to highlight the functionality.
    PRINT i; ") "; Player$(i), Score(i)
NEXT
 
 
 
 
 
 
 
'SERVER CODE BELOW
 
 
 
FUNCTION ConnectAsClient (Port$, IP$)
    IF Verbose THEN PRINT "Connecting to Host as Client";
    DO
        count = count + 1
        temp = _OPENCLIENT("TCP/IP:" + Port$ + ":" + IP$) 'attempt to join as client
        _LIMIT 10
        IF Verbose THEN PRINT ".";
    LOOP UNTIL temp <> 0 OR count > 100
    IF Verbose THEN PRINT
    IF count > 50 THEN
        IF Verbose THEN PRINT "Cannot connect to Host.  Terminating program."
        END
    END IF
    IF Verbose THEN PRINT "Client Connected Successfully."
    ConnectAsClient = temp
END FUNCTION
 
SUB Send (Who, What$)
    IF Client = 0 OR What$ = "" THEN EXIT SUB
    out$ = CHR$(2) 'an initial byte to say, "We're sending data."
    out$ = out$ + _MK$(_INTEGER64, LEN(What$) + 8) '8 bytes to store the length of the data we're sending.
    out$ = out$ + What$
    PUT Client, , out$
END FUNCTION
 
SUB Receive (Who, What$)
    STATIC In AS STRING
    DIM B AS _UNSIGNED _BYTE
    IF Client = 0 THEN EXIT SUB
    IF In = "" THEN
        GET Client, , B
    ELSE
        B = ASC(In)
        r$ = r$ + In
        In = "" 'Is there a message waiting for us, after we processed one message?
    END IF
    IF B = 2 THEN
        DO
            GET Client, , a$
            IF a$ <> "" THEN r$ = r$ + a$
            IF LEN(r$) > 8 THEN length = _CV(_INTEGER64, LEFT$(r$, 8))
            _LIMIT 10
        LOOP UNTIL LEN(r$) >= length AND length <> 0
        What$ = MID$(r$, 9) '8 bytes for the length
        In = MID$(r$, length + 1)
    END IF
END SUB
 
FUNCTION Verify$
    DO
        Receive Client, OK$ 'Get the confirmation message.
        _LIMIT 10 'Use low CPU while waiting.  No need for a high number here... Be patient and let the server have time to respond.  Checking 10 times a second is more than enough to get an [OK] or [ERROR] message.
    LOOP UNTIL OK$ <> ""
    Verify$ = OK$
END FUNCTION
 

My first game to take advantage of my little Open Game Server (topic here: https://www.qb64.org/forum/index.php?topic=1920.0). If this works as it should for everyone, it'll highlight the process which people could follow to link their own games into the game server.

All I can say at this point is to test it out and see if the thing works for you like it should, or not. The first time you run it, you'll need to register a new account. From them on, just log into your existing account.

Play the game -- it's quite complex, but I imagine you guys can sort it out without needing a ton of instructions -- and see who can get the highest score! ;D

This might be tangential, but that is interesting way to get clear of a click, except stuck with mouse down point but fine for most uses.

It’s how I generally get a lazy “click”. Only when the mouse was up, and we push it down, does it count as a “click”. Of course, we can hold it forever, and it won’t change anything or register any hold events, but it works excellent for getting single click events.

And, I know there’s not much game to this “game”. The main purpose here is to show folks how they can connect to my server and use it for their own games, if they don’t have a static ip, open ports, or a space PC to run 24/7 hosting one. ;)

Looking at the data file where a few people have played already, it seems as if the file is getting corrupted with bad data. I’ll need to do some double checking to see what/where the glitch is occurring. Passing 3-4 records seems fine. More than that and things get buggy internally.

Almost there, but not quite 100% yet. :(

Post above has been replaced with a new version of Click It!

I completely redid the server/client communication protocol, making things much simpler and much more efficient on both ends. (I think there was about 50 lines of code which got shortened over all.)

The file corruption with the high score lists has been corrected as well. You guys are welcome to try it out once more, but I think things are finally working as intended with this little pet server project.

Wow, Lots faster and more streamlined! nice.

Arg in second place now! have to click more!

back in first! :D

QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on November 27, 2019, 12:09:27 am