QB64.org Forum

Active Forums => Programs => Topic started by: SierraKen on July 21, 2019, 05:47:21 pm

Title: Alphabet Invaders
Post by: SierraKen on July 21, 2019, 05:47:21 pm

I made this game in ASIC 5.0 back in the 90's which is why you see so many lines in this game, ASIC was a lot like GW-BASIC. For example, you couldn't separate code lines on the same line using : and many other things you couldn't do. One thing is that I had to add goto to the IF/THEN commands which ASIC just did like If a$="Ken" then Ken: I also had to change the speed using _DELAY and RND stuff on it as well. I think ASIC couldn't even use the arrow keys, if I recall right, which is why originally this game had to use the numbers on the number pad  lol. So I changed that to arrow keys and added Esc instead of the old fashioned Q to quit. It's a very simple game, no graphics, just text animation. :D Soon I might try to make a game like this again, except you have to press the right letters on the keyboard to shoot the letter out of the sky. Someone made that back in the 90's but I have no idea who did it and would like a try myself. It would be a good way for people to learn how to type as well. But try this one first, you move your + guy back and forth to shoot the oncoming letters before they reach the bottom. You have to shoot down 100 of them to win the game. If you miss one, your guy explodes lol. Tell me what you think. :)

Code: QB64: [Select]

