QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Cobalt on October 09, 2019, 01:28:34 pm

Title: Need some help with player movement..
Post by: Cobalt on October 09, 2019, 01:28:34 pm

I have a tile based game I'm playing around with, but am having some issues getting the player to move correctly.
The tiles and character are 32pix square.

Player can move in the 4 main directions.

There is a slight (.1 sec) delay before the character starts to move, that way the player can look in a direction without moving in that direction right away.

the character moves by pixels (so moves 32 pixels per tile)

the character finishes moving even if direction key is no longer pressed, so if the player is halfway through a tile the animation needs to finish them into the next tile before stopping.

I can manage the delay and direction but when(IF) the character starts moving they don't stop until the array errors out. I've tried using TIMERs, I've try using flags, its just not working for me. Can't shut down the whole execution to move the player cause there are other NPCs that need to be able to move in time with the player. so this has to happen 'in flow' EX;

Code: [Select]

Do
 control routine...
 if player moving then do frame of movement...
 if NPCs are moving then move NPCs a frame of movement....
 do other house keeping....
 build screen....
 display screen...
 delay...
Loop until quit
and execution needs to be constant.

I can get it to move by whole tiles, I just can't get the 32pixel walk to work. and I'm at my wits end with this. I really need help with the mechanics of that part, the controls, graphics, and final movement I can get, it is just that 1 phase that is not working.

Bplus, [banned user], Steve, you guys have any ideas?

Title: Re: Need some help with player movement..
Post by: Petr on October 09, 2019, 01:50:49 pm

Hi Cobalt. Is very hard to say, what is wrong without real source code. If your character step is 32 pixels, try use something as this:

Code: QB64: [Select]

1. SCREEN 13
2. character_position = 160
3.  
4. DO UNTIL i$ = CHR$(27)
5.     i$ = INKEY$
6.     IF i$ = "a" THEN char_step = 1
7.     IF i$ = "z" THEN char_step = -1
8.     IF i$ = "" THEN char_step = 0
9.  
10.     IF LEN(i$) THEN
11.         FOR move = 1 TO 32 'character size = 32 pixels
12.             character_position = character_position + char_step
13.             CLS
14.             LINE (character_position, 100)-(character_position + 32, 132), , B
15.             _DELAY .01
16.         NEXT
17.         i$ = ""
18.     END IF
19.  
20.  
21.     LINE (character_position, 100)-(character_position + 32, 132), , B
22. LOOP
23.  

OR maybe, if character start moving, then limit graphic shift with DO UNTIL move MOD 32 = 0 condition after first pixel increase or decrease.

Title: Re: Need some help with player movement..
Post by: bplus on October 09, 2019, 01:53:34 pm

Hi Cobalt,

I think I would set a target x, y for character movement to reach, when the character was within a limit of that target (using distance formula) I would snap the character image into the tile. You could even have code to check that character IS closing in on target and alert you if it weren't or just snap it in then.

Title: Re: Need some help with player movement..
Post by: Cobalt on October 09, 2019, 05:59:21 pm

Quote from: Petr on October 09, 2019, 01:50:49 pm

Hi Cobalt. Is very hard to say, what is wrong without real source code. If your character step is 32 pixels, try use something as this:

If you think the source would help, good luck!


my last incarnation of failure, attempting to use a TIMER to control the movement.

Title: Re: Need some help with player movement..
Post by: Petr on October 10, 2019, 05:38:25 am

Hi Cobalt, thank you, i try it.  Which IDE version you use? Unknown statement _SETBIT found on line 436.

Title: Re: Need some help with player movement..
Post by: Petr on October 10, 2019, 08:02:20 am

I commented on rows that use the command above. I'm confused by your colission function. I have never seen a similar example of using SELECT CASE. Are you really sure that the function returns the expected results? I prefer to use a two-dimensional array for this type of detection.

Code: QB64: [Select]

1. FOR T = 1 TO 34
2.     result = 0
3.     SELECT CASE T
4.         CASE 1, 2, 3, 5, 6, 19 TO 23, 27, 30, 32, 33, 34
5.             result = 1
6.     END SELECT
7.     PRINT "Value for T:"; T; "Result:"; result
8.     SLEEP
9. NEXT
10.  

Title: Re: Need some help with player movement..
Post by: TempodiBasic on October 10, 2019, 08:07:13 am

Hi Cobalt
I confirm the experience of Petr if I load your code into QB64.

