Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SierraKen on November 03, 2019, 01:09:20 am

Title: WAV Player with Graphical Output Displays
Post by: SierraKen on November 03, 2019, 01:09:20 am
Most of this is by Petr. Thank you Petr! I added 6 more graphical displays for the music to go by. I also added the ability to type in a name of the .wav file you want to play.
I made this new thread so people can easily find a WAV player with graphical output displays better when they search. Petr helped me learn how to grab the left and right outputs and form them into graphics from the .wav sound file.
After you type in a .wav file name (with the .wav ending), use the Space Bar to change between 7 different graphical output displays. Petr made the first one. After the 7th, it goes back to the first. If you wonder how you can save an .mp3 as a .wav file, I use a free program called Audacity. But just remember, .wav files are about 10 times larger than .mp3.

Code: QB64: [Select]
  1. 'Almost all of this was made by Petr from the QB64.org forum.
  2. 'Some of the displays added by SierraKen (Ken G.).
  3. _TITLE "WAV Music Player - Space Bar Changes Display When Playing. Esc to Quit."
  4. SCREEN _NEWIMAGE(800, 600, 256)
  6.     CLS
  7.     PRINT: PRINT: PRINT
  8.     INPUT "Type .WAV music filename here or only Enter to quit:", nm$
  9.     IF nm$ = "" THEN END
  10.     CLS
  11.     wav nm$ 'insert uncompressed wav audio filename here
  13. SUB wav (file$)
  14.     TYPE head
  15.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  16.         size AS LONG '              4 bytes  (?E??)
  17.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  18.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  19.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  20.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  21.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  22.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  23.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  24.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  25.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  26.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  27.     END TYPE '                     40 bytes  total
  28.     DIM H AS head
  29.     ch = FREEFILE
  30.  
  31.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  32.     GET #ch, , H
  33.  
  34.     block = H.Block
  35.     RATE = H.rate
  36.     chan = H.channels
  37.     bits = H.Bits
  38.  
  39.  
  40.     DO WHILE NOT EOF(ch)
  41.  
  42.         vz = 44100 / 80
  43.         IF (SEEK(ch) - 40) MOD vz = 0 THEN
  44.             visual lefVis / vz, righVis / vz
  45.             lefVis = 0
  46.             righVis = 0
  47.         END IF
  48.         lefVis = lefVis + ABS(lef)
  49.         righVis = righVis + ABS(righ)
  50.  
  51.  
  52.  
  53.         IF bits = 16 AND chan = 2 THEN
  54.             REDIM lefi AS INTEGER, righi AS INTEGER
  55.             GET #ch, , lefi
  56.             GET #ch, , righi
  57.             lef = lefi / RATE
  58.             righ = righi / RATE
  59.         END IF
  60.  
  61.         IF bits = 16 AND chan = 1 THEN
  62.             REDIM leftMono AS INTEGER
  63.             GET #ch, , leftMono
  64.             lef = leftMono / RATE
  65.             righ = leftMono / RATE
  66.         END IF
  67.  
  68.         IF bits = 8 AND chan = 2 THEN
  69.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  70.             GET #ch, , lleft8
  71.             GET #ch, , rright8
  72.             lef = lleft8 / 256
  73.             righ = rright8 / 256
  74.         END IF
  75.  
  76.         IF bits = 8 AND chan = 1 THEN
  77.             REDIM mono8 AS _UNSIGNED _BYTE
  78.             GET #ch, , mono8
  79.             lef = mono8 / 256
  80.             righ = lef
  81.         END IF
  82.  
  83.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  84.         FOR plll = 1 TO frekvence / RATE
  85.             _SNDRAW lef, righ
  86.         NEXT plll
  87.  
  88.         DO WHILE _SNDRAWLEN > 0: LOOP: REM By commenting this row you DAMAGE SOUND / VIDEO synchronizing. TRY IT.
  89.  
  90.  
  91.     LOOP
  92.     CLOSE ch
  94.  
  95. SUB visual (lef, righ)
  96.     SHARED x, oldx1, oldx2, disp, tt, xxx, yyy, xxx2, yyy2, oldxxx, oldyyy, oldxxx2, oldyyy2
  97.     STP = 5 ' TRY rewriting STP value to other
  98.     x1 = lef * 200
  99.     x2 = righ * 200
  100.     a$ = INKEY$
  101.     IF a$ = " " THEN CLS: disp = disp + 1: tt = 0
  102.     IF a$ = CHR$(27) THEN END
  103.     IF disp > 6 THEN disp = 0
  104.  
  105.     IF oldx1 AND disp = 6 THEN
  106.         LINE (0, 0)-(800, 450), _RGBA(0, 0, 0, 30), BF
  107.         CIRCLE (200, 200), 182, 25
  108.         CIRCLE (600, 200), 182, 25
  109.         p = x1 * 5
  110.         p2 = x2 * 5
  111.         sec = (p * .6) + seconds
  112.         sec2 = (p2 * .6) + seconds2
  113.         seconds = sec
  114.         seconds2 = sec2
  115.         IF seconds > 359 THEN seconds = 0
  116.         seconds = seconds + 1
  117.         s = (60 - seconds) * 6 + 180
  118.         oldxxx = xxx: oldyyy = yyy
  119.         xxx = INT(SIN(s / 180 * _PI) * 180) + 200
  120.         yyy = INT(COS(s / 180 * _PI) * 180) + 200
  121.         LINE (200, 200)-(xxx, yyy), 14
  122.  
  123.         IF seconds2 > 359 THEN seconds = 0
  124.         seconds2 = seconds2 + 1
  125.         s2 = (60 - seconds2) * 6 + 180
  126.         oldxxx2 = xxx2: oldyyy2 = yyy2
  127.         xxx2 = INT(SIN(s2 / 180 * _PI) * 180) + 600
  128.         yyy2 = INT(COS(s2 / 180 * _PI) * 180) + 200
  129.         LINE (600, 200)-(xxx2, yyy2), 3
  130.         _DISPLAY
  131.     END IF
  132.  
  133.  
  134.     IF oldx1 AND disp = 5 THEN
  135.         IF x > 200 THEN CLS: x = 0
  136.         xx = x + 100
  137.         xx2 = x + 500
  138.         LINE (xx, 0)-(xx + STP, 400), 0, BF
  139.         FOR sz = .25 TO 5 STEP .25
  140.             CIRCLE (xx, 300 - (x1 * 2)), sz, 1
  141.             CIRCLE (xx - STP, 300 - (oldx1 * 2)), sz, 1
  142.         NEXT sz
  143.         FOR sz2 = .25 TO 5 STEP .25
  144.             CIRCLE (xx2, 300 - (x2 * 2)), sz2, 10
  145.             CIRCLE (xx2 - STP, 300 - (oldx2 * 2)), sz2, 10
  146.         NEXT sz2
  147.     END IF
  148.  
  149.  
  150.     IF oldx1 AND disp = 4 THEN
  151.         IF x > 799.9 THEN CLS: x = 0
  152.         LINE (x, 0)-(x + STP, 400), 0, BF
  153.         FOR sz = .25 TO 5 STEP .25
  154.             CIRCLE (x, 300 - (x1 * 2)), sz, 1
  155.             CIRCLE (x - STP, 300 - (oldx1 * 2)), sz, 1
  156.         NEXT sz
  157.         FOR sz2 = .25 TO 5 STEP .25
  158.             CIRCLE (x, 300 - (x2 * 2)), sz2, 10
  159.             CIRCLE (x - STP, 300 - (oldx2 * 2)), sz2, 10
  160.         NEXT sz2
  161.     END IF
  162.  
  163.  
  164.     IF oldx1 AND disp = 3 THEN
  165.         IF x = 800 THEN CLS: x = 0
  166.         LINE (x, 0)-(x + STP, 400), 0, BF
  167.         LINE (x, 300 - (x1 * 4))-(x - STP, 300 - (oldx1 * 4)), 15
  168.  
  169.         LINE (x, 200 - (x2 * 4))-(x - STP, 200 - (oldx2 * 4)), 14
  170.     END IF
  171.  
  172.  
  173.     IF oldx1 AND disp = 2 THEN
  174.         tt = tt + 1
  175.         IF tt < 5 THEN GOTO skip:
  176.         tt = 0
  177.         c1 = RND * 255
  178.         c2 = RND * 255
  179.         c3 = RND * 255
  180.         xx = RND * 800
  181.         yy = RND * 600
  182.         LINE (xx, yy)-((xx + x1) * 2, (yy + x2) * 2), _RGB32(c1, c2, c3), BF
  183.         skip:
  184.     END IF
  185.     IF oldx1 AND disp = 1 THEN
  186.         tt = tt + 1
  187.         IF tt < 5 THEN GOTO skip2:
  188.         tt = 0
  189.         c1 = RND * 255
  190.         c2 = RND * 255
  191.         c3 = RND * 255
  192.         xx = RND * 800
  193.         yy = RND * 600
  194.         CIRCLE (xx, yy), x1 * 2, _RGB32(c1, c2, c3)
  195.         PAINT (xx, yy), _RGB32(c1, c2, c3)
  196.         skip2:
  197.     END IF
  198.     IF oldx1 AND disp = 0 THEN
  199.         IF x = 800 THEN CLS: x = 0
  200.         LINE (x, 0)-(x + STP, 400), 0, BF
  201.         LINE (x, 200 - x1)-(x - STP, 200 - oldx1), 15
  202.  
  203.         LINE (x, 100 - x2)-(x - STP, 100 - oldx2), 14
  204.     END IF
  205.  
  206.     oldx1 = x1
  207.     oldx2 = x2
  208.     x = x + STP: IF x > _WIDTH THEN x = 0
  209.  
  210.     LINE (100, 600)-(300, 400), 0, BF
  211.     LINE (100, 600)-(300, 600 - 500 * lef), 14, BF
  212.  
  213.     LINE (700, 600)-(500, 400), 0, BF
  214.     LINE (700, 600)-(500, 600 - 500 * righ), 3, BF
  216.  