1. _TITLE "Alphabet Invaders"
2. begin:
3. x = 20
4. y = 20
5. p = 0
6.  
7. CLS
8. PRINT "        Alphabet Invaders"
9. PRINT "        -----------------"
10. PRINT
11. PRINT "           By Ken G."
12. PRINT
13. PRINT "Destroy 100 falling aliens to win the game."
14. PRINT
15. PRINT
16. PRINT "         Use These Keys"
17. PRINT
18. PRINT "Left Arrow Key and Right Arrow Key"
19. PRINT
20. PRINT "          Esc=Quit"
21. PRINT
22. PRINT "        Space Bar=Fire"
23. PRINT
24. PRINT "You= +"
25. PRINT "Fire Power= *"
26. PRINT
27. INPUT "Press Enter to begin.", a$
28. pick:
29. CLS
30. diffic:
31. CLS
32. LOCATE 4, 10
33. PRINT "Difficulty"
34. LOCATE 5, 10
35. PRINT "----------"
36. PRINT
37. PRINT "(1) 10 cannons - Easy"
38. PRINT "(2) 5 cannons - Average"
39. PRINT "(3) 3 cannons - Hard"
40. PRINT
41. PRINT "Type a number here (1 to 30):";
42. INPUT dif
43. IF dif > 3 THEN GOTO diffic:
44. IF dif < 1 THEN GOTO diffic:
45. IF dif = 1 THEN GOTO easy:
46. IF dif = 2 THEN GOTO average:
47. IF dif = 3 THEN GOTO hard:
48. easy:
49. m = 10
50. GOTO wow:
51. average:
52. m = 5
53. GOTO wow:
54. hard:
55. m = 3
56. wow:
57. GOTO ggo:
58. miss:
59. hy = y - 2
60. jy = y - 1
61. hx = x + 1
62. jx = x - 1
63. LOCATE y, x
64. PRINT "@"
65. LOCATE hy, hx
66. PRINT "@"
67. LOCATE jy, jx
68. PRINT "@"
69. LOCATE y, hx
70. PRINT "@"
71. LOCATE hy, x
72. PRINT "@"
73. LOCATE hy, jx
74. PRINT "@"
75. LOCATE jy, hx
76. PRINT "@"
77. LOCATE y, jx
78. PRINT "@"
79. SOUND 300, .5
80. SOUND 200, .5
81. _DELAY 1
82. m = m - 1
83. IF m = 0 THEN GOTO lose:
84. ggo:
85. YY = 1
86. CLS
87. LOCATE 10, 55
88. PRINT "Score: ";
89. PRINT p
90. LOCATE 12, 55
91. PRINT "Cannons Left: ";
92. PRINT m
93. RANDOMIZE TIMER
94. L = INT(RND * 25) + 65
95. B$ = CHR$(L)
96. RANDOMIZE TIMER
97. XX = INT(RND * 9) + 1
98. XX = XX * 5
99. N = 0
100.  
101. TIME1:
102. _DELAY .2
103. N = N + 1
104. IF N = 2 THEN GOTO GO:
105. GOTO GO:
106. ST:
107. GO:
108. N = 0
109. LOCATE YY, XX
110. PRINT " "
111. YY = YY + 1
112. ff = YY
113. IF YY > 21 THEN GOTO miss:
114. LOCATE YY, XX
115. PRINT B$
116. LOCATE y, x
117. PRINT "+"
118.  
119. E$ = INKEY$
120. IF E$ = CHR$(0) + CHR$(75) THEN GOTO LEFT1:
121. IF E$ = CHR$(0) + CHR$(77) THEN GOTO RIGHT1:
122. IF E$ = " " THEN GOTO FIRE:
123. IF E$ = CHR$(27) THEN GOTO DONE:
124. GOTO TIME1:
125. LEFT1:
126. LOCATE y, x
127. PRINT " "
128. x = x - 5
129. IF x < 5 THEN GOTO LEFT2:
130. GOTO GO:
131. LEFT2:
132. x = 5
133. GOTO GO:
134. RIGHT1:
135. LOCATE y, x
136. PRINT " "
137. x = x + 5
138. IF x > 50 THEN GOTO right2:
139. GOTO GO:
140. right2:
141. x = 50
142. GOTO GO:
143. FIRE:
144. R = x
145. sy = y - 1
146. FOR LS = ff TO sy
147.     LOCATE LS, R
148.     PRINT "*"
149. NEXT LS
150. _DELAY .1
151. SOUND 300, .5
152. FOR LL = ff TO sy
153.     LOCATE LL, R
154.     PRINT " "
155. NEXT LL
156. IF x = XX THEN GOTO HIT:
157. GOTO GO:
158. HIT:
159. p = p + 100
160. tx = XX - 1
161. rx = XX - 2
162. LOCATE YY, tx
163. PRINT "{ }"
164. SOUND 600, .5
165. _DELAY .15
166. LOCATE YY, rx
167. PRINT "{   }"
168. SOUND 200, .5
169. _DELAY .15
170. cont:
171. IF p = 10000 THEN GOTO WIN:
172. GOTO ggo:
173.  
174. lose:
175. LOCATE 3, 5
176. PRINT "Y O U  L O S T"
177. GOTO ending:
178.  
179. WIN:
180. CLS
181. LOCATE 1, 5
182. PRINT "Score: ";
183. PRINT p
184. LOCATE 3, 5
185. PRINT "Y O U   W I N   T H E   G A M E"
186. ending:
187. SOUND 230, .5
188. SOUND 200, .5
189. SOUND 210, .5
190. SOUND 150, .5
191. SOUND 100, .5
192. PRINT
193. PRINT "Do you want to play again(Y/N)";
194. INPUT ag$
195. IF ag$ = "Y" OR ag$ = "y" OR ag$ = "YES" OR ag$ = "Yes" OR ag$ = "yes" OR ag$ = "yES" OR ag$ = "yeS" THEN GOTO begin:
196. DONE:
197. END
198.  

Title: Re: Alphabet Invaders
Post by: johnno56 on July 21, 2019, 05:54:36 pm

Cool game... I still get killed off but a cool game just the same.... lol

Title: Re: Alphabet Invaders
Post by: Pete on July 21, 2019, 05:55:45 pm

Something similar: https://www.qb64.org/forum/index.php?topic=237.msg1223#msg1223

Pete

Title: Re: Alphabet Invaders
Post by: SierraKen on July 21, 2019, 05:57:42 pm

Thanks guys. I just removed 3 lines of code with time variables that are not needed anymore, so if you want, you can copy/paste it again with the same code above.

Title: Re: Alphabet Invaders
Post by: SierraKen on July 21, 2019, 06:04:09 pm

LOL Pete dang that's pretty good programming! Amazing how you copied the IDE perfectly lol. Great job.

Title: Re: Alphabet Invaders
Post by: SierraKen on July 21, 2019, 06:05:42 pm

This used to ask you what kind of computer you had so it could set the TIMER command even with the speed of your computer lol. Gotta love the old days.  Oh, and ASIC also changed the SOUND command so you had to actually type in the frequency of the sound, like this had around SOUND 20000,1 and when I played it on this computer, it squeeled so much I thought it would break my windows. LOL

