QB64.org Forum

Active Forums => Programs => Topic started by: Qwerkey on August 11, 2019, 10:24:10 am

Title: Methinks It Is Like A Weasel - An Evolutionary Program
Post by: Qwerkey on August 11, 2019, 10:24:10 am

Hamlet thinks that Polonius is a fool, which he demonstrates in the following conversation:

Hamlet: “Do you see yonder cloud that’s almost in shape of a camel?"
Polonius: "By the mass, and ‘tis like a camel, indeed."
Hamlet: "Methinks it is like a weasel."
Polonius: "It is backed like a weasel."
Hamlet: "Or like a whale?"
Polonius: "Very like a whale.”


You will be very familiar with Richard Dawkins (ethologist and evolutionary biologist) and his expositions of evolution which are always completely proof against any counter-argument.  In one of his books "The Blind Watchmaker" he describes his attempts to demonstrate natural selection by mutation and survival of the fittest by creating a computer program.  See the Wikipedia URL for detailed information.
https://en.wikipedia.org/wiki/Weasel_program (https://en.wikipedia.org/wiki/Weasel_program)

His computer program simulates an analogous process by attempting to create the phrase "Methinks It Is Like A Weasel" from a starting string block of random letters.  At some point in each of our lives there is probably a desire to write our own "Methinks It Is Like A Weasel" program, so this is my attempt (program updated 15/8/19 for more realistic probabilities, error removal and tidied).

Code: QB64: [Select]