Title: Re: WAV Player with Graphical Output Displays
Post by: Petr on November 03, 2019, 04:27:49 am
Nice work, SierraKen. if I have time today, I will also write some visualizations.
Title: Re: WAV Player with Graphical Output Displays
Post by: Petr on November 03, 2019, 05:26:38 am
SierraKen, this source code containst 1 visualization. Better solution. Program load 800 samples to array for both channels (because screen width is 800) and when is array full (contains 800 samples), so then draw all as two lines to screen, erase both arrays and again save next samples to arrays. For faster visualization speed is possible saving less samples and placing it in step to screen (second source code)

Source code: Show all samples (not fast)

Code: QB64: [Select]
  1. SCREEN _NEWIMAGE(800, 600, 256)
  2.  
  3. REDIM SHARED LeftCurve(799) AS INTEGER
  4. REDIM SHARED RightCurve(799) AS INTEGER
  5.  
  6. wav "s.wav" 'insert uncompressed wav audio filename here
  7.  
  8. SUB wav (file$)
  9.     TYPE head
  10.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  11.         size AS LONG '              4 bytes  (?E??)
  12.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  13.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  14.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  15.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  16.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  17.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  18.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  19.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  20.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  21.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  22.     END TYPE '                     40 bytes  total
  23.     DIM H AS head
  24.  
  25.  
  26.  
  27.     ch = FREEFILE
  28.  
  29.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  30.     GET #ch, , H
  31.  
  32.     block = H.Block
  33.     RATE = H.rate
  34.     chan = H.channels
  35.     bits = H.Bits
  36.  
  37.  
  38.     DO WHILE NOT EOF(ch)
  39.  
  40.         IF bits = 16 AND chan = 2 THEN
  41.             REDIM lefi AS INTEGER, righi AS INTEGER
  42.             GET #ch, , lefi
  43.             GET #ch, , righi
  44.             Lef = lefi / RATE
  45.             righ = righi / RATE
  46.         END IF
  47.  
  48.         IF bits = 16 AND chan = 1 THEN
  49.             REDIM leftMono AS INTEGER
  50.             GET #ch, , leftMono
  51.             Lef = leftMono / RATE
  52.             righ = leftMono / RATE
  53.         END IF
  54.  
  55.         IF bits = 8 AND chan = 2 THEN
  56.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  57.             GET #ch, , lleft8
  58.             GET #ch, , rright8
  59.             Lef = lleft8 / 256
  60.             righ = rright8 / 256
  61.         END IF
  62.  
  63.         IF bits = 8 AND chan = 1 THEN
  64.             REDIM mono8 AS _UNSIGNED _BYTE
  65.             GET #ch, , mono8
  66.             Lef = mono8 / 256
  67.             righ = Lef
  68.         END IF
  69.  
  70.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  71.         FOR plll = 1 TO frekvence / RATE
  72.             _SNDRAW Lef, righ
  73.         NEXT plll
  74.  
  75.         DO WHILE _SNDRAWLEN > 0: LOOP: REM By commenting this row you DAMAGE SOUND / VIDEO synchronizing. TRY IT.
  76.  
  77.         '----------------------------------------
  78.         Sample = Sample + 1
  79.         IF Sample > 799 THEN
  80.             Visual
  81.             REDIM LeftCurve(799) AS INTEGER
  82.             REDIM RightCurve(799) AS INTEGER
  83.             Sample = 0
  84.         END IF
  85.         LeftCurve(Sample) = 300 + Lef * 300
  86.         RightCurve(Sample) = 300 + righ * 300
  87.         '---------------------------------------
  88.  
  89.     LOOP
  90.     CLOSE ch
  92.  
  93. SUB Visual
  94.     CLS
  95.     FOR x = 0 TO 798 STEP 1
  96.         LINE (x, LeftCurve(x))-(x + 1, LeftCurve(x + 1)), 14
  97.         LINE (x, RightCurve(x))-(x + 1, RightCurve(x + 1)), 15
  98.     NEXT
  100.  

