QB64.org Forum

Active Forums => Programs => Topic started by: TempodiBasic on September 27, 2019, 03:13:30 pm

Title: Multiple objects/entities in the program: 2 ways to manage it
Post by: TempodiBasic on September 27, 2019, 03:13:30 pm

Hi friends

to continue the discussion  about how controlling different objects/entities on the screen
https://www.qb64.org/forum/index.php?topic=1718.msg109801#msg109801 (https://www.qb64.org/forum/index.php?topic=1718.msg109801#msg109801)

here my little experience
in this first code posted there is a poor structured and centralized manager of I/O that sends command to the engine of output of the program activating the object selected by user input by keyboard or mouse.

Code: QB64: [Select]

1. _TITLE "multiple entities on the screen NOT overlapping"
2. 'this is a little example of the 1st different concepts to manage
3. 'multiple entities on the screen (or in the program but
4. ' not visible like a timer or a counter)
5. '
6. '
7. _FONT 16
8. SCREEN _NEWIMAGE(800, 600, 32)
9. CONST White = _RGBA32(255, 255, 255, 255)
10. CONST Black = _RGBA32(0, 0, 0, 255)
11. CONST Blu = _RGBA32(0, 0, 200, 255)
12. CONST Red = _RGBA32(200, 0, 0, 255)
13. CONST Green = _RGBA32(0, 200, 0, 255)
14.  
15. TYPE btn
16.     x AS INTEGER
17.     y AS INTEGER
18.     H AS INTEGER
19.     w AS INTEGER
20.     T AS STRING * 30
21. END TYPE
22.  
23. DIM SHARED Height AS INTEGER, Widht AS INTEGER, Buttons(1 TO 10) AS btn, z AS INTEGER
24.  
25. Height = _FONTHEIGHT
26. Widht = _FONTWIDTH
27.  
28. textBase$ = "This is a try to show different" ' 30 chars
29.  
30. ' graphic output/interface--------------------------------
31. LINE (1, 1)-(799, 599), Green, B
32. MakeScreen textBase$
33. COLOR Red, Black
34. _PRINTSTRING (100, 520), " Press from 1 to 10 for activate the button or left click on it"
35. ' End graphic interface-----------------------------------
36.  
37. 'main manager of I/O----------------------------------
38. ManageInput
39. END
40.  
41. SUB ManageInput
42.     K$ = "Null"
43.     DO WHILE _MOUSEINPUT OR K$ <> "Done"
44.         ' keyboard manager
45.         IF K$ = CHR$(27) THEN K$ = "Done"
46.         IF K$ <> "" THEN
47.             IF INSTR("123456789", K$) THEN
48.                 ' command executor
49.                 DrawButton Buttons(VAL(K$)).x, Buttons(VAL(K$)).y, RTRIM$(Buttons(VAL(K$)).T), Green, Black
50.                 DO: LOOP UNTIL INKEY$ = ""
51.                 SLEEP 1
52.                 drawScreen
53.             END IF
54.         END IF
55.         K$ = INKEY$
56.         ' mouse manager
57.         IF _MOUSEBUTTON(2) THEN K$ = "Done"
58.         IF _MOUSEBUTTON(1) THEN K$ = LTRIM$(STR$(WhatEntity))
59.     LOOP
60. END SUB
61.  
62. FUNCTION WhatEntity
63.     mX = _MOUSEX
64.     mY = _MOUSEY
65.     WhatEntity = false
66.     FOR zz = 1 TO 9
67.         IF Buttons(zz).x <= mX AND Buttons(zz).x + Buttons(zz).w >= mX THEN
68.             IF Buttons(zz).y <= mY AND Buttons(zz).y + Buttons(zz).H >= mY THEN
69.                 WhatEntity = zz
70.                 EXIT FUNCTION
71.             END IF
72.         END IF
73.     NEXT
74. END FUNCTION
75.  
76. SUB drawScreen
77.     FOR zz = 1 TO 9
78.         DrawButton Buttons(zz).x, Buttons(zz).y, RTRIM$(Buttons(zz).T), Red, Blu
79.     NEXT
80. END SUB
81.  
82. SUB MakeScreen (T AS STRING)
83.     FOR z = 1 TO 9
84.         MakeButton (RND * 500) + 1, z * 40, RTRIM$(LEFT$(T, (RND * 30) + 1)), Red, Blu
85.     NEXT
86. END SUB
87.  
88. SUB MakeButton (X AS INTEGER, Y AS INTEGER, txt AS STRING, Bcolor AS _UNSIGNED LONG, Fcolor AS _UNSIGNED LONG)
89.     InitButtons X, Y, txt
90.     DrawButton X, Y, txt, Bcolor, Fcolor
91. END SUB
92.  
93. SUB DrawButton (X AS INTEGER, Y AS INTEGER, txt AS STRING, Bcolor AS _UNSIGNED LONG, Fcolor AS _UNSIGNED LONG)
94.     LINE (X, Y)-(X + (Widht * LEN(txt)) + 10, Y + Height + 10), Bcolor, BF
95.     COLOR Fcolor, Bcolor
96.     _PRINTSTRING (X + 5, Y + 5), txt
97.     LINE (X, Y)-(X + (Widht * LEN(txt)) + 10, Y + Height + 10), White, B
98. END SUB
99.  
100. SUB InitButtons (X AS INTEGER, Y AS INTEGER, T AS STRING)
101.     Buttons(z).x = X
102.     Buttons(z).y = Y
103.     Buttons(z).T = T
104.     Buttons(z).H = Height
105.     Buttons(z).w = Widht * LEN(Buttons(z).T)
106. END SUB

