Print Page - CatChum for CP/M

This is the idea:

Screenshot attached.

Code: QB64: [Select]

$RESIZE:STRETCH
SCREEN _NEWIMAGE(52, 24, 0)
 
_TITLE "CatChum for CP/M"
 
COLOR 2 'for a phosphor look
 
_CONTROLCHR OFF
 
CONST true = -1, false = NOT true
CONST powerPelletMAX = 7 'duration of the power pellet effects
 
TYPE new_DOT
    x AS INTEGER
    y AS INTEGER
    state AS _BYTE '0 = taken; 1 = dot; 2 = power pellet
END TYPE
 
DIM SHARED dot(1 TO 201) AS new_DOT
DIM SHARED mapData(1 TO 23) AS STRING
DIM SHARED PacMan AS new_DOT
DIM SHARED ghost(1 TO 4) AS new_DOT
DIM SHARED direction AS _BYTE, nextDirection AS _BYTE
DIM SHARED endGame AS _BYTE, lastMove!
DIM SHARED score AS LONG, powerPelletTimer AS SINGLE
 
DO
    setupMap
    setupDots
    endGame = false
    direction = 1
    lastMove! = 0
 
    DO
        CLS
        processInput
        movePacMan
        detectColision
 
        drawLabyrinth
        IF NOT _KEYDOWN(100306) THEN drawItems
 
        _PRINTSTRING (1, 24), STR$(score)
        _DISPLAY
        _LIMIT 30
    LOOP UNTIL endGame
LOOP
 
SUB detectColision
    FOR i = 1 TO UBOUND(dot)
        IF dot(i).x = PacMan.x AND dot(i).y = PacMan.y THEN
            SELECT CASE dot(i).state
                CASE 1
                    'dot
                    score = score + 10
                    dot(i).state = 0
                CASE 2
                    'power pellet
                    score = score + 20
                    dot(i).state = 0
                    powerPelletTimer = TIMER
            END SELECT
        END IF
    NEXT
END SUB
 
SUB movePacMan
    STATIC didMove AS _BYTE
 
    DIM refreshRate!
 
    IF direction = 1 OR direction = 3 THEN refreshRate! = .1
    IF direction = 2 OR direction = 4 THEN refreshRate! = .12
 
    IF TIMER - lastMove! < refreshRate! THEN EXIT SUB
 
    IF didMove = false AND lastMove! > 0 THEN direction = 0
 
    lastMove! = TIMER
 
    'same axis changes are immediately applied
    SELECT CASE nextDirection
        CASE 1, 3
            IF direction = 1 OR direction = 3 THEN direction = nextDirection: nextDirection = 0
        CASE 2, 4
            IF direction = 2 OR direction = 4 THEN direction = nextDirection: nextDirection = 0
    END SELECT
 
    IF direction = 0 THEN direction = nextDirection
 
    DIM prevDirection AS _BYTE
 
    IF nextDirection THEN
        prevDirection = direction
        direction = nextDirection
    END IF
 
    didMove = false
    DIM i AS INTEGER
    FOR i = 1 TO 2
        SELECT CASE direction
            CASE 1 'left
                IF PacMan.x > 1 THEN
                    IF ASC(mapData(PacMan.y), PacMan.x - 1) = 32 THEN
                        PacMan.x = PacMan.x - 1
                        didMove = true
                        EXIT FOR
                    ELSE
                        IF prevDirection THEN
                            nextDirection = direction
                            direction = prevDirection
                        END IF
                    END IF
                ELSE 'warp
                    PacMan.x = LEN(mapData(1))
                    didMove = true
                END IF
            CASE 2 'up
                IF PacMan.y > 1 THEN
                    IF ASC(mapData(PacMan.y - 1), PacMan.x) = 32 THEN
                        PacMan.y = PacMan.y - 1
                        didMove = true
                        EXIT FOR
                    ELSE
                        IF prevDirection THEN
                            nextDirection = direction
                            direction = prevDirection
                        END IF
                    END IF
                ELSE 'warp
                    PacMan.y = 23
                    didMove = true
                END IF
            CASE 3 'right
                IF PacMan.x < LEN(mapData(1)) THEN
                    IF ASC(mapData(PacMan.y), PacMan.x + 1) = 32 THEN
                        PacMan.x = PacMan.x + 1
                        didMove = true
                        EXIT FOR
                    ELSE
                        IF prevDirection THEN
                            nextDirection = direction
                            direction = prevDirection
                        END IF
                    END IF
                ELSE 'warp
                    PacMan.x = 1
                    didMove = true
                END IF
            CASE 4 'down
                IF PacMan.y < 23 THEN
                    IF ASC(mapData(PacMan.y + 1), PacMan.x) = 32 THEN
                        PacMan.y = PacMan.y + 1
                        didMove = true
                        EXIT FOR
                    ELSE
                        IF prevDirection THEN
                            nextDirection = direction
                            direction = prevDirection
                        END IF
                    END IF
                ELSE 'warp
                    PacMan.y = 1
                    didMove = true
                END IF
        END SELECT
    NEXT
