QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Pete on March 30, 2019, 03:27:30 pm

Title: Hi Mark, need a little help with this...
Post by: Pete on March 30, 2019, 03:27:30 pm

I tried your awesome text in space scrolling program, but when I made necessary corrections, it leaves out the last period of the final paragraph. My guess is it is over some limit, but I can't seem to figure out how to adjust for it.

Code: QB64: [Select]

1. ' Star Trek
2. SCREEN _NEWIMAGE(800, 700, 32)
3. _SCREENMOVE 300, 20
4. swt& = _NEWIMAGE(360, 512, 32)
5. _DEST swt&
6. COLOR _RGB32(0, 180, 0)
7. nl$ = CHR$(10)
8. sw$ = "Space, the final frontier. These are the" + nl$
9. sw$ = sw$ + "Voyages of the Starship, Enterprise" + nl$
10. sw$ = sw$ + "Its five year mission, to seek out new" + nl$
11. sw$ = sw$ + "life; to explore new worlds; To boldly" + nl$
12. sw$ = sw$ + "go where no man has gone before..." + nl$
13. sw$ = sw$ + nl$ + nl$
14. sw$ = sw$ + "Well that sure beats the other sci-fi," + nl$
15. sw$ = sw$ + "franchise, which pales by comparison to" + nl$
16. sw$ = sw$ + "the awesomeness of the Star Trek legacy." + nl$
17. sw$ = sw$ + "Stay tuned for other Star Trek moments." + nl$
18. sw$ = sw$ + nl$ + nl$
19. sw$ = sw$ + "This has been a public service message" + nl$
20. sw$ = sw$ + "for the United Federation of Planets." + nl$
21. sw$ = sw$ + "Any rebroadcast of this message, without" + nl$
22. sw$ = sw$ + "the explicit permission of the UFP, is" + nl$
23. sw$ = sw$ + "strictly prohibited. Live long & prosper." + nl$
24. LOCATE 25, 1
25. PRINT sw$
26.  
27. _DEST 0
28. yy = _HEIGHT / 3
29. FOR i = 11 TO 60 STEP .5
30.     CLS
31.     yy = yy - 60 / i
32.     cText _WIDTH / 2, yy + yy, yy, _RGB32(230, 220, 50), "Star Trek"
33.     cText _WIDTH / 2, yy + yy, yy * .96, _RGB32(0, 0, 0), "Star Trek"
34.     _DISPLAY
35.     _LIMIT 15
36. NEXT
37.  
38. cx = _WIDTH / 2
39. power = 1024 'TO 1 STEP -1
40. x = (_HEIGHT - 20) ^ (1 / power)
41. dy = 1 '256 pixel height / 50 blocks across
42. FOR y = -840 TO -270
43.     CLS
44.     FOR i = 0 TO power - 1
45.         '_PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&][, ][STEP][(sx1, sy1)[-STEP][(sx2, sy2)]]
46.         _PUTIMAGE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), swt&, 0, (0, y + dy * i)-(319, y + dy * (i + 1))
47.  
48.         'LINE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), , B
49.     NEXT
50.     _DISPLAY
51.     _LIMIT 15
52. NEXT
53. yy = 80
54. FOR i = 60 TO 0 STEP -.5
55.     CLS
56.     yy = yy + 60 / i
57.     cText _WIDTH / 2, yy + yy, yy, _RGB32(230, 220, 50), "Star Trek"
58.     cText _WIDTH / 2, yy + yy, yy * .96, _RGB32(0, 0, 0), "Star Trek"
59.     _DISPLAY
60.     _LIMIT 75
61. NEXT
62.  
63. SUB cText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
64. fg = _DEFAULTCOLOR
65. 'screen snapshot
66. cur& = _DEST
67. I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
68. _DEST I&
69. COLOR K, _RGBA32(0, 0, 0, 0)
70. _PRINTSTRING (0, 0), txt$
71. mult = textHeight / 16
72. xlen = LEN(txt$) * 8 * mult
73. _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
74. COLOR fg
75. _FREEIMAGE I&
76. END SUB
77.  

Title: Re: Hi Mark, need a little help with this...
Post by: bplus on March 30, 2019, 04:15:21 pm

EDIT: Nope that wasn't the problem. The problem was some freaky thing with certain key combinations. Reminds me of Walter's forum!?

EDIT 2: Forgot to check tail end and start first line at bottom of screen, fixed:

Anyway here is my fix:

Code: QB64: [Select]

