Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Qwerkey on August 06, 2019, 07:19:51 am

Title: FUNCTION and SUB By Reference and By Value
Post by: Qwerkey on August 06, 2019, 07:19:51 am
In Steve's Posting about the Wiki being incorrect for FUNCTION

https://www.qb64.org/forum/index.php?topic=1531.0 (https://www.qb64.org/forum/index.php?topic=1531.0)

I pointed out that arguments passed to a FUNCTION are passed By Reference by default and not by By Value.  That is to say, the argument gets modified in the FUNCTION and that modified value gets passed back to the calling argument.  This was a surprise to me, not to say rather a shock.

Incidentally, I never can remember which is By Reference and which is By Value (always have to look them up) – I'd rather they were called CHANGED and UNCHANGED respectively.

So, I discovered that if you don't want a FUNCTION to change your calling argument, you must pass the argument By Value, and this is done (QB64 methodology) by placing the argument within brackets, viz. if a FUNCTION F%() is called using a calling argument a% then

b% = F%(a%) - By Reference: a% will be modified

b% = F%((a%)) - By Value: a% will remain unchanged


So, I thought that I'd got that understood until I tried passing a String to a FUNCTION.  In this case, the String is always passed By Reference (and gets modified), no matter whether it is inside brackets or not.  Then I found that exactly the same thing happens with a SUB – a String is always modified by a SUB whether or not it is inside brackets.  I hope that you're still with me on this!

Code: QB64: [Select]
  1. 'Function / Sub By Val or By Ref
  2.  
  3. 'Now, the authentic definition is:
  4. 'When a parameter is passed by reference, the caller and the callee use the same variable for the parameter. If the callee modifies the parameter variable, the effect is visible to the caller's variable.
  5. 'When a parameter is passed by value, the caller and callee have two independent variables with the same value. If the callee modifies the parameter variable, the effect is not visible to the caller.
  6.  
  7. C1% = 3
  8. PRINT C1%; "- Numeric Original"
  9. CALL Cg((C1%))
  10. PRINT C1%; "- Numeric After SUB By Value"
  11. PRINT Ch%((C1%)); "- FUNCTION Result After FUNCTION By Value"
  12. PRINT C1%; "- Numeric After FUNCTION By Value"
  13. PRINT Ch%(C1%); "- FUNCTION Result After FUNCTION By Reference"
  14. PRINT C1%; "- Numeric After FUNCTION By Reference"
  15. CALL Cg(C1%)
  16. PRINT C1%; "- Numeric After SUB By Reference"
  18.  
  19. W2$ = "Change[to[Spaces"
  20. PRINT W2$; " - String Original"
  21. CALL Spacef((W2$))
  22. PRINT W2$; " - String After SUB By Value"
  23. PRINT Spaced$((W2$)); " - FUNCTION Result After FUNCTION By Value"
  24. PRINT W2$; " - String After FUNCTION By Value"
  25. PRINT Spaced$(W2$); " - FUNCTION Result After FUNCTION By Reference"
  26. PRINT W2$; " - String Result After FUNCTION By Reference"
  27. CALL Spacef(W2$)
  28. PRINT W2$; " - String Result After SUB By Reference"
  29.  
  31.  
  32. FUNCTION Ch% (C%)
  33.     C% = C% + 1
  34.     Ch% = 2 * C%
  36.  
  37. FUNCTION Spaced$ (X$)
  38.     I%% = INSTR(X$, "[")
  39.     WHILE I%% > 0
  40.         MID$(X$, I%%, 1) = " "
  41.         I%% = INSTR(X$, "[")
  42.     WEND
  43.     Spaced$ = X$
  45.  
  46. SUB Cg (C%)
  47.     C% = 3 * C%
  49.  
  50. SUB Spacef (X$)
  51.     X$ = X$ + "[zzz"

In the given code, there is a FUNCTION Ch%() which takes an Integer argument and a FUNCTION Spaced$() which takes a String argument, and there is a SUB Cg() which takes an Integer argument and a SUB Spacef() which takes a String argument.  The main block calls the FUNCTIONs and SUBs By Value and By Reference.

The code demonstrates what I have declared here:  a Numeric may be passed to a SUB or to a FUNCTION either By Reference (default) or By Value, but a String is always passed to a SUB or to a FUNCTION  By Reference.

Is this supposed to happen, and if so should a String behave differently to a Numeric?


From a queasy Qwerkey.
Title: Re: FUNCTION and SUB By Reference and By Value
Post by: SMcNeill on August 06, 2019, 07:51:54 am
I'd mentioned before that passing via parenthesis wasn't reliable.

