Print Page - 3D Tunnel Lines Demonstration

Title: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 11, 2019, 01:33:07 pm

This is about as good as I can do regarding 3D stuff. Although I could use the same type of thing for land I guess.
Use the up and down arrow keys to move forward and back. I will probably turn this into a game at some point. :)
Feel free to use it in your own stuff if you wish. I sure like the SCREEN _NEWIMAGE command's ability to change window sizes, makes things
like this so much easier.

(Code deleted to make it look a bit better, look at next post.)

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 11, 2019, 04:16:11 pm

I added 1 more square and made it look a bit better.

(Code deleted again, now it looks EXTREMELY better! Scroll down this forum thread to get the updated version, which includes the little monster sprite.)

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 11, 2019, 05:33:30 pm

I added a little sprite monster that pops up every so often and then disappears as you move. :) This is the start of a little dungeon game I'm making. Comments are welcome of course.

(Code deleted again, now it looks EXTREMELY better! Scroll down this forum thread to get the updated version.)

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 12, 2019, 01:32:28 am

Here is my 3D Tunnel pointed with mouse:

Code: QB64: [Select]

_TITLE "tunnel" ' B+ 2019-01-04
CONST xmax = 800
CONST ymax = 600
SCREEN _NEWIMAGE(xmax, ymax, 32)
_MOUSEHIDE
WHILE _KEYHIT <> 27
    CLS
    WHILE _MOUSEINPUT: WEND
    mx = _MOUSEX: my = _MOUSEY
    drx = mx / 50: dlx = (xmax - mx) / 50: dty = my / 50: dby = (ymax - my) / 50: i = 0
    x = mx: y = my
    FOR i = 50 TO 1 STEP -1
        LINE (mx - i * drx, my - i * dty)-(mx + i * dlx, my + i * dby), _RGB32(4 * i, 2 * i, 1 * i), BF
    NEXT
    _DISPLAY
    _LIMIT 60
WEND
 
 

To it, I added squared coil and trans-sender (lightning) between inner most point and outer most:

Code: QB64: [Select]

_TITLE "tunnel coil 3 with transcender" ' B+ 2019-01-08
CONST xmax = 800
CONST ymax = 600
SCREEN _NEWIMAGE(xmax, ymax, 32)
_MOUSEHIDE
WHILE _KEYHIT <> 27
    CLS
    WHILE _MOUSEINPUT: WEND
    mx = _MOUSEX: my = _MOUSEY
    dlx = (mx - 1) / 50: drx = (xmax - mx - 1) / 50: dty = (my - 1) / 50: dby = (ymax - my - 1) / 50
    x = mx: y = my
    tx = 0: ty = 0 '<<<<<<<<<<<<<<<< need this to work???
    FOR i = 50 TO 1 STEP -1
        LINE (mx - i * dlx, my - i * dty)-(mx + i * drx, my + i * dby), _RGB32(2 * i, 3 * i, 4 * i), BF
    NEXT
    COLOR _RGBA32(255, 140, 140, 120)
    x = xmax - mx: y = ymax - my
    PSET (x, y)
    tx = 0: ty = 0
    WHILE ty < ymax
        tx = tx + drx
        LINE -STEP(-tx, 0)
        ty = ty + dby
        LINE -STEP(0, -ty)
        tx = tx + dlx
        LINE -STEP(tx, 0)
        ty = ty + dty
        LINE -STEP(0, ty)
    WEND
    Lightning mx, my, xmax - mx, ymax - my, ymax
    _DISPLAY
    _LIMIT 60
WEND
 
SUB Lightning (x1, y1, x2, y2, d)
    IF d < 5 THEN
        COLOR _RGB(225, 225, 245)
        LINE (x1, y1)-(x2, y2)
    ELSE
        mx = (x2 + x1) / 2
        my = (y2 + y1) / 2
        mx = mx + -.5 * RND * d * .4 * rand&&(-2, 2)
        my = my + -.5 * RND * d * .4 * rand&&(-2, 2)
        Lightning x1, y1, mx, my, d / 2
        Lightning x2, y2, mx, my, d / 2
    END IF
END SUB
 
FUNCTION rand&& (lo&&, hi&&)
    rand&& = INT(RND * (hi&& - lo&& + 1)) + lo&&
END FUNCTION
 
 

Then I loaded a bunch of them onto a satellite (Stars.png attached):

Code: QB64: [Select]

_TITLE "Move your mouse" + SPACE$(53) + "Satellite" 'B+ post 2019-01-10
 
CONST xmax = 600
CONST ymax = 600
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 300, 60
map& = _NEWIMAGE(xmax, ymax, 32)
stars& = _LOADIMAGE("stars.png")
r = ymax / 2.5: xc = xmax / 2: yc = ymax / 2: xo = 0
_MOUSEHIDE
 
WHILE _KEYHIT <> 27
    WHILE _MOUSEINPUT: WEND
    mx = _MOUSEX / xmax: my = _MOUSEY / ymax
    _DEST map&
    COLOR , _RGB32(68, 68, 68): CLS
    FOR y = 0 TO ymax STEP 100
        FOR x = 0 TO xmax STEP 100
            tct x + 3, y + 3, 94, 94, mx, my
        NEXT
    NEXT
    _PUTIMAGE , stars&, 0
    FOR y = -r TO r
        x1 = SQR(r * r - y * y)
        tv = (_ASIN(y / r) + 1.5) / 3
        FOR x = -x1 + 1 TO x1
            tu = (_ASIN(x / x1) + 1.5) / 6
            _SOURCE map&
            pc~& = POINT((xo + tu * xmax) MOD xmax, tv * ymax)
            _DEST 0
            PSET (x + xc, y + yc), pc~&
        NEXT x
    NEXT y
    xo = xo - 1 + xmax
    xo = xo MOD xmax
    _DISPLAY
    _LIMIT 10
WEND
 
SUB tct (x, y, w, h, fx, fy)
    mx = fx * w
    my = fy * h
    dlx = (mx - 1) / 10: drx = (w - mx - 1) / 10: dty = (my - 1) / 10: dby = (h - my - 1) / 10
    tx = 0: ty = 0
    FOR i = 10 TO 1 STEP -1
        LINE (x + mx - i * dlx, y + my - i * dty)-(x + mx + i * drx, y + my + i * dby), _RGB32(5 * i, 10 * i, 15 * i), BF
    NEXT
    COLOR _RGBA32(155, 140, 40, 120)
    xx = x + w - mx: yy = y + h - my
    PSET (xx, yy)
    tx = 0: ty = 0
    WHILE tx < w - drx - dlx
        tx = tx + drx
        LINE -STEP(-tx, 0)
        ty = ty + dby
        LINE -STEP(0, -ty)
        tx = tx + dlx
        LINE -STEP(tx, 0)
        ty = ty + dty
        LINE -STEP(0, ty)
    WEND
    Lightning x + mx, y + my, xx, yy, h