1. 'METHINKS IT IS LIKE A WEASEL by QWERKEY 15/8/19
2.  
3. '128 Males + 128 Females
4. '128*Birthrate Male Offspring + 128*Birthrate Female Offspring: Male Odd-recessive, Female Even-recessive
5. 'A certain percentage of mutations in the offspring
6. 'Only the most adapted 128 Male and 128 Female Offspring survive
7. 'As Methinks2 (tidied up) but with immovable correct gene removed, mutation rate much reduced, and errors corrected
8.  
9. CONST True = -1, False = 0
10. CONST NoMates% = 128, NoIssue% = 141, JumpStart% = 256, MutationRate! = 2 / 1000
11. CONST Elite! = 3 / 7, Kappa! = 4, Prob0! = 0.23, GenLimit% = 30000
12. DIM Mates$(NoMates% - 1, 1), MatesDat%(NoMates% - 1, 1), IssueDat%(NoIssue% - 1, 1)
13. DIM Mating%%(NoMates% - 1)
14.  
15. _TITLE "Methinks It Is Like A Weasel"
16. Weasel$ = "METHINKS[IT[IS[LIKE[A[WEASEL"
17. Alphabet$ = "ABCDEFGHIJKLMNOPQRSTUVWXYZ["
18.  
19. SCREEN _NEWIMAGE(984, 720, 32)
20. _SCREENMOVE 10, 10
21. _DEST 0
22. _FONT 8
23.  
24. 'Initialise 1st Generation
25. Generation% = 1
26. RANDOMIZE (TIMER)
27. FOR R%% = 0 TO 1
28.     FOR N%% = 0 TO NoMates% - 1
29.         Mates$(N%%, R%%) = MID$(Alphabet$, INT(RND * 26) + 1, 1)
30.         FOR M%% = 2 TO 28
31.             Mates$(N%%, R%%) = Mates$(N%%, R%%) + MID$(Alphabet$, INT(RND * 27) + 1, 1)
32.         NEXT M%%
33.         MatesDat%(N%%, R%%) = 0
34.         FOR M%% = 1 TO 28
35.             MatesDat%(N%%, R%%) = MatesDat%(N%%, R%%) + ABS(ASC(MID$(Weasel$, M%%, 1)) - ASC(MID$(Mates$(N%%, R%%), M%%, 1)))
36.         NEXT M%%
37.     NEXT N%%
38. NEXT R%%
39. 'Sort & Display 1st Generation
40. CALL Sort1(MatesDat%(), Mates$())
41.  
42. 'Cycle through generations:
43. REDIM Papa%%(NoIssue% - 1, 1)
44. Dawkins%% = True
45. OneByOne%% = True
46. WHILE Dawkins%% AND Generation% < GenLimit%
47.     'Display Current Generation
48.     CLS
49.     COLOR _RGB32(255, 255, 255)
50.     _PRINTSTRING (4, 4), "Generation:"
51.     _PRINTSTRING (92, 4), STR$(Generation%)
52.     _PRINTSTRING (186, 4), "(" + LTRIM$(STR$(MatesDat%(0, 0))) + ")"
53.     FOR R%% = 0 TO 1
54.         IF R%% = 0 THEN
55.             COLOR _RGB32(255, 255, 0)
56.         ELSE
57.             COLOR _RGB32(0, 255, 255)
58.         END IF
59.         FOR N%% = 0 TO NoMates% - 1
60.             W$ = Mates$(N%%, R%%) 'W$ gets modified by Spaced$()
61.             IF N%% <= 63 THEN
62.                 _PRINTSTRING (4 + R%% * 500, 15 + N%% * 11), Spaced$(W$)
63.             ELSE
64.                 _PRINTSTRING (4 + 250 + R%% * 500, 15 + (N%% - 64) * 11), Spaced$(W$)
65.             END IF
66.         NEXT N%%
67.     NEXT R%%
68.     IF NOT OneByOne%% THEN
69.         _LIMIT 6
70.         _DISPLAY
71.     END IF
72.     'Find partners (monogamous, brother & sister not allowed to mate)
73.     PartnersAvailable%% = False
74.     WHILE NOT PartnersAvailable%%
75.         PartnersAvailable%% = True
76.         REDIM Mated%%(NoMates% - 1)
77.         FOR N%% = 0 TO NoMates% - 1
78.             CanMate%% = False
79.             NoTries% = 0
80.             WHILE NOT CanMate%%
81.                 IF N%% <= 63 THEN
82.                     N1%% = INT(RND * NoMates% / 2)
83.                     IF RND <= Elite! THEN N1%% = N1%% + 64
84.                 ELSE
85.                     N1%% = INT(RND * NoMates%)
86.                 END IF
87.                 NoTries% = NoTries% + 1
88.                 IF NOT Mated%%(N1%%) AND (Papa%%(N%%, 0) <> Papa%%(N1%%, 1) OR Generation% = 1) THEN 'By this time, Papa%% has been re-ordered
89.                     Mated%%(N1%%) = True
90.                     Mating%%(N%%) = N1%%
91.                     CanMate%% = True
92.                 END IF
93.                 IF NoTries% >= 1200 THEN
94.                     CanMate%% = True
95.                     PartnersAvailable%% = False
96.                     EXIT FOR
97.                 END IF
98.             WEND
99.         NEXT N%%
100.     WEND
101.     'Produce Children (always 1 male & 1 female offspring at the same time)
102.     REDIM Issue$(NoIssue% - 1, 1), Papa%%(NoIssue% - 1, 1)
103.     NoKidsLess1% = 0
104.     N%% = 0
105.     WHILE NoKidsLess1% <= NoIssue% - 1
106.         IF RND <= (Prob0! + ((Prob0! * N%% * (1 - Kappa!)) / ((NoMates%% - 1) * Kappa!))) THEN
107.             FOR R%% = 0 TO 1 'Male/Female Offspring
108.                 FOR M%% = 1 TO 28
109.                     IF RND < MutationRate! THEN
110.                         IF M%% = 1 THEN
111.                             Issue$(NoKidsLess1%, R%%) = MID$(Alphabet$, INT(RND * 26) + 1, 1)
112.                         ELSE
113.                             Issue$(NoKidsLess1%, R%%) = Issue$(NoKidsLess1%, R%%) + MID$(Alphabet$, INT(RND * 27) + 1, 1)
114.                         END IF
115.                     ELSEIF M%% MOD 2 = 0 THEN
116.                         Issue$(NoKidsLess1%, R%%) = Issue$(NoKidsLess1%, R%%) + MID$(Mates$(N%%, 0), M%%, 1) 'From father
117.                     ELSE
118.                         Issue$(NoKidsLess1%, R%%) = Issue$(NoKidsLess1%, R%%) + MID$(Mates$(Mating%%(N%%), 1), M%%, 1) 'From mother
119.                     END IF
120.                 NEXT M%%
121.                 IssueDat%(NoKidsLess1%, R%%) = 0
122.                 FOR M%% = 1 TO 28
123.                     IssueDat%(NoKidsLess1%, R%%) = IssueDat%(NoKidsLess1%, R%%) + ABS(ASC(MID$(Weasel$, M%%, 1)) - ASC(MID$(Issue$(NoKidsLess1%, R%%), M%%, 1)))
124.                 NEXT M%%
125.                 Papa%%(NoKidsLess1%, R%%) = N%%
126.             NEXT R%%
127.             NoKidsLess1% = NoKidsLess1% + 1
128.         END IF
129.         IF N%% = NoMates%% - 1 THEN
130.             N%% = 0
131.         ELSE
132.             N%% = N%% + 1
133.         END IF
134.     WEND
135.     IF OneByOne%% THEN
136.         'Delay
137.         _DELAY 1.5
138.         'Display Childless Parents
139.         FOR N%% = 0 TO NoMates% - 1 'N%% is the father
140.             Progeny%% = False
141.             T% = 0 'T% is the child
142.             WHILE NOT Progeny%% AND T% <= NoIssue% - 1
143.                 IF Papa%%(T%, 0) = N%% THEN Progeny%% = True
144.                 T% = T% + 1
145.             WEND
146.             IF NOT Progeny%% THEN
147.                 COLOR _RGB32(127, 127, 0)
148.                 W$ = Mates$(N%%, 0) 'W$ gets modified by Spaced$() - don't actually need this substitution here, as updated below
149.                 IF N%% <= 63 THEN
150.                     _PRINTSTRING (4, 15 + N%% * 11), Spaced$(W$)
151.                 ELSE
152.                     _PRINTSTRING (4 + 250, 15 + (N%% - 64) * 11), Spaced$(W$)
153.                 END IF
154.                 COLOR _RGB32(0, 127, 127)
155.                 N2%% = Mating%%(N%%)
156.                 W$ = Mates$(N2%%, 1) 'W$ gets modified by Spaced$() - don't actually need this substitution here, as updated below
157.                 IF N2%% <= 63 THEN
158.                     _PRINTSTRING (4 + 500, 15 + N2%% * 11), Spaced$(W$)
159.                 ELSE
160.                     _PRINTSTRING (4 + 250 + 500, 15 + (N2%% - 64) * 11), Spaced$(W$)
161.                 END IF
162.             END IF
163.         NEXT N%%
164.         'Use up keypresses & wait for keypress
165.         _KEYCLEAR
166.         SetAwhile%% = True
167.         WHILE SetAwhile%%
168.             _LIMIT 30
169.             K% = _KEYHIT
170.             SELECT CASE K%
171.                 CASE 32
172.                     SetAwhile%% = False
173.                 CASE 27
174.                     SetAwhile%% = False
175.                     Dawkins%% = False
176.                 CASE 102
177.                     OneByOne%% = False
178.                     SetAwhile%% = False
179.             END SELECT
180.         WEND
181.     ELSE
182.         K% = _KEYHIT
183.         SELECT CASE K%
184.             CASE 102
185.                 OneByOne%% = True
186.                 _AUTODISPLAY
187.             CASE 27
188.                 Dawkins%% = False
189.         END SELECT
190.     END IF
191.     IF Dawkins%% THEN
192.         ' Order children & set new generation
193.         CALL Sort2(IssueDat%(), Issue$(), Papa%%())
194.         FOR R%% = 0 TO 1
195.             FOR N%% = 0 TO NoMates%% - 1
196.                 Mates$(N%%, R%%) = Issue$(N%%, R%%)
197.                 MatesDat%(N%%, R%%) = 0
198.                 FOR M%% = 1 TO 28
199.                     MatesDat%(N%%, R%%) = MatesDat%(N%%, R%%) + ABS(ASC(MID$(Weasel$, M%%, 1)) - ASC(MID$(Mates$(N%%, R%%), M%%, 1)))
200.                 NEXT M%%
201.             NEXT N%%
202.         NEXT R%%
203.         RANDOMIZE (TIMER)
204.         Generation% = Generation% + 1
205.     END IF
206.     'IF NOT OneByOne%% THEN _DISPLAY
207. WEND
208.  
209. IF Generation% = GenLimit% THEN
210.     CLS
211.     _FONT 16
212.     PRINT "Generation Limit Reached"
213.     _KEYCLEAR
214.     WHILE INKEY$ = ""
215.         _LIMIT 30
216.     WEND
217. END IF
218.  
219. SYSTEM
220.  
221. FUNCTION Spaced$ (X$)
222.     I%% = INSTR(X$, "[")
223.     WHILE I%% > 0
224.         MID$(X$, I%%, 1) = " "
225.         I%% = INSTR(X$, "[")
226.     WEND
227.     Spaced$ = X$
228. END FUNCTION
229.  
230. SUB Sort1 (Numbers%(), Names$())
231.     FOR R%% = 0 TO 1
232.         Jump% = JumpStart%
233.         WHILE Jump% > 1
234.             Jump% = (Jump% - 1) \ 2
235.             Finished% = False
236.             WHILE NOT Finished%
237.                 Finished% = True
238.                 FOR Upper% = 1 TO NoMates% - Jump%
239.                     Lower% = Upper% + Jump%
240.                     IF Numbers%(Upper% - 1, R%%) > Numbers%(Lower% - 1, R%%) THEN
241.                         SWAP Names$(Upper% - 1, R%%), Names$(Lower% - 1, R%%)
242.                         SWAP Numbers%(Upper% - 1, R%%), Numbers%(Lower% - 1, R%%)
243.                         Finished% = False
244.                     END IF
245.                 NEXT Upper%
246.             WEND
247.         WEND
248.     NEXT R%%
249. END SUB
250.  
251. SUB Sort2 (Numbers%(), Names$(), WhosTheDaddy%%())
252.     FOR R%% = 0 TO 1
253.         Jump% = JumpStart%
254.         WHILE Jump% > 1
255.             Jump% = (Jump% - 1) \ 2
256.             Finished% = False
257.             WHILE NOT Finished%
258.                 Finished% = True
259.                 FOR Upper% = 1 TO NoIssue% - Jump%
260.                     Lower% = Upper% + Jump%
261.                     IF Numbers%(Upper% - 1, R%%) > Numbers%(Lower% - 1, R%%) THEN
262.                         SWAP Names$(Upper% - 1, R%%), Names$(Lower% - 1, R%%)
263.                         SWAP Numbers%(Upper% - 1, R%%), Numbers%(Lower% - 1, R%%)
264.                         SWAP WhosTheDaddy%%(Upper% - 1, R%%), WhosTheDaddy%%(Lower% - 1, R%%)
265.                         Finished% = False
266.                     END IF
267.                 NEXT Upper%
268.             WEND
269.         WEND
270.     NEXT R%%
271. END SUB
272.  
273.  

