Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SierraKen on October 31, 2019, 10:35:27 pm

Title: Sound Question
Post by: SierraKen on October 31, 2019, 10:35:27 pm
I'm 99% sure this is impossible in QB64, but is there a way to make a graphical display per ms of sound output? I'm talking about the same display some sound programs have like the old Winamp or others that show lines going up and down showing spikes of music volume and/or treble and bass output amounts. I looked into this deeply a few months ago but couldn't find this on the QB64.org Wiki page. I think all they have is the simple way to load, play, stop, FF, rewind, and pause. I started on a music player once that did these things but gave up because there's just so many better programs out there. I remember someone posting their sound player on my forum thread about it. I'm just wondering if there can be that graphical output. Thank you.
I wonder if a PORT command would work somehow? Although I do use a USB sound card.
Title: Re: Sound Question
Post by: SMcNeill on October 31, 2019, 11:32:06 pm
Petr has worked several programs which do this.  If you search the forums, you can probably find some nice examples of his stuff floating around a few of them.
Title: Re: Sound Question
Post by: SierraKen on November 01, 2019, 01:37:56 am
Thanks but I couldn't find it. I think I've scoured the entire Google database just about as well. lol I've also tried _MEM with _MEMGET using the Wiki examples for memory blocks, but I'm guessing it doesn't use those addresses for sound. I also looked at the old fashioned way with OUT and INP but QB64 only uses INP for 2 addresses which I don't believe are sound ports. My USB sound card probably wouldn't use that anyway.
Petr does any of this sound familiar? Any help is always appreciated.
Title: Re: Sound Question
Post by: Petr on November 01, 2019, 07:05:25 am
Hi SierraKen,
You can program the visualization of the sound with QB64. For the function of the program I highly recommend first to write a program that without visualization plays the sound in uncompressed WAV format. This music format is very easy to read and play, unlike compressed MP3 music for example. (Playing WAV is as easy as changing a bulb in a chandelier, playing MP3 is fundamentally, much more complicated.)
For visualization, you need detailed knowledge of the internal structure of the WAV file and the _SNDRAW, _SNDRAWLEN commands. Nothing more. But, at the outset, I have two important things to point out to you. First: There is an unknown, uncorrected bug that causes SNDRAW to play very strange stereo, rather mono sound, and that SNDRAW contains an internal buffer that you have to watch for audio and video synchronization, and that is not easy if you want precise visualization . If you look at my YouTube channel, there are some visuals written in QB64.
Another thing to note before writing a visualization is that the 16-bit stereo record contains 44100 samples (numbers). If you write the program incorrectly and want to display each sample, then the program will hang. It is necessary to take the mathematical average for the time period and use it for visualization.
To load a WAV music file, I recommend wikipedia to find the internal structure of the WAV file (it's not complicated, really) and then you'll read it using the GET command.

I also wrote MP3 playback, but I used a third-party decoder that can save MP3 to RAW format. The RAW format is the same as the WAV format, but without the file header, which is absolutely essential for proper file content playback. This program works only with some MP3 formats, it decodes the MP3 header, which is written so that individual bits of specific bytes carry the necessary information. MP3 is a compression format, so even the header is written in the smallest possible way. The header of the program must be read to know how the content in the RAW file is decompressed (is it mono or stereo sound ?, is it 8 bit, 16 bit, 24 bit sound?) Each such file is read differently, according to this information. After decoding, playback is the same as WAV format.

Unfortunately, there is no function in QB64 that allows direct access to music samples that are sent to the sound card. MEM commands are used only for graphical and array operations, they cannot be used to obtain RAW audio data, so to visualize you need this path to read data from a file + or write your own audio decoder. Apparently this is because QB64 uses third-party music decoders and does not allow licenses. Or, no one thought anyone wanted access to RAW audio data.

This is my audio PLAYER for WAV files WITHOUT visualization:

Code: QB64: [Select]
  1. wav "7.wav" 'insert uncompressed wav audio filename here
  2.  
  3. SUB wav (file$)
  4.     TYPE head
  5.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  6.         size AS LONG '              4 bytes  (?E??)
  7.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  8.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  9.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  10.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  11.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  12.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  13.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  14.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  15.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  16.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  17.     END TYPE '                     40 bytes  total
  18.     DIM H AS head
  19.     ch = FREEFILE
  20.  
  21.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  22.     GET #ch, , H
  23.  
  24.     block = H.Block
  25.     RATE = H.rate
  26.     chan = H.channels
  27.     bits = H.Bits
  28.  
  29.     DO WHILE NOT EOF(ch)
  30.         IF bits = 16 AND chan = 2 THEN
  31.             REDIM lefi AS INTEGER, righi AS INTEGER
  32.             GET #ch, , lefi
  33.             GET #ch, , righi
  34.             lef = lefi / RATE
  35.             righ = righi / RATE
  36.         END IF
  37.  
  38.         IF bits = 16 AND chan = 1 THEN
  39.             REDIM leftMono AS INTEGER
  40.             GET #ch, , leftMono
  41.             lef = leftMono / RATE
  42.             righ = leftMono / RATE
  43.         END IF
  44.  
  45.         IF bits = 8 AND chan = 2 THEN
  46.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  47.             GET #ch, , lleft8
  48.             GET #ch, , rright8
  49.             lef = lleft8 / 256
  50.             righ = rright8 / 256
  51.         END IF
  52.  
  53.         IF bits = 8 AND chan = 1 THEN
  54.             REDIM mono8 AS _UNSIGNED _BYTE
  55.             GET #ch, , mono8
  56.             lef = mono8 / 256
  57.             righ = lef
  58.         END IF
  59.  
  60.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  61.         FOR plll = 1 TO frekvence / RATE
  62.             _SNDRAW lef, righ
  63.         NEXT plll
  64.  
  65.         DO WHILE _SNDRAWLEN > 0: LOOP: REM comment this
  66.     LOOP
  67.     CLOSE ch
  69.  


Also see here: https://www.qb64.org/forum/index.php?topic=1399.msg105829#msg105829
Title: Re: Sound Question
Post by: SierraKen on November 01, 2019, 07:59:06 pm
Thanks Petr. But I am brand new with the GET command and I tried your WAV program, which works great by the way, but not knowing which variable to use or how to use the GET command, I just tried a bunch of things you had on there but couldn't get a variable that changed as the song went along. I also tried Wikipedia and other website about the .WAV file structure which is interesting, but without knowing how to use GET and what code to use, I'm at a loss. But it sure interests me a lot. It might be over my head, especially if I need to know what things to find within the .WAV file that I can't really see right now. I appreciate your help.
Title: Re: Sound Question
Post by: Petr on November 02, 2019, 04:33:39 am
Hi SierraKen. For drawing music curve use my source code and variables LEF and RIGH. This are sound values read from WAV file, always in range -1 to 1 (and -1 to 1 is also valid value for _SNDRAW). You can study my code, which show you how GET works, program read music samples from WAV so as is writed now.

I add small upgraded source code, now with easy visualisation. Do some experiments with it :)

