Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Babyboomerboy on March 29, 2019, 07:52:09 pm

Title: lining up numbers in columns
Post by: Babyboomerboy on March 29, 2019, 07:52:09 pm
Got a small problem. I have a for next routine that prints numbers 5 columns wide and 8 rows down. When it prints out, if one of the numbers is 2 digits, it moves the rest of the numbers on that row off line with the other numbers in that column. I remember several years ago I fixed this problem but I don’t remember how I did it. Any help would be appreciated.
Title: Re: lining up numbers in columns
Post by: SMcNeill on March 29, 2019, 08:11:49 pm
Easiest solution is to probably just use LOCATE.

FOR I = 1 TO 8
   LOCATE I, 1: PRINT I
   LOCATE I, 10: PRINT I * 2
   LOCATE I, 20: PRINT I * 3
   LOCATE I, 30: PRINT I * 4
   LOCATE I, 40: PRINT I * 5
NEXT

If you just want to print without setting the vertical position, just use LOCATE ,

FOR I = 1 TO 8
   LOCATE , 1: PRINT I;
   LOCATE , 10: PRINT I * 2;
   LOCATE , 20: PRINT I * 3;
   LOCATE , 30: PRINT I * 4;
   LOCATE , 40: PRINT I * 5
NEXT

Note: Notice the semi-colons which don’t cause the PRINT to move to a new row, until we want it to at the end.
Title: Re: lining up numbers in columns
Post by: Pete on March 29, 2019, 10:13:19 pm
Do us a favor. Post the code for the for/next loop. I don't understand how a 2-digit number is a problem in a 5-digit column.

Pete
Title: Re: lining up numbers in columns
Post by: Babyboomerboy on March 29, 2019, 11:15:02 pm
I am not very good at explaining my problem. When I run the code I might get 7 3 5 4
                                                                                                                   1 8 12 6
The 12 moved the 6 to the right of the column with the 4.
The 1 lines up under the 7 and the8 lines up under the 3
Here is the code

CLS
LOCATE 20, 15
PRINT
PRINT TAB(14); "        OFX,ETX,STX,FFX,   BTIME,BTIMEA"
FOR TTP = 1 TO 8
    PRINT TAB(15); "DOG"; TTP; "-"; OFX(TTP); " "; ETX(TTP); " "; STX(TTP); " "; FFX(TTP); "     "; BTIMEA%(TTP); " "; BTIMEA(TTP)
NEXT TTP
PRINT " "
PRINT TAB(5); "                  OP, EP, SP, FP,  PTOTAL"
FOR TTP = 1 TO 8

    PRINT TAB(15); "DOG"; TTP; " "; OPOINT(TTP); " "; EPOINT(TTP); " "; SPOINT(TTP); " "; FPOINT(TTP); "       "; POINTTOTALA(TTP)
NEXT TTP
INPUT H
Title: Re: lining up numbers in columns
Post by: bplus on March 30, 2019, 12:11:33 am
Code: QB64: [Select]
  1. FOR row = 1 TO 20
  2.     FOR col = 1 TO 10
  3.         r$ = STR$(INT((RND * 10 - 5) ^ INT(12 * RND - 6))) 'some wild and crazy numbers
  4.         PRINT RIGHT$(SPACE$(8) + r$, 8); '<<<<<<<<<<<<<<<<<< space out numbers on row
  5.     NEXT
  6.     PRINT
  8.  
Title: Re: lining up numbers in columns
Post by: Pete on March 30, 2019, 12:43:32 am
Here is an example with your first row/column code, and the code modified with LOCATE and LEN() LTRIM$ and STR$() keywords.

Let me know if this is the kind of alignment you wanted, and if so, I'd be happy to explain how the code woks.

Pete