For example, you can't even pass a User Defined Type with parenthesis, as you were attempting to do -- QB64 simply errors out:

Code: QB64: [Select]
  2.     x AS INTEGER
  3.     y AS INTEGER
  5.  
  6. DIM ex AS a
  7.  
  8. ex.x = 1: ex.y = 2
  9. result = foo((ex))
  10.  
  11. PRINT var.x, var.y
  12.  
  13. FUNCTION foo (var AS a)
  14.     var.x = var.x * 2
  15.     var.y = var.y * 3

The above won't work at all for you.

If you don't want to ever change the values of your parameters, the surefire method is to assign and pass the values through temp variables.

Code: [Select]
'Function / Sub By Val or By Ref

'Now, the authentic definition is:
'When a parameter is passed by reference, the caller and the callee use the same variable for the parameter. If the callee modifies the parameter variable, the effect is visible to the caller's variable.
'When a parameter is passed by value, the caller and callee have two independent variables with the same value. If the callee modifies the parameter variable, the effect is not visible to the caller.

C1% = 3
PRINT C1%; "- Numeric Original"
CALL Cg((C1%))
PRINT C1%; "- Numeric After SUB By Value"
PRINT Ch%((C1%)); "- FUNCTION Result After FUNCTION By Value"
PRINT C1%; "- Numeric After FUNCTION By Value"
PRINT Ch%(C1%); "- FUNCTION Result After FUNCTION By Reference"
PRINT C1%; "- Numeric After FUNCTION By Reference"
CALL Cg(C1%)
PRINT C1%; "- Numeric After SUB By Reference"
PRINT

W2$ = "Change[to[Spaces"
PRINT W2$; " - String Original"
CALL Spacef((W2$))
PRINT W2$; " - String After SUB By Value"
PRINT Spaced$((W2$)); " - FUNCTION Result After FUNCTION By Value"
PRINT W2$; " - String After FUNCTION By Value"
PRINT Spaced$(W2$); " - FUNCTION Result After FUNCTION By Reference"
PRINT W2$; " - String Result After FUNCTION By Reference"
CALL Spacef(W2$)
PRINT W2$; " - String Result After SUB By Reference"

END

FUNCTION Ch% (tempC%)
    C% = tempC%
    C% = C% + 1
    Ch% = 2 * C%
END FUNCTION

FUNCTION Spaced$ (tempX$)
    X$ = tempX$
    I%% = INSTR(X$, "[")
    WHILE I%% > 0
        MID$(X$, I%%, 1) = " "
        I%% = INSTR(X$, "[")
    WEND
    Spaced$ = X$
END FUNCTION

SUB Cg (tempC%)
    C% = tempC%
    C% = 3 * C%
END SUB

SUB Spacef (tempX$)
    X$ = tempX$
    X$ = X$ + "[zzz"
END SUB

Title: Re: FUNCTION and SUB By Reference and By Value
Post by: TempodiBasic on August 06, 2019, 09:19:23 am
Thanks
that is the sure solution
Quote
the surefire method is to assign and pass the values through temp variables.

but if we must call an external function of external library with string as value how can we pass string by value? Or is this my question an impossible case of coding?
 thanks to read and answer
Title: Re: FUNCTION and SUB By Reference and By Value
Post by: SMcNeill on August 06, 2019, 09:41:55 am
Quote from: TempodiBasic on August 06, 2019, 09:19:23 am
Thanks
that is the sure solution
but if we must call an external function of external library with string as value how can we pass string by value? Or is this my question an impossible case of coding?
 thanks to read and answer

Assign it to a temp value, whose whole purpose is just to pass the value and be changed and discarded

StringToKeep$ = "SteveIsAwesome"
temp$ = StringToKeep$
ExternalLibrary temp$ 'pass it temp$ so we won't care if it changes or not.
temp$ = "" 'and then blank the string to save memory after, if we want to.
Title: Re: FUNCTION and SUB By Reference and By Value
Post by: bplus on August 06, 2019, 10:07:53 am
Another method (to using () or different TYPE set) is to make copies of the arguments passed inside the sub or function and work with the copies inside the sub or function leaving the variables passed untouched.

This method leaves it up to the maker of the procedure to effectively pass by ref or by value, so the user doesn't have to guess maybe 10 years down the line whether they have to protect values in call to procedure or not.

It is what Steve is doing inside the procedures of his examples above but by calling them "temp" variables in parameters of procedure definition is misleading IMHO.