Source code: Show less samples at once (faster)

Code: QB64: [Select]
  1. SCREEN _NEWIMAGE(800, 600, 256)
  2.  
  3. REDIM SHARED LeftCurve(79) AS INTEGER
  4. REDIM SHARED RightCurve(79) AS INTEGER
  5.  
  6. wav "s.wav" 'insert uncompressed wav audio filename here
  7.  
  8. SUB wav (file$)
  9.     TYPE head
  10.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  11.         size AS LONG '              4 bytes  (?E??)
  12.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  13.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  14.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  15.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  16.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  17.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  18.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  19.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  20.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  21.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  22.     END TYPE '                     40 bytes  total
  23.     DIM H AS head
  24.  
  25.  
  26.  
  27.     ch = FREEFILE
  28.  
  29.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  30.     GET #ch, , H
  31.  
  32.     block = H.Block
  33.     RATE = H.rate
  34.     chan = H.channels
  35.     bits = H.Bits
  36.  
  37.  
  38.     DO WHILE NOT EOF(ch)
  39.  
  40.         IF bits = 16 AND chan = 2 THEN
  41.             REDIM lefi AS INTEGER, righi AS INTEGER
  42.             GET #ch, , lefi
  43.             GET #ch, , righi
  44.             Lef = lefi / RATE
  45.             righ = righi / RATE
  46.         END IF
  47.  
  48.         IF bits = 16 AND chan = 1 THEN
  49.             REDIM leftMono AS INTEGER
  50.             GET #ch, , leftMono
  51.             Lef = leftMono / RATE
  52.             righ = leftMono / RATE
  53.         END IF
  54.  
  55.         IF bits = 8 AND chan = 2 THEN
  56.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  57.             GET #ch, , lleft8
  58.             GET #ch, , rright8
  59.             Lef = lleft8 / 256
  60.             righ = rright8 / 256
  61.         END IF
  62.  
  63.         IF bits = 8 AND chan = 1 THEN
  64.             REDIM mono8 AS _UNSIGNED _BYTE
  65.             GET #ch, , mono8
  66.             Lef = mono8 / 256
  67.             righ = Lef
  68.         END IF
  69.  
  70.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  71.         FOR plll = 1 TO frekvence / RATE
  72.             _SNDRAW Lef, righ
  73.         NEXT plll
  74.  
  75.         DO WHILE _SNDRAWLEN > 0: LOOP: REM By commenting this row you DAMAGE SOUND / VIDEO synchronizing. TRY IT.
  76.  
  77.         '----------------------------------------
  78.         Sam = Sam + 1
  79.         IF Sam MOD 10 = 0 THEN 'Save every 10th sample to array for visualising (save CPU time and power)
  80.             sample = sample + 1
  81.             IF sample > 79 THEN
  82.                 Visual
  83.                 REDIM LeftCurve(799) AS INTEGER
  84.                 REDIM RightCurve(799) AS INTEGER
  85.                 sample = 0
  86.                 Sam = 0
  87.             END IF
  88.             LeftCurve(sample) = 300 + Lef * 300
  89.             RightCurve(sample) = 300 + righ * 300
  90.         END IF
  91.         '---------------------------------------
  92.  
  93.     LOOP
  94.     CLOSE ch
  96.  
  97. SUB Visual
  98.     CLS
  99.     FOR x = 0 TO 78
  100.         LINE (x * 10, LeftCurve(x))-(x * 10 + 10, LeftCurve(x + 1)), 14
  101.         LINE (x * 10, RightCurve(x))-(x * 10 + 10, RightCurve(x + 1)), 15
  102.     NEXT
  104.  

