Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: FellippeHeitor on March 15, 2019, 10:37:15 am

Title: Visualizing _PI challenge
Post by: FellippeHeitor on March 15, 2019, 10:37:15 am
Anyone would be willing to take on the challenge to recreate this or even reinvent it? https://www.reddit.com/r/dataisbeautiful/comments/b13h1d/adding_to_the_pi_visualizations_oc/
Title: Re: Visualizing _PI challenge
Post by: bplus on March 15, 2019, 11:02:41 am
Hi Fellippe,

Is there some sort of calculation of Pi going on or is this just bouncing from digit to digit of a Pi expansion?

Repeating digits could use a little loop, internal or external.
Title: Re: Visualizing _PI challenge
Post by: Qwerkey on March 15, 2019, 11:37:32 am
... And when you have taken up this challenge, unless you produce pi to more than 31 trillion digits, we shall think that you have hardly tried at all.  (To any mathematicians out there, why do mathematicians do that sort of thing and who knows if they're correct?).
Title: Re: Visualizing _PI challenge
Post by: Petr on March 15, 2019, 12:28:29 pm
It looks interesting. To calculate pi, we could use the formula π = 2 x (2 x 2 x 4 x 4 x 6 x 6 ...) / (1 x 3 x 3 x 5 x 5 x 7 ...)
but a sample example uses only a few decimal places to visualize ...

Code: QB64: [Select]
  1. SCREEN _NEWIMAGE(800, 600, 32)
  2.  
  3. TYPE nrs
  4.     x AS INTEGER
  5.     y AS INTEGER
  7. DIM N(10) AS nrs
  8.  
  9. CONST CX = 400
  10. CONST CY = 300
  11. pi$ = "3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342117067982148086513282306647093844609550582231725359408128481117450284102701938521105559644622948954930381964428810975665933446128475648233786783165271201909145648566923460348610454326648213393607260249141273"
  12.  
  13. FOR p = -60 TO 264 STEP 36
  14.     q = _D2R(p)
  15.     N(w).x = CX + COS(q) * 150
  16.     N(w).y = CY + SIN(q) * 150
  17.     w = w + 1
  18.     CIRCLE (CX + COS(q) * 150, CY + SIN(q) * 150), 3
  19.     _PRINTSTRING (CX + COS(q) * 170, CY + SIN(q) * 170), _TRIM$(STR$(num))
  20.     num = num + 1
  22.  
  23. CIRCLE (400, 300), 150
  24.  
  25. FOR sh = 1 TO LEN(pi$)
  26.     IF ASC(pi$, sh) >= 48 AND ASC(pi$, sh) <= 57 THEN
  27.         v$ = MID$(pi$, sh, 1)
  28.         LINE (ox, oy)-(ox2, oy2), _RGB32(127, 127, 127)
  29.          i = ASC(pi$, sh) - 48
  30.         LOCATE 1, 1: PRINT MID$(pi$, 1, sh)
  31.         ox = N(oldN).x: oy = N(oldN).y: ox2 = N(i).x: oy2 = N(i).y
  32.         LINE (N(oldN).x, N(oldN).y)-(N(i).x, N(i).y), _RGB32(255, 255, 255): oldN = i
  33.         oldN = i
  34.         _DELAY .2
  35.     END IF
  36. NEXT sh
  37.  
Title: Re: Visualizing _PI challenge
Post by: Petr on March 15, 2019, 12:46:30 pm
There is one more way - the infinite division using MOD, but the fraction 22/7 is inaccurate, because there is a wrong result in the third decimal place. Another fraction is 355/113, but there will also be an error in the seventh decimal place.
Title: Re: Visualizing _PI challenge
Post by: FellippeHeitor on March 15, 2019, 12:53:51 pm
Wow, that was fast, Petr. Good job!

@bplus
I don't know if they're calculating as they go or if it's just fetching from a precalculated list of digits. I just liked the visualization very much when I fist came across it.

@Qwerkey
It's indeed silly to try to break any supercomputer's record in findind the next digits of pi... Maybe mathematicians just wanna have fun in the end too (and measure dick).

I'm looking to take part in the challenge myself. I'll keep this thread as a post-it reminder for me to do it eventually.
Title: Re: Visualizing _PI challenge
Post by: Petr on March 15, 2019, 12:58:30 pm
Thank you Fellippe, it was a welcome change, such a rebound from the 3D maze editor that I am writing.
Title: Re: Visualizing _PI challenge
Post by: jack on March 15, 2019, 01:08:36 pm
I think the Spigot algorithm would be perfect for this https://rosettacode.org/wiki/Pi
Title: Re: Visualizing _PI challenge
Post by: Pete on March 15, 2019, 01:15:32 pm
I haven't figured out how far my string math routines would go, I just know if it was accurate and infinite, it would take about 40 years to surpass the record pi calculation to date, of 31.4 trillion digits. Anyone know where I can find a computer that will last 40 years, without a %^&^$# Windows update?

Pete
Title: Re: Visualizing _PI challenge
Post by: bplus on March 15, 2019, 02:14:22 pm
Hey Petr, nice and fast.

I had basic scheme worked out when I saw you had already posted. So I better have some better features!

I do. :)

