Print Page - Ball Breaker

Active Forums => Programs => Topic started by: SMcNeill on April 04, 2019, 12:33:29 pm

Title: Ball Breaker
Post by: SMcNeill on April 04, 2019, 12:33:29 pm

Code: QB64: [Select]

CONST Blue = &HFF0000FF~& ' _RGB32(0,0,255)
CONST Brown = &HFFA52A2A~& ' _RGB32(165,42,42)
CONST BrickRed = &HFFCB4154~& '_RGB32(203,65,84)
CONST Red = &HFFFF0000~&
CONST SkyBlue = &HFF87CEEB~& ' _RGB32(135,206,235)
 
 
DEFLNG A-Z
RANDOMIZE TIMER
WS = _NEWIMAGE(640, 480, 32)
SCREEN WS
_SCREENMOVE _MIDDLE
 
TYPE BulletInfo
    valid AS INTEGER
    x AS INTEGER
    y AS INTEGER
END TYPE
 
TYPE BallInfo
    valid AS INTEGER
    originalsize AS INTEGER
    size AS INTEGER
    x AS INTEGER
    y AS INTEGER
    movex AS INTEGER
    movey AS INTEGER
END TYPE
 
DIM SHARED Ball(100) AS BallInfo
DIM SHARED Bullet(100) AS BulletInfo
DIM SHARED ROF AS INTEGER
DIM SHARED Ammo AS LONG
DIM SHARED GameOver AS LONG
DIM SHARED score
 
CLS , SkyBlue
LINE (0, 479)-(639, 460), Brown, BF
PCOPY 0, 1 'Save as the background
x = 290
ROF = 50
Ammo = 1000
 
DO
    PCOPY 1, 0
    _LIMIT 180
    IF _KEYDOWN(19200) THEN
        x = x - 1
    ELSEIF _KEYDOWN(19712) THEN
        x = x + 1
    END IF
    IF x < 0 THEN x = 0
    IF x > 570 THEN x = 570
    IF _KEYDOWN(27) THEN GameOver = -1
    IF _KEYDOWN(32) THEN Shoot x
 
    GenerateBall
 
    DrawBalls
    DrawPlayer x
    DrawBullets
 
    DrawStatus
    _DISPLAY
LOOP UNTIL GameOver
 
DO
    _LIMIT 30
LOOP UNTIL _KEYDOWN(27)
END
 
SUB DrawBalls
    FOR i = 1 TO 100
        IF Ball(i).valid THEN
            Ball(i).x = Ball(i).x - Ball(i).movex
            Ball(i).y = Ball(i).y - Ball(i).movey
            IF Ball(i).x < Ball(i).size THEN Ball(i).x = Ball(i).size: Ball(i).movex = -Ball(i).movex
            IF Ball(i).y < -Ball(i).size THEN Ball(i).y = -Ball(i).size: Ball(i).movey = -Ball(i).movey
            IF Ball(i).x > 640 - Ball(i).size THEN Ball(i).x = 640 - Ball(i).size: Ball(i).movex = -Ball(i).movex
            IF Ball(i).y > 460 - Ball(i).size THEN Ball(i).y = 460 - Ball(i).size: Ball(i).movey = -Ball(i).movey
            CircleFill Ball(i).x, Ball(i).y, Ball(i).size, _RGB32(0, 0, 255 - i * 2)
        END IF
    NEXT
END SUB
 
 
SUB GenerateBall
    STATIC Spawn AS _FLOAT
    IF ExtendedTimer > Spawn + 2 THEN
        Spawn = ExtendedTimer
        FOR i = 1 TO 100
            IF Ball(i).valid = 0 THEN
                Ball(i).valid = -1
                Ball(i).x = RND * 640 + 1
                Ball(i).size = RND * 91 + 10
                Ball(i).y = -Ball(i).size
                Ball(i).originalsize = Ball(i).size
                Ball(i).movey = -RND * 3 + 1
                Ball(i).movex = 1 - RND * 3
                EXIT SUB
            END IF
        NEXT
    END IF
END SUB
 
 
SUB DrawStatus
    _PRINTSTRING (10, 462), "AMMO:" + STR$(Ammo)
    _PRINTSTRING (560, 462), TIME$
    _PRINTSTRING (200, 462), "SCORE:" + STR$(score)
END SUB
 
SUB DrawPlayer (x)
    FOR x1 = x TO x + 69
        FOR y1 = 445 TO 459
            IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
        NEXT
    NEXT
    FOR x1 = x + 10 TO x + 59
        FOR y1 = 425 TO 444
            IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
        NEXT
    NEXT
    FOR x1 = x + 30 TO x + 39
        FOR y1 = 415 TO 424
            IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
        NEXT
    NEXT
    LINE (x, 445)-STEP(70, 15), Red, BF
    LINE (x + 10, 425)-STEP(50, 20), Red, BF
    LINE (x + 30, 415)-STEP(10, 10), Red, BF