The assumptions/conditions in the program are as follows:

• Each generation has 128 males and 128 females who mate monogamously with a birthrate of 2.2 children (on average!).
• Each male and female of the first generation starts with a "gene sequence" defined by a 28-character string of random letters from "A" to "Z" (capitals only) and the Space character.
  
• The fitness-for-use criterion is defined by how close each character is to same-position character in the phrase "METHINKS IT IS LIKE A WEASEL".
• Each child inherits half its "genes" from the father and half from the mother.  Male parents are odd-numbered "gene-recessive", whilst female parents are even-numbered recessive.  Thus if the "DNA" were three characters long and the father was XYX and the mother YZY, the child would be YYY.  At each breeding, one male and one female offspring are produced.  Male and female offspring have the same genes as each other, except for the mutations.
• At each stage there is a chance (0.2% in this case) of gene mutation where a random character is produced in place of the inherited character.  This mutation rate is still much higher than in the biological case.
• Brother and sister may not mate (we are not only simulating superior genetics, but are also completely morally sound).
• The mate desirability is higher for the top half of the population.  (There is a 4:3 probability of top-half males selecting top-half females).
• For each 128/128 male/female generation, the top father has a 4-times probability of reproduction compared to that of the bottom pair.
• Of the 141 male & female offspring, only the top 128 survive to the next generation.