about the issue please answer to these questions:

Quote

when(IF) the character starts moving they don't stop until the array errors out.

1. the sprite array for animation uses an index used also for the other events of the game ?

Quote

Can't shut down the whole execution to move the player cause there are other NPCs that need to be able to move in time with the player. so this has to happen 'in flow' E

2. Do NPCs use player's moves to do their move?

Quote

the character finishes moving even if direction key is no longer pressed, so if the player is halfway through a tile the animation needs to finish them into the next tile before stopping.

3. do you like to end move when character gains the end of the tile where it is now?

Quote

Do
 control routine...
 if player moving then do frame of movement...
 if NPCs are moving then move NPCs a frame of movement....
 do other house keeping....
 build screen....
 display screen...
 delay...
Loop until quit

4. How does control_routine pass the Inputs/commands to this general engine_Loop?


Here a clear semplification of example posted by Petr

Code: QB64: [Select]

1. SCREEN 13
2. character_position = 160
3. TileLimit = 30
4. DO UNTIL i$ = CHR$(27)
5.     i$ = INKEY$
6.     IF i$ = "a" THEN char_step = 1
7.     IF i$ = "z" THEN char_step = -1
8.     IF i$ = "" THEN char_step = 0
9.  
10.     IF LEN(i$) THEN
11.         FOR move = 1 TO 32 'character size = 32 pixels
12.             ' stopping if it reaches the limit of movement (border of tale or other kind of limit)
13.             IF character_position + char_step <> TileLimit THEN character_position = character_position + char_step
14.             CLS
15.             LINE (TileLimit, 0)-(TileLimit, 300), 14
16.             LINE (character_position, 100)-(character_position + 32, 132), , B
17.             _DELAY .01
18.         NEXT
19.         i$ = ""
20.     END IF
21.  
22.     LINE (TileLimit, 0)-(TileLimit, 300), 14
23.     LINE (character_position, 100)-(character_position + 32, 132), , B
24. LOOP
25.  
26.  

Title: Re: Need some help with player movement..
Post by: Petr on October 10, 2019, 08:17:34 am

Thank you, TempodiBasic. Better outputs are, if you replace on row 19  I$ = ""  to _KEYCLEAR  for case, if is key still pressed.

Title: Re: Need some help with player movement..
Post by: Cobalt on October 10, 2019, 10:39:44 am

Quote from: Petr on October 10, 2019, 05:38:25 am

Hi Cobalt, thank you, i try it.  Which IDE version you use? Unknown statement _SETBIT found on line 436.

this version:
https://www.qb64.org/forum/index.php?topic=1664.msg108951#msg108951

Quote from: Petr on October 10, 2019, 08:02:20 am

I commented on rows that use the command above. I'm confused by your colission function. I have never seen a similar example of using SELECT CASE. Are you really sure that the function returns the expected results? I prefer to use a two-dimensional array for this type of detection.

see lines 286-289, that is all debugging and represents those 4 '0's along the right hand of the screen. if the bottom number turns -1 its found a collision. Which uses an array(PLACE(27,45,45)) and checks which sprite is displayed for 'walkable' and 'not walkable'.

Quote from: TempodiBasic on October 10, 2019, 08:07:13 am

Hi Cobalt
I confirm the experience of Petr if I load your code into QB64.

about the issue please answer to these questions:
1. the sprite array for animation uses an index used also for the other events of the game ?

there are, simply enough, only 2 frames for each direction and the TIMER(T(0)) simply toggles the Frame%% value. It has no other barring on the program.
When I referred to 'animation' I was referring to the movement from one tile to another.

Quote from: TempodiBasic on October 10, 2019, 08:07:13 am

2. Do NPCs use player's moves to do their move?

They will use a mirror of the same routine. Just with the NPCs data set. With random chance to change direction and\or move.

Quote from: TempodiBasic on October 10, 2019, 08:07:13 am

3. do you like to end move when character gains the end of the tile where it is now?

Unless the player still has the key pressed (_KEYDOWN) for the current direction of movement then it needs to keep moving 'smoothly' without a jitter each time the player finishes onto a tile.

Quote from: TempodiBasic on October 10, 2019, 08:07:13 am

4. How does control_routine pass the Inputs/commands to this general engine_Loop?

In this incarnation of failure, it simply sets the direction the player is facing then turns on a TIMER. Which runs the MOVE_PLAYER routine. Which sets the Moving flag. I have used the Controls routine to return a flag value to have the routine move_player called from the main loop too, again failure.