END SUB
 
SUB Lightning (x1, y1, x2, y2, d)
    IF d < 5 THEN
        COLOR _RGB(225, 225, 245)
        LINE (x1, y1)-(x2, y2)
    ELSE
        mx = (x2 + x1) / 2
        my = (y2 + y1) / 2
        mx = mx + -.5 * RND * d * .4 * rand&&(-2, 2)
        my = my + -.5 * RND * d * .4 * rand&&(-2, 2)
        Lightning x1, y1, mx, my, d / 2
        Lightning x2, y2, mx, my, d / 2
    END IF
END SUB
 
FUNCTION rand&& (lo&&, hi&&)
    rand&& = INT(RND * (hi&& - lo&& + 1)) + lo&&
END FUNCTION
 
 

Look what it did to my TV:

Code: QB64: [Select]

_TITLE "TV Static test, press esc to quit!"
SCREEN _NEWIMAGE(800, 600, 32)
 
TVimage& = _SCREENIMAGE
TVSCR& = _NEWIMAGE(500, 300, 32)
_PUTIMAGE , TVimage&, TVSCR&
'DIM m AS _MEM
'm = _MEMIMAGE(TVSCR&)
_FREEIMAGE TVimage&
eff = 1
 
'WHILE 1 'to make static move around put it in endless loop
'cheap way to draw box
FOR w = 50 TO 1 STEP -1 '.25
    LINE (100 - w, 100 - w)-(700 - 2 * w, 550 - 2 * w), _RGB32(124 - w, 62 - .5 * w, 31 - .25 * w), B
NEXT
LINE (100, 100)-(700, 550), _RGB32(124, 62, 31), BF
 
'some knobs
FOR r = 20 TO 1 STEP -.5
    CIRCLE (200, 500), r, _RGB(255 - r * 12, 255 - r * 12, 255 - r * 12)
    CIRCLE (600, 500), r, _RGB(255 - r * 12, 255 - r * 12, 255 - r * 12)
NEXT
FOR r = 4 TO 1 STEP -.1
    CIRCLE (200 + r, 500 + r), 8 - .5 * r, _RGB(0, 0, 0)
    CIRCLE (600 + r, 500 + r), 8 - .5 * r, _RGB(0, 0, 0)
    CIRCLE (300 + r, 500 + r), 8 - .5 * r, _RGB(0, 0, 0)
    CIRCLE (400 + r, 500 + r), 8 - .5 * r, _RGB(0, 0, 0)
    CIRCLE (500 + r, 500 + r), 8 - .5 * r, _RGB(0, 0, 0)
NEXT
'WEND
 
DO
    'picture "tube"
    FOR y = 150 TO 450 '                                           y range of box
        FOR x = 150 TO 650 '                                       x range of box
            '   _RGB32(red, green, blue) sets color in this graphics screen mode
            'B&W static   make R, G, B all same number for a shade of gray
 
            much = 250
            position = position + 1: IF position > 300 * 500 THEN position = 150 * 150
            k& = _KEYHIT
            IF k& = 27 THEN END '                             escape was pressed to quit
            IF k& = 32 THEN eff = eff + 1: IF eff > 10 THEN eff = 1
            IF position MOD eff = 0 THEN clr& = _RGB32(RND * 255, RND * 255, RND * 255) ELSE _SOURCE TVSCR&: clr& = POINT(x - 150, y - 150): _SOURCE 0
            PSET (x, y), clr&
        NEXT
    NEXT
    '    LINE (150, 150)-(650, 150 + 250 * RND), _RGB32(255, 255, 255), BF 'roll screen a bit
    DO UNTIL _SNDRAWLEN > .2: _SNDRAW RND: LOOP
    _DISPLAY 'keep flashing from drawing down to minimum
LOOP
'WEND
 
 

PS when trying to watch TV, press space bar.

Fun stuff! :D Carry on...

Title: Re: 3D Tunnel Lines Demonstration
Post by: Ashish on July 12, 2019, 08:30:13 am

Hi. Good job Bplus and Ken. I enjoyed the TV one program

Title: Re: 3D Tunnel Lines Demonstration
Post by: Petr on July 12, 2019, 10:30:29 am

Nice thread. I like all in this thread.

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 12, 2019, 10:37:52 am

Yes Petr, I am sure you contributed to that TV code, the sound and screen image/bad picture... :)

Remove comment on line 49 of TV for a rolling picture effect.

Title: Re: 3D Tunnel Lines Demonstration
Post by: Petr on July 12, 2019, 11:38:20 am

Really? Nice :-D

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 12, 2019, 01:04:08 pm

Awesome programs B+! I checked them all out. Your first one blew me away on the detail of the tunnel. I might learn a bit from that. The hardest thing on my tunnel was the illusion of moving through the tunnel using the arrow keys. You aren't exactly moving down the tunnel, the squares move about 50 coordinates then switch back to the next one, making the illusion. I tried to add paint and also a door on the side but it's too hard for me to figure out. But I might make mine a bit different with maybe many more squares, not sure yet. Thanks also to the others in here that liked my little 1980's looking tunnel. hehe :) I might also just keep it the way it is and add more monsters and gold and stuff. lol

Title: Re: 3D Tunnel Lines Demonstration
Post by: Pete on July 12, 2019, 02:26:19 pm

Reminds me of the TV I grew up watching... Only mine had bigger knobs!

Hey Mark, maybe you could incorporate my "pattern" challenge: https://www.qb64.org/forum/index.php?topic=1494.msg106908#msg106908

LOL - That was a fun run!

Pete

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 12, 2019, 02:56:03 pm

Quote from: SierraKen on July 12, 2019, 01:04:08 pm

Awesome programs B+! I checked them all out. Your first one blew me away on the detail of the tunnel. I might learn a bit from that. The hardest thing on my tunnel was the illusion of moving through the tunnel using the arrow keys. You aren't exactly moving down the tunnel, the squares move about 50 coordinates then switch back to the next one, making the illusion. I tried to add paint and also a door on the side but it's too hard for me to figure out. But I might make mine a bit different with maybe many more squares, not sure yet. Thanks also to the others in here that liked my little 1980's looking tunnel. hehe :) I might also just keep it the way it is and add more monsters and gold and stuff. lol