Code: QB64: [Select]
  1. WIDTH 80, 42: _SCREENMOVE 0, 0
  3. LOCATE 20, 15
  5. PRINT TAB(14); "        OFX,ETX,STX,FFX,   BTIME,BTIMEA"
  6. FOR TTP = 1 TO 8
  7.     OFX(TTP) = 7 + TTP: ETX(TTP) = 3 + TTP: STX(TTP) = 5 + TTP: FFX(TTP) = 4 + TTP: BTIMEA%(TTP) = 1 + TTP: BTIMEA(TTP) = 12 + TTP ' Make some test values.
  8.     PRINT TAB(15); "DOG"; TTP; "-"; OFX(TTP); " "; ETX(TTP); " "; STX(TTP); " "; FFX(TTP); "     "; BTIMEA%(TTP); " "; BTIMEA(TTP)
  9. NEXT TTP
  10. PRINT: LOCATE , 15: PRINT "Aligned Columns...": PRINT
  11. FOR TTP = 1 TO 8
  12.     LOCATE , 15: PRINT ; "DOG"; TTP;: LOCATE , 21: PRINT "-";
  13.     LOCATE , 25 - LEN(LTRIM$(STR$(OFX(TTP)))): PRINT LTRIM$(STR$(OFX(TTP)));
  14.     LOCATE , 29 - LEN(LTRIM$(STR$(ETX(TTP)))): PRINT LTRIM$(STR$(ETX(TTP)));
  15.     LOCATE , 33 - LEN(LTRIM$(STR$(STX(TTP)))): PRINT LTRIM$(STR$(STX(TTP)));
  16.     LOCATE , 37 - LEN(LTRIM$(STR$(FFX(TTP)))): PRINT LTRIM$(STR$(FFX(TTP)));
  17.     LOCATE , 44 - LEN(LTRIM$(STR$(BTIMEA%(TTP)))): PRINT LTRIM$(STR$(BTIMEA%(TTP)));
  18.     LOCATE , 49 - LEN(LTRIM$(STR$(BTIMEA(TTP)))): PRINT LTRIM$(STR$(BTIMEA(TTP)))
  19. NEXT TTP
  20.  
  21. PRINT " "
  22. PRINT TAB(5); "                  OP, EP, SP, FP,  PTOTAL"
  23. FOR TTP = 1 TO 8
  24.  
  25.     PRINT TAB(15); "DOG"; TTP; " "; OPOINT(TTP); " "; EPOINT(TTP); " "; SPOINT(TTP); " "; FPOINT(TTP); "       "; POINTTOTALA(TTP)
  26. NEXT TTP
  28.  
Title: Re: lining up numbers in columns
Post by: Babyboomerboy on April 01, 2019, 09:33:27 am
Thank you SMcNeil, bplus and Pete. I was able to use the code that Pete gave the best for my situation. I moved the columns a little wider and everyone lined up perfect.  You said you could explain how the code works and I would appreciate knowing this as I have learned to code all by myself through trial and error, lots of errors. Thanks again to all
Title: Re: lining up numbers in columns
Post by: bplus on April 01, 2019, 01:30:58 pm
Maybe exposure to more methods would help?

Code: QB64: [Select]
  2. SCREEN _NEWIMAGE(800, 600, 32)
  3.  
  4. 'set column starts for left alignment or column ends for right alignment
  5. DIM cTabs(1 TO 4)
  6. cTabs(1) = 5
  7. cTabs(2) = 15
  8. cTabs(3) = 25
  9. cTabs(4) = 35
  10.  
  11.  
  12. '  this method gives you left alignment at set column starts
  13. PRINT "1234567890123456789012345678901234567890"
  14. FOR row = 2 TO 11
  15.     LOCATE row, cTabs(1): PRINT -INT(RND * 10)
  16.     LOCATE row, cTabs(2): PRINT -INT(RND * 100)
  17.     LOCATE row, cTabs(3): PRINT -INT(RND * 1000)
  18.     LOCATE row, cTabs(4): PRINT -INT(RND * 10000)
  20.  
  21.  
  22. ' to get right alignment on columns which is desired for columns of numbers
  23.  
  24. 'subtract off the LEN() of the item you are about to print when you use LOCATE
  25. ' the cTabs become the right side of the cols
  26.  
  27. LOCATE 13, 1: PRINT "1234567890123456789012345678901234567890"
  28. FOR row = 14 TO 25
  29.  
  30.     n$ = STR$(INT(RND * 10)) 'next number to print
  31.  
  32.     'subtract it's LEN from cTabs(col)
  33.     LOCATE row, cTabs(1) - LEN(n$): PRINT n$
  34.  
  35.     'repeat for all numbers in row
  36.     n$ = STR$(INT(RND * 100))
  37.     LOCATE row, cTabs(2) - LEN(n$): PRINT n$
  38.     n$ = STR$(INT(RND * 1000))
  39.     LOCATE row, cTabs(3) - LEN(n$): PRINT n$
  40.     n$ = STR$(INT(RND * 10000))
  41.     LOCATE row, cTabs(4) - LEN(n$): PRINT n$
  43.  
  44.  
Title: Re: lining up numbers in columns
Post by: Pete on April 01, 2019, 02:08:26 pm
Sure...

STR$() Converts a numeric value to a string.
LTRIM$() stands for Left Trim, which means it trims off any spaces to the left side of a string.

Strings are letters like, A,b,c, and other characters like #, *, etc. Now strings can also be numbers, but here's a big difference. Try the code below...