What I am seeking help with is a way to finish a move onto the next tile when the player may stop pressing the direction key after starting the move. All my bag-o-tricks have failed so far.

Title: Re: Need some help with player movement..
Post by: bplus on October 10, 2019, 11:36:46 am

As you can see, the player acquires the target position no matter what speed it is going...

Code: QB64: [Select]

1. _TITLE "Aquiring Target Positions" 'for Colbalt 2019-10-10 B+
2. CONST xmax = 800, ymax = 600
3. SCREEN _NEWIMAGE(xmax, ymax, 32)
4. _SCREENMOVE 300, 40
5. TYPE xyType
6.     x AS INTEGER
7.     y AS INTEGER
8.     hit AS INTEGER
9. END TYPE
10. DIM SHARED targets(1 TO 100) AS xyType
11. FOR i = 1 TO 100
12.     targets(i).x = RND * xmax \ 1
13.     targets(i).y = RND * ymax \ 1
14. NEXT
15. DIM SHARED px, py, target, dwell
16. px = 400: py = 300: target = 1: dx = 5: dy = 5
17. WHILE _KEYDOWN(27) = 0
18.     update
19.     IF dwell THEN
20.         dwell = dwell - 1
21.     ELSE
22.         curDist = dist(px, py, targets(target).x, targets(target).y)
23.         IF dist(px + dx, py, targets(target).x, targets(target).y) < curDist THEN
24.             px = px + dx
25.         ELSEIF dist(px - dx, py, targets(target).x, targets(target).y) < curDist THEN
26.             px = px - dx
27.         ELSEIF dist(px, py + dy, targets(target).x, targets(target).y) < curDist THEN
28.             py = py + dy
29.         ELSEIF dist(px, py - dy, targets(target).x, targets(target).y) < curDist THEN
30.             py = py - dy
31.         ELSE
32.             'must be as close as we cane be so be there!
33.             px = targets(target).x: py = targets(target).y: dwell = 20
34.             'record the achievement
35.             targets(target).hit = -1
36.             'set next target
37.             target = target + 1: dx = dx + 1: dy = dy + 1
38.             IF target > 100 THEN update: PRINT "All Targets Hit!": END
39.         END IF
40.     END IF
41.     _DISPLAY
42.     _LIMIT 30
43. WEND
44.  
45. FUNCTION dist (x, y, x1, y1)
46.     dist = ((x - x1) ^ 2 + (y - y1) ^ 2) ^ .5
47. END FUNCTION
48.  
49. SUB drawTarget (x, y)
50.     FOR i = 0 TO 7
51.         IF (i \ 1) MOD 2 THEN CIRCLE (x, y), i, &HFFFFFFFF ELSE CIRCLE (x, y), i, &HFFFF0000
52.     NEXT
53. END SUB
54.  
55. SUB update
56.     CLS
57.     FOR i = 1 TO 100
58.         IF targets(i).hit = 0 THEN
59.             IF i <> target THEN
60.                 CIRCLE (targets(i).x, targets(i).y), 8, &HFFFFFF00
61.             ELSE
62.                 drawTarget targets(i).x, targets(i).y
63.             END IF
64.         END IF
65.     NEXT
66.     IF dwell THEN CIRCLE (targets(target - 1).x, targets(target - 1).y), 6, &HFFFFFF00
67.     LINE (px - 3, py - 3)-STEP(6, 6), &HFF0000FF, BF
68. END SUB
69.  

I added a dwell whenever a target has been hit.

Modified again to show that the square player image is precisely located correctly in place.

Title: Re: Need some help with player movement..
Post by: TempodiBasic on October 10, 2019, 01:35:11 pm

Hi Cobalt

so _SETBIT is one of your innovations for QB64
and I am fear that we must wait just some time before we can go on trying your code after downloading the new version of QB64 from github that has into it your innovations!

or in the while you can post a workaround for now until the gap is not covered.

Quote

syntax _SETBIT(VariableToset, parameter?%)

_SETBIT sets the high/low bit (or nibble) of a variable following the action activated by parameter?%

Parameter?% can have these values ?-?-?-?  or this range of values min??-max??

PS
looking at your static code (without possibility to run it for now)
this is my feedback

Code: QB64: [Select]

