Print Page - Binary file mode questions

I want to create a binary file that is byte based. Capable of accessing individual bytes, reading them in, logically modifying the bits within, and then writing the new byte back to the file. I did this many many years ago in QB4.5 no problem. This is for making state machine patterns I burn into flash memory and then clock out with a simple 19 bit counter. Think: "Player piano roll".
The QB keywords I can't recall were the ones that control the file pointer, read and write binary.
I can create the file. My counters is going from 0 to 524,287 (half a mega byte) But the resulting file is zero bytes long.

Would someone be kind enough to create a very simple code example of:
1. opening the file in binary mode,
2. writing a few hex FFs to it,
3. then reading one byte back in ,
4. modifying it and writing it back into the file at the same location?

Thanks in advance!
~Videolabguy~

Here's to get you started:

1. opening the file in binary mode,
http://www.qb64.org/wiki/OPEN

2. writing a few hex FFs to it,
http://www.qb64.org/wiki/PUT

3. then reading one byte back in ,
http://www.qb64.org/wiki/SEEK_(statement) (http://www.qb64.org/wiki/SEEK_(statement))
http://www.qb64.org/wiki/GET

4. modifying it and writing it back into the file at the same location?
http://www.qb64.org/wiki/PUT

Welcome to the forum.

Thanks!

Small training... :-D

Code: QB64: [Select]

 
'1. opening the file in binary mode,
'2. writing a few hex FFs to it,
'3. then reading one byte back in ,
'4. modifying it and writing it back into the file at the same location?
 
 
'So, how big is maximal value for writing to file? Is it integer value? Is it 0 to 256, so                 _UNSIGNED BYTE (1 byte record)? or
'                                                                       is it 0 to 65535, so               _UNSIGNED INTEGER (2 byte record), or
'                                                                       is it 0 to 4294967295,             _UNSIGNED LONG (4 byte record), or
'                                                                       is it  0 to 18446744073709551615,  _UNSIGNED INTEGER64 (8 byte record)
'
'                                           OR SIGNED integer value?             -128 to 127                   _BYTE, (1 byte record)
'                                                                               -32768 to 32767                 INTEGER (2 byte record)
'                                                                          -2147483648 to 2147483647            LONG (4 byte record)
'                                                                 -9223372036854775808 to 9223372036854775807   INTEGER64 (8 byte record)
 
'                                           OR DECIMAL value?  use SINGLE type up to 7 digits (4 byte lenght record), can not be _UNSIGNED
'                                                          or  use DOUBLE type up ti 15 digits (8 byte lenght record), can not be _UNSIGNED.
 
'so for code:
'1]
File$ = "BinaryFile" 'new binary file name
channel = FREEFILE 'give free number for opening file
IF _FILEEXISTS(File$) THEN PRINT File$; " exists. Owervrite it? [Y/N]": INPUT choice$ 'test, if file already exists or not
IF UCASE$(choice$) = "Y" THEN KILL File$ 'if file exist and you set OWERWRITE, delete old file with the same name
 
OPEN "BinaryFile" FOR BINARY AS #channel 'create new binary file
'write 10 _UNSIGNED _BYTE values to file. Are possible TWO ways how do it. First is convert every value to _UNSIGNED _BYTE numeric type  using _MK$, or
'with DIM:
 
 
'2]
DIM Value(9) AS _UNSIGNED _BYTE 'create 10 records in array Value, type _UNSIGBNED _BYTE in memory
PRINT "This values are now writed to binary file "; File$
PRINT
FOR fill = 0 TO 9
    Value(fill) = 10 * fill 'write this values to array: Value(0) = 0, Value(1) = 10 ..... Value(9) = 90
    PRINT Value(fill);: IF fill < 9 THEN PRINT LTRIM$(","); ELSE PRINT
    PUT #channel, , Value(fill) '  write it to file
NEXT fill
 
'3]
s:
INPUT "Which record read from file? [0-9]"; rec
'beacuse all values are _UNSIGNED _BYTE type, is every record lenght 1 byte.
IF rec > 9 THEN PRINT "invalid value": GOTO s
 
'reading value from file (file is opened)
 
DIM ValueNr AS _UNSIGNED _BYTE
SEEK #channel, rec + 1
GET #channel, , ValueNr
PRINT "Value nr. "; rec; "writed in file is "; ValueNr
 
INPUT "Read next value? [Y/N]"; rnv$
IF UCASE$(rnv$) = "Y" THEN GOTO s
 
 
'4]  Modifiyng it and write to the same position:
'is as reading file:
t:
INPUT "Input record number (0-9) for rewriting"; recnr
IF recnr < 0 OR recnr > 9 THEN PRINT "Invalid record": GOTO t
PRINT "Insert new value in range 0 - 255, OR insert bigger value, but this": PRINT "is then writed BAD!, because is OUT OF RANGE for _UNSIGNED _BYTE type!"
DIM NewVal AS _UNSIGNED _BYTE
INPUT "Insert new value for this position"; NewVal
'again: 1 record lenght is 1 byte. So first shift to area i n file contains previous record:
 
'two ways how do it:
SEEK #channel, recnr + 1 ' because record 0 start on byte 1 and not on byte 0. SEEK shift position in file
PUT #channel, , NewVal
 
'or in one step:      PUT #channel, recnr+1 , newval
 
'now read and print all values from file to screen:
 
PRINT "In file "; File$; "are writed this values:"
'i use previous _UNSIGNED _BYTE type variable named as ValueNr
 
FOR read_it = 1 TO 10
    GET #channel, read_it, ValueNr
    PRINT ValueNr;
NEXT
 

To allow a NewVal record greater than 255 (on end this program) , this variable must be defined as another data type. This, of course, will change the length of the record in the file, so all subsequent values in the file will be invalid without any further modifications to the program.

Thank you kindly.

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Videolabguy on April 23, 2019, 11:42:59 pm