This draws an outer loop around digit when digit repeats sequentially (you have to wait awhile for 7), plus it has the pointer moving between points...
Code: QB64: [Select]
  1. _TITLE "Visualizing Pi" 'B+ 2019-03-15
  2.  
  3. 'Featuring a circle loop around the a repeated digit.
  4. ' 3 first, 8, 9, 4, 1, 6, 2, 5, 0 (300+ digits), 7 (560 digits) EDIT
  5.  
  6. 'ref  http://www.math.com/tables/constants/pi.htm  First 100 digits
  7. CONST pi100 = "3141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342117067"
  8. 'ref same as above 1000 digits, see if can circle all digits pi shortened to 560 digits
  9. CONST pi = "314159265358979323846264338327950288419716939937510582097494459230781640628620899862803482534211706798214808651328230664709384460955058223172535940812848111745028410270193852110555964462294895493038196442881097566593344612847564823378678316527120190914564856692346034861045432664821339360726024914127372458700660631558817488152092096282925409171536436789259036001133053054882046652138414695194151160943305727036575959195309218611738193261179310511854807446237996274956735188575272489122793818301194912983367336244065664308602139494639522473719070217986094370277"
  10. 'PRINT INSTR(pi, "77") ' last number to get circled for repeating at 560
  11.  
  12. CONST xmax = 800
  13. CONST ymax = 720
  14. CONST x0 = 400
  15. CONST y0 = 420
  16. CONST radius = 240
  17. CONST r2 = 20
  18.  
  19. TYPE vectorType
  20.     x AS SINGLE
  21.     y AS SINGLE
  23.  
  24. SCREEN _NEWIMAGE(xmax, ymax, 32)
  25. _SCREENMOVE 300, 20
  26. s2& = _NEWIMAGE(xmax, ymax, 32) 'to update drawing lines in isolation
  27. t = TIMER(.001)
  28. ca = _PI(2 / 10)
  29. DIM vdigit(0 TO 9) AS vectorType
  30. DIM outer(0 TO 9) AS vectorType
  31. CIRCLE (x0, y0), radius
  32. FOR i = 0 TO 9
  33.     vdigit(i).x = x0 + radius * COS(ca * i - 2 * ca)
  34.     vdigit(i).y = y0 + radius * SIN(ca * i - 2 * ca)
  35.     CIRCLE (vdigit(i).x, vdigit(i).y), 2
  36.     x = x0 + (radius + 18) * COS(ca * i - 2 * ca) - 2
  37.     y = y0 + (radius + 18) * SIN(ca * i - 2 * ca) - 6
  38.     _PRINTSTRING (x, y), LTRIM$(STR$(i))
  39.     outer(i).x = x0 + (radius + r2) * COS(ca * i - 2 * ca)
  40.     outer(i).y = y0 + (radius + r2) * SIN(ca * i - 2 * ca)
  42. _PUTIMAGE , 0, s2&
  43.  
  44. digitPointer = 1
  45. cx = x0: cy = y0: speed = 10
  46. WHILE digitPointer <= LEN(pi)
  47.     d = VAL(MID$(pi, digitPointer, 1))
  48.     targetx = vdigit(d).x: targety = vdigit(d).y
  49.     targetangle = _ATAN2(targety - cy, targetx - cx)
  50.     rc~& = _RGB32(255 * RND, 255 * RND, 255 * RND)
  51.     IF lastd = d THEN
  52.         _DEST s2&
  53.         CIRCLE (outer(d).x, outer(d).y), r2, rc~&
  54.         _DEST 0
  55.         CLS
  56.         _PUTIMAGE , s2&, 0
  57.         CIRCLE (cx, cy), 2, &HFFFFFFFF, BF
  58.         LOCATE 1, 1: PRINT MID$(pi, 1, digitPointer - 1)
  59.         _DISPLAY
  60.     ELSE
  61.         DO
  62.             dist = SQR((targetx - cx) ^ 2 + (targety - cy) ^ 2)
  63.             IF dist < speed THEN
  64.                 newX = targetx
  65.                 newY = targety
  66.             ELSE
  67.                 newX = cx + speed * COS(targetangle)
  68.                 newY = cy + speed * SIN(targetangle)
  69.             END IF
  70.             _DEST s2&
  71.             LINE (cx, cy)-(newX, newY), rc~&
  72.             _DEST 0
  73.             CLS
  74.             _PUTIMAGE , s2&, 0
  75.             CIRCLE (newX, newY), 2, &HFFFFFFFF, BF
  76.             cx = newX: cy = newY
  77.             LOCATE 1, 1: PRINT MID$(pi, 1, digitPointer - 1)
  78.             _DISPLAY
  79.             _LIMIT 60
  80.         LOOP UNTIL cx = targetx AND cy = targety
  81.     END IF
  82.     digitPointer = digitPointer + 1
  83.     lastd = d
  85. LOCATE 1, 1: PRINT MID$(pi, 1, digitPointer)
  86. PRINT TIMER(.001) - t; " secs"
  88.  