1.  SUB Move_Player ()
2.     IF P(0).Map >= 0 THEN X%% = P(0).MapX: Y%% = P(0).MapY ELSE X%% = P(0).WorldX: Y%% = P(0).WorldY
3.     SELECT CASE P(Who%%).Facing
4.         CASE DOWN
5.             BEEP
6.             IF Collision(0, X%%, Y%% + 1) = FALSE THEN
7.                 G.Moving = TRUE
8.                 P(0).MoveY = P(0).MoveY + 1   '<--- here you increase position of character on the world
9.                 IF P(0).MoveY >= 32 THEN   ' <--- here only if character has done 32 pixel steps you stop movement of character
10.                                  ' ^
11.                                  ' | so here  you must add the Flag to control the movement of your character following your will
12.                                  ' | with for example an ...OR FlagStop%% THEN
13.                     G.Moving = FALSE: TIMER(T(1)) OFF
14.                     IF P(0).Map >= 0 THEN
15.                         P(0).MapY = P(0).MapY + 1
16.                         P(0).MoveY = 0       ' if you like you can move this line where is ***
17.                     ELSE
18.                         P(0).WorldY = P(0).WorldY + 1
19.                         P(0).MoveY = 0       ' if you like you can move this line where is ***
20.                     END IF
21.                     Check_Location 0
22.                 END IF
23.                 '***
24.             ELSE
25.                 'play collision sound
26.                 Check_Location 0
27.             END IF
28.     END SELECT
29. END SUB
30. [code]
31.  
32.  

Title: Re: Need some help with player movement..
Post by: Cobalt on October 10, 2019, 09:07:20 pm

Quote from: bplus on October 10, 2019, 11:36:46 am

As you can see, the player acquires the target position no matter what speed it is going...
I added a dwell whenever a target has been hit.
Modified again to show that the square player image is precisely located correctly in place.

that may be a little outside the scope of this game,

without actually playing its hard to get the feel for the movement, but that is about how it should look.

Title: Re: Need some help with player movement..
Post by: bplus on October 10, 2019, 10:07:44 pm

So the player doesn't move inside the screen, the world moves around the player.

Code: QB64: [Select]

1. _TITLE "Walking between cells" 'for Colbalt 2019-10-10 B+
2. ' the map moves around the player in the center
3.  
4. CONST xmax = 801, ymax = 641
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 300, 40
7. RANDOMIZE TIMER
8. DIM SHARED mCols, mRows
9. mCols = 12: mRows = 10
10. DIM SHARED map(1 TO mCols, 1 TO mRows) AS INTEGER
11.  
12. FOR i = 1 TO 12 'landmarks
13.     rx = INT(RND * mCols) + 1: ry = INT(RND * mRows) + 1
14.     map(rx, ry) = INT(RND * 4) + 1
15.     PRINT rx, ry, map(rx, ry)
16. NEXT
17.  
18. pr = 10: pc = 12: xoff = 0: yoff = 0
19. WHILE _KEYDOWN(27) = 0
20.     IF txoff = 0 AND tyoff = 0 THEN 'we have finished moving and can take another keypress
21.         kh& = _KEYHIT
22.         SELECT CASE kh&
23.             CASE 18432 'up
24.                 IF pr - 1 >= 1 THEN
25.                     IF map(pc, pr - 1) = 0 THEN pr = pr - 1: txoff = 0: dx = 0: tyoff = 33: dy = 1
26.                 END IF
27.             CASE 19712 'right
28.                 IF pc + 1 <= mCols THEN 'make sure not past the array limit
29.                     IF map(pc + 1, pr) = 0 THEN pc = pc + 1: txoff = -33: dx = -1: tyoff = 0: dy = 0
30.                 END IF
31.             CASE 20480 'down
32.                 IF pr + 1 <= mRows THEN
33.                     IF map(pc, pr + 1) = 0 THEN pr = pr + 1: txoff = 0: dx = 0: tyoff = -33: dy = -1
34.                 END IF
35.             CASE 19200 'left
36.                 IF pc - 1 >= 1 THEN
37.                     IF map(pc - 1, pr) = 0 THEN pc = pc - 1: txoff = 33: dx = 1: tyoff = 0: dy = 0
38.                 END IF
39.         END SELECT
40.         _KEYCLEAR
41.     END IF
42.     txoff = txoff - dx: tyoff = tyoff - dy
43.     IF txoff = 0 THEN dx = 0
44.     IF tyoff = 0 THEN dy = 0
45.     xoff = xoff + dx: yoff = yoff + dy
46.     drawMap xoff, yoff
47.     _DISPLAY
48.     _LIMIT 30
49. WEND
50.  
51. SUB drawMap (xOff, yOff) 'x and y offset = 0
52.     CLS
53.     FOR y = 1 TO mRows
54.         FOR x = 1 TO mCols
55.             SELECT CASE map(x, y)
56.                 CASE 0: LINE (xOff + x * 32, yOff + y * 32)-STEP(32, 32), &HFF006000, BF
57.                 CASE 1: LINE (xOff + x * 32, yOff + y * 32)-STEP(32, 32), &HFF773300, BF
58.                 CASE 2: LINE (xOff + x * 32, yOff + y * 32)-STEP(32, 32), &HFF884422, BF
59.                 CASE 3: LINE (xOff + x * 32, yOff + y * 32)-STEP(32, 32), &HFF336600, BF
60.                 CASE 4: LINE (xOff + x * 32, yOff + y * 32)-STEP(32, 32), &HFF006644, BF
61.             END SELECT
62.         NEXT
63.     NEXT
64.     LINE (12 * 32, 10 * 32)-STEP(32, 32), &HFFFFFFFF, BF
65. END SUB
66.  