Code: QB64: [Select]
  1. a = 1
  2. a$ = "1"
  3. PRINT "|"; a; "|"
  4. PRINT "|"; a$; "|"
  5. PRINT "|"; STR$(a); "|"
  6. PRINT "|"; LTRIM$(STR$(a)); "|"
  7.  

So printing a number as a numeric variable results in a space in front of the number, and a space in back of the number. Now when we use STR$() to represent the numeric variable as a string, it gets rid of the trailing space, but notice it still keeps that leading space. That space is reserved for a negative sign. See code below...

Code: QB64: [Select]
  1. a = -1
  2. a$ = "-1"
  3. PRINT "|"; a; "|"
  4. PRINT "|"; a$; "|"
  5. PRINT "|"; STR$(a); "|"
  6.  

So if a negative sign was present, it wouldn't need to be "Left Trimmed" but you could still use LTRIM$(STR$(a)) if you want to. I always use it that way, as most of my work contains negative and positive numbers, so I just want one simple way to do it all. So LTRIM$(STR$(a)) makes the 1 just take up one space, instead of 3 spaces, and that is critical to aligning text.

Next, LOCATE...

LOCATE has two variables, ROW,  COLUMN. So why did I leave the ROW part out and write LOCATE , 15 in the code? Well, omitting the ROW variable tells QB64 to locate on the current row. So if I'm on the 10th row,  LOCATE , 15 keeps me on the 10th row, and starts the first text writing space at COLUMN 15. So, no need to write it as LOCATE 10, 15. It's neat typing saver!

Finally, the LEN() statement. LEN() measures the length of your string. Not a big deal if they are all the same length, but let's say the first variable is one space like "7" and in the row below it, the next variable is: "53" So the first variable has LEN("1") = 1 character in length, and the second LEN("53") would be 2-characters long. If we wanted to line up the variables, so they all end at column 9 we would need...

Code: QB64: [Select]
  1. LOCATE , 10 - LEN(LTRIM$(STR$(7))): PRINT "7"
  2. LOCATE , 10 - LEN(LTRIM$(STR$(53))): PRINT "53"

So the first statement starts at the current row at column 10 - length of the number 7, which is 10 - 1 or 9. It then prints 1 at column 9. Notice the PRINT statement is not followed by a semi-colon as in PRINT; so just PRINT alone tells QB64 to print and move down to the next row. A semi-colon added would tell it to stay on the same row. So since we omitted a semi-colon, we printed 7 and we are now on the next row, below. The second statement locates on that row at column 10 - 2, because our next number, 53, has a length of 2-characters. We use LTRIM$(STR$(53)) to get rid of the leading and trailing spaces. So the 5 of the 53 gets printed at column 8 (10 - 2) and the 3 ends up at column 9, the same column the number 7 is printed in, in the row above.

I hope this makes sense. If not, just ask.

Pete




 
Title: Re: lining up numbers in columns
Post by: bplus on April 01, 2019, 04:45:08 pm
Dang! I keep forgetting about the space on the right, left from STR$(number) (including my last snippet above, which explains why the numbers weren't finishing exactly on the cTab() value).

Best to TRIM$(STR$(number)) with a newer version of QB64

Title: Re: lining up numbers in columns
Post by: FellippeHeitor on April 01, 2019, 05:01:05 pm
_TRIM it is :-)
Title: Re: lining up numbers in columns
Post by: bplus on April 01, 2019, 06:26:14 pm
Thanks Fellippe,

Where is that right space when you are looking for it?
Code: QB64: [Select]
  1. _TITLE "Test _TRIM$"
  2. n = 42.
  3. ns$ = STR$(42)
  4. nts$ = _TRIM$(ns$)
  5. PRINT LEN(ns$), "*"; ns$; "*"
  6. PRINT LEN(nts$), "*"; nts$; "*"
  7.  

Code: QB64: [Select]
  1. _TITLE "Test _TRIM$"
  2. n = 42.
  3. ns$ = STR$(n)
  4. nts$ = _TRIM$(ns$)
  5. PRINT LEN(ns$), "*"; ns$; "*"
  6. PRINT LEN(nts$), "*"; nts$; "*"
Title: Re: lining up numbers in columns
Post by: SMcNeill on April 01, 2019, 06:43:04 pm
And remember simple little TAB...
Title: Re: lining up numbers in columns
Post by: RadioHacktive on April 01, 2019, 06:54:51 pm
"Print using" does not work? http://qb64.org/wiki/PRINT_USING (http://qb64.org/wiki/PRINT_USING)
Title: Re: lining up numbers in columns
Post by: bplus on April 01, 2019, 07:11:44 pm
Wait, where did I get this idea of there being a space on the right of a STR$(number)?