Code: QB64: [Select]
  1. SCREEN _NEWIMAGE(800, 600, 256)
  2.  
  3. wav "7.wav" 'insert uncompressed wav audio filename here
  4.  
  5. SUB wav (file$)
  6.     TYPE head
  7.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  8.         size AS LONG '              4 bytes  (?E??)
  9.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  10.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  11.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  12.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  13.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  14.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  15.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  16.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  17.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  18.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  19.     END TYPE '                     40 bytes  total
  20.     DIM H AS head
  21.     ch = FREEFILE
  22.  
  23.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  24.     GET #ch, , H
  25.  
  26.     block = H.Block
  27.     RATE = H.rate
  28.     chan = H.channels
  29.     bits = H.Bits
  30.  
  31.  
  32.     DO WHILE NOT EOF(ch)
  33.  
  34.         vz = 44100 / 80
  35.         IF (SEEK(ch) - 40) MOD vz = 0 THEN
  36.             visual lefVis / vz, righVis / vz
  37.             lefVis = 0
  38.             righVis = 0
  39.         END IF
  40.         lefVis = lefVis + ABS(lef)
  41.         righVis = righVis + ABS(righ)
  42.  
  43.  
  44.  
  45.         IF bits = 16 AND chan = 2 THEN
  46.             REDIM lefi AS INTEGER, righi AS INTEGER
  47.             GET #ch, , lefi
  48.             GET #ch, , righi
  49.             lef = lefi / RATE
  50.             righ = righi / RATE
  51.         END IF
  52.  
  53.         IF bits = 16 AND chan = 1 THEN
  54.             REDIM leftMono AS INTEGER
  55.             GET #ch, , leftMono
  56.             lef = leftMono / RATE
  57.             righ = leftMono / RATE
  58.         END IF
  59.  
  60.         IF bits = 8 AND chan = 2 THEN
  61.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  62.             GET #ch, , lleft8
  63.             GET #ch, , rright8
  64.             lef = lleft8 / 256
  65.             righ = rright8 / 256
  66.         END IF
  67.  
  68.         IF bits = 8 AND chan = 1 THEN
  69.             REDIM mono8 AS _UNSIGNED _BYTE
  70.             GET #ch, , mono8
  71.             lef = mono8 / 256
  72.             righ = lef
  73.         END IF
  74.  
  75.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  76.         FOR plll = 1 TO frekvence / RATE
  77.             _SNDRAW lef, righ
  78.         NEXT plll
  79.  
  80.         DO WHILE _SNDRAWLEN > 0: LOOP: REM By commenting this row you DAMAGE SOUND / VIDEO synchronizing. TRY IT.
  81.  
  82.  
  83.     LOOP
  84.     CLOSE ch
  86.  
  87. SUB visual (lef, righ)
  88.     SHARED x, oldx1, oldx2
  89.     STP = 5 ' TRY rewriting STP value to other
  90.     x1 = lef * 200
  91.     x2 = righ * 200
  92.  
  93.     IF oldx1 THEN
  94.         LINE (x, 0)-(x + STP, 400), 0, BF
  95.         LINE (x, 200 - x1)-(x - STP, 200 - oldx1), 15
  96.  
  97.         LINE (x, 100 - x2)-(x - STP, 100 - oldx2), 14
  98.  
  99.     END IF
  100.     oldx1 = x1
  101.     oldx2 = x2
  102.     x = x + STP: IF x > _WIDTH THEN x = 0
  103.  
  104.     LINE (100, 600)-(300, 300), 0, BF
  105.     LINE (100, 600)-(300, 600 - 500 * lef), 14, BF
  106.  
  107.     LINE (700, 600)-(500, 300), 0, BF
  108.     LINE (700, 600)-(500, 600 - 500 * righ), 3, BF
  110.  