before:
Code: QB64: [Select]
  1. _TITLE "GetDay$ function test."
  3.     PRINT "(don't forget 0's, just enter to quit)"
  4.     INPUT "  Enter yyyy-mm-dd date format: "; yymmdd$
  5.     yyyy = VAL(MID$(yymmdd$, 1, 4))
  6.     mm = VAL(MID$(yymmdd$, 6, 2))
  7.     dd = VAL(MID$(yymmdd$, 9, 2))
  8.     PRINT GetDay$(mm, dd, yyyy)
  9.     PRINT
  10. LOOP UNTIL yymmdd$ = ""
  11.  
  12. 'Steve (SAM) function fix for Ken
  13. FUNCTION GetDay$ (mm, dd, yyyy) 'use 4 digit year
  14.     'From Zeller's congruence: https://en.wikipedia.org/wiki/Zeller%27s_congruence
  15.     IF mm < 3 THEN mm = mm + 12: yyyy = yyyy - 1
  16.     century = yyyy MOD 100
  17.     zerocentury = yyyy \ 100
  18.     result = (dd + INT(13 * (mm + 1) / 5) + century + INT(century / 4) + INT(zerocentury / 4) + 5 * zerocentury) MOD 7
  19.     SELECT CASE result
  20.         CASE 0: Day$ = "Saturday"
  21.         CASE 1: Day$ = "Sunday"
  22.         CASE 2: Day$ = "Monday"
  23.         CASE 3: Day$ = "Tuesday"
  24.         CASE 4: Day$ = "Wednesday"
  25.         CASE 5: Day$ = "Thursday"
  26.         CASE 6: Day$ = "Friday"
  27.     END SELECT
  28.     GetDay$ = Day$
after:
Code: QB64: [Select]
  1. _TITLE "GetDay$ function test."
  3.     PRINT "(don't forget 0's, just enter to quit)"
  4.     INPUT "  Enter yyyy-mm-dd date format: "; yymmdd$
  5.     yyyy = VAL(MID$(yymmdd$, 1, 4))
  6.     mm = VAL(MID$(yymmdd$, 6, 2))
  7.     dd = VAL(MID$(yymmdd$, 9, 2))
  8.     PRINT GetDay$(mm, dd, yyyy)
  9.     PRINT
  10. LOOP UNTIL yymmdd$ = ""
  11.  
  12. 'Steve (SAM) function fix for Ken, bplus fix for user 10 years from now
  13. FUNCTION GetDay$ (mm, dd, yyyy) 'use 4 digit year
  14.     m = mm 'copy mm because we change it
  15.     y = yyyy 'copy yyyy because we may chnge that as well
  16.     ' dd is unchanged below
  17.     'From Zeller's congruence: https://en.wikipedia.org/wiki/Zeller%27s_congruence
  18.     IF m < 3 THEN m = m + 12: y = y - 1
  19.     century = y MOD 100
  20.     zerocentury = y \ 100
  21.     result = (dd + INT(13 * (m + 1) / 5) + century + INT(century / 4) + INT(zerocentury / 4) + 5 * zerocentury) MOD 7
  22.     SELECT CASE result
  23.         CASE 0: Day$ = "Saturday"
  24.         CASE 1: Day$ = "Sunday"
  25.         CASE 2: Day$ = "Monday"
  26.         CASE 3: Day$ = "Tuesday"
  27.         CASE 4: Day$ = "Wednesday"
  28.         CASE 5: Day$ = "Thursday"
  29.         CASE 6: Day$ = "Friday"
  30.     END SELECT
  31.     GetDay$ = Day$
  33.  
Title: Re: FUNCTION and SUB By Reference and By Value
Post by: Qwerkey on August 06, 2019, 10:40:48 am
Quote from: SMcNeill on August 06, 2019, 07:51:54 am
I'd mentioned before that passing via parenthesis wasn't reliable.

Not reliable???  Everything issuing from Microsoft is unreliable, but QB64?  I'm disappointed!

Seriously, the By Value / By Reference is sort-of covered in the Wiki under ByVal (I've just looked) - see image.

The last bullet point under Description says to use parentheses for SUB and FUNCTION calls to pass By Value.  The Errors section below says that you can't use ByVal before STRING or TYPE variables: although slightly different to what I was doing, I suppose that a half-intelligent user might have queried just blundering use of parentheses (brackets).  (I'm still disappointed that a FUNCTION ever changes any of its calling arguments).
Text Only | Text with Attachments