To get a number to right align on column x it is: LOCATE ,  x - LEN(STR$(number)) + 1
Code: QB64: [Select]
  2. SCREEN _NEWIMAGE(800, 600, 32)
  3.  
  4. 'set column starts for left alignment or column ends for right alignment
  5. DIM cTabs(1 TO 4)
  6. cTabs(1) = 5
  7. cTabs(2) = 15
  8. cTabs(3) = 25
  9. cTabs(4) = 35
  10.  
  11.  
  12. ' to get right alignment on columns which is desired for columns of numbers
  13.  
  14. 'subtract off the LEN() of the item you are about to print when you use LOCATE
  15. ' the cTabs become the right side of the cols
  16.  
  17. LOCATE 13, 1: PRINT "1234567890123456789012345678901234567890"
  18. FOR row = 14 TO 25
  19.  
  20.     n$ = STR$(INT(RND * 10)) 'next number to print
  21.  
  22.     'subtract it's LEN from cTabs(col)
  23.     LOCATE row, cTabs(1) - LEN(n$) + 1: PRINT n$
  24.  
  25.     'repeat for all numbers in row
  26.     n$ = STR$(INT(RND * 100))
  27.     LOCATE row, cTabs(2) - LEN(n$) + 1: PRINT n$
  28.     n$ = STR$(INT(RND * 1000))
  29.     LOCATE row, cTabs(3) - LEN(n$) + 1: PRINT n$
  30.     n$ = STR$(INT(RND * 10000))
  31.     LOCATE row, cTabs(4) - LEN(n$) + 1: PRINT n$
  33.  


Quote from: RadioHacktive on April 01, 2019, 06:54:51 pm
"Print using" does not work? http://qb64.org/wiki/PRINT_USING (http://qb64.org/wiki/PRINT_USING)

Save that for REAL Numbers! ;-))
Title: Re: lining up numbers in columns
Post by: FellippeHeitor on April 01, 2019, 08:08:40 pm
Quote from: bplus on April 01, 2019, 07:11:44 pm
Wait, where did I get this idea of there being a space on the right of a STR$(number)?

No idea :-)
Title: Re: lining up numbers in columns
Post by: bplus on April 01, 2019, 08:21:20 pm
Ah! from this:
Code: QB64: [Select]
  1. print "Here is a number";26;"and here is another";len("Mark");", any spaces on the right side?"
Title: Re: lining up numbers in columns
Post by: Pete on April 01, 2019, 11:28:24 pm
Quote from: FellippeHeitor on April 01, 2019, 05:01:05 pm
_TRIM it is :-)

Oh, you mean you are THINKING about making that a keyword. I wish you would have stated that in the first place, because Ive been running all through the wiki, looking for _TRIM!

Pete :D

Based on a spoof from a TV series: Hey June, where's Ward? He's running all over town looking for Beaver!

Seriously, it would save typing two keywords, like LTRIM$(STR$()) and LTRIM$(RTRIM$()), and should be a snap to implement. Nothing like the FN hell you'd have to go through to implement FN.
Title: Re: lining up numbers in columns
Post by: FellippeHeitor on April 01, 2019, 11:36:33 pm
_TRIM$() is already available in the development builds and will make it to the wiki as soon as 1.3 is released ;-)

More on what's coming up here: https://www.qb64.org/forum/index.php?topic=304.msg2554#msg2554
Title: Re: lining up numbers in columns
Post by: bplus on April 02, 2019, 01:50:34 am
Quote from: RadioHacktive on April 01, 2019, 06:54:51 pm
"Print using" does not work? http://qb64.org/wiki/PRINT_USING (http://qb64.org/wiki/PRINT_USING)

It is really an excellent idea. Welcome to the forum RadoiHactive!
Title: Re: lining up numbers in columns
Post by: Jack002 on April 02, 2019, 12:15:27 pm
Years ago I would make a fn called trim that was rtrim and ltrim together. I assume this is what we're discussing?

STR$ will make a space to the left of the number. I have often done a mid$ 2 of it just to zap it. Trim also works.
Title: Re: lining up numbers in columns
Post by: Pete on April 02, 2019, 05:05:37 pm
STR$() actually doesn't make the space. The space is already there. It just doesn't get rid of it. Try print 1. You'll see the 1 is indented one space to the left. Now try print 2. You see the - sign is on the margin, followed by the 1. So the computer language just formats numbers in this manner, preserving a space in case a negative is involved. At least that's my non-schooled take on the matter. As the the trailing space that STR$() does trim off, well, I used to know what that was for, but I have to admit, I've forgotten!

Pete
Text Only | Text with Attachments