Dang RND * 4 \ 1 + 1 Does not give me integers from 1 to 4, it gives me integers 1 to 5?

Colbalt, without _KEYCLEAR the player (white box) walks in first arrow direction until border or obstacle, maybe the same problem you were having?

Title: Re: Need some help with player movement..
Post by: FellippeHeitor on October 11, 2019, 12:06:30 am

World moving around player example, something in there may be of use: https://www.qb64.org/forum/index.php?topic=93.msg501#msg501

Title: Re: Need some help with player movement..
Post by: TempodiBasic on October 11, 2019, 07:28:48 am

Hi Fellippe
I have forgotten your platform demo!

Thanks so I have played it again... Cool and fine parallax perspective!
  [ This attachment cannot be displayed inline in 'Print Page' view ]  
  [ This attachment cannot be displayed inline in 'Print Page' view ]  


@Cobalt
about

Quote

Quote from: TempodiBasic on Yesterday at 08:07:13 AM
4. How does control_routine pass the Inputs/commands to this general engine_Loop?
In this incarnation of failure, it simply sets the direction the player is facing then turns on a TIMER. Which runs the MOVE_PLAYER routine. Which sets the Moving flag. I have used the Controls routine to return a flag value to have the routine move_player called from the main loop too, again failure.

LOL yesterday I have tried to mod Petr's example using a TIMER (ON TIMER ...., TIMER ON, TIMER OFF, TIMER FREE) and so I have loosen my mind and meself into TIMER dimension.... :-)
 The use of a timer brings some collateral side effects!
The first that I found is how syncronize I/O and timer events.

Title: Re: Need some help with player movement..
Post by: _vince on October 11, 2019, 09:33:39 am

Quote from: TempodiBasic on October 10, 2019, 01:35:11 pm

so _SETBIT is one of your innovations for QB64
and I am fear that we must wait just some time before we can go on trying your code after downloading the new version of QB64 from github that has into it your innovations!

Why not make a SUB setbit? What are SUBs for anyway? I guess Cobalt is probably using C bit shifting operations but it can all be done in pure QB.

Title: Re: Need some help with player movement..
Post by: TempodiBasic on October 11, 2019, 03:22:43 pm

@Cobalt

I can confirm that the issue is the sincronization between main loop and timer's events!

Here the Petr's code example converted to use a ON TIMER.... after some attempts and a glass of beer I have understood that the difficult to pass variable SHARED to Timer subroutine is the frequency of the timer's events...

so I solve the question with code working... the key is the ratio between time interval of timer's event (in the example .3) and time of delaying the main loop (in the example .1)

Code: QB64: [Select]