Title: Re: Alphabet Invaders
Post by: SierraKen on July 21, 2019, 06:30:54 pm

I see there's too many other games out there that use Space Invaders as a way to learn to type on the keyboard, so I'm going to try to think of something else.

Title: Re: Alphabet Invaders
Post by: OldMoses on July 21, 2019, 07:17:57 pm

Yep, I suspected I'd lose again. I think the old style games are often the most challenging.

Title: Re: Alphabet Invaders
Post by: bplus on July 21, 2019, 09:42:32 pm

Sorry I can not shoot at B nor will I shoot at U. :D

I like how the brackets fly away when letter is shot.

Title: Re: Alphabet Invaders
Post by: SierraKen on July 21, 2019, 09:58:39 pm

Thanks B+. :) It's a fun little game, would be good for new programmers to learn. Same with my Lemonade Stand.

Title: Re: Alphabet Invaders
Post by: Ashish on July 22, 2019, 08:21:50 am

Nice game. I like these types of the game where you have to shoot to enemies. (like COD-MW2, BF3...,  etc) :)

Title: Re: Alphabet Invaders
Post by: TempodiBasic on July 22, 2019, 05:27:26 pm

Cool
fine to type type to shoot letters!

Title: Re: Alphabet Invaders
Post by: SierraKen on July 22, 2019, 06:10:40 pm

Thanks guys!

Title: Re: Alphabet Invaders
Post by: bplus on July 22, 2019, 07:48:26 pm

Quote from: OldMoses on July 21, 2019, 07:17:57 pm

Yep, I suspected I'd lose again. I think the old style games are often the most challenging.

What is challenging is to read through this spaghetti to find a place to install a _LIMIT so you can adjust the play action to your system and skill level.