Hi Ken,

I didn't even know your tunnel moved until the demon arrived, by then I realized there must be more to first 2 posts. You might mention in introduction of code... it probably is why I pulled out that old code, to show how a tunnel is done. :-))

The moving tunnel is a nice effect, I wonder if it can be done without all the line statements? (I will test.) The effect is definitely a keeper! Yes, racer games are built on such... instead of walls, landscape is moving...

Hi Pete,

Yes, your test pattern would work nicely with TV rolling image, a QB64 screen not bad though considering not having to store or attach image.

I was wondering when I would see a comment about the knobs :D

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 12, 2019, 03:02:29 pm

Here is a MUCH better tunnel example. I realized after looking at B+'s code that all I needed was a loop to make it look much better. I also changed the square movement dynamics to be a REAL movement instead of an illusion. B+ I'm sorry you are also working on this, I should have been more precise in my wording on what I was going to do next. I did put a thank you in the code to you for your example. I also added instructions on the _TITLE so people can see it better. Your examples really helped me. Here is the updated version:

Code: QB64: [Select]

'Made by Ken G. on July 11, 2019
'Thank you to B+ for his example on QB64.org forum!
 
_TITLE "Ken's Tunnel - Use Up and Down Arrow Keys"
SCREEN _NEWIMAGE(600, 600, 32)
x = 300: y = 300: t = 50
s = 10
sz2 = 10
FOR sz = s TO 300
    LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(0, sz / 2, 0), B
NEXT sz
 
go:
_LIMIT 1000
a$ = INKEY$
IF a$ = CHR$(27) THEN END
IF a$ = CHR$(0) + CHR$(72) THEN
    os = s
    s = s + 5
    IF s < 10 THEN s = 300
    IF s > 300 THEN s = 10
    t = t + 10
    IF t > 255 THEN t = 20
    LINE (x - os, y - os)-(x + os, y + os), _RGB32(0, sz2 / 2, 0), B
    sz2 = sz2 + 5
    IF sz2 < 10 THEN sz2 = 300
    IF sz2 > 300 THEN sz2 = 10
    LINE (x - s, y - s)-(x + s, y + s), _RGB32(0, t * 2, 0), B
 
    IF m = 0 THEN
        RANDOMIZE TIMER
        monster = INT(RND * 500) + 1
        IF monster > 498 THEN
            m = 1
            GOSUB monster:
        END IF
    END IF
    IF m = 1 THEN
        mon = mon + 1
        IF mon > 50 THEN
            LINE (290, 284)-(316, 316), _RGB32(0, 0, 0), BF
            m = 0
            mon = 0
        END IF
    END IF
END IF
IF a$ = CHR$(0) + CHR$(80) THEN
    os = s
    s = s - 5
    IF s < 10 THEN s = 300
    IF s > 300 THEN s = 10
    t = t + 10
    IF t > 255 THEN t = 20
    LINE (x - os, y - os)-(x + os, y + os), _RGB32(0, sz2 / 2, 0), B
    sz2 = sz2 - 5
    IF sz2 < 10 THEN sz2 = 300
    IF sz2 > 300 THEN sz2 = 10
    LINE (x - s, y - s)-(x + s, y + s), _RGB32(0, t * 2, 0), B
    IF m = 0 THEN
        RANDOMIZE TIMER
        monster = INT(RND * 500) + 1
        IF monster > 498 THEN
            m = 1
            GOSUB monster:
        END IF
    END IF
    IF m = 1 THEN
        mon = mon + 1
        IF mon > 50 THEN
            LINE (290, 284)-(316, 316), _RGB32(0, 0, 0), BF
            m = 0
            mon = 0
        END IF
    END IF
END IF
GOTO go:
 
monster:
RESTORE monsterdata:
FOR my = 1 TO 13
    FOR mx = 1 TO 13
        READ cl
        PSET (mx + 290, my + 290), _RGB32(0, cl * 100, 0)
    NEXT mx
NEXT my
 
RETURN
monsterdata:
DATA 0,0,0,0,4,4,4,4,4,0,0,0,0
DATA 0,0,0,4,0,0,0,0,0,4,0,0,0
DATA 0,0,4,0,0,0,0,0,0,0,4,0,0
DATA 0,4,0,5,5,0,0,5,5,0,0,4,0
DATA 4,0,0,5,5,0,0,5,5,0,0,0,4
DATA 4,0,0,0,0,0,0,0,0,0,0,0,4
DATA 4,0,0,0,0,4,4,0,0,0,0,0,4
DATA 4,0,0,0,0,4,4,0,0,0,0,0,4
DATA 0,4,0,0,0,0,0,0,0,0,0,4,0
DATA 0,0,4,0,4,4,4,4,0,0,4,0,0
DATA 0,0,4,0,4,4,4,4,0,0,4,0,0
DATA 0,0,4,0,0,0,0,0,0,0,4,0,0
DATA 0,0,4,4,4,4,4,4,4,4,4,0,0
 
 

Title: Re: 3D Tunnel Lines Demonstration
Post by: Pete on July 12, 2019, 06:01:09 pm

You'll probably be asked to reove the code for sake of copyright infringement. Sure, you say it's a tunnel, but to me it looks a lot like the old X-box logo!

Hi Mark. Yes. TV was better in the old days, when you could grab both knobs and find what you were looking for. Today, we're stuck in our easy chairs holding our own remotes. That's not progress, that's just pathetic.

Pete

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 12, 2019, 07:06:20 pm

Hi Ken,

Try this:

Code: QB64: [Select]

OPTION _EXPLICIT
'Made by Ken G. on July 11, 2019
'Thank you to B+ for his example on QB64.org forum!
 
_TITLE "Ken's Tunnel - Use Up and Down Arrow Keys" 'mod B+ 2019-07-12
SCREEN _NEWIMAGE(600, 600, 32)
DIM offset, my, mx, cl, s, sz, a$, monster, ms
 
offset = 600000 'track if we are coming or going
DIM SHARED m(1 TO 13, 1 TO 13) AS _UNSIGNED LONG 'monster color storage
FOR my = 1 TO 13 'load monster color array
    FOR mx = 1 TO 13
        READ cl
        m(mx, my) = _RGB32(cl * 60, 0, 0)
    NEXT mx
NEXT my
 