Title: Re: Visualizing _PI challenge
Post by: Petr on March 15, 2019, 02:31:17 pm
Hi BPlus!  It's very nice. I even discovered the BF parameter for Circle with your program, I haven't seen it yet. Motion in circle is also very interesting.
Title: Re: Visualizing _PI challenge
Post by: bplus on March 15, 2019, 02:34:44 pm
Quote from: Petr on March 15, 2019, 02:31:17 pm
Hi BPlus!  It's very nice. I even discovered the BF parameter for Circle with your program, I haven't seen it yet. Motion in circle is also very interesting.

HA! Twice!
Code: QB64: [Select]
  1. CIRCLE (cx, cy), 2, &HFFFFFFFF, BF  
  2.  

I started with a line for a solid pointer, forgot to erase that BF!
Title: Re: Visualizing _PI challenge
Post by: Petr on March 15, 2019, 02:37:40 pm
Quote
I started with a line for a solid pointer, forgot to erase that BF!

Really? I thought I discovered something new! :-D
Title: Re: Visualizing _PI challenge
Post by: jack on March 15, 2019, 04:36:30 pm
hello bplus
here's spigot sub for you
Code: QB64: [Select]
  1. DIM pi(100) AS _BYTE
  3. spigot pi()
  4.  
  5. PRINT LTRIM$(STR$(pi(1))); ".";
  6. FOR i = 2 TO UBOUND(pi)
  7.     PRINT LTRIM$(STR$(pi(i)));
  11.  
  12. SUB spigot (pi() AS _BYTE)
  13.     DIM N AS LONG
  14.     N = UBOUND(pi)
  15.     DIM ln AS LONG
  16.     ln = INT((10 * N) / 3) + 1
  17.     DIM A(0 TO ln - 1) AS LONG
  18.     DIM npi AS LONG
  19.     DIM i AS LONG, j AS LONG, k AS LONG
  20.     npi = 0
  21.     FOR i = 0 TO ln - 1
  22.         A(i) = 2
  23.     NEXT
  24.  
  25.     DIM nines AS LONG
  26.     DIM predigit AS LONG
  27.     nines = 0
  28.     predigit = 0
  29.     FOR j = 1 TO N
  30.         DIM q AS LONG
  31.         q = 0
  32.         FOR i = ln TO 1 STEP -1
  33.             DIM x AS LONG
  34.             x = (10 * A((i - 1))) + (q * i)
  35.             A((i - 1)) = x MOD ((2 * i) - 1)
  36.             q = x \ ((2 * i) - 1)
  37.         NEXT
  38.         A(0) = q MOD 10
  39.         q = q \ 10
  40.  
  41.         IF 9 = q THEN
  42.             nines = nines + 1
  43.         ELSEIF 10 = q THEN
  44.             pi(npi) = predigit + 1: npi = npi + 1
  45.             FOR k = 0 TO nines - 1
  46.                 pi(npi) = 0: npi = npi + 1
  47.             NEXT
  48.             predigit = 0
  49.             nines = 0
  50.         ELSE
  51.             pi(npi) = predigit: npi = npi + 1
  52.             predigit = q
  53.  
  54.             IF 0 <> nines THEN
  55.                 FOR k = 0 TO nines - 1
  56.                     pi(npi) = 9: npi = npi + 1
  57.                 NEXT
  58.                 nines = 0
  59.             END IF
  60.         END IF
  61.     NEXT
  62.     pi(npi) = predigit
  64.  