Title: Re: WAV Player with Graphical Output Displays
Post by: SierraKen on November 03, 2019, 06:51:29 pm
That's really good and tightly made. But I don't have the experience with SUBs to implement my displays on your new ones. I do see that your loop in the visual sub keeps going pretty much the same time as your wav sub does. Maybe if I played around with it enough I could figure out how to add to it, but I think I'm just going to leave it as it is so people can have a choice on what to do with these examples. Thanks your help.
Title: Re: WAV Player with Graphical Output Displays
Post by: Lucky_Strikez on November 07, 2019, 04:25:45 pm
That's awesome!
Title: Re: WAV Player with Graphical Output Displays
Post by: Petr on November 08, 2019, 12:07:42 pm
Small upgrade, which show you how to add next visualisations:

Code: QB64: [Select]
  1. SCREEN _NEWIMAGE(800, 600, 256)
  2.  
  3. REDIM SHARED LeftCurve(799) AS INTEGER
  4. REDIM SHARED RightCurve(799) AS INTEGER
  5. DIM SHARED Angle1, Angle2
  6.  
  7. wav "w.wav" 'insert uncompressed wav audio filename here
  8.  
  9. SUB wav (file$)
  10.     TYPE head
  11.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  12.         size AS LONG '              4 bytes  (?E??)
  13.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  14.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  15.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  16.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  17.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  18.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  19.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  20.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  21.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  22.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  23.     END TYPE '                     40 bytes  total
  24.     DIM H AS head
  25.  
  26.  
  27.  
  28.     ch = FREEFILE
  29.  
  30.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  31.     GET #ch, , H
  32.  
  33.     block = H.Block
  34.     RATE = H.rate
  35.     chan = H.channels
  36.     bits = H.Bits
  37.  
  38.  
  39.     DO WHILE NOT EOF(ch)
  40.  
  41.         IF bits = 16 AND chan = 2 THEN
  42.             REDIM lefi AS INTEGER, righi AS INTEGER
  43.             GET #ch, , lefi
  44.             GET #ch, , righi
  45.             Lef = lefi / RATE
  46.             righ = righi / RATE
  47.         END IF
  48.  
  49.         IF bits = 16 AND chan = 1 THEN
  50.             REDIM leftMono AS INTEGER
  51.             GET #ch, , leftMono
  52.             Lef = leftMono / RATE
  53.             righ = leftMono / RATE
  54.         END IF
  55.  
  56.         IF bits = 8 AND chan = 2 THEN
  57.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  58.             GET #ch, , lleft8
  59.             GET #ch, , rright8
  60.             Lef = lleft8 / 256
  61.             righ = rright8 / 256
  62.         END IF
  63.  
  64.         IF bits = 8 AND chan = 1 THEN
  65.             REDIM mono8 AS _UNSIGNED _BYTE
  66.             GET #ch, , mono8
  67.             Lef = mono8 / 256
  68.             righ = Lef
  69.         END IF
  70.  
  71.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  72.         FOR plll = 1 TO frekvence / RATE
  73.             _SNDRAW Lef, righ
  74.         NEXT plll
  75.  
  76.         DO WHILE _SNDRAWLEN > 0: LOOP: REM By commenting this row you DAMAGE SOUND / VIDEO synchronizing. TRY IT.
  77.  
  78.         '----------------------------------------
  79.         IF _KEYHIT = 32 THEN eff = eff + 1: IF eff > 2 THEN eff = 0
  80.  
  81.  
  82.  
  83.         Sample = Sample + 1
  84.         IF Sample > 799 THEN
  85.             Visual eff
  86.             REDIM LeftCurve(799) AS INTEGER
  87.             REDIM RightCurve(799) AS INTEGER
  88.             Sample = 0
  89.         END IF
  90.         LeftCurve(Sample) = 300 + Lef * 300
  91.         RightCurve(Sample) = 300 + righ * 300
  92.         '---------------------------------------
  93.  
  94.     LOOP
  95.     CLOSE ch
  97.  
  98. SUB Visual (EffectNr)
  99.  
  100.     CLS
  101.     SELECT CASE EffectNr
  102.         CASE 0
  103.             _AUTODISPLAY
  104.             FOR x = 0 TO 798 STEP 1
  105.                 LINE (x, LeftCurve(x))-(x + 1, LeftCurve(x + 1)), 14
  106.                 LINE (x, RightCurve(x))-(x + 1, RightCurve(x + 1)), 15
  107.             NEXT
  108.  
  109.         CASE 1 'do circle.
  110.             _AUTODISPLAY
  111.             Angle1 = Angle1 + .01
  112.             Angle2 = Angle2 - .01
  113.             STP = _PI(2) / 800
  114.             FOR C = 0 TO _PI(2) - STP STEP STP
  115.                 X1 = 400 + SIN(C + Angle1) * LeftCurve(i) / 2
  116.                 X2 = 400 + SIN(C + STP + Angle1) * LeftCurve(i + 1) / 2
  117.                 Y1 = 300 + COS(C + Angle1) * LeftCurve(i) / 2
  118.                 Y2 = 300 + COS(C + STP + Angle1) * LeftCurve(i + 1) / 2
  119.                 IF ox1 = 0 THEN ox1 = X1: oy1 = Y1
  120.                 LINE (X1, Y1)-(X2, Y2), 14
  121.  
  122.                 X3 = 400 + SIN(C + Angle2) * RightCurve(i) / 3
  123.                 X4 = 400 + SIN(C + STP + Angle2) * RightCurve(i + 1) / 3
  124.                 Y3 = 300 + COS(C + Angle2) * RightCurve(i) / 3
  125.                 Y4 = 300 + COS(C + STP + Angle2) * RightCurve(i + 1) / 3
  126.                 IF ox3 = 0 THEN ox3 = X3: oy3 = Y3
  127.                 LINE (X3, Y3)-(X4, Y4), 15
  128.  
  129.                 i = i + 1
  130.             NEXT
  131.             LINE (X2, Y2)-(ox1, oy1), 14: ox1 = 0
  132.             LINE (X4, Y4)-(ox3, oy3), 15: ox3 = 0
  133.  
  134.         CASE 2 'small modification CASE 1
  135.             STP = _PI(2) / 800
  136.             Angle1 = Angle1 + .01
  137.             Angle2 = Angle2 - .01
  138.             FOR C = 0 TO _PI(2) - STP STEP STP
  139.                 X1 = 150 + SIN(C + Angle1) * LeftCurve(i) / 3
  140.                 Y1 = 300 + COS(C + Angle1) * LeftCurve(i) / 3
  141.                 X2 = 650 + SIN(C + Angle2) * RightCurve(i) / 3
  142.                 Y2 = 300 + COS(C + Angle2) * RightCurve(i) / 3
  143.  
  144.                 LINE (X2, Y2)-(650, 300), 14
  145.                 LINE (X1, Y1)-(150, 300), 15
  146.                 i = i + 1
  147.             NEXT
  148.             _DISPLAY
  149.     END SELECT
  151.  