DO 'go: << DO... LOOP indents main loop and makes it easier to read  
    CLS
 
    'handle tunnel
    offset = offset + s
    IF offset = 0 THEN offset = 300000
    IF offset = 600001 THEN offset = 300000
    FOR sz = 0 TO 300
        IF (sz + offset) MOD 40 THEN
            LINE (300 - sz, 300 - sz)-(300 + sz, 300 + sz), _RGB32(0, sz / 2, 0), B
        ELSE
            LINE (300 - sz, 300 - sz)-(300 + sz, 300 + sz), _RGB32(255 * sz / 300, 255 * sz / 300, 255 * sz / 300), B
        END IF
    NEXT sz
 
    'handle keys
    a$ = INKEY$
    IF a$ = CHR$(27) THEN END
    IF a$ = CHR$(0) + CHR$(72) THEN s = s - 1: IF s < -5 THEN s = -5
    IF a$ = CHR$(0) + CHR$(80) THEN s = s + 1: IF s > 5 THEN s = 5
 
    'handle monster
    monster = monster - 1
    IF s > 0 THEN ms = ms - .01
    IF s < 0 THEN ms = ms + .01
    IF ms > 5 THEN ms = 5
    IF ms < 0 THEN ms = 0
    IF monster <= 0 THEN monster = RND * 500 ELSE GOSUB showMonster
 
    _DISPLAY
    _LIMIT 60
LOOP 'goto go
 
showMonster:
FOR my = 1 TO 13
    FOR mx = 1 TO 13
        IF s > 0 THEN
            LINE (mx * ms + 270, my * ms + 270)-STEP(ms, ms), m(mx, my), BF
        ELSE
            LINE (mx * ms + 270, my * ms + 270)-STEP(ms, ms), m(mx, my), BF
        END IF
    NEXT
NEXT
RETURN
 
monsterdata:
DATA 0,0,0,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,4,0,0
DATA 0,4,4,4,4,4,4,4,4,4,4,0,0
DATA 0,4,4,4,4,4,4,4,4,4,4,0,0
DATA 4,4,4,1,1,4,4,1,1,4,4,4,0
DATA 4,4,4,4,4,4,4,4,4,4,4,4,0
DATA 4,4,4,4,4,4,1,4,4,4,4,4,0
DATA 4,4,4,4,4,1,1,4,4,4,4,4,0
DATA 0,4,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,1,1,1,1,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,0,0,0,0
 

EDIT: made monster size, ms, work better.
EDIT2: more comments and monster face lift

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 12, 2019, 09:55:45 pm

That's really amazing B+.... am a bit shocked how much you guys know. For example, I should learn what MOD means and what offset does. It might take awhile for me to make a game out of this, if I do make one. This Summer Heat is really slowing down my programming about half as much as it was a few weeks ago. But I still want to keep going. :))) Thank you!

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 12, 2019, 10:13:49 pm

Hi Ken,

MOD is the remainder part of a division of two integers:
1/3 = 0 R 1 so 1 MOD 3 = 1
2/3 = 0 R 2 so 2 MOD 3 = 2
3/3 = 1 R 0 so 3 MOD 3 = 0 another way of saying 3 divides 3 exactly, like 3 divides 6, 3 divides 9, 3 divides 12...
4/3 = 1 R 1 so 4 MOD 3 = 1
5/3 = 1 R 2 so 5 MOD 3 = 2, the remainder of m/n is always between 0 and n-1, you can never have a remainder >= n which comes in really handy for allot things in computer programming.

n MOD m
+ it always keeps numbers between 0 and m-1
+ you can test if something divides evenly, if a mod b = 0, b divides a as 6 mod 3 = 0 because 3 divides 6
+ toggle = (toggle + 1) MOD 2 always keeps toggle at 0 or 1

offset is just an add on, say you want a box every 10 pixels, but you want to start with a margin of 5 from edge the the x offset is 5: boxX(i) = i * 10 + xOffset

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 12, 2019, 11:59:41 pm

Very cool, thanks B+. I've also been wondering about how I used to use XOR with PUT to make graphics put on top of other graphics and the rest remains, without having to draw it again. Might be something for me to look into if it's still online somewhere.

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 13, 2019, 12:05:23 pm

Quote from: SierraKen on July 12, 2019, 11:59:41 pm

Very cool, thanks B+. I've also been wondering about how I used to use XOR with PUT to make graphics put on top of other graphics and the rest remains, without having to draw it again. Might be something for me to look into if it's still online somewhere.

I don't know if XOR is used that much unless manipulating bits, you're talking numbers in binary format.

Let's stick to elements this thread brings up. I would spend my time learning _PUTIMAGE over the old way of PUT.