soon I hope to post the different method in which the behavior of the object is not flagged by general manager but it is managed from into each object.

Thanks to read and try

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: TempodiBasic on September 27, 2019, 06:34:57 pm

Hi
here is the second way that I know to manage multiple objects/entities in the program

in this case the flow of program runs into all interested objects  that manage the input...

Code: QB64: [Select]

1. _TITLE "multiple entities on the screen NOT overlapping 2"
2. 'this is a little example of the 1st different concepts to manage
3. 'multiple entities on the screen (or in the program but
4. ' not visible like a timer or a counter)
5. '
6. '
7. _FONT 16
8. SCREEN _NEWIMAGE(800, 600, 32)
9. CONST White = _RGBA32(255, 255, 255, 255)
10. CONST Black = _RGBA32(0, 0, 0, 255)
11. CONST Blu = _RGBA32(0, 0, 200, 255)
12. CONST Red = _RGBA32(200, 0, 0, 255)
13. CONST Green = _RGBA32(0, 200, 0, 255)
14.  
15. TYPE btn
16.     x AS INTEGER
17.     y AS INTEGER
18.     H AS INTEGER
19.     w AS INTEGER
20.     T AS STRING * 30
21.     N AS STRING * 1
22. END TYPE
23.  
24. DIM SHARED Height AS INTEGER, Widht AS INTEGER, Buttons(1 TO 10) AS btn, z AS INTEGER, K$
25.  
26. Height = _FONTHEIGHT
27. Widht = _FONTWIDTH
28.  
29. textBase$ = "This is a try to show different" ' 30 chars
30.  
31. ' graphic output/interface--------------------------------
32. LINE (1, 1)-(799, 599), Green, B
33. MakeScreen textBase$
34. COLOR Red, Black
35. _PRINTSTRING (100, 520), " Press from 1 to 10 for activate the button or left click on it"
36. ' End graphic interface-----------------------------------
37.  
38. 'main
39.  
40. 'the events of the main are managed here
41. DO
42.     K$ = "Null"
43.     FOR zz = 1 TO 9
44.  
45.         ActivateButtons zz
46.  
47.     NEXT
48.  
49.     IF K$ = CHR$(27) THEN K$ = "Done"
50.     IF _MOUSEBUTTON(2) THEN K$ = "Done"
51. LOOP WHILE K$ <> "Done"
52.  
53. END
54.  
55. SUB ActivateButtons (Index AS INTEGER)
56.  
57.     IF K$ = "Null" THEN
58.         ' it controls the keyboard and mouse if it is not done
59.         DO
60.             K$ = INKEY$
61.             IF _MOUSEINPUT THEN K$ = "Null": EXIT DO
62.         LOOP UNTIL K$ <> ""
63.     END IF
64.  
65.     IF UCASE$(K$) = Buttons(Index).N THEN
66.         EventButton Index
67.         EXIT SUB
68.     END IF
69.     LOCATE 1, 1: PRINT K$, Buttons(Index).N
70.     IF _MOUSEBUTTON(1) THEN
71.         mX = _MOUSEX
72.         mY = _MOUSEY
73.         IF Buttons(Index).x <= mX AND Buttons(Index).x + Buttons(Index).w >= mX THEN
74.             IF Buttons(Index).y <= mY AND Buttons(Index).y + Buttons(Index).H >= mY THEN
75.                 EventButton Index
76.             END IF
77.         END IF
78.     END IF
79. END SUB
80.  
81. SUB EventButton (Index AS INTEGER)
82.     DrawButton Buttons(Index).x, Buttons(Index).y, RTRIM$(Buttons(Index).T), Green, Black
83.     _DELAY .25
84.     DrawButton Buttons(Index).x, Buttons(Index).y, RTRIM$(Buttons(Index).T), Red, Blu
85. END SUB
86.  
87. SUB MakeScreen (T AS STRING)
88.     FOR z = 1 TO 9
89.         MakeButton (RND * 500) + 1, z * 40, RTRIM$(LEFT$(T, (RND * 30) + 1)), Red, Blu
90.     NEXT
91. END SUB
92.  
93. SUB MakeButton (X AS INTEGER, Y AS INTEGER, txt AS STRING, Bcolor AS _UNSIGNED LONG, Fcolor AS _UNSIGNED LONG)
94.     InitButtons X, Y, txt
95.     DrawButton X, Y, txt, Bcolor, Fcolor
96. END SUB
97.  
98. SUB DrawButton (X AS INTEGER, Y AS INTEGER, txt AS STRING, Bcolor AS _UNSIGNED LONG, Fcolor AS _UNSIGNED LONG)
99.     LINE (X, Y)-(X + (Widht * LEN(txt)) + 10, Y + Height + 10), Bcolor, BF
100.     COLOR Fcolor, Bcolor
101.     _PRINTSTRING (X + 5, Y + 5), txt
102.     LINE (X, Y)-(X + (Widht * LEN(txt)) + 10, Y + Height + 10), White, B
103. END SUB
104.  
105. SUB InitButtons (X AS INTEGER, Y AS INTEGER, T AS STRING)
106.     Buttons(z).x = X
107.     Buttons(z).y = Y
108.     Buttons(z).T = T
109.     Buttons(z).H = Height
110.     Buttons(z).w = Widht * LEN(Buttons(z).T)
111.     Buttons(z).N = LTRIM$(STR$(z))
112. END SUB