Title: Re: Visualizing _PI challenge
Post by: bplus on March 15, 2019, 05:53:27 pm
Thanks Jack I will check it out.

Update: That compares very well with the reference Pi I was using. I used the following code as a check:
Code: QB64: [Select]
  1. 'from Jack 2019-03-15 QB64 forum "Visualizing Pi" B+ mod to check Pi with reference Pi.
  2. _TITLE "Compare Spigot to Pi Ref digit by digit"
  3. SCREEN _NEWIMAGE(600, 720, 32)
  4. _SCREENMOVE 300, 20
  5. CONST piRef = "314159265358979323846264338327950288419716939937510582097494459230781640628620899862803482534211706798214808651328230664709384460955058223172535940812848111745028410270193852110555964462294895493038196442881097566593344612847564823378678316527120190914564856692346034861045432664821339360726024914127372458700660631558817488152092096282925409171536436789259036001133053054882046652138414695194151160943305727036575959195309218611738193261179310511854807446237996274956735188575272489122793818301194912983367336244065664308602139494639522473719070217986094370277"
  6. DIM pi%(561)
  7. spigot pi%()
  8.  
  9. FOR i = 1 TO UBOUND(pi%)
  10.     PRINT i; " digit spigot vrs ref "; pi%(i); " vrs "; MID$(piRef, i, 1)
  11.     IF i MOD 30 = 29 THEN
  12.         INPUT "OK, press enter "; wate$
  13.         CLS
  14.     END IF
  17.  
  18. SUB spigot (pi%())
  19.     DIM N%
  20.     N% = UBOUND(pi%)
  21.     DIM ln AS LONG
  22.     ln = INT((10 * N%) / 3) + 1
  23.     DIM A(0 TO ln - 1) AS LONG
  24.     DIM npi AS LONG
  25.     DIM i AS INTEGER, j AS INTEGER, k AS INTEGER
  26.     npi = 0
  27.     FOR i = 0 TO ln - 1
  28.         A(i) = 2
  29.     NEXT
  30.  
  31.     DIM nines AS LONG
  32.     DIM predigit AS LONG
  33.     nines = 0
  34.     predigit = 0
  35.     FOR j = 1 TO N%
  36.         DIM q AS LONG
  37.         q = 0
  38.         FOR i = ln TO 1 STEP -1
  39.             DIM x AS LONG
  40.             x = (10 * A((i - 1))) + (q * i)
  41.             A((i - 1)) = x MOD ((2 * i) - 1)
  42.             q = x \ ((2 * i) - 1)
  43.         NEXT
  44.         A(0) = q MOD 10
  45.         q = q \ 10
  46.  
  47.         IF 9 = q THEN
  48.             nines = nines + 1
  49.         ELSEIF 10 = q THEN
  50.             pi%(npi) = predigit + 1: npi = npi + 1
  51.             FOR k = 0 TO nines - 1
  52.                 pi%(npi) = 0: npi = npi + 1
  53.             NEXT
  54.             predigit = 0
  55.             nines = 0
  56.         ELSE
  57.             pi%(npi) = predigit: npi = npi + 1
  58.             predigit = q
  59.  
  60.             IF 0 <> nines THEN
  61.                 FOR k = 0 TO nines - 1
  62.                     pi%(npi) = 9: npi = npi + 1
  63.                 NEXT
  64.                 nines = 0
  65.             END IF
  66.         END IF
  67.     NEXT
  68.     pi%(npi) = predigit
  70.  
  71.  