We could practice with the monster image. Can you set up an area to draw the monster using _NEWIMAGE, draw the monster there with the data statements (then you don't need an array to store the colors nor have to redraw from array, just use _PUTIMAGE). This is when you learn _SOURCE and _DEST, specially _DEST for telling QB where images are coming from (_SOURCE) and are to go (_DEST) that's what _PUTIMAGE needs the most.

'set up Monster area to draw it and store image under the handle monster& << notice type long

Code: QB64: [Select]

monster& = _NEWIMAGE(12, 12, 32) 'the monster is 13 x 13 which is 0 to 12 X 0 to 12
_DEST monster&  '<<< drawing commands will now go to monster& area
FOR my = 0 TO 12 'draw monster in monster& image area
    FOR mx = 0 TO 12
        READ cl
        pset (mx, my), _RGB32(cl * 60, 0, 0)
    NEXT mx
NEXT my
'we now have a monster image stored under the handle monster& 
_DEST 0 ' back to the screen

Use _PUTIMAGE to show monster. Here is the "monster" Swiss army knife of _PUTIMAGE command:
' _PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&][, ][STEP][(sx1, sy1)[-STEP][(sx2, sy2)]]

dx, dy controls where on screen for top, left corner, bottom right corner, the monster image will stretch or shrink to fit there dx, dy coordinates you specify. d stand for destination which is main screen for our monster&
(dx1, dy1) is top left corner
(dx2, dy2) is bottom left corner
with these you can control how big or small to show the monster on main screen.

Source handle is monster&
Destination handle is 0 for default screen

sx, sy controls what parts to show from source image, we are using whole image so those options remain blank

This code replace load array colors of monster and _PUTIMAGE replaces the GOSUB showMonster:

Still need:
monsterdata:
DATA 0,0,0,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,4,0,0
DATA 0,4,4,4,4,4,4,4,4,4,4,0,0
DATA 0,4,4,4,4,4,4,4,4,4,4,0,0
DATA 4,4,4,1,1,4,4,1,1,4,4,4,0
DATA 4,4,4,4,4,4,4,4,4,4,4,4,0
DATA 4,4,4,4,4,4,1,4,4,4,4,4,0
DATA 4,4,4,4,4,1,1,4,4,4,4,4,0
DATA 0,4,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,1,1,1,1,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,0,0,0,0

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 13, 2019, 01:34:22 pm

And this is what I worked out for ShowMonster

Code: QB64: [Select]

showMonster:
'PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&]
_PUTIMAGE (300 - ms * 10, 300 - ms * 10)-(300 + ms * 10, 300 + ms * 10), monsterh&, 0
RETURN
 

Title: Re: 3D Tunnel Lines Demonstration
Post by: SMcNeill on July 13, 2019, 02:44:39 pm

Bplus: PUT (as the graphical command), was the old school way to store images in an array buffer and place them onto the screen, and XOR was one of the options available to draw (and remove) those images. The wiki has a description of the PUT options here: https://www.qb64.org/wiki/PUT_(graphics_statement)

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 13, 2019, 03:27:37 pm

Quote from: SMcNeill on July 13, 2019, 02:44:39 pm

Bplus: PUT (as the graphical command), was the old school way to store images in an array buffer and place them onto the screen, and XOR was one of the options available to draw (and remove) those images. The wiki has a description of the PUT options here: https://www.qb64.org/wiki/PUT_(graphics_statement)

Yes, I did call PUT the "old way", but Steve wouldn't you advise learning new way with _PUTIMAGE, it's so much better!

This works great for resizing demon image:

Code: QB64: [Select]

OPTION _EXPLICIT
'Made by Ken G. on July 11, 2019
'Thank you to B+ for his example on QB64.org forum!
'2019-07-13 Bplus update with using image techniques
_TITLE "Ken's Tunnel - Use Up and Down Arrow Keys" 'mod B+ 2019-07-12
SCREEN _NEWIMAGE(600, 600, 32)
DIM offset, my, mx, cl, s, sz, a$, monster, ms, monsterh&
 
'get monster image stored under monsterh&
monsterh& = _NEWIMAGE(12, 12, 32) 'the monster is 13 x 13 which is 0 to 12 X 0 to 12
_DEST monsterh& '<<< drawing commands will now go to monster& area
FOR my = 0 TO 12 'draw monster in monster& image area
    FOR mx = 0 TO 12
        READ cl
        PSET (mx, my), _RGB32(cl * 60, cl * 60, cl * 60)
    NEXT mx
NEXT my
'we now have a monster image stored under the handle monster&
_DEST 0 ' back to the screen
 
offset = 600000 'track if we are coming or going
 
DO 'go:  DO... LOOP indents main loop and makes it easier to read
    CLS
 
    'handle tunnel
    offset = offset + s
    IF offset = 0 THEN offset = 300000
    IF offset = 600001 THEN offset = 300000
    FOR sz = 0 TO 300
        IF (sz + offset) MOD 40 THEN
            LINE (300 - sz, 300 - sz)-(300 + sz, 300 + sz), _RGB32(0, sz / 2, 0), B
        ELSE
            LINE (300 - sz, 300 - sz)-(300 + sz, 300 + sz), _RGB32(255 * sz / 300, 255 * sz / 300, 255 * sz / 300), B
        END IF
    NEXT sz
 
    'handle keys
    a$ = INKEY$
    IF a$ = CHR$(27) THEN END
    IF a$ = CHR$(0) + CHR$(72) THEN s = s - 1: IF s < -5 THEN s = -5
    IF a$ = CHR$(0) + CHR$(80) THEN s = s + 1: IF s > 5 THEN s = 5
 
    'handle monster
    monster = monster - 1
    IF s > 0 THEN ms = ms - .05
    IF s < 0 THEN ms = ms + .05
    IF ms > 5 THEN ms = 5
    IF ms < 0 THEN ms = 0
    IF monster <= 0 THEN monster = RND * 500 ELSE GOSUB showMonster
 
    _DISPLAY
    _LIMIT 60
LOOP 'goto go
 
showMonster:
'PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&]
_PUTIMAGE (300 - ms * 10, 300 - ms * 10)-(300 + ms * 10, 300 + ms * 10), monsterh&, 0
RETURN
 
monsterdata:
DATA 0,0,0,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,4,0,0
DATA 0,0,4,4,4,4,4,4,4,4,4,4,0
DATA 0,4,4,4,4,4,4,4,4,4,4,4,0
DATA 0,4,4,1,1,1,4,4,1,1,1,4,4
DATA 0,4,4,1,1,1,4,4,1,1,1,4,4
DATA 0,4,4,2,2,2,4,4,2,2,2,4,4
DATA 0,4,4,4,4,4,1,1,4,4,4,4,4
DATA 0,0,4,4,4,4,4,4,4,4,4,4,0
DATA 0,0,4,4,4,1,1,1,1,4,4,0,0
DATA 0,0,0,4,4,4,4,4,4,4,4,0,0
DATA 0,0,0,4,4,4,4,4,4,4,0,0,0
DATA 0,0,0,4,4,4,4,4,4,4,0,0,0
 

PS I was screwing around with image data...

Title: Re: 3D Tunnel Lines Demonstration
Post by: SMcNeill on July 13, 2019, 03:39:29 pm

Aye. I’d definitely promote _PUTIMAGE over PUT. I was mainly just responding to your statement here:

Quote

I don't know if XOR is used that much unless manipulating bits, you're talking numbers in binary format.

It’s not used much nowadays, but you’ll see it in old QBasic programs to do as Ken suggested — drawing on top of various backgrounds. ;)

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 13, 2019, 03:59:47 pm