so each object make a slice of the polling on the keyboard and mouse if it isn't already done while it verify if it must react to input.

Thanks for reading

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: bplus on September 27, 2019, 10:29:23 pm

It's an interesting problem isn't it! I have been thinking about it for going on a week now.

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: Petr on September 28, 2019, 03:06:21 am

Good work, TempodiBasic. I use this method oft.

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: TempodiBasic on October 06, 2019, 01:16:19 pm

A smooth and fast version for the second tecnique: a slice of polling for each entities

I got it using a layer for manage mouse button. In the fashion of QB64, the mouse's informations have been saved in a buffer stack also while you are not using _MOUSEINPUT.

waiting the imagination and energy to add _MOUSECLEAR to QB64 new statements.

Code: QB64: [Select]

1. _TITLE "multiple entities on the screen NOT overlapping"
2. 'this is a little example of the 1st different concepts to manage
3. 'multiple entities on the screen (or in the program but
4. ' not visible like a timer or a counter)
5. '
6.  
7. 'IMHO when we go to think as objects or entities to use in our programs we have two option...
8. '1.  centered managing of mouse and keyboard and other input ways  ,
9. '      so we can think about it like a pyramid that has like apex the I/O routine to be directed to the right entity at bottom,
10. '      or like a collection of areas to be activated by a flag (in Windows there are the messages among objects)
11. '2. a plane or circular managing of I/O  in which the objects/entities have the own different action that is activated by the specific
12. '    position of the mouse and by the specific comboKey
13. '
14. 'the substantial difference between them is that in the first the apex
15. 'manages I/O and triggers entity's action, in the second there is a main
16. 'loop in which each entity tests if position of mouse
17. 'and combokey activate its action/s.
18. '
19. _FONT 16
20. SCREEN _NEWIMAGE(800, 600, 32)
21. CONST White = _RGBA32(255, 255, 255, 255)
22. CONST Black = _RGBA32(0, 0, 0, 255)
23. CONST Blu = _RGBA32(0, 0, 200, 255)
24. CONST Red = _RGBA32(200, 0, 0, 255)
25. CONST Green = _RGBA32(0, 200, 0, 255)
26.  
27. TYPE btn
28.     x AS INTEGER
29.     y AS INTEGER
30.     H AS INTEGER
31.     W AS INTEGER
32.     T AS STRING * 30
33.     N AS STRING * 1
34. END TYPE
35.  
36. DIM SHARED Height AS INTEGER, Widht AS INTEGER, Buttons(1 TO 10) AS btn, z AS INTEGER, K$, mX, mY, mB
37.  
38. Height = _FONTHEIGHT
39. Widht = _FONTWIDTH
40.  
41. textBase$ = "This is a try to show different" ' 30 chars
42.  
43. ' graphic output/interface--------------------------------
44. LINE (1, 1)-(799, 599), Green, B
45. MakeScreen textBase$
46. COLOR Red, Black
47. _PRINTSTRING (100, 520), " Press from 1 to 10 for activate the button or left click on it"
48. ' End graphic interface-----------------------------------
49.  
50. 'main
51.  
52. 'the events of the main are managed here
53. DO
54.  
55.     K$ = "Null"
56.     FOR zz = 1 TO 9
57.  
58.         ActivateButtons zz
59.  
60.     NEXT
61.  
62.     IF K$ = CHR$(27) THEN K$ = "Done"
63.     IF _MOUSEBUTTON(2) THEN K$ = "Done"
64. LOOP WHILE K$ <> "Done"
65.  
66. END
67.  
68. SUB ActivateButtons (Index AS INTEGER)
69.  
70.     TakeInput
71.     ' here it analyzes input taken
72.  
73.     ' keyboard input event
74.     IF UCASE$(K$) = Buttons(Index).N THEN
75.         EventButton Index
76.         EXIT SUB
77.     END IF
78.  
79.     ' mouse input event
80.     IF mB > 0 THEN
81.         IF Buttons(Index).x <= mX AND Buttons(Index).x + Buttons(Index).W >= mX THEN
82.             IF Buttons(Index).y <= mY AND Buttons(Index).y + Buttons(Index).H >= mY THEN
83.                 EventButton Index
84.                 mB = 0 ' we need to read new status of mousebuttons
85.             END IF
86.         END IF
87.     END IF
88. END SUB
89.  
90. SUB EventButton (Index AS INTEGER)
91.     DrawButton Buttons(Index).x, Buttons(Index).y, RTRIM$(Buttons(Index).T), Green, Black
92.     _DELAY .25
93.     DrawButton Buttons(Index).x, Buttons(Index).y, RTRIM$(Buttons(Index).T), Red, Blu
94. END SUB
95.  
96. SUB MakeScreen (T AS STRING)
97.     FOR z = 1 TO 9
98.         MakeButton (RND * 500) + 1, z * 40, RTRIM$(LEFT$(T, (RND * 30) + 1)), Red, Blu
99.     NEXT
100. END SUB
101.  
102. SUB MakeButton (X AS INTEGER, Y AS INTEGER, txt AS STRING, Bcolor AS _UNSIGNED LONG, Fcolor AS _UNSIGNED LONG)
103.     InitButtons X, Y, txt
104.     DrawButton X, Y, txt, Bcolor, Fcolor
105. END SUB
106.  
107. SUB DrawButton (X AS INTEGER, Y AS INTEGER, txt AS STRING, Bcolor AS _UNSIGNED LONG, Fcolor AS _UNSIGNED LONG)
108.     LINE (X, Y)-(X + (Widht * LEN(txt)) + 10, Y + Height + 10), Bcolor, BF
109.     COLOR Fcolor, Bcolor
110.     _PRINTSTRING (X + 5, Y + 5), txt
111.     LINE (X, Y)-(X + (Widht * LEN(txt)) + 10, Y + Height + 10), White, B
112. END SUB
113.  
114. SUB InitButtons (X AS INTEGER, Y AS INTEGER, T AS STRING)
115.     Buttons(z).x = X
116.     Buttons(z).y = Y
117.     Buttons(z).T = T
118.     Buttons(z).H = Height
119.     Buttons(z).W = Widht * LEN(Buttons(z).T)
120.     Buttons(z).N = LTRIM$(STR$(z))
121. END SUB
122.  
123. SUB __MouseClear
124.     DO
125.         REM do nothing!
126.     LOOP UNTIL _MOUSEINPUT
127. END SUB
128.  
129. SUB TakeInput
130.     IF K$ = "Null" THEN
131.         ' it controls the keyboard and mouse if it is not done
132.         DO
133.             K$ = INKEY$
134.             IF _MOUSEINPUT THEN
135.                 K$ = "Null"
136.  
137.                 IF _MOUSEBUTTON(1) THEN mB = mB + 1
138.                 IF _MOUSEBUTTON(2) THEN mB = mB + 2
139.                 __MouseClear
140.                 mX = _MOUSEX
141.                 mY = _MOUSEY
142.             END IF
143.         LOOP UNTIL K$ <> ""
144.     END IF
145.  
146. END SUB