Title: Re: Visualizing _PI challenge
Post by: Jack002 on March 15, 2019, 07:38:19 pm
Quote from: Pete on March 15, 2019, 01:15:32 pm
I haven't figured out how far my string math routines would go, I just know if it was accurate and infinite, it would take about 40 years to surpass the record pi calculation to date, of 31.4 trillion digits. Anyone know where I can find a computer that will last 40 years, without a %^&^$# Windows update?

Pete
That computer Deep Thought in Hitchhiker's Guide to the Galaxy never had these problems. :-)
 
Title: Re: Visualizing _PI challenge
Post by: jack on March 15, 2019, 08:14:29 pm
in the spigot routine, if the dimension in pi is greater than 9830 then I get an unhandled error #9, subscription out of range, anybody know why?
not that anybody would use that routine to calculate pi to that many places.
Title: Re: Visualizing _PI challenge
Post by: codeguy on March 15, 2019, 08:57:24 pm
Wasn't certain where this arbitrary precision Pi calculation algorithm should go.
Code: QB64: [Select]
  1. DECLARE SUB atan239 (denom&)
  2. DECLARE SUB atan5 (denom&)
  3. DECLARE SUB PrintOut (words%)
  4.  
  5. 'Program to calculate pi, version 4.8
  6. 'A major rewrite of version 4.2, this uses only two arrays instead of
  7. 'three, and includes a host of speedups based on a similar C program.
  8. 'A sampler: all the carries are reserved until the end, the divide and
  9. 'add routines are combined, two terms are added at a time, and the number
  10. 'of function calls is minimized. It's a big change for a small gain, since
  11. 'the compiled version requires 28.6 seconds for 5000 digits on my 486 66MHz
  12. 'computer, a 10% gain over version 4.2; like before, it's capable of about
  13. '150,000 digits of pi.
  14. '
  15. 'This program has come a long way from version 1.0; thanks are due to
  16. 'Larry Shultis, Randall Williams, Bob Farrington and Adrian Umpleby.
  17. 'One final note for speed freaks: this program will run about 6 times faster
  18. 'if written in C using an optimizing compiler. Likewise, if you can figure
  19. 'out a way to do integer division and use both the quotient and remainder,
  20. 'this program can easily be sped up by 25%.      -jasonp@isr.umd.edu
  21.  
  22. DEFINT A-Z
  24. INPUT "how many digits"; digits&
  25.  
  26. words = digits& \ 4 + 3
  27. DIM SHARED sum&(words + 1), term(words + 1)
  28. start! = TIMER
  29.                                        
  30.                                          '---------------16*atan(1/5)
  31. denom& = 3: firstword = 1: lastword = 2
  32. sum&(1) = 3: term(1) = 3: sum&(2) = 2000: term(2) = 2000
  33.  
  34. DO UNTIL firstword >= words
  35.    CALL atan5(denom&)
  36.    denom& = denom& + 2
  38.  
  39.                                          '------------   -4*atan(1/239)
  40. denom& = 3: firstword = 2: remainder& = 4
  41.  
  42. FOR x = 2 TO words
  43.    dividend& = remainder& * 10000              'crunch out 1st term
  44.    term(x) = dividend& \ 239&
  45.    remainder& = dividend& - term(x) * 239&
  46.    sum&(x) = sum&(x) - term(x)
  48.  
  49. DO UNTIL firstword >= words
  50.    CALL atan239(denom&)
  51.    denom& = denom& + 4
  53.                                      
  54.  
  55. FOR x = words TO 2 STEP -1                        '-------finish up
  56.    IF sum&(x) < 0 THEN                                  'release carries
  57.       quotient& = sum&(x) \ 10000                       'and borrows
  58.       sum&(x) = sum&(x) - (quotient& - 1) * 10000
  59.       sum&(x - 1) = sum&(x - 1) + quotient& - 1
  60.    END IF
  61.    IF sum&(x) >= 10000 THEN
  62.       quotient& = sum&(x) \ 10000
  63.       sum&(x) = sum&(x) - quotient& * 10000
  64.       sum&(x - 1) = sum&(x - 1) + quotient&
  65.    END IF
  67.  
  68. CALL PrintOut(words)
  69. PRINT "computation time: "; TIMER - start!; " seconds"
  71.  
  72. '------------------------------------------------------------------
  73. SUB atan239 (denom&)
  74. SHARED words, firstword
  75.  
  76. remainder1& = term(firstword)                        'first divide implicitly
  77. remainder2& = 0: remainder3& = 0: remainder4& = 0
  78. denom2& = denom& + 2: firstword = firstword + 1
  79.  
  80. FOR x = firstword TO words
  81.    temp& = term(x)
  82.    dividend& = remainder1& * 10000 + temp&
  83.    temp& = dividend& \ 57121
  84.    remainder1& = dividend& - temp& * 57121
  85.  
  86.    dividend& = remainder2& * 10000 + temp&
  87.    temp2& = dividend& \ denom&
  88.    remainder2& = dividend& - temp2& * denom&
  89.    sum&(x) = sum&(x) + temp2&
  90.  
  91.    dividend& = remainder3& * 10000 + temp&
  92.    temp& = dividend& \ 57121
  93.    remainder3& = dividend& - temp& * 57121
  94.  
  95.    dividend& = remainder4& * 10000 + temp&
  96.    temp2& = dividend& \ denom2&
  97.    remainder4& = dividend& - temp2& * denom2&
  98.    sum&(x) = sum&(x) - temp2&
  99.    term(x) = temp&
  101.  
  102. firstword = firstword + 1
  103. IF term(firstword) = 0 THEN firstword = firstword + 1
  104.  
  106.  
  107. '-------------------------------------------------------------------
  108. SUB atan5 (denom&)
  109. SHARED words, firstword, lastword
  110.  
  111. FOR x = firstword TO lastword + 1
  112.    temp& = term(x)
  113.    dividend& = remainder1& * 10000 + temp&
  114.    temp& = dividend& \ 25
  115.    remainder1& = dividend& - temp& * 25&
  116.    term(x) = temp&
  117.  
  118.    dividend& = remainder2& * 10000 + temp&
  119.    temp& = dividend& \ denom&
  120.    remainder2& = dividend& - temp& * denom&
  121.    sum&(x) = sum&(x) - temp&
  123.  
  124. FOR x = lastword + 2 TO words
  125.    dividend& = remainder2& * 10000
  126.    temp& = dividend& \ denom&
  127.    remainder2& = dividend& - temp& * denom&
  128.    sum&(x) = sum&(x) - temp&
  130.  
  131. IF term(lastword + 1) > 0 AND lastword < words THEN lastword = lastword + 1
  132. IF term(firstword) = 0 THEN firstword = firstword + 1
  133.  
  134. denom& = denom& + 2
  135. remainder1& = 0: remainder2& = 0
  136.  
  137. FOR x = firstword TO lastword + 1
  138.    temp& = term(x)
  139.    dividend& = remainder1& * 10000 + temp&
  140.    temp& = dividend& \ 25
  141.    remainder1& = dividend& - temp& * 25&
  142.    term(x) = temp&
  143.  
  144.    dividend& = remainder2& * 10000 + temp&
  145.    temp& = dividend& \ denom&
  146.    remainder2& = dividend& - temp& * denom&
  147.    sum&(x) = sum&(x) + temp&
  149.  
  150. FOR x = lastword + 2 TO words
  151.    dividend& = remainder2& * 10000
  152.    temp& = dividend& \ denom&
  153.    remainder2& = dividend& - temp& * denom&
  154.    sum&(x) = sum&(x) + temp&
  156.  
  157. IF term(lastword + 1) > 0 AND lastword < words THEN lastword = lastword + 1
  158. IF term(firstword) = 0 THEN firstword = firstword + 1
  159.  
  161.  
  162. '------------------------------------------------------------------
  163. SUB PrintOut (words)
  164. PRINT "pi = 3+."
  165. FOR i = 1 TO words \ 3
  166.    PRINT " ";
  167.    PRINT RIGHT$("0000" + LTRIM$(STR$(sum&(3 * (i - 1) + 2))), 4);
  168.    PRINT RIGHT$("0000" + LTRIM$(STR$(sum&(3 * (i - 1) + 3))), 4);
  169.    PRINT RIGHT$("0000" + LTRIM$(STR$(sum&(3 * (i - 1) + 4))), 4);
  170.    IF i MOD 5 = 0 THEN PRINT "  :"; 12 * i
  172.  
  173. PRINT " ";
  174. FOR i = 3 * (words \ 3) + 2 TO digits
  175.    PRINT RIGHT$("0000" + LTRIM$(STR$(sum&(i))), 4);
  178.  
  180. [code=qb64]
  181.  