Thanks guys, but B+ you are doing too much. I pretty much took off on my original code, but I am using your monster. I tried to put your code in mine but it didn't work for some reason and I couldn't figure it out. Here is where I am so far, but unless I ask for certain help on something, there's no need to try to help me with it. I use the Wiki pages a lot and today I learned how to use JPG pictures for doors on the side. For a few days I've just been using boxes for doors on the side but my own JPG pictures look much better. :) I will also do that for monsters too, etc. I'm not certain yet if I will keep that sprite monster, it was pretty much only for testing. Also, I really don't have a plan yet on my game, I just add something when I come up with something. But if you are curious, here is my code so far, but as of right now I don't need anything. I appreciate all the help you have given though. I just don't want you to take off in one direction and me the other. Also, personally, it feels best when I know exactly what all my code does. Back in the 90's I used to toss other people's code in my programs and most of the time I had no idea what it did. I'm a slow learner. lol But of course, feel free to always have suggestions, thanks. Oh, and right now the doors are just for looks, you can't enter them yet, but soon I hope to be able to. The door pictures are attached to this post. Oh also, I removed the way to back up so people just use the up arrow key now to go forward. There wouldn't be much of a need to back up. If I get really good and want people to turn around, they can use the arrow keys. I'm thinking to open the doors, people can just press the O or D keys, but that will be in the _TITLE so people know first.

(Note: There is a much better version below on this forum page.)

Code: QB64: [Select]

OPTION _EXPLICIT
'Made by Ken G.
'Thank you to B+ for his example on QB64.org forum!
'Other files needed for this game: doorl.jpg, doorr.jpg
 
_TITLE "Ken's Tunnel - Use Up Arrow Key To Move"
 
begin:
DIM segment(100)
DIM my, mx, cl, s, sz, a$, monster, ms, x, y, t, sz2, seg2, length, rt, tu, doorr, doorl, os, m, mon
 
SCREEN _NEWIMAGE(600, 600, 32)
x = 300: y = 300: t = 50
s = 10
sz2 = 10
seg2 = 1
'Load tunnel into memory.
RANDOMIZE TIMER
length = INT(RND * 60) + 30
tunnel:
RANDOMIZE TIMER
rt = INT(RND * 100) + 1
tu = tu + 1
IF rt < 25 THEN
    segment(tu) = 1 'Right Door
END IF
IF rt >= 25 AND rt < 50 THEN
    segment(tu) = 2 'Left Door
END IF
IF rt >= 50 THEN
    segment(tu) = 3 'No Door
END IF
IF tu = length THEN GOTO starttunnel:
GOTO tunnel:
 
starttunnel:
FOR sz = s TO 300
    LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 2, sz / 2, sz / 2), B
NEXT sz
 
 
 
doorl = _LOADIMAGE("doorl.jpg", 32)
doorr = _LOADIMAGE("doorr.jpg", 32)
 
go:
 
a$ = INKEY$
IF a$ = CHR$(27) THEN END
IF a$ = CHR$(0) + CHR$(72) THEN
    os = s
    s = s + 5
    IF s < 10 THEN s = 300: seg2 = seg2 - 1
    IF s > 300 THEN s = 10: seg2 = seg2 + 1
    t = t + 10
    IF t > 255 THEN t = 20
 
    sz2 = sz2 + 1
    IF sz2 < 10 THEN sz2 = 300
    IF sz2 > 300 THEN sz2 = 10
    IF m = 0 THEN
        RANDOMIZE TIMER
        monster = INT(RND * 500) + 1
        IF monster > 498 THEN
            m = 1
            GOSUB monster:
        END IF
    END IF
    IF m = 1 THEN
        mon = mon + 1
        IF mon > 50 THEN
            LINE (290, 284)-(316, 316), _RGB32(0, 0, 0), BF
            m = 0
            mon = 0
        END IF
    END IF
END IF
IF segment(seg2) = 1 THEN 'Right Door
 
    _PUTIMAGE (x + 50 + s, y - s - 50)-(x + 70 + s * 1.5, y + s + 50), doorr
    FOR sz = s + 50 TO 10 STEP -1
        LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 2, sz / 2, sz / 2), B
    NEXT sz
END IF
 
IF segment(seg2) = 2 THEN 'Left Door
    _PUTIMAGE (x - 70 - s * 1.5, y - s - 50)-(x - 50 - s, y + s + 50), doorl
 
    FOR sz = s + 50 TO 10 STEP -1
        LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 2, sz / 2, sz / 2), B
    NEXT sz
END IF
 
IF segment(seg2) = 3 THEN 'No Door
    LINE (x - s, y - s)-(x + s, y + s), _RGB32(127, 255, 127), B
    FOR sz = s - 1 TO 10 STEP -1
        LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 2, sz / 2, sz / 2), B
    NEXT sz
END IF
 
IF segment(seg2) = 0 THEN
    LOCATE 30, 30: PRINT "You Beat The Tunnel!"
    LOCATE 35, 30: INPUT "Press enter to end.", a$
    END
END IF
 
 
 
GOTO go:
 
monster:
RESTORE monsterdata:
FOR my = 1 TO 13
    FOR mx = 1 TO 13
        READ cl
        PSET (mx + 290, my + 290), _RGB32(0, cl * 100, 0)
    NEXT mx
NEXT my
RETURN
 
RETURN
 
 
 
monsterdata:
DATA 0,0,0,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,4,0,0
DATA 0,4,4,4,4,4,4,4,4,4,4,0,0
DATA 0,4,4,4,4,4,4,4,4,4,4,0,0
DATA 4,4,4,1,1,4,4,1,1,4,4,4,0
DATA 4,4,4,4,4,4,4,4,4,4,4,4,0
DATA 4,4,4,4,4,4,1,4,4,4,4,4,0
DATA 4,4,4,4,4,1,1,4,4,4,4,4,0
DATA 0,4,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,1,1,1,1,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,4,0,0,0
DATA 0,0,4,4,4,4,4,4,4,0,0,0,0
 
 

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 19, 2019, 02:19:35 pm

I'm back at working with this game. This morning I was able to add the ability to go through the doors :). It doesn't show the doors opening or anything but you use the left and right arrow keys to go to a different tunnel by going through them when you see them. The tunnels also change colors as you go through the doors so you know you are in a different tunnel. I think I'm going to make this into a little 3d shooter game of some kind. Maybe have the monster shoot at you or something. Or shooter / RPG dungeon game. Now that I got the doors out of the way, I can add pretty much anything! :))

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 19, 2019, 07:36:19 pm

I finished the game! It's self explanatory on the front page. Tell me what you think everyone :).
You also have to use the 2 door picture files I will put again as attachments to this post. So I suggest putting the game and 2 door pictures in its own folder. I did decide to make a different monster to make him larger and easier to see.
It's mostly another random game, except you have to shoot the monster before he shoots you. You also can run from the monster by entering any of the doors to another tunnel.
Have fun!

Code: QB64: [Select]