END SUB
 
SUB processInput
    DIM k AS LONG
 
    k = _KEYHIT
    IF k = 27 THEN endGame = true
 
    IF _KEYDOWN(19200) THEN nextDirection = 1
    IF _KEYDOWN(18432) THEN nextDirection = 2
    IF _KEYDOWN(19712) THEN nextDirection = 3
    IF _KEYDOWN(20480) THEN nextDirection = 4
END SUB
 
SUB setupMap
    DIM i AS INTEGER
 
    RESTORE
    FOR i = 1 TO 23
        READ mapData(i)
    NEXT
END SUB
 
SUB setupDots
    DIM i AS INTEGER
 
    FOR i = 1 TO 23
        DIM c AS INTEGER, thisDot AS INTEGER, thisGhost AS INTEGER
 
        FOR c = 1 TO LEN(mapData(i))
            SELECT CASE ASC(mapData(i), c)
                CASE 46
                    'dot
                    ASC(mapData(i), c) = 32
                    thisDot = thisDot + 1
                    dot(thisDot).x = c
                    dot(thisDot).y = i
                    dot(thisDot).state = 1
                CASE 111
                    'power pellet
                    ASC(mapData(i), c) = 32
                    thisDot = thisDot + 1
                    dot(thisDot).x = c
                    dot(thisDot).y = i
                    dot(thisDot).state = 2
                CASE 65
                    'ghost
                    ASC(mapData(i), c) = 32
                    thisGhost = thisGhost + 1
                    ghost(thisGhost).x = c
                    ghost(thisGhost).y = i
                    ghost(thisGhost).state = true
                CASE 67
                    'PacMan
                    ASC(mapData(i), c) = 32
                    PacMan.x = c
                    PacMan.y = i
                CASE 35
                    'wall separator
                    ASC(mapData(i), c) = 0
            END SELECT
        NEXT
    NEXT
END SUB
 
SUB drawLabyrinth
    DIM i AS INTEGER
 
    FOR i = 1 TO 23
        _PRINTSTRING (3, i), mapData(i)
    NEXT
END SUB
 
SUB drawItems
    DIM i AS INTEGER, c$
 
    FOR i = 1 TO UBOUND(dot)
        c$ = " "
        IF dot(i).state = 1 THEN c$ = "."
        IF dot(i).state = 2 THEN c$ = "o"
        _PRINTSTRING (2 + dot(i).x, dot(i).y), c$
    NEXT
 
    SELECT CASE direction
        CASE 0
            PacManChar$ = "C"
        CASE 1, 3 'left or right
            IF PacMan.x MOD 2 = 0 THEN PacManChar$ = "C" ELSE PacManChar$ = "c"
        CASE 2, 4 'up or down
            IF PacMan.y MOD 2 <> 0 THEN PacManChar$ = "C" ELSE PacManChar$ = "c"
    END SELECT
 
    _PRINTSTRING (2 + PacMan.x, PacMan.y), PacManChar$
 
    IF TIMER - powerPelletTimer < powerPelletMAX THEN ghostChar$ = "m" ELSE ghostChar$ = "A"
 
    FOR i = 1 TO UBOUND(ghost)
        _PRINTSTRING (2 + ghost(i).x, ghost(i).y), ghostChar$
    NEXT