Title: Re: Visualizing _PI challenge
Post by: Pete on March 15, 2019, 09:28:23 pm
Quote from: jack on March 15, 2019, 08:14:29 pm
in the spigot routine, if the dimension in pi is greater than 9830 then I get an unhandled error #9, subscription out of range, anybody know why?
not that anybody would use that routine to calculate pi to that many places.

Sorry, never saw the movie, if there was one, or read the book, but great, now I miss Blondie. :(

Pete
Title: Re: Visualizing _PI challenge
Post by: Pete on March 15, 2019, 09:32:00 pm
Quote from: jack on March 15, 2019, 08:14:29 pm
in the spigot routine, if the dimension in pi is greater than 9830 then I get an unhandled error #9, subscription out of range, anybody know why?
not that anybody would use that routine to calculate pi to that many places.

Sure, i is dim as an integer and at that many iterations. i surpasses the 32767 limit. QB then returns a -32768 for i, which throws the subscript out of range error. Try DIM as _INTEGER64 instead of INTEGER for all dimension integers.

Pete
Title: Re: Visualizing _PI challenge
Post by: doppler on March 16, 2019, 05:40:17 pm
My PI challenge is

Apple
Blue berry
Cherry
and sometimes Peach.

Sorry I can't resist.
Title: Re: Visualizing _PI challenge
Post by: Pete on March 16, 2019, 06:02:56 pm
Q: What's the difference between a round pi and a square pie? A: $6.72.

A round pi is 3.14, and a square pi is 9.86

Ah, pi humor. And now back to our regularly scheduled program-ing...

Pete
Title: Re: Visualizing _PI challenge
Post by: jack on March 17, 2019, 03:27:46 am
thanks Pete :)
Title: Re: Visualizing _PI challenge
Post by: Bert22306 on March 17, 2019, 09:29:50 pm
So, pi humor aside, I thought searching for a fraction of two rational integers that approximates pi was kind of interesting. Of course, a fraction of two rational integers will always be a rational number, so it'll never be exact. So I wrote a search routine, and here are the first few results. I won't list the intermediate results except for the first two, just to show how the routine works. (Not terribly efficient, since I see the value 3.14 showing up repeatedly, as I increase the numerator or the denominator, in that last trial especially.)