1. ' Star Trek
2. SCREEN _NEWIMAGE(800, 700, 32)
3. _SCREENMOVE 300, 20
4. swt& = _NEWIMAGE(344, 544, 32)
5. _DEST swt&
6. COLOR _RGB32(0, 180, 0)
7. nl$ = CHR$(10)
8. sw$ = "Space, the final frontier. These are the" + nl$
9. sw$ = sw$ + "Voyages of the Starship, Enterprise" + nl$
10. sw$ = sw$ + "Its five year mission, to seek out new" + nl$
11. sw$ = sw$ + "life; to explore new worlds; To boldly" + nl$
12. sw$ = sw$ + "go where no man has gone before..." + nl$
13. sw$ = sw$ + nl$ + nl$
14. sw$ = sw$ + "Well that sure beats the other sci-fi," + nl$
15. sw$ = sw$ + "franchise, which pales by comparison to" + nl$
16. sw$ = sw$ + "the awesomeness of the Star Trek legacy." + nl$
17. sw$ = sw$ + "Stay tuned for other Star Trek moments." + nl$
18. sw$ = sw$ + nl$ + nl$
19. sw$ = sw$ + "This has been a public service message" + nl$
20. sw$ = sw$ + "for the United Federation of Planets." + nl$
21. sw$ = sw$ + "Any rebroadcast of this message, without" + nl$
22. sw$ = sw$ + "the explicit permission of the UFP, is" + nl$
23. sw$ = sw$ + "strictly prohibited." + nl$ + nl$
24. sw$ = sw$ + "          Live long and code." + nl$ + nl$
25.  
26. LOCATE 24, 1
27. PRINT sw$
28.  
29. _DEST 0
30. yy = _HEIGHT / 3
31. FOR i = 11 TO 60 STEP .5
32.     CLS
33.     yy = yy - 60 / i
34.     cText _WIDTH / 2, yy + yy, yy, _RGB32(230, 220, 50), "Star Trek"
35.     cText _WIDTH / 2, yy + yy, yy * .96, _RGB32(0, 0, 0), "Star Trek"
36.     _DISPLAY
37.     _LIMIT 15
38. NEXT
39.  
40. cx = _WIDTH / 2
41. power = 1000 'TO 1 STEP -1
42. x = (_HEIGHT - 20) ^ (1 / power)
43. dy = 1 '256 pixel height / 50 blocks across
44. FOR y = -840 TO -250
45.     CLS
46.     FOR i = 0 TO power - 1
47.         '_PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&][, ][STEP][(sx1, sy1)[-STEP][(sx2, sy2)]]
48.         _PUTIMAGE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), swt&, 0, (0, y + dy * i)-(319, y + dy * (i + 1))
49.  
50.         'LINE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), , B
51.     NEXT
52.     _DISPLAY
53.     _LIMIT 15
54. NEXT
55. yy = 80
56. FOR i = 60 TO 0 STEP -.5
57.     CLS
58.     yy = yy + 60 / i
59.     cText _WIDTH / 2, yy + yy, yy, _RGB32(230, 220, 50), "Star Trek"
60.     cText _WIDTH / 2, yy + yy, yy * .96, _RGB32(0, 0, 0), "Star Trek"
61.     _DISPLAY
62.     _LIMIT 75
63. NEXT
64.  
65. SUB cText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
66.     fg = _DEFAULTCOLOR
67.     'screen snapshot
68.     cur& = _DEST
69.     I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
70.     _DEST I&
71.     COLOR K, _RGBA32(0, 0, 0, 0)
72.     _PRINTSTRING (0, 0), txt$
73.     mult = textHeight / 16
74.     xlen = LEN(txt$) * 8 * mult
75.     _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
76.     COLOR fg
77.     _FREEIMAGE I&
78. END SUB
79.  
80.  

Title: Re: Hi Mark, need a little help with this...
Post by: Pete on March 30, 2019, 04:54:38 pm

Nope, that didn't fix it. If I put the line back as:

strictly prohibited. Live long & prosper.

The period still gets cut off. I can't seem to extend that text lines past 40 characters. The period, at the end, would be character 41.

Anyway, thanks for trying. I might be able to get a handle on it in the future. For some weird reason, I really like this as a text reader. It seems to hold my attention better than a ... oh, what's that over... I think steak for dinner would be... Anyway, great effect!

Pete

Title: Re: Hi Mark, need a little help with this...
Post by: bplus on March 30, 2019, 04:57:47 pm

I think I just found the problem, hold on...

It was this line:
_PUTIMAGE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), swt&, 0, (0, y + dy * i)-(319, y + dy * (i + 1))

change to:
_PUTIMAGE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), swt&, 0, (0, y + dy * i)-(359, y + dy * (i + 1))