'Ken's Tunnels
'Made by Ken G.
'Thank you to B+ for his example on QB64.org forum!
'Other files needed for this game: doorl.jpg, doorr.jpg
'
'This game makes a rnadom dungeon before you start, so every game will be different.
'Use the up arrow key and the left and right arrow key to move forward and through the doors on the sides.
 
_TITLE "Ken's Tunnel - Use Up and Left and Right Arrow Keys To Move and Space Bar."
 
begin:
DIM segment(500)
SCREEN _NEWIMAGE(600, 600, 32)
CLS
PRINT "                           K e n ' s   T u n n e l s"
PRINT: PRINT: PRINT
PRINT "                                 By Ken G."
PRINT: PRINT: PRINT
PRINT "Use the arrow keys up, left, and right to move forward and into the next"
PRINT "tunnels on the left or right doors."
PRINT "Use the Space Bar to fire at the monster ahead of you."
PRINT "You can dodge the monster by going into any of the doors."
PRINT "If you see a door anywhere on your screen, you can use it."
PRINT "The object of the game is to finish the tunnels without losing the game."
PRINT "To end anytime, press the Esc key."
PRINT "Every game is different!"
PRINT
PRINT "Be ready as soon as it starts!"
PRINT
INPUT "Press Enter to start game.", a$
CLS
 
x = 300: y = 300: t = 50
s = 20
sz2 = 10
seg2 = 1
lives = 10
m = 0
mon = 0
points = 0
tu = 0
'Load tunnel into memory.
RANDOMIZE TIMER
length = INT(RND * 15) + 25
tunnel:
RANDOMIZE TIMER
rt = INT(RND * 100) + 1
tu = tu + 1
IF rt < 25 THEN
    segment(tu) = 1 'Right Door
END IF
IF rt >= 25 AND rt < 50 THEN
    segment(tu) = 2 'Left Door
END IF
IF rt >= 50 THEN
    segment(tu) = 3 'No Door
END IF
IF tu = length THEN GOTO starttunnel:
GOTO tunnel:
 
starttunnel:
GOSUB drawtunnel:
 
 
doorl = _LOADIMAGE("doorl.jpg", 32)
doorr = _LOADIMAGE("doorr.jpg", 32)
 
go:
_LIMIT 400
a$ = INKEY$
IF a$ = CHR$(27) THEN END
IF a$ = CHR$(0) + CHR$(72) THEN
    os = s
    s = s + 5
    IF s < 10 THEN s = 300: seg2 = seg2 - 1
    IF s > 300 THEN s = 20: seg2 = seg2 + 1
    t = t + 10
    IF t > 255 THEN t = 20
 
    sz2 = sz2 + 1
    IF sz2 < 10 THEN sz2 = 300
    IF sz2 > 300 THEN sz2 = 10
    IF m = 0 THEN
        RANDOMIZE TIMER
        monster = INT(RND * 500) + 1
        IF monster > 495 THEN
            m = 1
            GOSUB monster:
        END IF
    END IF
    IF m = 1 THEN
        mon = mon + 1
        IF mon > 50 THEN
            LINE (285, 284)-(316, 316), _RGB32(0, 0, 0), BF
            m = 0
            mon = 0
        END IF
    END IF
END IF
 
IF m = 1 THEN
    RANDOMIZE TIMER
    monstershoot = INT(RND * 1000) + 1
    IF monstershoot > 998 THEN
        SOUND 800, 1
        FOR blast = 3 TO 26 STEP 1
            CIRCLE (300, 300), blast, _RGB32(127, 255, 127)
            _DELAY .01
            CIRCLE (300, 300), blast, _RGB32(0, 0, 0)
        NEXT blast
        lives = lives - 1
        GOSUB monster:
        SOUND 400, 1
        SOUND 300, 2
        SOUND 200, 2
        SOUND 100, 3
        points$ = STR$(points)
        lives$ = STR$(lives)
        _TITLE "Ken's Tunnels            Score:" + points$ + "             Lives: " + lives$
        IF lives < 1 THEN
            LOCATE 20, 30: PRINT "G A M E     O V E R"
            LOCATE 23, 30: PRINT "Score:"; points
            LOCATE 25, 30: INPUT "Play Again (Yes/No)?", ag$
            IF ag$ = "y" OR ag$ = "Y" OR ag$ = "YES" OR ag$ = "yes" OR ag$ = "yes" OR ag$ = "yES" OR ag$ = "yeS" OR ag$ = "yes" THEN GOTO begin:
            END
        END IF
    END IF
    points$ = STR$(points)
    lives$ = STR$(lives)
    _TITLE "Ken's Tunnels            Score:" + points$ + "             Lives: " + lives$
END IF
 
 
IF a$ = CHR$(0) + CHR$(77) AND segment(seg2) = 1 THEN
    RANDOMIZE TIMER
    cl = INT(RND * 200) + 1
    RANDOMIZE TIMER
    cl2 = INT(RND * 200) + 1
    RANDOMIZE TIMER
    cl3 = INT(RND * 200) + 1
    LINE (285, 284)-(316, 316), _RGB32(0, 0, 0), BF
    m = 0
    mon = 0
    GOSUB drawtunnel:
 
END IF
IF a$ = CHR$(0) + CHR$(75) AND segment(seg2) = 2 THEN
    RANDOMIZE TIMER
    cl = INT(RND * 200) + 1
    RANDOMIZE TIMER
    cl2 = INT(RND * 200) + 1
    RANDOMIZE TIMER
    cl3 = INT(RND * 200) + 1
    LINE (285, 284)-(316, 316), _RGB32(0, 0, 0), BF
    m = 0
    mon = 0
    GOSUB drawtunnel:
END IF
 
IF a$ = " " THEN
    SOUND 100, 1
    FOR blast = 25 TO 3 STEP -1
        CIRCLE (300, 300), blast, _RGB32(255, 6, 0)
        _DELAY .01
        CIRCLE (300, 300), blast, _RGB32(0, 0, 0)
    NEXT blast
    IF m = 1 THEN
        SOUND 100, 1
        SOUND 200, 2
        SOUND 300, 2
        SOUND 400, 3
        LINE (285, 284)-(316, 316), _RGB32(0, 0, 0), BF
        m = 0
        mon = 0
        points = points + 100
        points$ = STR$(points)
        lives$ = STR$(lives)
        _TITLE "Ken's Tunnels            Score:" + points$ + "             Lives: " + lives$
    END IF
END IF
 
nex:
 