Title: Re: Sound Question
Post by: SierraKen on November 02, 2019, 05:44:40 pm
That is so awesome! Thanks Petr! I added 2 displays as well as yours and changed the way your line goes over the old line, I did a CLS as soon as it gets to the end of the screen.
Press the Space Bar to switch between displays.  :)

Code: QB64: [Select]
  1. 'Almost all of this was made by Petr from the QB64.org forum.
  2. 'Some of the displays added by SierraKen (Ken G.).
  3. _TITLE "WAV Music Player - Space Bar Changes Display When Playing. Esc to Quit."
  4. SCREEN _NEWIMAGE(800, 600, 256)
  6.     CLS
  7.     PRINT: PRINT: PRINT
  8.     INPUT "Type .WAV music filename here or only Enter to quit:", nm$
  9.     IF nm$ = "" THEN END
  10.     CLS
  11.     wav nm$ 'insert uncompressed wav audio filename here
  13. SUB wav (file$)
  14.     TYPE head
  15.         chunk AS STRING * 4 '       4 bytes  (RIFF)
  16.         size AS LONG '              4 bytes  (?E??)
  17.         fomat AS STRING * 4 '       4 bytes  (WAVE)
  18.         sub1 AS STRING * 4 '        4 bytes  (fmt )
  19.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  20.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  21.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  22.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  23.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  24.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  25.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  26.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  27.     END TYPE '                     40 bytes  total
  28.     DIM H AS head
  29.     ch = FREEFILE
  30.  
  31.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
  32.     GET #ch, , H
  33.  
  34.     block = H.Block
  35.     RATE = H.rate
  36.     chan = H.channels
  37.     bits = H.Bits
  38.  
  39.  
  40.     DO WHILE NOT EOF(ch)
  41.  
  42.         vz = 44100 / 80
  43.         IF (SEEK(ch) - 40) MOD vz = 0 THEN
  44.             visual lefVis / vz, righVis / vz
  45.             lefVis = 0
  46.             righVis = 0
  47.         END IF
  48.         lefVis = lefVis + ABS(lef)
  49.         righVis = righVis + ABS(righ)
  50.  
  51.  
  52.  
  53.         IF bits = 16 AND chan = 2 THEN
  54.             REDIM lefi AS INTEGER, righi AS INTEGER
  55.             GET #ch, , lefi
  56.             GET #ch, , righi
  57.             lef = lefi / RATE
  58.             righ = righi / RATE
  59.         END IF
  60.  
  61.         IF bits = 16 AND chan = 1 THEN
  62.             REDIM leftMono AS INTEGER
  63.             GET #ch, , leftMono
  64.             lef = leftMono / RATE
  65.             righ = leftMono / RATE
  66.         END IF
  67.  
  68.         IF bits = 8 AND chan = 2 THEN
  69.             REDIM lleft8 AS _UNSIGNED _BYTE, rright8 AS _UNSIGNED _BYTE
  70.             GET #ch, , lleft8
  71.             GET #ch, , rright8
  72.             lef = lleft8 / 256
  73.             righ = rright8 / 256
  74.         END IF
  75.  
  76.         IF bits = 8 AND chan = 1 THEN
  77.             REDIM mono8 AS _UNSIGNED _BYTE
  78.             GET #ch, , mono8
  79.             lef = mono8 / 256
  80.             righ = lef
  81.         END IF
  82.  
  83.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
  84.         FOR plll = 1 TO frekvence / RATE
  85.             _SNDRAW lef, righ
  86.         NEXT plll
  87.  
  88.         DO WHILE _SNDRAWLEN > 0: LOOP: REM By commenting this row you DAMAGE SOUND / VIDEO synchronizing. TRY IT.
  89.  
  90.  
  91.     LOOP
  92.     CLOSE ch
  94.  
  95. SUB visual (lef, righ)
  96.     SHARED x, oldx1, oldx2, disp, tt
  97.     STP = 5 ' TRY rewriting STP value to other
  98.     x1 = lef * 200
  99.     x2 = righ * 200
  100.     a$ = INKEY$
  101.     IF a$ = " " THEN CLS: disp = disp + 1: tt = 0
  102.     IF a$ = CHR$(27) THEN END
  103.     IF disp > 2 THEN disp = 0
  104.  
  105.     IF oldx1 AND disp = 2 THEN
  106.         tt = tt + 1
  107.         IF tt < 5 THEN GOTO skip:
  108.         tt = 0
  109.         c1 = RND * 255
  110.         c2 = RND * 255
  111.         c3 = RND * 255
  112.         xx = RND * 800
  113.         yy = RND * 600
  114.         LINE (xx, yy)-((xx + x1) * 2, (yy + x2) * 2), _RGB32(c1, c2, c3), BF
  115.         skip:
  116.     END IF
  117.     IF oldx1 AND disp = 1 THEN
  118.         tt = tt + 1
  119.         IF tt < 5 THEN GOTO skip2:
  120.         tt = 0
  121.         c1 = RND * 255
  122.         c2 = RND * 255
  123.         c3 = RND * 255
  124.         xx = RND * 800
  125.         yy = RND * 600
  126.         CIRCLE (xx, yy), x1 * 2, _RGB32(c1, c2, c3)
  127.         PAINT (xx, yy), _RGB32(c1, c2, c3)
  128.         skip2:
  129.     END IF
  130.     IF oldx1 AND disp = 0 THEN
  131.         IF x = 800 THEN CLS: x = 0
  132.         LINE (x, 0)-(x + STP, 400), 0, BF
  133.         LINE (x, 200 - x1)-(x - STP, 200 - oldx1), 15
  134.  
  135.         LINE (x, 100 - x2)-(x - STP, 100 - oldx2), 14
  136.     END IF
  137.  
  138.     oldx1 = x1
  139.     oldx2 = x2
  140.     x = x + STP: IF x > _WIDTH THEN x = 0
  141.  
  142.     LINE (100, 600)-(300, 400), 0, BF
  143.     LINE (100, 600)-(300, 600 - 500 * lef), 14, BF
  144.  
  145.     LINE (700, 600)-(500, 400), 0, BF
  146.     LINE (700, 600)-(500, 600 - 500 * righ), 3, BF
  148.  
Title: Re: Sound Question
Post by: SierraKen on November 03, 2019, 01:03:16 am
OK I got 7 displays on it now. I'm going to make a new thread so people can see this better and will post it there.
Text Only | Text with Attachments