Now you can!

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Alpha-Bit Invaders" 'mod Ken's original from spaghetti version
3. DEFINT A-Z
4. SCREEN _NEWIMAGE(640, 360, 32)
5. RANDOMIZE TIMER
6. DIM SHARED x, y, p, m, xx, yy, gameOver, goAgain
7. goAgain = -1
8. COLOR _RGB32(180, 180, 225), _RGB32(25, 10, 50)
9. DO
10.     Begin
11.     GoRounds
12. LOOP UNTIL goAgain = 0
13.  
14. SUB GoRounds
15.     DIM b$, e$, l
16.     WHILE gameOver = 0 'setup next letter round
17.         yy = 1
18.         CLS
19.         LOCATE 10, 55: PRINT "Score: "; p;
20.         LOCATE 12, 55: PRINT "Cannons Left: "; m;
21.         b$ = CHR$(INT(RND * 26) + 65)
22.         xx = (INT(RND * 9) + 1) * 5
23.         LOCATE yy, xx: PRINT b$;
24.         _DELAY .5
25.         DO
26.             LOCATE yy, xx: PRINT " ";
27.             yy = yy + 1
28.             IF yy > 21 THEN Miss: EXIT DO
29.             LOCATE yy, xx: PRINT b$;
30.             e$ = INKEY$
31.             IF e$ = CHR$(0) + CHR$(75) THEN
32.                 LOCATE y, x: PRINT " ";
33.                 x = x - 5
34.                 IF x < 5 THEN x = 5
35.                 LOCATE y, x: PRINT "+";
36.             END IF
37.             IF e$ = CHR$(0) + CHR$(77) THEN
38.                 LOCATE y, x: PRINT " ";
39.                 x = x + 5
40.                 IF x > 50 THEN x = 50
41.                 LOCATE y, x: PRINT "+";
42.             END IF
43.             IF e$ = " " THEN
44.                 FOR l = yy TO y - 1
45.                     LOCATE l, x: PRINT "*";
46.                 NEXT
47.                 _DELAY .1
48.                 SOUND 300, .5
49.                 FOR l = yy TO y - 1
50.                     LOCATE l, x: PRINT " ";
51.                 NEXT
52.                 IF x = xx THEN Hit: EXIT DO
53.             END IF
54.             IF e$ = CHR$(27) THEN END
55.             LOCATE y, x: PRINT "+";
56.             _LIMIT 10  '<<<<<<<<<<<<<<<<<<<<< old geezers with bad eyes adjust here!
57.         LOOP
58.     WEND
59.     Ending
60. END SUB
61.  
62. SUB Hit
63.     p = p + 100
64.     LOCATE yy, xx - 1: PRINT "{ }";
65.     SOUND 600, .5
66.     _DELAY .15
67.     LOCATE yy, xx - 2
68.     PRINT "{   }";
69.     SOUND 200, .5
70.     _DELAY .15
71.     IF p = 10000 THEN
72.         CLS
73.         LOCATE 10, 55: PRINT "Score: "; p;
74.         LOCATE 12, 55: PRINT "Cannons Left: "; m;
75.         LOCATE 1, 5: PRINT "Score: "; p;
76.         LOCATE 3, 5: PRINT "Y O U   W I N   T H E   G A M E";
77.         gameOver = -1
78.     END IF
79. END SUB
80.  
81. SUB Miss
82.     DIM row, col
83.     FOR row = (y - 1) TO (y + 1)
84.         FOR col = (x - 1) TO (x + 1)
85.             IF row = y AND col = x THEN LOCATE row, col: PRINT " "; ELSE LOCATE row, col: PRINT "@";
86.         NEXT
87.     NEXT
88.     SOUND 300, .5
89.     SOUND 200, .5
90.     _DELAY 1
91.     m = m - 1
92.     IF m = 0 THEN
93.         CLS
94.         LOCATE 10, 55: PRINT "Score: "; p;
95.         LOCATE 12, 55: PRINT "Cannons Left: "; m;
96.         LOCATE 3, 5: PRINT "Y O U  L O S T";: gameOver = -1
97.     END IF
98. END SUB
99.  
100. SUB Ending
101.     DIM ag$, k$
102.     SOUND 230, .5
103.     SOUND 200, .5
104.     SOUND 210, .5
105.     SOUND 150, .5
106.     SOUND 100, .5
107.     PRINT
108.     CP "Do you want to play again(Y/N)"
109.     WHILE LEN(ag$) = 0
110.         k$ = INKEY$
111.         IF LEN(k$) THEN ag$ = k$
112.     WEND
113.     IF LEFT$(UCASE$(ag$), 1) <> "Y" THEN goAgain = 0
114. END SUB
115.  
116. SUB Begin
117.     DIM dif, k$
118.     x = 20: y = 20: p = 0: gameOver = 0
119.     CLS
120.     LOCATE 4, 1: CP "Alpha-Bit Invaders"
121.     CP "-----------------": PRINT
122.     CP "By Ken G. mod bplus 2019-07-22": PRINT
123.     CP "Destroy 100 falling aliens to win the game.": PRINT: PRINT
124.     CP "Use These Keys": PRINT
125.     CP "Arrow Keys Left and Right to position under letter for firing."
126.     CP "Space Bar to Fire": PRINT
127.     CP "You are here + firing these *": PRINT
128.     CP "Esc to Quit": PRINT
129.     CP "Press any to begin."
130.     SLEEP
131.     CLS
132.     DO
133.         CLS: PRINT: PRINT: PRINT
134.         CP "Difficulty"
135.         CP "----------"
136.         PRINT
137.         CP "(1) 10 cannons - Easy  "
138.         CP "(2) 5 cannons - Average"
139.         CP "(3) 3 cannons - Hard   "
140.         PRINT
141.         CP "Press a number (1 to 3):"
142.         WHILE dif = 0
143.             k$ = INKEY$
144.             IF LEN(k$) THEN dif = VAL(k$)
145.         WEND
146.         IF dif = 1 THEN m = 10
147.         IF dif = 2 THEN m = 5
148.         IF dif = 3 THEN m = 3
149.     LOOP UNTIL 0 < dif AND dif < 4
150. END SUB
151.  
152. SUB CP (s$)
153.     LOCATE CSRLIN, (80 - LEN(s$)) / 2: PRINT s$
154. END SUB
155.  
156.  

EDIT: Almost missed, "Your guy explodes on Miss."

Title: Re: Alphabet Invaders
Post by: Petr on July 23, 2019, 03:09:47 am

Really cool game :-D

Title: Re: Alphabet Invaders
Post by: SierraKen on July 23, 2019, 12:14:08 pm

Thanks Petr :). This was just something I converted from a game back in the 90's.

Text Only | Text with Attachments