Run the program as follows:

The display shows two groups of 128 parents, "males" in yellow and "females" in cyan, each in two columns.  They are shown in fitness-for-use order (highest at the top).  The 64 highest are in the left-hand column, with the 64 lowest at the right.

After a short delay, the parents who fail to breed successfully are shown darkened.  The program will wait for a Spacebar press to proceed to the next generation.  You can cycle through the generations in this way.  You will see that the most poorly fit-for-use parents are most likely not to reproduce.

Evolution proceeds quite slowly and you will very soon want to speed things up.  Pressing "f" instead of the Spacebar will then quickly cycle through the generations.  Pressing "f" will revert to the one-by-one generation display.  Esc at any time quits the program.

You will see that about 3000 generations are required to produce a population in which all 256 individuals have the desired gene sequence (this takes about 10 minutes).  This is despite the fact that gene evolution is quite heavily biassed in favour of the desired result.  This is because of the presence in the population of such a large gene diversity.  You will also notice that the likelihood of gene changes falls as the population gets closer to the final result.  This is because any mutation tends to be quickly bred out by the extant majority.  In Dawkins's program, he obtains the final result in 47 generations.  I believe that this is so because his had a simpler procedure and less overall gene diversity.

I apologise for the slight bias in favour of the male sex, both in the coding and in this discussion.  No matter how we try, sexism is difficulty to battle.