Thanks to try

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: bplus on October 06, 2019, 06:19:43 pm

Hi TempodiBasic,

Seems to work well, nice job!

I can't wait to try your simple little mouseClear, I hate using _delay .2 so code doesn't act like it's been clicked 5 times! I have a new spot where my old tricks did not work but yours might. :)

Update, it worked! Bless you!

Code: QB64: [Select]

1. DO: _LIMIT 100: LOOP UNTIL _MOUSEINPUT

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: TempodiBasic on October 07, 2019, 05:12:33 pm

Thanks Bplus
you give me the right vision of the SUB

Syntax
_MouseClear [ LoopForSecond]

• LoopForSecond range 0.2 to 1000
  
• if omitted the parameter the default is  100

inner code

Code: QB64: [Select]

1. DO: _LIMIT LoopForSecond: LOOP UNTIL _MOUSEINPUT

--- Well this is a good point.

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: bplus on October 07, 2019, 06:55:30 pm

Hi,

I do have an update for using that little line of code. Do it only after you detect a MouseButton, otherwise it will really bog down your code. When I reported my happy results it was after a detection of a mousebutton that I applied the "clear". I got tired of placing it in so many places so I tried it right after the WHILE _MOUSEINPUT: WEND. That's when the code really bogged down, so I added an IF mb1 (mouse button detection) then the "clear" and now it works well with only the one time placement.

Title: Re: Multiple objects/entities in the program: 2 ways to manage it
Post by: TempodiBasic on October 09, 2019, 06:34:03 am

Hi Bplus

about

Quote

I got tired of placing it in so many places so I tried it right after the WHILE _MOUSEINPUT: WEND.

I think that

Code: QB64: [Select]

1. WHILE _MOUSEINPUT:wend

is the specular definition of

Code: QB64: [Select]

1. DO:LOOP UNTIL _MOUSEINPUT

so to  be safer the new function function can have at start a control on general _MOUSEINPUT

Code: QB64: [Select]

1. IF _MOUSEINPUT THEN DO: _LIMIT LoopForSecond: LOOP UNTIL _MOUSEINPUT

Text Only | Text with Attachments