END SUB
 
'Map data
DATA "+-------------------+# #+# #+-------------------+"
DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
DATA "|#.#+-----+#.#+-----+#.#|#.#+-----+#.#+-----+#.#|"
DATA "|#o#|     |#.#|     |#.#|#.#|     |#.#|     |#o#|"
DATA "|#.#+-----+#.#+-----+#.#|#.#+-----+#.#+-----+#.#|"
DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
DATA "|#.#-------#.#|#.#------+------#.#|#.#-------#.#|"
DATA "|#. . . . . .#|#. . . .#|#. . . .#|#. . . . . .#|"
DATA "+---------+#.#------+# #|# #+-----+#.#+---------+"
DATA "          |#.#|#                 #|#.#|          "
DATA "----------+#.#|# #+-----#-----+# #|#.#+----------"
DATA "            .    #|  A A A A  |#    .            "
DATA "----------+#.#|# #+-----#-----+# #|#.#+----------"
DATA "          |#.#|#                 #|#.#|          "
DATA "+---------+#.#|# #------+------# #|#.#+---------+"
DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
DATA "|#.#------+#.#-------#.#|#.#-------#.#+------#.#|"
DATA "|#o . . .#|#. . . . . . C . . . . . .#|#. . . o#|"
DATA "+------#.#|#.#|# #-------------# #|#.#|#.#------+"
DATA "|#. . . . . .#|#. . . . . . . . .#|#. . . . . .#|"
DATA "|#.#----------+------#.#|#.#------+----------#.#|"
DATA "|#. . . . . . . . . . .#|#. . . . . . . . . . .#|"
DATA "+-------------------+# #+# #+-------------------+"
 

I'll be posting the progress here as I go.

Nice! I like it! :)

Wow, CP/M. Now thats oldschool. :)

I like it a lot!

Hi, nice game!

If you're looking to reproduce authentic style Pacman gameplay, you might want to take a look at this link: http://gameinternals.com/post/2072558330/understanding-pac-man-ghost-behavior

That does the best job of any write up which I've ever seen, explaining how the Ghost AI behaves and operates in Pacman. It might be of some use to you. ;)

Thanks for sharing the link, Steve!

I'd looked at that article before, and it kinda slowed me down, as I figured it'd be harder than just chasing Pacman. This updated version in the attachment has ghosts doing just that, chasing Pacman blindly.

Maybe I'll get to it when I'm on vacation again.

PS: Hit "m" for a more "modern" look, as in the screenshot.

PS2: Ghosts are harmless for now.

Hi Fellippe, on line 139 - its new command _CONTINUE ? My IDE write syntax error for this, i comment this line and then it start. I like new graphic after m press.

Hi Petr.

Yes, _CONTINUE is a new QB64 statement introduced in build 20170628/55. It works exactly like its C counterpart:

Quote

The continue statement in C programming works somewhat like the break statement. Instead of forcing termination, it forces the next iteration of the loop to take place, skipping any code in between.

From https://www.tutorialspoint.com/cprogramming/c_continue_statement.htm

It's a shortcut to a goto, and if you look in the C++ output, that's exactly what it does. Take the code below:

Code: QB64: [Select]

FOR i = 1 to 10
    IF i = 5 THEN GOTO skip
    PRINT i;
    skip:
NEXT

You can write the same using _CONTINUE as follows:

Code: QB64: [Select]

FOR i = 1 to 10
    IF i = 5 THEN _CONTINUE
    PRINT i;
NEXT

Both will output:

Quote

1 2 3 4 6 7 8 9 10

You can also use _CONTINUE in DO/LOOP and WHILE/WEND blocks, with the same purpose of skipping to the end of the block without exiting it.

Hi FellippeHeitor, thank you for your clear explanation. So it's time to upgrade my IDE ...

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: FellippeHeitor on July 19, 2017, 06:09:38 am