Of course, Dawkins was quite aware that writing a program to head towards a known result does not describe how biology works, and the program here is a just-for-fun exercise.

This is my contribution to the demonstration of selection by fitness-for-use.  Please contribute your own program if you care to, describing what assumptions are made and how many generations it takes to produce the final population result.  Methinks it could be fun for you too.

Title: Re: Methinks It Is Like A Weasel - An Evolutionary Program
Post by: bplus on August 15, 2019, 10:55:43 am

Hi Qwerkey,

Very interesting topic, despite your efforts to keep it light, I can't help wondering seriously, maybe philosophically, how much morality contributes to fitness... well maybe that's better topic for another forum, still it'd be nice to test something with code.

Program wise, I don't like your fitness criteria, and toy with idea for mod or make over. To me, either the letter is right and in the right place or it is no good. So selection would be a test how many letters in the right place. Need a backstory explaining how letters in right place contributes to fitness and that should round out the code for the app / experiment. Like everyone, no matter their genetic makeup are attracted to the ones who have highest letter match counts, such that not just sexual attraction but the high match counts get all the best jobs, food, shelter... cars! So they spread their jeans everywhere in the land of weasel likers and have resources to support offspring (assuming they were a little moral and own up to their non-monogamous habits).

So the code mods would be about the high matchers mobility and getting every advantage, low matchers stuck where they are unattractive, sickly and low birthrates and survival rates...

Title: Re: Methinks It Is Like A Weasel - An Evolutionary Program
Post by: bplus on August 15, 2019, 02:52:38 pm

Here is an implementation of the algorithm outlined in Wiki (same fitness test I prefer):

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Quick Dawking" '  B+ 2019-08-15
3. 'Pursing Qwerkey's link from Wiki:
4. '   Although Dawkins did not provide the source code for his program, a "Weasel" style algorithm could run as follows.
5. '   Start with a random string of 28 characters.
6. '   Make 100 copies of the string (reproduce).
7. '   For each character in each of the 100 copies, with a probability of 5%, replace (mutate) the character with a new random character.
8. '   Compare each new string with the target string "METHINKS IT IS LIKE A WEASEL", and give each a score (the number of letters in the string that are correct and in the correct position).
9. '   If any of the new strings has a perfect score (28), halt. Otherwise, take the highest scoring string, and go to step 2.
10.  
11. CONST target = "METHINKS IT IS LIKE A WEASEL"
12. CONST Genes = "ABCDEFGHIJKLMNOPQRSTUVWXYZ " 'we could match counts of occurance with number of genes eg 3 Es, 1M, 2 Ts  and just go for odering
13. DIM i AS INTEGER, j AS INTEGER, Rstring$, eve$, nGeberation AS LONG, bestMutant$, bestMatchCnt AS INTEGER
14. RANDOMIZE TIMER
15.  
16. 'geberate random string
17. FOR i = 1 TO 28
18.     Rstring$ = Rstring$ + MID$(Genes, INT(RND * 27) + 1, 1)
19. NEXT
20. 'Rstring$ = "HEY QWERKEY SHOULDA USED RND"
21.  
22. eve$ = Rstring$
23. DIM copies(99) AS STRING
24.  
25. DO
26.     'initialize
27.     FOR i = 0 TO 99
28.         copies(i) = Rstring$
29.     NEXT
30.     'geberate
31.     FOR i = 1 TO 99
32.         FOR j = 1 TO 28
33.             IF RND < .05 THEN
34.  
35.                 ''don't mutate fit genes, this makes thing go really fast, no but cuts generations by half approx
36.                 'IF MID$(copies(i), j, 1) <> MID$(target$, j, 1) THEN
37.                 '    MID$(copies(i), j, 1) = MID$(Genes, INT(RND * 27) + 1, 1)
38.                 'END IF
39.  
40.                 ''mutate good gene or not,
41.                 MID$(copies(i), j, 1) = MID$(Genes, INT(RND * 27) + 1, 1)
42.                 ''not much difference because of the way the rest of this program goes
43.  
44.             END IF
45.         NEXT
46.     NEXT
47.     nGeberation = nGeberation + 1
48.     'select from geberation
49.     bestMutant$ = copies(0): bestMatchCnt = nMatches(copies(0))
50.     FOR i = 1 TO 99
51.         IF nMatches(copies(i)) > bestMatchCnt THEN bestMutant$ = copies(i)
52.     NEXT
53.     Rstring$ = bestMutant$
54.     CLS: PRINT nGeberation, Rstring$
55.     _LIMIT 60
56. LOOP UNTIL bestMutant$ = target
57. PRINT "From "; eve$; " to "; target; " in "; nGeberation; " generations."
58.  
59. FUNCTION nMatches (s$)
60.     DIM i AS INTEGER, n AS INTEGER
61.     FOR i = 1 TO 28
62.         IF MID$(target, i, 1) = MID$(s$, i, 1) THEN n = n + 1
63.     NEXT
64.     nMatches = n
65. END FUNCTION
66.  
67.  