END SUB
 
SUB DrawBullets
    DIM P AS _UNSIGNED LONG
    FOR i = 1 TO 100
        IF Bullet(i).valid THEN
            Bullet(i).y = Bullet(i).y - 1
            IF Bullet(i).y < 0 THEN Bullet(i).valid = 0: _CONTINUE
            P = POINT(Bullet(i).x, Bullet(i).y)
            IF P <> SkyBlue THEN
                Bullet(i).valid = 0
                B = (255 - _BLUE32(P)) / 2
                Ball(B).size = Ball(B).size - 1: score = score + 1
                IF Ball(B).size < 10 THEN Ball(B).valid = 0: Ammo = Ammo + Ball(B).originalsize
                _CONTINUE
            END IF
 
            LINE (Bullet(i).x, Bullet(i).y)-STEP(3, 5), BrickRed, BF
        END IF
    NEXT
    IF Ammo = 0 THEN
        FOR i = 1 TO 100
            IF Bullet(i).valid THEN EXIT SUB
        NEXT
        GameOver = -1 'once you're out of bullets and there's none left on the screen, the game is over.
    END IF
END SUB
 
 
SUB Shoot (x)
    STATIC Delay AS _FLOAT
    IF ExtendedTimer > Delay + ROF / 1000 THEN 'only shoot once every Rate Of Fire
        FOR i = 1 TO 100
            IF Bullet(i).valid = 0 THEN
                Bullet(i).valid = -1
                Bullet(i).x = x + 33
                Bullet(i).y = 410
                Ammo = Ammo - 1
                Delay = ExtendedTimer
                EXIT SUB
            END IF
        NEXT
    END IF
END SUB
 
 
FUNCTION ExtendedTimer##
    d$ = DATE$
    l = INSTR(d$, "-")
    l1 = INSTR(l + 1, d$, "-")
    m = VAL(LEFT$(d$, l))
    d = VAL(MID$(d$, l + 1))
    y = VAL(MID$(d$, l1 + 1)) - 1970
    FOR i = 1 TO m
        SELECT CASE i 'Add the number of days for each previous month passed
            CASE 1: d = d 'January doestn't have any carry over days.
            CASE 2, 4, 6, 8, 9, 11: d = d + 31
            CASE 3: d = d + 28
            CASE 5, 7, 10, 12: d = d + 30
        END SELECT
    NEXT
    FOR i = 1 TO y
        d = d + 365
    NEXT
    FOR i = 2 TO y STEP 4
        IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 2016
    NEXT
    s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
    ExtendedTimer## = (s~&& + TIMER)
END FUNCTION
 
SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    ' CX = center x coordinate
    ' CY = center y coordinate
    '  R = radius
    '  C = fill color
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R)
    RadiusError = -Radius
    X = Radius
    Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
 

A little shooter game which I was playing around with making, though it seems a little too difficult with the current settings. Spawn timer may need to be reduced to create new balls at a slightly slower rate, and ball move speed might need to be decreased a bit to keep the game going, but as it is, it's a nice workable game already -- just not one where you can play for more than a few moments at a time. :P

Move left/right with the arrow keys.
Shoot with the space bar.
Bullets use Ammo, but each successful hit on a ball shrinks it in size. Once the ball "pops" and you destroy it, you get the ball's original size back to increase your ammo.
You get hit with a ball and it's game over.
Run out of ammo and it's game over.
You earn 1 point for each bullet which hits the target balls.

And that's it! :P

Title: Re: Ball Breaker
Post by: SMcNeill on April 04, 2019, 12:55:24 pm

A slightly tweaked version which spawns balls at an ever increasing rate as you play, and in which the player shooter is a little more responsive to movements.

Code: QB64: [Select]

CONST Blue = &HFF0000FF~& ' _RGB32(0,0,255)
CONST Brown = &HFFA52A2A~& ' _RGB32(165,42,42)
CONST BrickRed = &HFFCB4154~& '_RGB32(203,65,84)
CONST Red = &HFFFF0000~&
CONST SkyBlue = &HFF87CEEB~& ' _RGB32(135,206,235)
 
 
DEFLNG A-Z
RANDOMIZE TIMER
WS = _NEWIMAGE(640, 480, 32)
SCREEN WS
_SCREENMOVE _MIDDLE
 
TYPE BulletInfo
    valid AS INTEGER
    x AS INTEGER
    y AS INTEGER
END TYPE
 