IF segment(seg2) = 1 THEN 'Right Door
 
    _PUTIMAGE (x + 50 + s, y - s - 50)-(x + 70 + s * 1.5, y + s + 50), doorr
    FOR sz = s + 50 TO 20 STEP -1
        LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 5 + cl, sz / 6 + cl2, sz / 7 + cl3), B
    NEXT sz
END IF
 
IF segment(seg2) = 2 THEN 'Left Door
    _PUTIMAGE (x - 70 - s * 1.5, y - s - 50)-(x - 50 - s, y + s + 50), doorl
 
    FOR sz = s + 50 TO 20 STEP -1
        LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 5 + cl, sz / 6 + cl2, sz / 7 + cl3), B
    NEXT sz
END IF
 
IF segment(seg2) = 3 THEN 'No Door
    LINE (x - s, y - s)-(x + s, y + s), _RGB32(127, 255, 127), B
    FOR sz = s - 1 TO 20 STEP -1
        LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 5 + cl, sz / 6 + cl2, sz / 7 + cl3), B
    NEXT sz
END IF
 
IF segment(seg2) = 0 THEN
    LOCATE 21, 30: PRINT "You Beat The Tunnels!"
    LOCATE 23, 30: PRINT "Score:"; points
    LOCATE 25, 30: INPUT "Play Again (Yes/No)?", ag$
    IF ag$ = "y" OR ag$ = "Y" OR ag$ = "YES" OR ag$ = "yes" OR ag$ = "yes" OR ag$ = "yES" OR ag$ = "yeS" OR ag$ = "yes" THEN GOTO begin:
    END
END IF
 
 
 
GOTO go:
 
monster:
RESTORE monsterdata:
FOR my = 1 TO 16
    FOR mx = 1 TO 30
        READ cll
        PSET (mx + 285, my + 290), _RGB32(0, cll * 250, 0)
    NEXT mx
NEXT my
RETURN
 
RETURN
 
drawtunnel:
FOR sz = s TO 300
    LINE (x - sz, y - sz)-(x + sz, y + sz), _RGB32(sz / 5 + cl, sz / 6 + cl2, sz / 7 + cl3), B
NEXT sz
segment(seg2) = 3
RETURN
 
 
 
 
monsterdata:
DATA 0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,0,0,0,0,0,0
DATA 0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,0,0,0,0,0,0
DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,1,1,1,1,0,0,0,0,1,1,1,0,0,0,0,0,0
DATA 0,0,0,1,1,1,1,1,1,0,0,0,0,1,1,1,1,0,0,0,0,1,1,1,1,1,1,0,0,0
DATA 0,0,0,1,1,1,1,1,1,0,0,0,0,1,1,1,1,0,0,0,0,1,1,1,1,1,1,0,0,0
DATA 0,0,0,1,1,1,1,1,1,0,0,0,0,1,1,1,1,0,0,0,0,1,1,1,1,1,1,0,0,0
DATA 0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,0,0,0,0,0,0
DATA 0,0,0,0,0,0,1,1,1,1,1,1,1,1,0,0,1,1,1,1,1,1,1,1,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,1,1,1,1,1,0,0,0,0,1,1,1,1,1,0,0,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,1,0,0,0,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,0,0,0,0,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,0,0,0,1,1,0,0,0,0,1,1,0,0,0,0,0,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,0,0,0,1,1,0,0,0,0,1,1,0,0,0,0,0,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,0,0,0,1,1,0,0,0,0,1,1,0,0,0,0,0,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,0,0,0,0,0,0,0,0,0,0,0
DATA 0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,0,0,0,0,0,0,0,0,0,0,0
 
 
 

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 20, 2019, 06:18:12 pm

It's been a little over 1 month now since I started using QB64. June 20 was when I completed Ping Pong 2 which was my first game on QB64. So I want to thank you all for encouraging me to keep programming and making apps and games with this language. It has been a wild ride and has kept me busy. Thank you!

Title: Re: 3D Tunnel Lines Demonstration
Post by: bplus on July 20, 2019, 06:43:39 pm

Quote from: SierraKen on July 20, 2019, 06:18:12 pm

It's been a little over 1 month now since I started using QB64. June 20 was when I completed Ping Pong 2 which was my first game on QB64. So I want to thank you all for encouraging me to keep programming and making apps and games with this language. It has been a wild ride and has kept me busy. Thank you!

I like your enthusiasm and your ability to turn even this little bit of tunnel code into a game, excellent start!

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 20, 2019, 06:59:28 pm

Thanks B+! Maybe soon I'll think of something else to make. lol

Title: Re: 3D Tunnel Lines Demonstration
Post by: OldMoses on July 21, 2019, 01:12:35 pm

Quote from: SierraKen on July 20, 2019, 06:18:12 pm

It's been a little over 1 month now since I started using QB64. June 20 was when I completed Ping Pong 2 which was my first game on QB64. So I want to thank you all for encouraging me to keep programming and making apps and games with this language. It has been a wild ride and has kept me busy. Thank you!

Just like you, I joined (relatively) recently; last year about this time, and have been like a kid in a candy store with QB64. There's so much more power at your fingertips than QuickBasic 4.5 could muster, and no more DOS emulators, as fine as they were. It's cool to see someone else discovering it.

I note that you mentioned MOD earlier. That's one that I never paid attention to before, but recently discovered wields a lot of utility once you get to know it, it greatly simplified several display tools in my space vector plotter. A 20+ year old program which was DOA until QB64 brought some bigger variable ranges to the table.

Great job on the game, keep 'em comin'.

PS... I was thinking that you could _PUTIMAGE the monsters face and have it grow in perspective size as it comes down the tunnel...just a thought to challenge you with. ;)

PPS You know, you never really "finish" a game. You just put out there and let it roll until you can come back with new and better tools to upgrade it.

Title: Re: 3D Tunnel Lines Demonstration
Post by: SierraKen on July 21, 2019, 04:44:16 pm

LOL That's true about games or programs, you never really finish them. I haven't used this version of MOD yet, but it's funny you bring that up because right now I'm working on a VERY simple Space Invaders like game, which I am converting from an ASIC 5.0 language one I did back in the 90's and I used MOD in a different way back then, with RND, but I still don't know exactly why, I can't remember why I used it. Had something to do with the range of random numbers to pick from. Maybe ASIC's MOD was different than QBasic, or maybe not, I can't tell, but it's not important. Actually, the more I think about it, I think it used RND with MOD by picking a random number between 0 and 1 and then getting the MOD of that and then I timed that by the number I wanted the range to be in. I think that's what I did.

Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SierraKen on July 11, 2019, 01:33:07 pm