QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Cobalt on March 18, 2019, 11:43:18 pm

Title: A question about OpenGL shapes and applying a texture?
Post by: Cobalt on March 18, 2019, 11:43:18 pm

More so a question for Ashish and his example from this post;
https://www.qb64.org/forum/index.php?topic=1137.msg103321#msg103321
actually 2 questions,
A: How is the GL rountine called? I don't see any reference calls in the Main loop in this example
B: Is it possible to apply a Texture map to the Cube? to say make it look like a 6 sided Dice?

Code: QB64: [Select]

1. '##########################
2. '  OpenGL 3D Shapes
3. '    By Ashish Kushwaha
4. '##########################
5. ' :)
6.  
7. _TITLE "OpenGL 3D Shapes"
8. SCREEN _NEWIMAGE(600, 600, 32)
9.  
10. DECLARE LIBRARY
11.  
12. 'Sphere
13.     SUB glutSolidSphere (BYVAL radius AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG)
14.     SUB glutWireSphere (BYVAL radius AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG)
15.  
16.     'Cube
17.     SUB glutWireCube (BYVAL dsize AS DOUBLE)
18.     SUB glutSolidCube (BYVAL dsize AS DOUBLE)
19.  
20.     'Torus
21.     SUB glutWireTorus (BYVAL dInnerRadius AS DOUBLE, BYVAL dOuterRadius AS DOUBLE, BYVAL nSides AS LONG, BYVAL nRings AS LONG)
22.     SUB glutSolidTorus (BYVAL dInnerRadius AS DOUBLE, BYVAL dOuterRadius AS DOUBLE, BYVAL nSides AS LONG, BYVAL nRings AS LONG)
23.  
24.     'Cone
25.     SUB glutWireCone (BYVAL base AS DOUBLE, BYVAL height AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG)
26.     SUB glutSolidCone (BYVAL base AS DOUBLE, BYVAL height AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG)
27.  
28.     'Cylinder
29.     SUB glutWireCylinder (BYVAL base AS DOUBLE, BYVAL height AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG)
30.     SUB glutSolidCylinder (BYVAL base AS DOUBLE, BYVAL height AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG)
31.  
32. END DECLARE
33.  
34. 'Used by GLH RGB/etc helper functions
35. DIM SHARED DONT_USE_GLH_COL_RGBA(1 TO 4) AS SINGLE
36.  
37. DIM SHARED shapeId
38. DIM SHARED walk 'this will hold value about how close we are to our object
39. walk = 5
40. DO
41.     k& = _KEYHIT
42.     IF k& = ASC(" ") THEN
43.         IF shapeId = 4 THEN shapeId = 0 ELSE shapeId = shapeId + 1
44.     END IF
45.     'Hi Sir!
46.     'try to press 'w' or 's'
47.     IF k& = ASC("s") THEN walk = walk + .05
48.     IF k& = ASC("w") THEN walk = walk - .05
49.     _LIMIT 30
50. LOOP
51.  
52. SUB _GL STATIC
53.     _glViewport 0, 0, _WIDTH, _HEIGHT
54.  
55.     'Enable Z-Buffer read/write
56.     _glEnable _GL_DEPTH_TEST
57.    
58.     _glEnable _GL_LIGHTING
59.     _glEnable _GL_LIGHT0
60.    
61.     _glLightfv _GL_LIGHT0, _GL_AMBIENT, GLH_RGB(.15, .15, .15)
62.     _glLightfv _GL_LIGHT0, _GL_SPECULAR, GLH_RGB(.8, .8, .8)
63.     _glLightfv _GL_LIGHT0, _GL_POSITION, GLH_RGBA(COS(clock#), 0, SIN(clock#), 0)
64.    
65.     'clears the depth
66.     _glClearDepth 1.0
67.    
68.     'swich Projection matrix mode
69.     _glMatrixMode _GL_PROJECTION
70.     _glLoadIdentity
71.    
72.     'setting up perpective
73.     aspect# = _WIDTH / _HEIGHT
74.     _gluPerspective 40, aspect#, 1, 200
75.    
76.     'Now, we'll use ModelView
77.     _glMatrixMode _GL_MODELVIEW
78.     _glLoadIdentity
79.    
80.     _glClear _GL_COLOR_BUFFER_BIT OR _GL_DEPTH_BUFFER_BIT
81.     'this clock# variable increases everytime as it is  used for rotation.
82.     clock# = clock# + .01
83.    
84.     'note that  here walk value should be negative.
85.     'Lesser the walk, object become closes, and vise versa
86.     _glTranslatef 0, 0, -walk
87.    
88.     _glRotatef 30 * clock#, 1, 0, 0
89.     _glRotatef 60 * clock#, 0, 1, 0
90.     _glRotatef 90 * clock#, 0, 0, 1
91.  
92.     _glColor3f 1, 1, 1
93.  
94.     SELECT CASE shapeId
95.         CASE 0
96.             glutSolidSphere .5, 50, 50
97.         CASE 1
98.             glutSolidTorus .2, .5, 50, 50
99.         CASE 2
100.             glutSolidCube .5
101.         CASE 3
102.             glutSolidCone .4, .5, 30, 30
103.         CASE 4
104.             glutSolidCylinder .2, .8, 40, 40
105.     END SELECT
106.  
107.     _glFlush
108. END SUB
109.  
110. 'used opengl rgba functions
111. FUNCTION GLH_RGB%& (r AS SINGLE, g AS SINGLE, b AS SINGLE)
112.     DONT_USE_GLH_COL_RGBA(1) = r
113.     DONT_USE_GLH_COL_RGBA(2) = g
114.     DONT_USE_GLH_COL_RGBA(3) = b
115.     DONT_USE_GLH_COL_RGBA(4) = 1
116.     GLH_RGB = _OFFSET(DONT_USE_GLH_COL_RGBA())
117. END FUNCTION
118.  
119. FUNCTION GLH_RGBA%& (r AS SINGLE, g AS SINGLE, b AS SINGLE, a AS SINGLE)
120.     DONT_USE_GLH_COL_RGBA(1) = r
121.     DONT_USE_GLH_COL_RGBA(2) = g
122.     DONT_USE_GLH_COL_RGBA(3) = b
123.     DONT_USE_GLH_COL_RGBA(4) = a
124.     GLH_RGBA = _OFFSET(DONT_USE_GLH_COL_RGBA())
125. END FUNCTION
126.  
127.  

or if anybody else might have a Cube routine that could have each side texture mapped as such and rotated in a 'tumbling' kind of way. I could do it in QB45 using DirectQB but not sure how to accomplish the same results with QB64.

Title: Re: A question about OpenGL shapes and applying a texture?
Post by: Ashish on March 23, 2019, 09:35:29 am

Hi Cobalt!
A : GL routine is a special subroutine. It called automatically at 60 or 48 times a second depending on the refreshrate of display. I usually add a loop so that program can be hold and GL can be called continuously in the background.
B : It is possible. You can apply texture to any type of object/shape, whether it is 2D or 3D. You can even apply 3D textures as well as multiple textures.
Using textures in OpenGL is a bit cumbersome. I have started a tutorial here - https://ashishkingdom.github.io/OpenGL-Tutorials/ (not completed yet). You can either go through the tutorial and understand the behind the scenes thing about GL. For now, I can provide you a simple routine which can render a cube with the texture map as an arguement soon.

Text Only | Text with Attachments