Turns out, 355/113 is a pretty decent rational approximation! You have to go a lot ,longer to gain an extra decimal of accuracy.

Actual pi = 3.141592653589793238....

Iteration 1    1 / 1 = 1
Iteration 2    2 / 1 = 2
Iteration 3    3 / 1 = 3
Accuracy requested = 1
-------------------------------------
Iteration 1    1 / 1 = 1
Iteration 2    2 / 1 = 2
Iteration 3    3 / 1 = 3
Iteration 4    4 / 1 = 4
Iteration 5    4 / 2 = 2
Iteration 6    5 / 2 = 2.5
Iteration 7    6 / 2 = 3
Iteration 8    7 / 2 = 3.5
Iteration 9    7 / 3 = 2.333333333333333
Iteration 10   8 / 3 = 2.666666666666667
Iteration 11   9 / 3 = 3
Iteration 12   10 / 3 = 3.333333333333333
Iteration 13   10 / 4 = 2.5
Iteration 14   11 / 4 = 2.75
Iteration 15   12 / 4 = 3
Iteration 16   13 / 4 = 3.25
Iteration 17   13 / 5 = 2.6
Iteration 18   14 / 5 = 2.8
Iteration 19   15 / 5 = 3
Iteration 20   16 / 5 = 3.2
Accuracy requested = .1
----------------------------
Iteration 28   22 / 7 = 3.142857142857143
Accuracy requested = .01
----------------------------
Iteration 264   201 / 64 = 3.140625
Accuracy requested = .001
----------------------------
Iteration 438   333 / 106 = 3.141509433962264
Accuracy requested = .0001
----------------------------
Iteration 467   355 / 113 = 3.141592920353983
Accuracy requested = .00001
----------------------------
Iteration 467    355 / 113 = 3.141592920353983
Accuracy requested = .000001
----------------------------
Iteration 100122   75948 / 24175 = 3.141592554291623
Accuracy requested = .0000001
Text Only | Text with Attachments