TYPE BallInfo
    valid AS INTEGER
    originalsize AS INTEGER
    size AS INTEGER
    x AS _FLOAT
    y AS _FLOAT
    movex AS _FLOAT
    movey AS _FLOAT
END TYPE
 
DIM SHARED Ball(100) AS BallInfo
DIM SHARED Bullet(100) AS BulletInfo
DIM SHARED ROF AS INTEGER
DIM SHARED Ammo AS LONG
DIM SHARED GameOver AS LONG
DIM SHARED score
 
CLS , SkyBlue
LINE (0, 479)-(639, 460), Brown, BF
PCOPY 0, 1 'Save as the background
x = 290
ROF = 50
Ammo = 1000
 
DO
    PCOPY 1, 0
    _LIMIT 180
    IF _KEYDOWN(19200) THEN
        x = x - 3
    ELSEIF _KEYDOWN(19712) THEN
        x = x + 3
    END IF
    IF x < 0 THEN x = 0
    IF x > 570 THEN x = 570
    IF _KEYDOWN(27) THEN GameOver = -1
    IF _KEYDOWN(32) THEN Shoot x
 
    GenerateBall
    DrawBalls
    DrawPlayer x
    DrawBullets
 
    DrawStatus
    _DISPLAY
LOOP UNTIL GameOver
 
DO
    _LIMIT 30
LOOP UNTIL _KEYDOWN(27)
END
 
SUB DrawBalls
    FOR i = 1 TO 100
        IF Ball(i).valid THEN
            Ball(i).x = Ball(i).x - Ball(i).movex
            Ball(i).y = Ball(i).y - Ball(i).movey
            IF Ball(i).x < Ball(i).size THEN Ball(i).x = Ball(i).size: Ball(i).movex = -Ball(i).movex
            IF Ball(i).y < -Ball(i).size THEN Ball(i).y = -Ball(i).size: Ball(i).movey = -Ball(i).movey
            IF Ball(i).x > 640 - Ball(i).size THEN Ball(i).x = 640 - Ball(i).size: Ball(i).movex = -Ball(i).movex
            IF Ball(i).y > 460 - Ball(i).size THEN Ball(i).y = 460 - Ball(i).size: Ball(i).movey = -Ball(i).movey
            CircleFill Ball(i).x, Ball(i).y, Ball(i).size, _RGB32(0, 0, 255 - i * 2)
        END IF
    NEXT
END SUB
 
 
SUB GenerateBall
    STATIC Spawn AS _FLOAT
    STATIC StartTime AS _FLOAT
    DIM SpawnTime AS _FLOAT
    IF Spawn = 0 THEN
        StartTime = ExtendedTimer
    END IF
    SELECT CASE ExtendedTimer - StartTime
        CASE IS < 30: SpawnTime = 8
        CASE IS < 60: SpawnTime = 6.5
        CASE IS < 120: SpawnTime = 5
        CASE IS < 300: SpawnTime = 3
        CASE IS < 600: SpawnTime = 2
        CASE ELSE: SpawnTime = 1
    END SELECT
    IF ExtendedTimer > Spawn + SpawnTime THEN
        Spawn = ExtendedTimer
        FOR i = 1 TO 100
            IF Ball(i).valid = 0 THEN
                Ball(i).valid = -1
                Ball(i).x = RND * 640 + 1
                Ball(i).size = RND * 91 + 10
                Ball(i).y = -Ball(i).size
                Ball(i).originalsize = Ball(i).size
                DO
                    Ball(i).movey = -RND * 3 + 1
                LOOP UNTIL Ball(i).movey <> 0
                Ball(i).movex = 1 - RND * 3
                EXIT SUB
            END IF
        NEXT
    END IF
END SUB
 
 
SUB DrawStatus
    _PRINTSTRING (10, 462), "AMMO:" + STR$(Ammo)
    _PRINTSTRING (560, 462), TIME$
    _PRINTSTRING (200, 462), "SCORE:" + STR$(score)
END SUB
 
SUB DrawPlayer (x)
    FOR x1 = x TO x + 69
        FOR y1 = 445 TO 459
            IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
        NEXT
    NEXT
    FOR x1 = x + 10 TO x + 59
        FOR y1 = 425 TO 444
            IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
        NEXT
    NEXT
    FOR x1 = x + 30 TO x + 39
        FOR y1 = 415 TO 424
            IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
        NEXT
    NEXT
    LINE (x, 445)-STEP(70, 15), Red, BF
    LINE (x + 10, 425)-STEP(50, 20), Red, BF
    LINE (x + 30, 415)-STEP(10, 10), Red, BF
END SUB
 