Don't have to take lunch waiting for this to finish it's run, you wont even make it out the door!

Title: Re: Methinks It Is Like A Weasel - An Evolutionary Program
Post by: Qwerkey on August 16, 2019, 04:43:41 am

bplus, thanks for the implementation of Dawkins's algorithm for completeness.  I'd have thought that he would have provided his code to Rosetta or wherever, but presumably he wrote it so long ago and never kept it (or more likely thought it trivial in his terms).

Quote from: bplus on August 15, 2019, 10:55:43 am

Very interesting topic

Well, I thought so, and thought that others might create their own unique code and show us what happens.  But it looks like we're keeping this topic to ourselves.  You mention that mine has elements which are not very "gene-like".  But we must remember that what we're doing is simple mathematics, comparison and random number generation, not a simulation of biology.  Although my text is sprinkled with biological terms, it was just done to maintain the degree of "lightness"  which you spotted.

Quote from: bplus on August 15, 2019, 10:55:43 am

how much morality contributes to fitness...

That would be a difficult project!  Where would one start?  It is much beyond Darwinian evolution* which does lend itself to such simple analogues as we have done here.  Going into civilisation is something else completely.  Remember the fools who, having heard of Dawkins's term "The Selfish Gene", thought that this meant that it was a good and natural thing to be selfish?

*  It remains a wonder that Darwin (and others at the time) came up with the idea even though they had no knowledge of what a gene is.  And then the chemistry of biology gives exactly how Darwinian evolution works.

Title: Re: Methinks It Is Like A Weasel - An Evolutionary Program
Post by: bplus on August 16, 2019, 09:25:29 am

Hi Qwerkey,

Ha! I just noticed how close in spelling Dawkins and Darwin are! 4 matches and w is only in wrong place out for 5 of first 6 letters.
I bet Dawkins might have noticed too! Maybe created extra sympathy for Darwin early on in his development.

You say, "You mention that mine has elements which are not very "gene-like".
I only objected to your fitness criteria, genes that are right but in wrong order is like having the perfect nose but exactly where an ear should go or like with code, if your file is off 1 byte, it is likely corrupted, close only counts in horse shoes (and grenades) as they say. 

Don't get me wrong, I do appreciate the effort you made to simulate reproduction / regeneration and kept code around 300 lines, nice job.

Since we are likely to get nowhere testing ideas of morality, I am toying with idea of mutating 9 digit number strings to solve Sudoku puzzles, to mutate you only swap gene / digit positions, so every string starts, right out of the gate, with the right stuff, then, just a matter of getting it in the right order for proper fitness. So far this idea has me planning a possible redesign of my Sudoku worksheet app. Use genetic mutation for solving Sudoku puzzles, how practical is that! (Maybe I have been playing too much word Scrambler lately ;-))

Title: Re: Methinks It Is Like A Weasel - An Evolutionary Program
Post by: Qwerkey on August 16, 2019, 09:56:29 am

Quote from: bplus on August 16, 2019, 09:25:29 am

I am toying with idea of mutating 9 digit number strings to solve Sudoku puzzles, to mutate you only swap gene / digit positions

Yes, that sounds very interesting and likely to work, I think.

Text Only | Text with Attachments