All values, which you need are in SHARED arrays LeftCurve and RightCurve. Both are from 0 to 799. Use spaceboard for switching visualisations.

For testing it, i recommend SPEEDCORE, or HARDCORE music style :-)
Title: Re: WAV Player with Graphical Output Displays
Post by: SierraKen on November 08, 2019, 02:14:04 pm
I added a couple of visuals to your new one Petr. :) Thanks!

Code: QB64: [Select]
  1. SCREEN _NEWIMAGE(800, 600, 256)
  2.  
  3. REDIM SHARED LeftCurve(799) AS INTEGER
  4. REDIM SHARED RightCurve(799) AS INTEGER
  5. DIM SHARED Angle1, Angle2
  6.  
  7. wav "Delight.wav" 'insert uncompressed wav audio filename here
  8.  
  9. SUB wav (file$)
  10.     TYPE head
  11.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  12.         size AS LONG '              4 bytes  (?E??)
  13.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  14.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  15.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  16.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  17.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  18.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  19.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  20.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  21.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  22.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  23.     END TYPE '                     40 bytes  total
  24.     DIM H AS head
  25.  
  26.  
  27.  
  28.     ch = FREEFILE
  29.  
  30.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  31.     GET #ch, , H
  32.  
  33.     block = H.Block
  34.     RATE = H.rate
  35.     chan = H.channels
  36.     bits = H.Bits
  37.  
  38.  
  39.     DO WHILE NOT EOF(ch)
  40.  
  41.         IF bits = 16 AND chan = 2 THEN
  42.             REDIM lefi AS INTEGER, righi AS INTEGER
  43.             GET #ch, , lefi
  44.             GET #ch, , righi
  45.             Lef = lefi / RATE
  46.             righ = righi / RATE
  47.         END IF
  48.  
  49.         IF bits = 16 AND chan = 1 THEN
  50.             REDIM leftMono AS INTEGER
  51.             GET #ch, , leftMono
  52.             Lef = leftMono / RATE
  53.             righ = leftMono / RATE
  54.         END IF
  55.  
  56.         IF bits = 8 AND chan = 2 THEN
  57.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  58.             GET #ch, , lleft8
  59.             GET #ch, , rright8
  60.             Lef = lleft8 / 256
  61.             righ = rright8 / 256
  62.         END IF
  63.  
  64.         IF bits = 8 AND chan = 1 THEN
  65.             REDIM mono8 AS _UNSIGNED _BYTE
  66.             GET #ch, , mono8
  67.             Lef = mono8 / 256
  68.             righ = Lef
  69.         END IF
  70.  
  71.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  72.         FOR plll = 1 TO frekvence / RATE
  73.             _SNDRAW Lef, righ
  74.         NEXT plll
  75.  
  76.         DO WHILE _SNDRAWLEN > 0: LOOP: REM By commenting this row you DAMAGE SOUND / VIDEO synchronizing. TRY IT.
  77.  
  78.         '----------------------------------------
  79.         IF _KEYHIT = 32 THEN eff = eff + 1: IF eff > 6 THEN eff = 0
  80.  
  81.  
  82.  
  83.         Sample = Sample + 1
  84.         IF Sample > 799 THEN
  85.             Visual eff
  86.             REDIM LeftCurve(799) AS INTEGER
  87.             REDIM RightCurve(799) AS INTEGER
  88.             Sample = 0
  89.         END IF
  90.         LeftCurve(Sample) = 300 + Lef * 300
  91.         RightCurve(Sample) = 300 + righ * 300
  92.         '---------------------------------------
  93.  
  94.     LOOP
  95.     CLOSE ch
  97.  
  98. SUB Visual (EffectNr)
  99.  
  100.     CLS
  101.     SELECT CASE EffectNr
  102.         CASE 0
  103.             _AUTODISPLAY
  104.             FOR x = 0 TO 798 STEP 1
  105.                 LINE (x, LeftCurve(x))-(x + 1, LeftCurve(x + 1)), 14
  106.                 LINE (x, RightCurve(x))-(x + 1, RightCurve(x + 1)), 15
  107.             NEXT
  108.  
  109.         CASE 1 'do circle.
  110.             _AUTODISPLAY
  111.             Angle1 = Angle1 + .01
  112.             Angle2 = Angle2 - .01
  113.             STP = _PI(2) / 800
  114.             FOR C = 0 TO _PI(2) - STP STEP STP
  115.                 X1 = 400 + SIN(C + Angle1) * LeftCurve(i) / 2
  116.                 X2 = 400 + SIN(C + STP + Angle1) * LeftCurve(i + 1) / 2
  117.                 Y1 = 300 + COS(C + Angle1) * LeftCurve(i) / 2
  118.                 Y2 = 300 + COS(C + STP + Angle1) * LeftCurve(i + 1) / 2
  119.                 IF ox1 = 0 THEN ox1 = X1: oy1 = Y1
  120.                 LINE (X1, Y1)-(X2, Y2), 14
  121.  
  122.                 X3 = 400 + SIN(C + Angle2) * RightCurve(i) / 3
  123.                 X4 = 400 + SIN(C + STP + Angle2) * RightCurve(i + 1) / 3
  124.                 Y3 = 300 + COS(C + Angle2) * RightCurve(i) / 3
  125.                 Y4 = 300 + COS(C + STP + Angle2) * RightCurve(i + 1) / 3
  126.                 IF ox3 = 0 THEN ox3 = X3: oy3 = Y3
  127.                 LINE (X3, Y3)-(X4, Y4), 15
  128.  
  129.                 i = i + 1
  130.             NEXT
  131.             LINE (X2, Y2)-(ox1, oy1), 14: ox1 = 0
  132.             LINE (X4, Y4)-(ox3, oy3), 15: ox3 = 0
  133.  
  134.         CASE 2 'small modification CASE 1
  135.             STP = _PI(2) / 800
  136.             Angle1 = Angle1 + .01
  137.             Angle2 = Angle2 - .01
  138.             FOR C = 0 TO _PI(2) - STP STEP STP
  139.                 X1 = 150 + SIN(C + Angle1) * LeftCurve(i) / 3
  140.                 Y1 = 300 + COS(C + Angle1) * LeftCurve(i) / 3
  141.                 X2 = 650 + SIN(C + Angle2) * RightCurve(i) / 3
  142.                 Y2 = 300 + COS(C + Angle2) * RightCurve(i) / 3
  143.  
  144.                 LINE (X2, Y2)-(650, 300), 14
  145.                 LINE (X1, Y1)-(150, 300), 15
  146.                 i = i + 1
  147.             NEXT
  148.  
  149.         CASE 3
  150.             LINE (0, 0)-(800, 450), _RGBA(0, 0, 0, 30), BF
  151.             CIRCLE (200, 200), 182, 25
  152.             CIRCLE (600, 200), 182, 25
  153.             X1 = LeftCurve(i)
  154.             p = X1 * 5
  155.             sec = (p * .6) + seconds
  156.             seconds = sec
  157.             IF seconds > 359 THEN seconds2 = 0
  158.             seconds = seconds + 1
  159.             s = (60 - seconds) * 6 + 90
  160.             xxx = INT(SIN(s / 90 * _PI) * 180) + 200
  161.             yyy = INT(COS(s / 90 * _PI) * 180) + 200
  162.             LINE (200, 200)-(xxx, yyy), 14
  163.             X2 = RightCurve(i)
  164.             p2 = X2 * 5
  165.             sec2 = (p2 * .6) + seconds2
  166.             seconds2 = sec2
  167.             IF seconds2 > 359 THEN seconds = 0
  168.             seconds2 = seconds2 + 1
  169.             s2 = (60 - seconds2) * 6 + 90
  170.             xxx2 = INT(SIN(s2 / 90 * _PI) * 180) + 600
  171.             yyy2 = INT(COS(s2 / 90 * _PI) * 180) + 200
  172.             LINE (600, 200)-(xxx2, yyy2), 3
  173.  
  174.  
  175.         CASE 4
  176.  
  177.             FOR x = 0 TO 798 STEP 1
  178.                 LINE (x, LeftCurve(x))-(x + 1, LeftCurve(x + 1) * 1.25), 14
  179.                 LINE (x, RightCurve(x))-(x + 1, RightCurve(x + 1) * 1.25), 15
  180.             NEXT
  181.  
  182.         CASE 5
  183.             FOR x = 0 TO 798 STEP 1
  184.                 LINE (LeftCurve(x), x)-(LeftCurve(x + 1) * 1.25, x + 1), 14
  185.                 LINE (RightCurve(x), x)-(RightCurve(x + 1) * 1.25, x + 1), 15
  186.             NEXT
  187.         CASE 6
  188.             xx = LeftCurve(x)
  189.             yy = LeftCurve(x)
  190.             xx2 = RightCurve(x) + 200
  191.             yy2 = RightCurve(x)
  192.             CIRCLE (xx, yy), LeftCurve(x) / 10, 14
  193.             PAINT (xx, yy), 14
  194.             CIRCLE (xx2, yy2), RightCurve(x) / 10, 15
  195.             PAINT (xx2, yy2), 15
  196.             _DISPLAY
  197.     END SELECT
  199.  
Text Only | Text with Attachments