SUB DrawBullets
    DIM P AS _UNSIGNED LONG
    FOR i = 1 TO 100
        IF Bullet(i).valid THEN
            Bullet(i).y = Bullet(i).y - 1
            IF Bullet(i).y < 0 THEN Bullet(i).valid = 0: _CONTINUE
            P = POINT(Bullet(i).x, Bullet(i).y)
            IF P <> SkyBlue THEN
                Bullet(i).valid = 0
                B = (255 - _BLUE32(P)) / 2
                Ball(B).size = Ball(B).size - 1: score = score + 1
                IF Ball(B).size < 10 THEN Ball(B).valid = 0: Ammo = Ammo + Ball(B).originalsize
                _CONTINUE
            END IF
 
            LINE (Bullet(i).x, Bullet(i).y)-STEP(3, 5), BrickRed, BF
        END IF
    NEXT
    IF Ammo = 0 THEN
        FOR i = 1 TO 100
            IF Bullet(i).valid THEN EXIT SUB
        NEXT
        GameOver = -1 'once you're out of bullets and there's none left on the screen, the game is over.
    END IF
END SUB
 
 
SUB Shoot (x)
    STATIC Delay AS _FLOAT
    IF ExtendedTimer > Delay + ROF / 1000 THEN 'only shoot once every Rate Of Fire
        FOR i = 1 TO 100
            IF Bullet(i).valid = 0 THEN
                Bullet(i).valid = -1
                Bullet(i).x = x + 33
                Bullet(i).y = 410
                Ammo = Ammo - 1
                Delay = ExtendedTimer
                EXIT SUB
            END IF
        NEXT
    END IF
END SUB
 
 
FUNCTION ExtendedTimer##
    d$ = DATE$
    l = INSTR(d$, "-")
    l1 = INSTR(l + 1, d$, "-")
    m = VAL(LEFT$(d$, l))
    d = VAL(MID$(d$, l + 1))
    y = VAL(MID$(d$, l1 + 1)) - 1970
    FOR i = 1 TO m
        SELECT CASE i 'Add the number of days for each previous month passed
            CASE 1: d = d 'January doestn't have any carry over days.
            CASE 2, 4, 6, 8, 9, 11: d = d + 31
            CASE 3: d = d + 28
            CASE 5, 7, 10, 12: d = d + 30
        END SELECT
    NEXT
    FOR i = 1 TO y
        d = d + 365
    NEXT
    FOR i = 2 TO y STEP 4
        IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 2016
    NEXT
    s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
    ExtendedTimer## = (s~&& + TIMER)
END FUNCTION
 
SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    ' CX = center x coordinate
    ' CY = center y coordinate
    '  R = radius
    '  C = fill color
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R)
    RadiusError = -Radius
    X = Radius
    Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 

Title: Re: Ball Breaker
Post by: Pete on April 04, 2019, 01:14:38 pm

Quote from: SMcNeill on April 04, 2019, 12:55:24 pm

And that's it! :P

I hope, for your sake, the name isn't based on your marital experience. If so, I'd recommend LOCATE apostrophe, +2 to the quoted line above.

Hey, nice game! I also liked the scoring. I've always thought more shooting games should incorporate a conservation of ammo instead of games like Defender, where you could just paste the trigger lever down and concentrate all day on just flying and positioning the spaceship. I've considered models where you have a certain amount of ammo per a time period. Run out before the reload time, and you're left dodging opponents until that time elapses. A reload vehicle could even appear on the scene, but if you can't get to it, or it gets destroyed, you have to wait for the next shipment. Although I don't make games anymore, I do get that the best ideas are usually ones that are simple. In other words a bare bones version is still lots of fun to play, you don't need to tweak or add much to have a winner like Pac Man, etc.

Pete

Title: Re: Ball Breaker
Post by: qb4ever on April 05, 2019, 02:59:37 am

Quote from: SMcNeill on April 04, 2019, 12:55:24 pm

A slightly tweaked version which spawns balls at an ever increasing rate as you play, and in which the player shooter is a little more responsive to movements.

Great mix between space invaders and breakout.
Very nice idea !
Have a nice day.

Title: Re: Ball Breaker
Post by: Ashish on April 05, 2019, 03:35:27 am

Nice job! But it is a bit hard to play this game. :D

Title: Re: Ball Breaker
Post by: johnno56 on April 05, 2019, 08:42:04 am

Reminds of the little game called Pang... Cool...

Title: Re: Ball Breaker
Post by: TempodiBasic on April 05, 2019, 05:35:30 pm

Yes it remembers to me this one https://www.youtube.com/watch?v=kE-jzDmt1SI (https://www.youtube.com/watch?v=kE-jzDmt1SI) called SuperPang

Text Only | Text with Attachments

QB64.org Forum

Active Forums => Programs => Topic started by: SMcNeill on April 04, 2019, 12:33:29 pm