1. CONST True = -1, False = NOT True
2. DIM SHARED character_position AS INTEGER, TileLimit AS INTEGER, char_Step AS INTEGER
3. DIM SHARED i AS STRING 'AS INTEGER
4.  
5. SCREEN 13
6. character_position = 160
7. TileLimit = 30
8.  
9.  
10. t0 = _FREETIMER
11. ON TIMER(t0, .3) Make_move ' time of event must be just a little more than delay in the main loop
12. TIMER(t0) ON
13.  
14. DO UNTIL i = CHR$(27)
15.     CLS
16.     LINE (TileLimit, 0)-(TileLimit, 300), 14
17.     LINE (character_position, 100)-(character_position + 32, 132), , B
18.     _KEYCLEAR ' to clear keyboard buffer
19.     i = "" ' to return in the WHILE WEND
20.     WHILE i = "" ' this focus on take input
21.         i = INKEY$
22.         char_Step = 0 ' no movement
23.         _LIMIT 50
24.     WEND
25.     IF i = "a" THEN char_Step = 1 ' movement to right
26.     IF i = "z" THEN char_Step = -1 'movement to left
27.     _DELAY .1 ' we need this to elaborate the input
28. LOOP
29. TIMER(t0) OFF
30. TIMER(t0) FREE
31. END
32.  
33. SUB Make_move
34.  
35.     IF LEN(i) THEN
36.         FOR Move = 1 TO 32 'character size = 32 pixels
37.             ' stopping if it reaches the limit of movement (border of tale or other kind of limit)
38.             IF character_position + char_Step <> TileLimit THEN character_position = character_position + char_Step
39.             CLS
40.             LINE (TileLimit, 0)-(TileLimit, 300), 14
41.             LINE (character_position, 100)-(character_position + 32, 132), , B
42.             _DELAY .01
43.         NEXT
44.     END IF
45. END SUB
46.  

Thanks to read

@ _Vince
I agree
it is a workaround.

Title: Re: Need some help with player movement..
Post by: Cobalt on October 11, 2019, 09:14:23 pm

Quote from: _vince on October 11, 2019, 09:33:39 am

Why not make a SUB setbit? What are SUBs for anyway? I guess Cobalt is probably using C bit shifting operations but it can all be done in pure QB.

I've a whole set of BIT handling routines on the platter, just can't get into Github to see about pushing them to QB64 yet.
just for ease of use and speed. but yes they can be reproduced in house too. Although I would rather put my effort elsewhere in a program.

Title: Re: Need some help with player movement..
Post by: Cobalt on October 11, 2019, 09:37:26 pm

Although thanks to your guys help, in giving me ideas and things to try I think I've finally got it!!! up way too late last night working it out, but it looks like it works, I've REMed the bithandling out for now if you guys want to try it, you'll need to Re-download the GAMEDATAV1b.dat  file cause I had to modify things in it. but you can roam MOST of the world until I get the entry code setup to enter caves, castles, and towns.


okay I lied, I simply deleted that routine for now. (removed stray _SETBIT)

Don't know why that was so hard for me to get the movement working, but

Thanks guys.

Title: Re: Need some help with player movement..
Post by: FellippeHeitor on October 11, 2019, 10:52:32 pm

Still a bunch of stray _SETBIT in this latest code block.

Title: Re: Need some help with player movement..
Post by: TempodiBasic on October 13, 2019, 06:40:53 am

yes _SETBIT showed at line 463 of code in QB64IDE

Title: Re: Need some help with player movement..
Post by: Cobalt on October 13, 2019, 12:20:43 pm

Quote from: FellippeHeitor on October 11, 2019, 10:52:32 pm

Still a bunch of stray _SETBIT in this latest code block.

Not sure I consider 1 a bunch?  If I'm holding 1 banana I don't think anybody is going to say  "look Cobalt is holding a bunch of bananas!"

the whole magic learning system is bit based. in reality though better than half of items in the game should be bit flag based.

Title: Re: Need some help with player movement..
Post by: FellippeHeitor on October 13, 2019, 05:58:02 pm

Point is: code still not runnable by everyone.

Title: Re: Need some help with player movement..
Post by: SMcNeill on October 13, 2019, 08:41:34 pm

Just swap in a function SetBit if you’re having issues:

FUNCTION SetBit (variable AS _INTEGER64, bit, toggle)
   b = bit - 1
   If toggle THEN
      SetBit = variable OR (2 ^ b)
   ELSE
      SetBit = variable AND NOT (2 ^ b)
   END IF
END FUNCTION

a = SetBit(a, 3, OFF) ‘Sets the third bit off
b = SetBit(b, 2, ON) ‘Sets the second bit on

Title: Re: Need some help with player movement..
Post by: FellippeHeitor on October 14, 2019, 02:36:07 am

Quote from: Cobalt on October 11, 2019, 09:37:26 pm

I've REMed the bithandling out for now if you guys want to try it

Point is: code shared by cobalt is not runnable as is. I’m not the one to adapt it.

Text Only | Text with Attachments