319 was the old image width.

Title: Re: Hi Mark, need a little help with this...
Post by: Pete on March 30, 2019, 06:06:45 pm

Cool! So now that you pointed out where the sizing part is, presto, I squeaked a few other character spaces out of it, and was able to change the & sign to "and."

Thanks!!!!

Code: QB64: [Select]

1. ' Star Trek
2. SCREEN _NEWIMAGE(800, 700, 32)
3. _SCREENMOVE 300, 20
4. swt& = _NEWIMAGE(344, 512, 32)
5. _DEST swt&
6. COLOR _RGB32(0, 180, 0)
7. nl$ = CHR$(10)
8. sw$ = "Space, the final frontier. These are the" + nl$
9. sw$ = sw$ + "voyages of the Starship, Enterprise." + nl$
10. sw$ = sw$ + "Its five year mission, to seek out new" + nl$
11. sw$ = sw$ + "life; to explore new worlds; To boldly" + nl$
12. sw$ = sw$ + "go where no man has gone before..." + nl$
13. sw$ = sw$ + nl$ + nl$
14. sw$ = sw$ + "Well that sure beats the other sci-fi," + nl$
15. sw$ = sw$ + "franchise, which pales by comparison to" + nl$
16. sw$ = sw$ + "the awesomeness of the Star Trek legacy." + nl$
17. sw$ = sw$ + "Stay tuned for other Star Trek moments." + nl$
18. sw$ = sw$ + nl$ + nl$
19. sw$ = sw$ + "This has been a public service message" + nl$
20. sw$ = sw$ + "for the United Federation of Planets." + nl$
21. sw$ = sw$ + "Any rebroadcast of this message, without" + nl$
22. sw$ = sw$ + "the explicit permission of the U.F.P., is" + nl$
23. sw$ = sw$ + "strictly prohibited. Live long and prosper." + nl$
24. LOCATE 25, 1
25. PRINT sw$
26.  
27. _DEST 0
28. yy = _HEIGHT / 3
29. FOR i = 11 TO 60 STEP .5
30.     CLS
31.     yy = yy - 60 / i
32.     cText _WIDTH / 2, yy + yy, yy, _RGB32(230, 220, 50), "Star Trek"
33.     cText _WIDTH / 2, yy + yy, yy * .96, _RGB32(0, 0, 0), "Star Trek"
34.     _DISPLAY
35.     _LIMIT 15
36. NEXT
37.  
38. cx = _WIDTH / 2
39. power = 1024 'TO 1 STEP -1
40. x = (_HEIGHT - 20) ^ (1 / power)
41. dy = 1 '256 pixel height / 50 blocks across
42. FOR y = -840 TO -270
43.     CLS
44.     FOR i = 0 TO power - 1
45.         '_PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&][, ][STEP][(sx1, sy1)[-STEP][(sx2, sy2)]]
46.         _PUTIMAGE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), swt&, 0, (0, y + dy * i)-(343, y + dy * (i + 1))
47.  
48.         'LINE (cx - .75 * x ^ i, 10 + x ^ i)-(cx + .75 * x ^ i, 10 + x ^ (i + 1)), , B
49.     NEXT
50.     _DISPLAY
51.     _LIMIT 15
52. NEXT
53. yy = 80
54. FOR i = 60 TO 0 STEP -.5
55.     CLS
56.     yy = yy + 60 / i
57.     cText _WIDTH / 2, yy + yy, yy, _RGB32(230, 220, 50), "Star Trek"
58.     cText _WIDTH / 2, yy + yy, yy * .96, _RGB32(0, 0, 0), "Star Trek"
59.     _DISPLAY
60.     _LIMIT 75
61. NEXT
62.  
63. SUB cText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
64. fg = _DEFAULTCOLOR
65. 'screen snapshot
66. cur& = _DEST
67. I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
68. _DEST I&
69. COLOR K, _RGBA32(0, 0, 0, 0)
70. _PRINTSTRING (0, 0), txt$
71. mult = textHeight / 16
72. xlen = LEN(txt$) * 8 * mult
73. _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
74. COLOR fg
75. _FREEIMAGE I&
76. END SUB
77.  

Title: Re: Hi Mark, need a little help with this...
Post by: johnno56 on April 02, 2019, 10:32:29 pm

Well, I think THIS is pretty cool.... I like it !!

Well done!

Title: Re: Hi Mark, need a little help with this...
Post by: bplus on April 03, 2019, 09:34:25 am

Hey johnno56!

Can't imagine why you like it? ;-))

Text Only | Text with Attachments