Print Page - Yuck String Math or What's wrong with FOO?

Title: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 23, 2019, 04:35:51 pm

In response to Steve's "Yuck string math.." comment in thread: https://www.qb64.org/forum/index.php?topic=1091.msg102860#msg102860

Well, yes, it is messy. This would be my approach, and note this example only handles addition and subtraction of positive or negative integers, at least for now.

I'm thinking if a few people are interested, it might be nice to have a way to calculate numbers for programs added to the new tool box section. It doesn't have to be this method, there are other ways, maybe better ones. Anyway, have a look and if anyone else has played around with ways to get your programs to convert counting numbers to base 10, please post.

Code: QB64: [Select]

DIM a AS _INTEGER64
DO
INPUT "Input first number:"; a
a$ = LTRIM$(STR$(a))
PRINT "Press plus or minus: ";
DO
    operator$ = INKEY$
    IF LEN(operator$) THEN
        IF operator$ = CHR$(27) THEN SYSTEM
        IF operator$ = "+" OR operator$ = "=" OR operator$ = "-" THEN EXIT DO
    END IF
LOOP
IF operator$ = "=" THEN operator$ = "+"
PRINT operator$
INPUT "Input second number:"; a
b$ = LTRIM$(STR$(a))
origa$ = a$: origb$ = b$: origoperator$ = operator$ ' Testing purposes only.
 
IF LEFT$(a$, 1) = "-" THEN sign1$ = "-" ELSE sign1$ = "+"
IF LEFT$(b$, 1) = "-" THEN sign2$ = "-" ELSE sign2$ = "+"
 
sign = 0
SELECT CASE sign1$ + operator$ + sign2$
    CASE "+++", "+--"
        operator$ = "+"
        IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
    CASE "++-", "+-+"
        operator$ = "-"
        IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
        IF VAL(b$) > VAL(a$) THEN SWAP a$, b$: sign = -1
    CASE "---", "-++"
        operator$ = "-"
        IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
        IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
        IF VAL(b$) > VAL(a$) THEN SWAP a$, b$ ELSE sign = -1
    CASE "--+", "-+-"
        operator$ = "+"
        IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
        IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
        sign = -1
END SELECT
 
IF LEN(a$) > LEN(b$) THEN
    b$ = STRING$(LEN(a$) - LEN(b$), "0") + b$
ELSEIF LEN(a$) < LEN(b$) THEN
    a$ = STRING$(LEN(b$) - LEN(a$), "0") + a$
END IF
x1$ = ""
 
SELECT CASE operator$
    CASE "+", "="
        FOR i = LEN(a$) TO 1 STEP -1
            x1 = VAL(MID$(a$, i, 1)) + VAL(MID$(b$, i, 1)) + carry
            IF x1 > 9 THEN x1 = x1 - 10: carry = 1 ELSE carry = 0
            x1$ = LTRIM$(STR$(x1)) + x1$
        NEXT
        IF carry THEN x1$ = "1" + x1$: carry = 0
    CASE "-"
        FOR i = LEN(a$) TO 1 STEP -1
            x1 = VAL(MID$(a$, i, 1)) - VAL(MID$(b$, i, 1)) + carry
            IF x1 < 0 THEN x1 = x1 + 10: carry = -1 ELSE carry = 0
            x1$ = LTRIM$(STR$(x1)) + x1$
        NEXT
        DO UNTIL LEFT$(x1$, 1) <> "0" ' Remove leading zeros.
            x1$ = MID$(x1$, 2)
        LOOP
        IF x1$ = "" THEN x1$ = "0": sign = 0
        IF carry THEN x1$ = "-" + x1$: carry = 0
END SELECT
 
IF sign THEN
    IF LEFT$(x1$, 1) = "-" THEN x1$ = MID$(x1$, 2) ELSE x1$ = "-" + x1$
END IF
 
PRINT " String total = "; x1$
 
SELECT CASE origoperator$ ' Testing purposes only.
    CASE "+"
        PRINT "Numeric total = "; LTRIM$(STR$(VAL(origa$) + VAL(origb$)))
    CASE "-"
        PRINT "Numeric total = "; LTRIM$(STR$(VAL(origa$) - VAL(origb$)))
END SELECT
 
PRINT "------------------------------"
LOOP

Here is the above placed in a subroutine. It can be used as a progressive integer addition / subtraction calculator. Huge numbers welcome!

Code: QB64: [Select]

DO
    INPUT "Input number:"; b$
    CALL stringcalc(a$, operator$, b$)
    IF operator$ <> "" THEN
        PRINT "____________________"
        PRINT "Sub Total = "; a$
    END IF
    PRINT "Plus or minus: ";
    DO
        operator$ = INKEY$
        IF LEN(operator$) THEN
            IF operator$ = CHR$(27) THEN SYSTEM
            IF operator$ = "+" OR operator$ = "=" OR operator$ = "-" THEN EXIT DO
        END IF
    LOOP
    IF operator$ = "=" THEN operator$ = "+"
    PRINT operator$
LOOP
 
SUB stringcalc (a$, operator$, b$)
IF a$ <> "" AND operator$ <> "" AND b$ <> "" THEN
    IF LEFT$(a$, 1) = "-" THEN sign1$ = "-" ELSE sign1$ = "+"
    IF LEFT$(b$, 1) = "-" THEN sign2$ = "-" ELSE sign2$ = "+"
 
    sign = 0
    SELECT CASE sign1$ + operator$ + sign2$
        CASE "+++", "+--"
            operator$ = "+"
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
        CASE "++-", "+-+"
            operator$ = "-"
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
            IF VAL(b$) > VAL(a$) THEN SWAP a$, b$: sign = -1
        CASE "---", "-++"
            operator$ = "-"
            IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
            IF VAL(b$) > VAL(a$) THEN SWAP a$, b$ ELSE sign = -1
        CASE "--+", "-+-"
            operator$ = "+"
            IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
            sign = -1
    END SELECT
 
    IF LEN(a$) > LEN(b$) THEN
        b$ = STRING$(LEN(a$) - LEN(b$), "0") + b$
    ELSEIF LEN(a$) < LEN(b$) THEN
        a$ = STRING$(LEN(b$) - LEN(a$), "0") + a$
    END IF
    x1$ = ""
 
    SELECT CASE operator$
        CASE "+", "="
            FOR i = LEN(a$) TO 1 STEP -1
                x1 = VAL(MID$(a$, i, 1)) + VAL(MID$(b$, i, 1)) + carry
                IF x1 > 9 THEN x1 = x1 - 10: carry = 1 ELSE carry = 0
                x1$ = LTRIM$(STR$(x1)) + x1$
            NEXT
            IF carry THEN x1$ = "1" + x1$: carry = 0
        CASE "-"
            FOR i = LEN(a$) TO 1 STEP -1
                x1 = VAL(MID$(a$, i, 1)) - VAL(MID$(b$, i, 1)) + carry
                IF x1 < 0 THEN x1 = x1 + 10: carry = -1 ELSE carry = 0
                x1$ = LTRIM$(STR$(x1)) + x1$
            NEXT
            DO UNTIL LEFT$(x1$, 1) <> "0" ' Remove leading zeros.
                x1$ = MID$(x1$, 2)
            LOOP
            IF x1$ = "" THEN x1$ = "0": sign = 0
            IF carry THEN x1$ = "-" + x1$: carry = 0
    END SELECT
 
    IF sign THEN
        IF LEFT$(x1$, 1) = "-" THEN x1$ = MID$(x1$, 2) ELSE x1$ = "-" + x1$
    END IF
    a$ = x1$
ELSE
    a$ = b$
END IF
END SUB

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: bplus on February 24, 2019, 01:41:23 pm

Steve might have said "Yuck" to string math but he had a pretty good working set at Walter's forum, if I am recalling correctly.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: SMcNeill on February 24, 2019, 03:36:12 pm

I do. I’ll see about digging it up and sharing sometime soonish. ;)

As a rule, I don’t like string math simply for the speed (sloooow), and I don’t have any real need for it usually. LONGs get the majority of my work done, with _FLOATS used only when necessary (and even less often, SINGLE or DOUBLE), and string math is just a novelty needed by others much more than by me. ;)

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 25, 2019, 11:54:03 am

Well I think I'm at the "Yuck" part. Division. I finished addition, subtraction, and multiplication for positive and negative integers and decimal numbers, but get the steps needed for friggin' string division...

' 1) Add 20 zeros more than the divisor to the dividend.
' 2) Make a string the length of the divisor out of the left side of the dividend.
' 3) Compare cut dividend to divisor. If larger, go to next step. If smaller, bring next digit down and go onto next step.
' 4) Multiply divisor backwards from 9 until product is the same or smaller than cut dividend then save that number to a new string variable.
' 5) Subtract.
' 6) Bring down next digit.
' 7) Repeat at step 3.

I'll probably make a numeric pseudo one first, just to be certain my logic pans out. Square root strings follow a somewhat similar pattern. As far as trig functions, multiplying sine and cosine is easy enough, but there are probably some hair raising steps involved in other functions that Bill could bring to light. I'll probably stop at division, and call it a year.

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: jack on February 25, 2019, 03:27:27 pm

Pete, about division, how about using Newton-Raphson with a double or _float division as the first estimate?

Quote

The steps of Newton–Raphson division are:
Calculate an estimate for the reciprocal of the divisor .
Compute successively more accurate estimates. of the reciprocal. This is where one employs the Newton–Raphson method as such.
Compute the quotient by multiplying the dividend by the reciprocal of the divisor

https://en.wikipedia.org/wiki/Division_algorithm
https://web.stanford.edu/class/ee486/doc/chap5.pdf

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 25, 2019, 04:25:09 pm

Hi Jack,

Oh crap, I'm on a plane. I'm glad I didin't type that out loud...

Anyway. Yes, I'll have to look into that as a testing method. It's probably similar to the trick to estimate square roots. For now, I've been banging it out old school. Here is what I have so far, which just works for positive and negative integers. I'll figure out how to divide decimals later. Also, this is NOT a sting function. I don't want all that extra code in the way until I get a working routine. I'll convert it then.

Code: QB64: [Select]

' Division
' 1) Compare each digit of dividend to divisor. If dividend is larger, exit loop. If smaller, bring next digit down and loop.
' 2) Multiply divisor backwards from 9 until product is the same or smaller than cut dividend then save that number to a new string variable.
' 3) Subtract.
' 4) Repeat.
 
LINE INPUT "Divisor: "; a$
LINE INPUT "Dividend: "; b$
m1$ = a$
m2$ = b$
IF LEFT$(m1$, 1) = "0" THEN PRINT "Division by zero not allowed.": END
IF LEFT$(m1$, 1) = "-" THEN sign = -1: m1$ = MID$(m1$, 2)
IF LEFT$(m2$, 1) = "-" THEN
    IF sign THEN
        sign = 0
    ELSE
        sign = -1
    END IF
    m2$ = MID$(m2$, 2)
END IF
DO
    DO UNTIL LEN(cutd$) > LEN(m1$) OR LEN(cutd$) = LEN(m1$) AND cutd$ >= m1$
        cutd% = cutd% + 1: cutd$ = cutd$ + MID$(m2$, cutd%, 1)
        IF MID$(m2$, cutd%, 1) = "" THEN
            IF LEFT$(cutd$, 1) = "0" THEN divflag% = -1: EXIT DO
            IF INSTR(q$, ".") = 0 THEN
                q$ = q$ + "."
            ELSE
                IF LEN(MID$(q$, INSTR(q$, "."))) > 3 THEN divflag% = -2: EXIT DO
                q$ = q$ + "0"
            END IF
            cutd$ = cutd$ + "0" ' No more digits to bring down.
        END IF
    LOOP
    IF divflag% THEN divflag% = 0: EXIT DO
    FOR i = 9 TO 1 STEP -1
        IF i * VAL(a$) <= VAL(cutd$) THEN EXIT FOR
    NEXT
    x1$ = LTRIM$(STR$(VAL(LTRIM$(STR$(i))) * VAL(m1$)))
    q$ = q$ + LTRIM$(STR$(i))
    cutd$ = LTRIM$(STR$(VAL(cutd$) - VAL(x1$)))
LOOP
IF q$ = "" THEN q$ = "0" ' dividend is zero.
IF LEFT$(q$, 1) = "0" THEN sign = 0
IF sign THEN q$ = "-" + q$
PRINT q$
RUN
 

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: bplus on February 25, 2019, 05:43:39 pm

De Ja Vu, Steve will tell you (unless I did) that you can bring down more than 1 digit at a time.

I remember having to create a routine for >, >= .... for numeric strings to judge if one number string was bigger in numeric value than the other. That's when I hit the yuck level.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 25, 2019, 05:51:02 pm

Yes, you can have it pull down so the remainder ends up as the number of digits of the divisor, before ever having to evaluate it.

As far as the > < evaluations, simple. If the string length is smaller, it's smaller. If it's the same size, just evaluate the LEFT$(string$, 1) of each string. The larger is the larger. If the string length is larger, it's larger. Of course signs have to be considered in this evaluation, too. It's the opposite for negative, and positives are always larger than negatives.

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: jack on February 26, 2019, 11:23:50 am

here's Visual Basic 3 source for string-bignum called bnc http://www.rain.org/~mkummel/tbvault.html, it may give you some ideas.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: SMcNeill on February 26, 2019, 02:53:37 pm

Quote from: Pete on February 25, 2019, 05:51:02 pm

Yes, you can have it pull down so the remainder ends up as the number of digits of the divisor, before ever having to evaluate it.

As far as the > < evaluations, simple. If the string length is smaller, it's smaller. If it's the same size, just evaluate the LEFT$(string$, 1) of each string. The larger is the larger. If the string length is larger, it's larger. Of course signs have to be considered in this evaluation, too. It's the opposite for negative, and positives are always larger than negatives.

Pete

You pull it down based on the size of your variable...

For instance “1234567890” + “2345678901”....

We can solve this byte by byte:

“0” + “1”... 1, no carry over
“9” + “0” + 0 carry over... 9, no carry over
“8” + “9” + 0 carry over... 7, carry over 1
“7” + “8” + 1 carry over... 6, carry over 1...

And so on...

OR...

We can pull numbers down 2 digits at a time, with the same process:
“90” + “01” = “91”, no carry over
“78” + “89” = “67”, carry over 1

Same process, just pull larger values so we’re not reading a single string character at a time, but instead are reading a value from 0 to 99 instead...

Half the work, twice the speed!

(And If we use INT64 values, we pull down 18 [I think] digits per pass, instead of 1.)

No need to solve byte by byte. Solve INT64 by INT64 instead.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 27, 2019, 01:14:39 am

Division eats up a lot of lines of code. Decimal placement seems to require four conditions. I'm not sure if I want to try to optimize this more, or just substitute in the string math.

Code: QB64: [Select]

' Division
' 1) Compare each digit of dividend to divisor. If dividend is larger, exit loop. If smaller, bring next digit down and loop.
' 2) Multiply divisor backwards from 9 until product is the same or smaller than cut dividend then save that number to a new string variable.
' 3) Subtract.
' 4) Repeat.
 
LINE INPUT "Divisor: "; a$
LINE INPUT "Dividend: "; b$
m1$ = a$
m2$ = b$
IF LEFT$(m1$, 1) = "0" AND LEN(m1$) = 1 THEN PRINT "Division by zero not allowed.": END
IF LEFT$(m1$, 1) = "-" THEN sign = -1: m1$ = MID$(m1$, 2)
IF LEFT$(m2$, 1) = "-" THEN
    IF sign THEN
        sign = 0
    ELSE
        sign = -1
    END IF
    m2$ = MID$(m2$, 2)
END IF
IF INSTR(m1$, ".") <> 0 THEN
    DO UNTIL RIGHT$(m1$, 1) <> "0"
        m1$ = MID$(m1$, 1, LEN(m1$) - 1) ' Strip off trailing zeros
    LOOP
    place% = LEN(m1$) - INSTR(m1$, ".")
    m1$ = MID$(m1$, 1, INSTR(m1$, ".") - 1) + MID$(m1$, INSTR(m1$, ".") + 1) ' Strip off decimal point.
    DO UNTIL LEFT$(m1$, 1) <> "0"
        m1$ = MID$(m1$, 2) ' Strip off leading zeros for divisors smaller than .1
    LOOP
END IF
IF INSTR(m2$, ".") <> 0 THEN
    m2$ = m2$ + STRING$(place% - LEN(m2$) - INSTR(m2$, "."), "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
    place2% = INSTR(m2$, ".")
    DO UNTIL RIGHT$(m2$, 1) <> "0"
        m2$ = MID$(m2$, 1, LEN(m2$) - 1) ' Strip off trailing zeros
    LOOP
    m2$ = MID$(m2$, 1, INSTR(m2$, ".") - 1) + MID$(m2$, INSTR(m2$, ".") + 1) ' Strip off decimal point.
ELSE
    m2$ = m2$ + STRING$(place%, "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
    place% = 0
END IF
DO
    DO
        cutd% = cutd% + 1: cutd$ = cutd$ + MID$(m2$, cutd%, 1)
        IF MID$(m2$, cutd%, 1) = "" THEN
            IF LEFT$(cutd$, 1) = "0" AND LEN(q$) > LEN(m2$) THEN divflag% = -1: EXIT DO
            carry = carry + 1
            IF carry = 1 THEN place3% = cutd% - 1 ' larger whole number divisor smaller whol number dividend.
            IF carry > 20 + LEN(m1$) THEN divflag% = -2: EXIT DO
            cutd$ = cutd$ + "0" ' No more digits to bring down.
        END IF
        IF LEN(cutd$) > LEN(m1$) OR LEN(cutd$) = LEN(m1$) AND cutd$ >= m1$ THEN EXIT DO
        q$ = q$ + "0"
    LOOP
    IF divflag% THEN divflag% = 0: EXIT DO
    FOR i = 9 TO 1 STEP -1
        IF i * VAL(m1$) <= VAL(cutd$) THEN EXIT FOR
    NEXT
    '-------------------------Multiply Function Needed Here.
    x1$ = LTRIM$(STR$(VAL(LTRIM$(STR$(i))) * VAL(m1$)))
    q$ = q$ + LTRIM$(STR$(i))
    '-------------------------Subtraction Function Needed Here.
    cutd$ = LTRIM$(STR$(VAL(cutd$) - VAL(x1$)))
LOOP
IF place% = 0 AND place2% = 0 THEN place% = place3%
IF place2% THEN place% = place% + place2% - 1
IF q$ = "" THEN q$ = "0": place% = 0 ' dividend is zero.
IF place% OR place2% THEN
    IF place% < LEN(q$) OR place2% THEN
        q$ = MID$(q$, 1, place%) + "." + MID$(q$, place% + 1)
    END IF
    DO UNTIL RIGHT$(q$, 1) <> "0"
        q$ = MID$(q$, 1, LEN(q$) - 1) ' Strip off trailing zeros
    LOOP
    IF RIGHT$(q$, 1) = "." THEN q$ = MID$(q$, 1, LEN(q$) - 1) ' Strip off abandoned decimal.
END IF
DO UNTIL LEFT$(q$, 1) <> "0"
    q$ = MID$(q$, 2) ' Strip off leading zeros
LOOP
IF q$ = "" THEN q$ = "0": sign = 0
IF sign THEN q$ = "-" + q$
PRINT q$, VAL(b$) / VAL(a$)
RUN
 

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 27, 2019, 10:43:34 am

Hey guys, did you know this...

So I'm considering what to do about rounding the trailing decimal digit in quotients that need to be truncated. What I discovered is that QB math seems to round everything up. At least it appeared that way, when I tried...

18 / 7

My string math gets: 2.571428571428571428571
Using numeric QB math I get: 2.571428571428572

So let's look at those so my number (top) has the same number of digits as the numeric calculation...

2.571428571428571..........428571
2.571428571428572

Now you can check my number with MS Windows Calculator, which also gives 2.571428571428571, my number truncated to 15 decimal places.

So what should we do here? Do I round a remainder like ...428571 up, to match QB math, or take the math traditional road of rounding anything less than 5 down to zero?

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: SMcNeill on February 27, 2019, 11:20:58 am

What’s the value after the 1?

...5714? Or ...5715 and higher?

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 27, 2019, 11:35:44 am

428571

Try the Windows calculator with 18 / 7. I'm not sure if the Windows calculator rounds or just truncates, as it won't display past that digit. I was just surprised QB math rounded 428571 up, so instead of the 15 digit ( the number just in front of the 4 of 428571, ending in 1, it rounded it up to 2!

2.571428571428571 Windows calculator and mine up to this number of digits, mine goes a few digits more.
2.571428571428572 QB numeric results from doing VAL("18") / VAL("7")

Edit: Windows Calculator definitely rounds last digit up. Try .2222 / .34 Windows Calculator rounds the last digit it can display up to a 9. On my string math calc function, it is 882352941, which should get rounded up to 9.

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on February 28, 2019, 07:17:34 pm

Well, while Steve is playing with his clock, I decided that in my math world, .5 gets rounded up. Here is what I have for division. It incorporates the multiplication and subtraction string math, so, it's a lot of lines.

It's a mess right now. I need to clean up some of the variable names... no, not those kind of names, but a$, b$, etc. just make it easier for me to make the initial framework.

I also need to put together a way I want to call these functions. Anyway, this should divide large positive or negative whole and/or decimal numbers.

Repeated numbers, like 7 / 18 = .3888888 I decided not to round, but get this, QB64 rounds that to ...89 but if we try 2 / 3, QB64 lets it stay as ...66 repeating. Apparently, QB64 only considers it repeating if all digits after the decimal are the same. I'll have to look into that while Steve is playing with his clock. Well, at least I got my "l" key working again. :D

Pete

Code: QB64: [Select]

LINE INPUT "Divisor: "; a$
LINE INPUT "Dividend: "; b$
d1$ = a$
d2$ = b$
IF LEFT$(d1$, 1) = "0" AND LEN(d1$) = 1 THEN PRINT "Division by zero not allowed.": END
IF LEFT$(d1$, 1) = "-" THEN divsign% = -1: d1$ = MID$(d1$, 2)
IF LEFT$(d2$, 1) = "-" THEN
    IF divsign% THEN
        divsign% = 0
    ELSE
        divsign% = -1
    END IF
    d2$ = MID$(d2$, 2)
END IF
IF INSTR(d1$, ".") <> 0 THEN
    DO UNTIL RIGHT$(d1$, 1) <> "0"
        d1$ = MID$(d1$, 1, LEN(d1$) - 1) ' Strip off trailing zeros
    LOOP
    divplace% = LEN(d1$) - INSTR(d1$, ".")
    d1$ = MID$(d1$, 1, INSTR(d1$, ".") - 1) + MID$(d1$, INSTR(d1$, ".") + 1) ' Strip off decimal point.
    DO UNTIL LEFT$(d1$, 1) <> "0"
        d1$ = MID$(d1$, 2) ' Strip off leading zeros for divisors smaller than .1
    LOOP
END IF
 
IF INSTR(d2$, ".") <> 0 THEN
    d2$ = d2$ + STRING$(divplace% - LEN(d2$) - INSTR(d2$, "."), "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
    divplace2% = INSTR(d2$, ".")
    DO UNTIL RIGHT$(d2$, 1) <> "0"
        d2$ = MID$(d2$, 1, LEN(d2$) - 1) ' Strip off trailing zeros
    LOOP
    d2$ = MID$(d2$, 1, INSTR(d2$, ".") - 1) + MID$(d2$, INSTR(d2$, ".") + 1) ' Strip off decimal point.
ELSE
    d2$ = d2$ + STRING$(divplace%, "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
    divplace% = 0
END IF
DO
    DO
        cutd% = cutd% + 1: cutd$ = cutd$ + MID$(d2$, cutd%, 1)
        IF MID$(d2$, cutd%, 1) = "" THEN
            IF cutd$ = STRING$(LEN(cutd$), "0") AND LEN(q$) > LEN(d2$) THEN divflag% = -1: EXIT DO
            divcarry = divcarry + 1
            IF divcarry = 1 THEN divplace3% = cutd% - 1 ' larger whole number divisor smaller whol number dividend.
            IF divcarry > 20 + LEN(d1$) THEN divflag% = -2: EXIT DO
            cutd$ = cutd$ + "0" ' No more digits to bring down.
        END IF
        IF LEN(cutd$) > LEN(d1$) OR LEN(cutd$) = LEN(d1$) AND cutd$ >= d1$ THEN EXIT DO
        q$ = q$ + "0"
    LOOP
    IF divflag% THEN divflag% = 0: EXIT DO
    FOR idiv% = 9 TO 1 STEP -1
        m1$ = LTRIM$(STR$(idiv%)): m2$ = d1$
        product$ = "": GOSUB stringmultiply
        tempcutd$ = cutd$ ' cutd$ can be 00 or other leading zero values.
        DO
            IF LEN(tempcutd$) = 1 THEN EXIT DO
            IF LEFT$(tempcutd$, 1) = "0" THEN
                tempcutd$ = MID$(tempcutd$, 2)
            ELSE
                EXIT DO
            END IF
        LOOP
        IF LEN(tempcutd$) > LEN(product$) OR LEN(tempcutd$) = LEN(product$) AND product$ <= tempcutd$ THEN EXIT FOR
    NEXT
    q$ = q$ + LTRIM$(STR$(idiv%))
    m1$ = LTRIM$(STR$(idiv%)): m2$ = d1$
    product$ = "": GOSUB stringmultiply
    operator$ = "-": a$ = cutd$: b$ = product$: GOSUB stringcalc: cutd$ = a$
LOOP
'''PRINT "Raw q$ = "; q$
IF divplace% = 0 AND divplace2% = 0 THEN divplace% = divplace3%
IF divplace2% THEN divplace% = divplace% + divplace2% - 1
IF q$ = "" THEN divplace% = 0 ' dividend is zero.
IF divplace% OR divplace2% THEN
    tempq$ = MID$(q$, INSTR(q$, ".") + 1)
    IF LEN(tempq$) >= 3 THEN
        IF RIGHT$(tempq$, 3) <> STRING$(3, RIGHT$(tempq$, 1)) THEN
            IF RIGHT$(q$, 1) < "5" THEN
                q$ = MID$(q$, 1, LEN(q$) - 1)
            ELSE
                a$ = MID$(q$, 1, LEN(q$))
                b$ = STRING$(LEN(a$) - 1, "0") + LTRIM$(STR$(10 - VAL(RIGHT$(q$, 1))))
                operator$ = "+": GOSUB stringcalc
                q$ = a$
            END IF
        END IF
    END IF
    IF divplace% < LEN(q$) OR divplace2% THEN
        q$ = MID$(q$, 1, divplace%) + "." + MID$(q$, divplace% + 1)
    END IF
    DO UNTIL RIGHT$(q$, 1) <> "0"
        q$ = MID$(q$, 1, LEN(q$) - 1) ' Strip off trailing zeros
    LOOP
    IF RIGHT$(q$, 1) = "." THEN q$ = MID$(q$, 1, LEN(q$) - 1) ' Strip off abandoned decimal.
END IF
DO UNTIL LEFT$(q$, 1) <> "0"
    q$ = MID$(q$, 2) ' Strip off leading zeros
LOOP
IF q$ = "" THEN q$ = "0": divsign% = 0
IF divsign% THEN q$ = "-" + q$
PRINT "Pete's String Division: "; q$
PRINT "QB64 Numeric Division:  "; LTRIM$(STR$(VAL(d2$) / VAL(d1$)))
RUN
 
stringmultiply:
multsumcnt% = 0: multcarry% = 0: multplace% = 0: x1$ = ""
IF LEN(b$) > LEN(a$) THEN SWAP m1$, m2$
IF LEFT$(m1$, 1) = "-" THEN m1$ = MID$(m1$, 2): multsign% = -1
IF LEFT$(m2$, 1) = "-" THEN m2$ = MID$(m2$, 2): IF multsign% THEN multsign% = 0 ELSE multsign% = -1
IF INSTR(m1$, ".") <> 0 THEN multplace% = LEN(m1$) - INSTR(m1$, "."): m1$ = MID$(m1$, 1, INSTR(m1$, ".") - 1) + MID$(m1$, INSTR(m1$, ".") + 1)
IF INSTR(m2$, ".") <> 0 THEN multplace% = multplace% + LEN(m2$) - INSTR(m2$, "."): m2$ = MID$(m2$, 1, INSTR(m2$, ".") - 1) + MID$(m2$, INSTR(m2$, ".") + 1)
 
FOR multii% = LEN(m2$) TO 1 STEP -1
    n2$ = MID$(m2$, multii%, 1)
    x1$ = ""
    FOR multjj% = LEN(m1$) TO 1 STEP -1
        n1$ = MID$(m1$, multjj%, 1)
        multkk = VAL(n1$) * VAL(n2$) + multcarry%
        IF multkk > 9 THEN
            multcarry% = VAL(LEFT$(LTRIM$(STR$(multkk)), 1))
            multkk = VAL(RIGHT$(LTRIM$(STR$(multkk)), 1))
        ELSE
            multcarry% = 0
        END IF
        x1$ = LTRIM$(STR$(multkk)) + x1$
    NEXT
    IF multcarry% THEN x1$ = LTRIM$(STR$(multcarry%)) + x1$: multcarry% = 0
    GOSUB multsums
NEXT
IF multplace% AND product$ <> "0" THEN
    product$ = MID$(product$, 1, LEN(product$) - multplace%) + "." + MID$(product$, LEN(product$) - multplace% + 1)
END IF
DO UNTIL LEFT$(product$, 1) <> "0" ' Remove leading zeros.
    product$ = MID$(product$, 2)
LOOP
IF product$ = "" THEN product$ = "0": multsign% = 0
IF multsign% THEN product$ = "-" + product$
' Product$ is the multiplication product variable to return.
RETURN
 
multsums:
IF product$ <> "" THEN
    multsumcnt% = multsumcnt% + 1
    x1$ = x1$ + STRING$(multsumcnt%, "0")
    multhh% = 0
    DO
        IF multhh% < LEN(product$) THEN ms1$ = MID$(product$, LEN(product$) - multhh%, 1) ELSE ms1$ = ""
        IF multhh% < LEN(x1$) THEN ms2$ = MID$(x1$, LEN(x1$) - multhh%, 1) ELSE ms2$ = ""
        IF ms1$ = "" AND ms2$ = "" THEN EXIT DO
        x1 = VAL(ms1$) + VAL(ms2$) + multcarry%
        IF x1 > 9 THEN x1 = x1 - 10: multcarry% = 1 ELSE multcarry% = 0
        xproduct$ = LTRIM$(STR$(x1)) + xproduct$
        multhh% = multhh% + 1
    LOOP
    IF multcarry% THEN product$ = "1" + xproduct$: multcarry% = 0 ELSE product$ = xproduct$
    IF multplace% THEN
        DO UNTIL RIGHT$(product$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
            product$ = MID$(product$, 1, LEN(product$) - 1)
            multplace% = multplace% - 1
        LOOP
    END IF
    xproduct$ = ""
ELSE
    product$ = x1$: x1$ = ""
END IF
RETURN
 
stringcalc:
IF a$ <> "" AND operator$ <> "" AND b$ <> "" THEN
    IF INSTR(a$, ".") <> 0 THEN ' Evaluate sum for decimal fraction.
        sumplace% = LEN(a$) - INSTR(a$, ".")
        a$ = MID$(a$, 1, INSTR(a$, ".") - 1) + MID$(a$, INSTR(a$, ".") + 1) ' Strip out decimal
    END IF
    IF INSTR(b$, ".") <> 0 THEN ' Evaluate number for decimal fraction.
        numplace% = LEN(b$) - INSTR(b$, ".")
        b$ = MID$(b$, 1, INSTR(b$, ".") - 1) + MID$(b$, INSTR(b$, ".") + 1) ' Strip out decimal
    END IF
    IF sumplace% > numplace% THEN place% = sumplace% ELSE place% = numplace%
    IF sumplace% > place% THEN
        a$ = a$ + STRING$(sumplace% - place%, "0")
    ELSEIF place% > sumplace% THEN
        a$ = a$ + STRING$(place% - sumplace%, "0")
    END IF
    IF numplace% > place% THEN
        b$ = b$ + STRING$(numplace% - place%, "0")
    ELSEIF place% > numplace% THEN
        b$ = b$ + STRING$(place% - numplace%, "0")
    END IF ' END Decimal evaluations........................
 
    IF LEFT$(a$, 1) = "-" THEN sign1$ = "-" ELSE sign1$ = "+"
    IF LEFT$(b$, 1) = "-" THEN sign2$ = "-" ELSE sign2$ = "+"
 
    sign = 0
    SELECT CASE sign1$ + operator$ + sign2$
        CASE "+++", "+--"
            operator$ = "+"
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
        CASE "++-", "+-+"
            operator$ = "-"
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
            IF VAL(b$) > VAL(a$) THEN SWAP a$, b$: sign = -1
        CASE "---", "-++"
            operator$ = "-"
            IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
            IF VAL(b$) > VAL(a$) THEN SWAP a$, b$ ELSE sign = -1
        CASE "--+", "-+-"
            operator$ = "+"
            IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
            IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
            sign = -1
    END SELECT
 
    IF LEN(a$) > LEN(b$) THEN
        b$ = STRING$(LEN(a$) - LEN(b$), "0") + b$
    ELSEIF LEN(a$) < LEN(b$) THEN
        a$ = STRING$(LEN(b$) - LEN(a$), "0") + a$
    END IF
    x1$ = ""
 
    SELECT CASE operator$
        CASE "+", "="
            FOR i = LEN(a$) TO 1 STEP -1
                x1 = VAL(MID$(a$, i, 1)) + VAL(MID$(b$, i, 1)) + carry
                IF x1 > 9 THEN x1 = x1 - 10: carry = 1 ELSE carry = 0
                x1$ = LTRIM$(STR$(x1)) + x1$
            NEXT
            IF carry THEN x1$ = "1" + x1$: carry = 0
            GOSUB replacedecimal
        CASE "-"
            FOR i = LEN(a$) TO 1 STEP -1
                x1 = VAL(MID$(a$, i, 1)) - VAL(MID$(b$, i, 1)) + carry
                IF x1 < 0 THEN x1 = x1 + 10: carry = -1 ELSE carry = 0
                x1$ = LTRIM$(STR$(x1)) + x1$
            NEXT
            IF x1$ <> "" AND x1$ <> STRING$(LEN(x1$), "0") THEN GOSUB replacedecimal
            DO UNTIL LEFT$(x1$, 1) <> "0" ' Remove leading zeros.
                x1$ = MID$(x1$, 2)
            LOOP
            IF x1$ = "" THEN
                x1$ = "0": sign = 0
            ELSE
                IF carry THEN x1$ = "-" + x1$: carry = 0
            END IF
    END SELECT
 
    IF sign THEN
        IF LEFT$(x1$, 1) = "-" THEN x1$ = MID$(x1$, 2) ELSE x1$ = "-" + x1$
    END IF
    a$ = x1$
ELSE
    a$ = b$
END IF
RETURN
 
replacedecimal:
IF place% THEN
    x1$ = STRING$(place% - LEN(x1$), "0") + x1$
    DO UNTIL RIGHT$(x1$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
        x1$ = MID$(x1$, 1, LEN(x1$) - 1)
        place% = place% - 1
    LOOP
    IF place% > 0 THEN ' Do not replace decimal if total has become an integer amount.
        x1$ = MID$(x1$, 1, LEN(x1$) - place%) + "." + MID$(x1$, LEN(x1$) - place% + 1)
    END IF
END IF
RETURN
 

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: jack on March 01, 2019, 08:44:17 am

hello Pete
just tried printing the fractions you mentioned in your favorite language, FreeBasic, and the results are rounded as you mentioned
then I looked at the hexadecimal representation of the numbers and it makes sense that the numbers are rounded the way they are
for example, try printing 2/3 in single precision, you will get 0.6666667
the hex representation for 2/3 is 3F2AAAAB single precision and 3FE5555555555555 double precision
you can try it yourself with the online IEEE-754 Calculator at https://babbage.cs.qc.cuny.edu/IEEE-754/
you can enter fractions in the input box and it will be evaluated, for example 18/7 or 2/3
btw, the online calculator uses javascript to do the calculations, you can save the web page to your hard drive and use it offline.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on March 01, 2019, 11:38:13 am

My favorite language, F'Basic. :D

I need to check a few sources, like the ones you posted, and I also need to decide if I want just digits, or notation like take D-8, etc.

Well here is what I have so far, It can be used as a calculator for +-*/ of positive and negative whole numbers and decimals. It has not been well tested and I would still like to clean up some variable names.

Code: QB64: [Select]

DO
    LINE INPUT "Number: "; b$
    CALL stringmath(a$, operator$, b$, runningtotal$)
    IF runningtotal$ <> "" THEN
        PRINT "Pete's String Total: "; runningtotal$
        '''PRINT "QB64 Numeric Total:  "; LTRIM$(STR$(VAL(d2dividend$) / VAL(d1divisor$)))
    END IF
    PRINT "Operator: +-/*: ";
    DO
        operator$ = INKEY$
        IF LEN(operator$) THEN
            IF operator$ = CHR$(27) THEN SYSTEM
            IF INSTR("-+/*=8", operator$) THEN EXIT DO
        END IF
    LOOP
    IF operator$ = "=" THEN operator$ = "+"
    IF operator$ = "8" THEN operator$ = "*"
    PRINT operator$
LOOP
 
SUB stringmath (a$, operator$, b$, runningtotal$)
IF a$ = "" THEN a$ = b$: EXIT SUB
IF runningtotal$ <> "" THEN a$ = runningtotal$
SELECT CASE operator$
    CASE "/"
        operationdivision% = -1
        d2dividend$ = a$
        d1divisor$ = b$
        IF LEFT$(d1divisor$, 1) = "0" AND LEN(d1divisor$) = 1 THEN PRINT "Division by zero not allowed.": END
        IF LEFT$(d1divisor$, 1) = "-" THEN divsign% = -1: d1divisor$ = MID$(d1divisor$, 2)
        IF LEFT$(d2dividend$, 1) = "-" THEN
            IF divsign% THEN
                divsign% = 0
            ELSE
                divsign% = -1
            END IF
            d2dividend$ = MID$(d2dividend$, 2)
        END IF
        IF INSTR(d1divisor$, ".") <> 0 THEN
            DO UNTIL RIGHT$(d1divisor$, 1) <> "0"
                d1divisor$ = MID$(d1divisor$, 1, LEN(d1divisor$) - 1) ' Strip off trailing zeros
            LOOP
            divplace% = LEN(d1divisor$) - INSTR(d1divisor$, ".")
            d1divisor$ = MID$(d1divisor$, 1, INSTR(d1divisor$, ".") - 1) + MID$(d1divisor$, INSTR(d1divisor$, ".") + 1) ' Strip off decimal point.
            DO UNTIL LEFT$(d1divisor$, 1) <> "0"
                d1divisor$ = MID$(d1divisor$, 2) ' Strip off leading zeros for divisors smaller than .1
            LOOP
        END IF
 
        IF INSTR(d2dividend$, ".") <> 0 THEN
            d2dividend$ = d2dividend$ + STRING$(divplace% - LEN(d2dividend$) - INSTR(d2dividend$, "."), "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
            divplace2% = INSTR(d2dividend$, ".")
            DO UNTIL RIGHT$(d2dividend$, 1) <> "0"
                d2dividend$ = MID$(d2dividend$, 1, LEN(d2dividend$) - 1) ' Strip off trailing zeros
            LOOP
            d2dividend$ = MID$(d2dividend$, 1, INSTR(d2dividend$, ".") - 1) + MID$(d2dividend$, INSTR(d2dividend$, ".") + 1) ' Strip off decimal point.
        ELSE
            d2dividend$ = d2dividend$ + STRING$(divplace%, "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
            divplace% = 0
        END IF
        DO
            DO
                divremainder% = divremainder% + 1: divremainder$ = divremainder$ + MID$(d2dividend$, divremainder%, 1)
                IF MID$(d2dividend$, divremainder%, 1) = "" THEN
                    IF divremainder$ = STRING$(LEN(divremainder$), "0") AND LEN(q$) > LEN(d2dividend$) THEN divflag% = -1: EXIT DO
                    divcarry = divcarry + 1
                    IF divcarry = 1 THEN divplace3% = divremainder% - 1 ' larger whole number divisor smaller whol number dividend.
                    IF divcarry > 20 + LEN(d1divisor$) THEN divflag% = -2: EXIT DO
                    divremainder$ = divremainder$ + "0" ' No more digits to bring down.
                END IF
                IF LEN(divremainder$) > LEN(d1divisor$) OR LEN(divremainder$) = LEN(d1divisor$) AND divremainder$ >= d1divisor$ THEN EXIT DO
                q$ = q$ + "0"
            LOOP
            IF divflag% THEN divflag% = 0: EXIT DO
            FOR idiv% = 9 TO 1 STEP -1
                a$ = LTRIM$(STR$(idiv%)): b$ = d1divisor$
                product$ = "": GOSUB stringmultiply
                tempcutd$ = divremainder$ ' divremainder$ can be 00 or other leading zero values.
                DO
                    IF LEN(tempcutd$) = 1 THEN EXIT DO
                    IF LEFT$(tempcutd$, 1) = "0" THEN
                        tempcutd$ = MID$(tempcutd$, 2)
                    ELSE
                        EXIT DO
                    END IF
                LOOP
                IF LEN(tempcutd$) > LEN(product$) OR LEN(tempcutd$) = LEN(product$) AND product$ <= tempcutd$ THEN EXIT FOR
            NEXT
            q$ = q$ + LTRIM$(STR$(idiv%))
            a$ = LTRIM$(STR$(idiv%)): b$ = d1divisor$
            product$ = "": GOSUB stringmultiply
            operator$ = "-": a$ = divremainder$: b$ = product$: GOSUB stringcalc: divremainder$ = a$: operator$ = "/"
        LOOP
        ' Prepare results.
        IF divplace% = 0 AND divplace2% = 0 THEN divplace% = divplace3%
        IF divplace2% THEN divplace% = divplace% + divplace2% - 1
        IF q$ = "" THEN divplace% = 0 ' dividend is zero.
        IF divplace% OR divplace2% THEN
            tempq$ = MID$(q$, INSTR(q$, ".") + 1)
            IF LEN(tempq$) >= 3 THEN
                IF RIGHT$(tempq$, 3) <> STRING$(3, RIGHT$(tempq$, 1)) THEN
                    IF RIGHT$(q$, 1) < "5" THEN
                        q$ = MID$(q$, 1, LEN(q$) - 1)
                    ELSE
                        a$ = MID$(q$, 1, LEN(q$))
                        b$ = STRING$(LEN(a$) - 1, "0") + LTRIM$(STR$(10 - VAL(RIGHT$(q$, 1))))
                        operator$ = "+": GOSUB stringcalc:: operator$ = "/"
                        q$ = a$
                    END IF
                END IF
            END IF
            IF divplace% < LEN(q$) OR divplace2% THEN
                q$ = MID$(q$, 1, divplace%) + "." + MID$(q$, divplace% + 1)
            END IF
            DO UNTIL RIGHT$(q$, 1) <> "0"
                q$ = MID$(q$, 1, LEN(q$) - 1) ' Strip off trailing zeros
            LOOP
            IF RIGHT$(q$, 1) = "." THEN q$ = MID$(q$, 1, LEN(q$) - 1) ' Strip off abandoned decimal.
        END IF
        DO UNTIL LEFT$(q$, 1) <> "0"
            q$ = MID$(q$, 2) ' Strip off leading zeros
        LOOP
        IF q$ = "" THEN q$ = "0": divsign% = 0
        IF divsign% THEN q$ = "-" + q$
        runningtotal$ = q$
        operationdivision% = 0
        EXIT SUB
 
    CASE "*"
        stringmultiply:
        multsumcnt% = 0: multcarry% = 0: multplace% = 0: x1$ = ""
        factor1$ = a$: factor2$ = b$
        IF LEN(b$) > LEN(a$) THEN SWAP factor1$, factor2$
        IF LEFT$(factor1$, 1) = "-" THEN factor1$ = MID$(factor1$, 2): multsign% = -1
        IF LEFT$(factor2$, 1) = "-" THEN factor2$ = MID$(factor2$, 2): IF multsign% THEN multsign% = 0 ELSE multsign% = -1
        IF INSTR(factor1$, ".") <> 0 THEN multplace% = LEN(factor1$) - INSTR(factor1$, "."): factor1$ = MID$(factor1$, 1, INSTR(factor1$, ".") - 1) + MID$(factor1$, INSTR(factor1$, ".") + 1)
        IF INSTR(factor2$, ".") <> 0 THEN multplace% = multplace% + LEN(factor2$) - INSTR(factor2$, "."): factor2$ = MID$(factor2$, 1, INSTR(factor2$, ".") - 1) + MID$(factor2$, INSTR(factor2$, ".") + 1)
 
        FOR multii% = LEN(factor2$) TO 1 STEP -1
            n2$ = MID$(factor2$, multii%, 1)
            x1$ = ""
            FOR multjj% = LEN(factor1$) TO 1 STEP -1
                n1$ = MID$(factor1$, multjj%, 1)
                multkk% = VAL(n1$) * VAL(n2$) + multcarry%
                IF multkk% > 9 THEN
                    multcarry% = VAL(LEFT$(LTRIM$(STR$(multkk%)), 1))
                    multkk% = VAL(RIGHT$(LTRIM$(STR$(multkk%)), 1))
                ELSE
                    multcarry% = 0
                END IF
                x1$ = LTRIM$(STR$(multkk%)) + x1$
            NEXT
            IF multcarry% THEN x1$ = LTRIM$(STR$(multcarry%)) + x1$: multcarry% = 0
            GOSUB multsums
        NEXT
        IF multplace% AND product$ <> "0" THEN
            product$ = MID$(product$, 1, LEN(product$) - multplace%) + "." + MID$(product$, LEN(product$) - multplace% + 1)
        END IF
        DO UNTIL LEFT$(product$, 1) <> "0" ' Remove leading zeros.
            product$ = MID$(product$, 2)
        LOOP
        IF product$ = "" THEN product$ = "0": multsign% = 0
        IF multsign% THEN product$ = "-" + product$
        IF RIGHT$(product$, 1) = "." THEN product$ = MID$(product$, 1, LEN(product$) - 1) ' Remove decimal from end of an integer total.
        ' Product$ is the multiplication product variable to return.
        IF operator$ = "/" THEN RETURN
        runningtotal$ = product$
        EXIT SUB
 
        multsums:
        IF product$ <> "" THEN
            multsumcnt% = multsumcnt% + 1
            x1$ = x1$ + STRING$(multsumcnt%, "0")
            multhh% = 0
            DO
                IF multhh% < LEN(product$) THEN ms1$ = MID$(product$, LEN(product$) - multhh%, 1) ELSE ms1$ = ""
                IF multhh% < LEN(x1$) THEN ms2$ = MID$(x1$, LEN(x1$) - multhh%, 1) ELSE ms2$ = ""
                IF ms1$ = "" AND ms2$ = "" THEN EXIT DO
                x1 = VAL(ms1$) + VAL(ms2$) + multcarry%
                IF x1 > 9 THEN x1 = x1 - 10: multcarry% = 1 ELSE multcarry% = 0
                xproduct$ = LTRIM$(STR$(x1)) + xproduct$
                multhh% = multhh% + 1
            LOOP
            IF multcarry% THEN product$ = "1" + xproduct$: multcarry% = 0 ELSE product$ = xproduct$
            IF multplace% THEN
                DO UNTIL RIGHT$(product$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
                    product$ = MID$(product$, 1, LEN(product$) - 1)
                    multplace% = multplace% - 1
                LOOP
            END IF
            xproduct$ = ""
        ELSE
            product$ = x1$: x1$ = ""
        END IF
        RETURN
 
    CASE "+", "-"
        stringcalc:
        IF INSTR(a$, ".") <> 0 THEN ' Evaluate sum for decimal fraction.
            sumplace% = LEN(a$) - INSTR(a$, ".")
            a$ = MID$(a$, 1, INSTR(a$, ".") - 1) + MID$(a$, INSTR(a$, ".") + 1) ' Strip out decimal
        END IF
        IF INSTR(b$, ".") <> 0 THEN ' Evaluate number for decimal fraction.
            numplace% = LEN(b$) - INSTR(b$, ".")
            b$ = MID$(b$, 1, INSTR(b$, ".") - 1) + MID$(b$, INSTR(b$, ".") + 1) ' Strip out decimal
        END IF
        IF sumplace% > numplace% THEN addsubplace% = sumplace% ELSE addsubplace% = numplace%
        IF sumplace% > addsubplace% THEN
            a$ = a$ + STRING$(sumplace% - addsubplace%, "0")
        ELSEIF addsubplace% > sumplace% THEN
            a$ = a$ + STRING$(addsubplace% - sumplace%, "0")
        END IF
        IF numplace% > addsubplace% THEN
            b$ = b$ + STRING$(numplace% - addsubplace%, "0")
        ELSEIF addsubplace% > numplace% THEN
            b$ = b$ + STRING$(addsubplace% - numplace%, "0")
        END IF ' END Decimal evaluations........................
 
        IF LEFT$(a$, 1) = "-" THEN sign1$ = "-" ELSE sign1$ = "+"
        IF LEFT$(b$, 1) = "-" THEN sign2$ = "-" ELSE sign2$ = "+"
 
        addsubsign% = 0
        SELECT CASE sign1$ + operator$ + sign2$
            CASE "+++", "+--"
                operator$ = "+"
                IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
            CASE "++-", "+-+"
                operator$ = "-"
                IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
                IF VAL(b$) > VAL(a$) THEN SWAP a$, b$: addsubsign% = -1
            CASE "---", "-++"
                operator$ = "-"
                IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
                IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
                IF VAL(b$) > VAL(a$) THEN SWAP a$, b$ ELSE addsubsign% = -1
            CASE "--+", "-+-"
                operator$ = "+"
                IF LEFT$(a$, 1) = "-" THEN a$ = MID$(a$, 2)
                IF LEFT$(b$, 1) = "-" THEN b$ = MID$(b$, 2)
                addsubsign% = -1
        END SELECT
 
        IF LEN(a$) > LEN(b$) THEN
            b$ = STRING$(LEN(a$) - LEN(b$), "0") + b$
        ELSEIF LEN(a$) < LEN(b$) THEN
            a$ = STRING$(LEN(b$) - LEN(a$), "0") + a$
        END IF
        x1$ = ""
 
        SELECT CASE operator$
            CASE "+", "="
                FOR addsubii% = LEN(a$) TO 1 STEP -1
                    x1 = VAL(MID$(a$, addsubii%, 1)) + VAL(MID$(b$, addsubii%, 1)) + addsubcarry%
                    IF x1 > 9 THEN x1 = x1 - 10: addsubcarry% = 1 ELSE addsubcarry% = 0
                    x1$ = LTRIM$(STR$(x1)) + x1$
                NEXT
                IF addsubcarry% THEN x1$ = "1" + x1$: addsubcarry% = 0
                GOSUB replacedecimal
            CASE "-"
                FOR addsubii% = LEN(a$) TO 1 STEP -1
                    x1 = VAL(MID$(a$, addsubii%, 1)) - VAL(MID$(b$, addsubii%, 1)) + addsubcarry%
                    IF x1 < 0 THEN x1 = x1 + 10: addsubcarry% = -1 ELSE addsubcarry% = 0
                    x1$ = LTRIM$(STR$(x1)) + x1$
                NEXT
                IF x1$ <> "" AND x1$ <> STRING$(LEN(x1$), "0") THEN GOSUB replacedecimal
                DO UNTIL LEFT$(x1$, 1) <> "0" ' Remove leading zeros.
                    x1$ = MID$(x1$, 2)
                LOOP
                IF x1$ = "" THEN
                    x1$ = "0": addsubsign% = 0
                ELSE
                    IF addsubcarry% THEN x1$ = "-" + x1$: addsubcarry% = 0
                END IF
        END SELECT
 
        IF addsubsign% THEN
            IF LEFT$(x1$, 1) = "-" THEN x1$ = MID$(x1$, 2) ELSE x1$ = "-" + x1$
        END IF
        a$ = x1$
        IF operationdivision% THEN RETURN
        runningtotal$ = a$
        EXIT SUB
 
        replacedecimal:
        IF addsubplace% THEN
            x1$ = STRING$(addsubplace% - LEN(x1$), "0") + x1$
            DO UNTIL RIGHT$(x1$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
                x1$ = MID$(x1$, 1, LEN(x1$) - 1)
                addsubplace% = addsubplace% - 1
            LOOP
            IF addsubplace% > 0 THEN ' Do not replace decimal if total has become an integer amount.
                x1$ = MID$(x1$, 1, LEN(x1$) - addsubplace%) + "." + MID$(x1$, LEN(x1$) - addsubplace% + 1)
            END IF
        END IF
        RETURN
END SELECT
END SUB

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: jack on March 01, 2019, 01:50:45 pm

found some links that may be of interest, bigfloat in javascript, MIT license https://github.com/charto/bigfloat and predicates in C, license in the public domain https://github.com/danshapero/predicates

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on March 02, 2019, 05:11:17 am

Those are some HUGE number places. I haven't decided how to account for some displays. I mean an advantage to string math is it can go on forever, but at some point you need a better way to display the results than just a million characters OFF the screen. For now, I have it carry out 20 places past the decimal, but that can be user regulated with a variable in the future. It doesn't use D or E notation to report leading, trailing zeros yet. I may or may not add that option. In this edition, I put in an input validator.

One bug found in trailing zeros part of division. Hope to have it fixed soon and reposted.

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on March 02, 2019, 07:46:48 pm

Fixed on bug. I still have some rounding work to do. I'm a bit ticked that some repeating decimals like .66666 form 2 / 3 don't get rounded, while others like .5555555555555555 get rounded to .5555555555555556. Really? Anyway, I'm not quite sure what I want to do about accuracy, meaning number of digits to display. Right now, it is unlimited for integer values, and user limited by the variable divaccuracy%, which is currently set to 30 places.

Anyway, still not well tested so try it and report any bugs, but of course there is no warranty of use; so use it at your own foolish risk for anything other than just beta testing.

Oh, speaking of testing, I do have it show the numeric math for comparison, but I quickly learned because the string math is more accurate, several computations would lead to a wider discrepancy of results. To eliminate that, for each computation the numeric value is set to the string value after both are displayed.

Pete

Code: QB64: [Select]

divaccuracy% = 40
DO
    DO
        LINE INPUT "Number: "; stringmathb$
        origb$ = stringmathb$
        CALL stringmath(stringmatha$, operator$, stringmathb$, runningtotal$, divaccuracy%)
        IF stringmathb$ <> "invalid number" THEN EXIT DO
    LOOP
    IF runningtotal$ <> "" THEN
        SELECT CASE origoperator$
            CASE "+"
                runningtotal# = VAL(origa$) + VAL(origb$)
            CASE "-"
                runningtotal# = VAL(origa$) - VAL(origb$)
            CASE "*"
                runningtotal# = VAL(origa$) * VAL(origb$)
            CASE "/"
                runningtotal# = VAL(origa$) / VAL(origb$)
        END SELECT
        origa$ = LTRIM$(STR$(runningtotal#))
        COLOR 8, 0: PRINT "Numeric Total: "; origa$: COLOR 7, 0
        PRINT "String Total:  "; runningtotal$
        origa$ = runningtotal$ ' Allign variable total for next computation.
    ELSE
        origa$ = stringmatha$
    END IF
    COLOR 2, 0: PRINT "Operator: +-/*: ";: COLOR 7, 0
    DO
        operator$ = INKEY$
        IF LEN(operator$) THEN
            IF operator$ = CHR$(27) THEN SYSTEM
            IF INSTR("-+/*=8", operator$) THEN EXIT DO
        END IF
    LOOP
    IF operator$ = "=" THEN operator$ = "+"
    IF operator$ = "8" THEN operator$ = "*"
    PRINT operator$
    origoperator$ = operator$
LOOP
 
SUB stringmath (stringmatha$, operator$, stringmathb$, runningtotal$, divaccuracy%)
IF stringmatha$ = "" THEN
    stringmatha$ = stringmathb$
    GOSUB validatestringnumber
    IF stringmathb$ = "invalid number" THEN stringmatha$ = ""
    EXIT SUB
ELSE
    GOSUB validatestringnumber
    IF stringmathb$ = "invalid number" THEN EXIT SUB
END IF
IF runningtotal$ <> "" THEN stringmatha$ = runningtotal$
 
SELECT CASE operator$
    CASE "+", "-"
        stringcalc:
        IF INSTR(stringmatha$, ".") <> 0 THEN ' Evaluate sum for decimal fraction.
            sumplace% = LEN(stringmatha$) - INSTR(stringmatha$, ".")
            stringmatha$ = MID$(stringmatha$, 1, INSTR(stringmatha$, ".") - 1) + MID$(stringmatha$, INSTR(stringmatha$, ".") + 1) ' Strip out decimal
        END IF
        IF INSTR(stringmathb$, ".") <> 0 THEN ' Evaluate number for decimal fraction.
            numplace% = LEN(stringmathb$) - INSTR(stringmathb$, ".")
            stringmathb$ = MID$(stringmathb$, 1, INSTR(stringmathb$, ".") - 1) + MID$(stringmathb$, INSTR(stringmathb$, ".") + 1) ' Strip out decimal
        END IF
        IF sumplace% > numplace% THEN addsubplace% = sumplace% ELSE addsubplace% = numplace%
        IF sumplace% > addsubplace% THEN
            stringmatha$ = stringmatha$ + STRING$(sumplace% - addsubplace%, "0")
        ELSEIF addsubplace% > sumplace% THEN
            stringmatha$ = stringmatha$ + STRING$(addsubplace% - sumplace%, "0")
        END IF
        IF numplace% > addsubplace% THEN
            stringmathb$ = stringmathb$ + STRING$(numplace% - addsubplace%, "0")
        ELSEIF addsubplace% > numplace% THEN
            stringmathb$ = stringmathb$ + STRING$(addsubplace% - numplace%, "0")
        END IF ' END Decimal evaluations........................
 
        IF LEFT$(stringmatha$, 1) = "-" THEN sign1$ = "-" ELSE sign1$ = "+"
        IF LEFT$(stringmathb$, 1) = "-" THEN sign2$ = "-" ELSE sign2$ = "+"
 
        addsubsign% = 0
        SELECT CASE sign1$ + operator$ + sign2$
            CASE "+++", "+--"
                operator$ = "+"
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
            CASE "++-", "+-+"
                operator$ = "-"
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
                IF VAL(stringmathb$) > VAL(stringmatha$) THEN
                    SWAP stringmatha$, stringmathb$
                    addsubsign% = -1
                    SWAP origa$, origb$
                END IF
            CASE "---", "-++"
                operator$ = "-"
                IF LEFT$(stringmatha$, 1) = "-" THEN stringmatha$ = MID$(stringmatha$, 2)
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
                IF VAL(stringmathb$) > VAL(stringmatha$) THEN
                    SWAP stringmatha$, stringmathb$
                    SWAP origa$, origb$
                ELSE
                    addsubsign% = -1
                END IF
            CASE "--+", "-+-"
                operator$ = "+"
                IF LEFT$(stringmatha$, 1) = "-" THEN stringmatha$ = MID$(stringmatha$, 2)
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
                addsubsign% = -1
        END SELECT
 
        IF LEN(stringmatha$) > LEN(stringmathb$) THEN
            stringmathb$ = STRING$(LEN(stringmatha$) - LEN(stringmathb$), "0") + stringmathb$
        ELSEIF LEN(stringmatha$) < LEN(stringmathb$) THEN
            stringmatha$ = STRING$(LEN(stringmathb$) - LEN(stringmatha$), "0") + stringmatha$
        END IF
        addsubx1$ = ""
 
        SELECT CASE operator$
            CASE "+", "="
                FOR addsubii% = LEN(stringmatha$) TO 1 STEP -1
                    addsubx1% = VAL(MID$(stringmatha$, addsubii%, 1)) + VAL(MID$(stringmathb$, addsubii%, 1)) + addsubcarry%
                    IF addsubx1% > 9 THEN addsubx1% = addsubx1% - 10: addsubcarry% = 1 ELSE addsubcarry% = 0
                    addsubx1$ = LTRIM$(STR$(addsubx1%)) + addsubx1$
                NEXT
                IF addsubcarry% THEN addsubx1$ = "1" + addsubx1$: addsubcarry% = 0
                GOSUB replacedecimal
            CASE "-"
                FOR addsubii% = LEN(stringmatha$) TO 1 STEP -1
                    addsubx1% = VAL(MID$(stringmatha$, addsubii%, 1)) - VAL(MID$(stringmathb$, addsubii%, 1)) + addsubcarry%
                    IF addsubx1% < 0 THEN addsubx1% = addsubx1% + 10: addsubcarry% = -1 ELSE addsubcarry% = 0
                    addsubx1$ = LTRIM$(STR$(addsubx1%)) + addsubx1$
                NEXT
                IF addsubx1$ <> "" AND addsubx1$ <> STRING$(LEN(addsubx1$), "0") THEN GOSUB replacedecimal
                DO UNTIL LEFT$(addsubx1$, 1) <> "0" ' Remove leading zeros.
                    addsubx1$ = MID$(addsubx1$, 2)
                LOOP
                IF addsubx1$ = "" THEN
                    addsubx1$ = "0": addsubsign% = 0
                ELSE
                    IF addsubcarry% THEN addsubx1$ = "-" + addsubx1$: addsubcarry% = 0
                END IF
        END SELECT
 
        IF addsubsign% THEN
            IF LEFT$(addsubx1$, 1) = "-" THEN addsubx1$ = MID$(addsubx1$, 2) ELSE addsubx1$ = "-" + addsubx1$
        END IF
        stringmatha$ = addsubx1$
        IF operationdivision% THEN RETURN
        runningtotal$ = stringmatha$
        EXIT SUB
 
        replacedecimal:
        IF addsubplace% THEN
            addsubx1$ = STRING$(addsubplace% - LEN(addsubx1$), "0") + addsubx1$
            DO UNTIL RIGHT$(addsubx1$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
                addsubx1$ = MID$(addsubx1$, 1, LEN(addsubx1$) - 1)
                addsubplace% = addsubplace% - 1
            LOOP
            IF addsubplace% > 0 THEN ' Do not replace decimal if total has become an integer amount.
                addsubx1$ = MID$(addsubx1$, 1, LEN(addsubx1$) - addsubplace%) + "." + MID$(addsubx1$, LEN(addsubx1$) - addsubplace% + 1)
            END IF
        END IF
        RETURN
 
    CASE "*"
        stringmultiply:
        multsumcnt% = 0: multcarry% = 0: multplace% = 0: multiconcat$ = ""
        factor1$ = stringmatha$: factor2$ = stringmathb$
        IF LEN(stringmathb$) > LEN(stringmatha$) THEN
            SWAP factor1$, factor2$
        END IF
        IF LEFT$(factor1$, 1) = "-" THEN factor1$ = MID$(factor1$, 2): multsign% = -1
        IF LEFT$(factor2$, 1) = "-" THEN factor2$ = MID$(factor2$, 2): IF multsign% THEN multsign% = 0 ELSE multsign% = -1
        IF INSTR(factor1$, ".") <> 0 THEN multplace% = LEN(factor1$) - INSTR(factor1$, "."): factor1$ = MID$(factor1$, 1, INSTR(factor1$, ".") - 1) + MID$(factor1$, INSTR(factor1$, ".") + 1)
        IF INSTR(factor2$, ".") <> 0 THEN multplace% = multplace% + LEN(factor2$) - INSTR(factor2$, "."): factor2$ = MID$(factor2$, 1, INSTR(factor2$, ".") - 1) + MID$(factor2$, INSTR(factor2$, ".") + 1)
 
        FOR multii% = LEN(factor2$) TO 1 STEP -1
            multii$ = MID$(factor2$, multii%, 1)
            multiiconcat$ = ""
            FOR multjj% = LEN(factor1$) TO 1 STEP -1
                multkk% = VAL(MID$(factor1$, multjj%, 1)) * VAL(multii$) + multcarry%
                IF multkk% > 9 THEN
                    multcarry% = VAL(LEFT$(LTRIM$(STR$(multkk%)), 1))
                    multkk% = VAL(RIGHT$(LTRIM$(STR$(multkk%)), 1))
                ELSE
                    multcarry% = 0
                END IF
                multiiconcat$ = LTRIM$(STR$(multkk%)) + multiiconcat$
            NEXT
            IF multcarry% THEN multiiconcat$ = LTRIM$(STR$(multcarry%)) + multiiconcat$: multcarry% = 0
            GOSUB multsums
        NEXT
        IF multplace% AND product$ <> "0" THEN
            product$ = MID$(product$, 1, LEN(product$) - multplace%) + "." + MID$(product$, LEN(product$) - multplace% + 1)
        END IF
        DO UNTIL LEFT$(product$, 1) <> "0" ' Remove leading zeros.
            product$ = MID$(product$, 2)
        LOOP
        IF product$ = "" THEN product$ = "0": multsign% = 0
        IF multsign% THEN product$ = "-" + product$
        IF RIGHT$(product$, 1) = "." THEN product$ = MID$(product$, 1, LEN(product$) - 1) ' Remove decimal from the end of an integer total.
        IF operator$ = "/" THEN RETURN
        runningtotal$ = product$
        EXIT SUB
 
        multsums:
        IF product$ <> "" THEN
            multsumcnt% = multsumcnt% + 1
            multiiconcat$ = multiiconcat$ + STRING$(multsumcnt%, "0")
            multhh% = 0
            DO
                IF multhh% < LEN(product$) THEN ms1$ = MID$(product$, LEN(product$) - multhh%, 1) ELSE ms1$ = ""
                IF multhh% < LEN(multiiconcat$) THEN ms2$ = MID$(multiiconcat$, LEN(multiiconcat$) - multhh%, 1) ELSE ms2$ = ""
                IF ms1$ = "" AND ms2$ = "" THEN EXIT DO
                addsubx1% = VAL(ms1$) + VAL(ms2$) + multcarry%
                IF addsubx1% > 9 THEN addsubx1% = addsubx1% - 10: multcarry% = 1 ELSE multcarry% = 0
                xproduct$ = LTRIM$(STR$(addsubx1%)) + xproduct$
                multhh% = multhh% + 1
            LOOP
            IF multcarry% THEN product$ = "1" + xproduct$: multcarry% = 0 ELSE product$ = xproduct$
            IF multplace% THEN
                DO UNTIL RIGHT$(product$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
                    product$ = MID$(product$, 1, LEN(product$) - 1)
                    multplace% = multplace% - 1
                LOOP
            END IF
            xproduct$ = ""
        ELSE
            product$ = multiiconcat$: multiiconcat$ = ""
        END IF
        RETURN
 
    CASE "/"
        operationdivision% = -1: quotient$ = ""
        d2dividend$ = stringmatha$
        d1divisor$ = stringmathb$
        IF LEFT$(d1divisor$, 1) = "0" AND LEN(d1divisor$) = 1 THEN PRINT "Division by zero not allowed.": END
        IF LEFT$(d1divisor$, 1) = "-" THEN divsign% = -1: d1divisor$ = MID$(d1divisor$, 2)
        IF LEFT$(d2dividend$, 1) = "-" THEN
            IF divsign% THEN
                divsign% = 0
            ELSE
                divsign% = -1
            END IF
            d2dividend$ = MID$(d2dividend$, 2)
        END IF
        IF INSTR(d1divisor$, ".") <> 0 THEN
            DO UNTIL RIGHT$(d1divisor$, 1) <> "0"
                d1divisor$ = MID$(d1divisor$, 1, LEN(d1divisor$) - 1) ' Strip off trailing zeros
            LOOP
            divplace% = LEN(d1divisor$) - INSTR(d1divisor$, ".")
            d1divisor$ = MID$(d1divisor$, 1, INSTR(d1divisor$, ".") - 1) + MID$(d1divisor$, INSTR(d1divisor$, ".") + 1) ' Strip off decimal point.
            DO UNTIL LEFT$(d1divisor$, 1) <> "0"
                d1divisor$ = MID$(d1divisor$, 2) ' Strip off leading zeros for divisors smaller than .1
            LOOP
        END IF
 
        IF INSTR(d2dividend$, ".") <> 0 THEN
            d2dividend$ = d2dividend$ + STRING$(divplace% - LEN(d2dividend$) - INSTR(d2dividend$, "."), "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
            divplace2% = INSTR(d2dividend$, ".")
            DO UNTIL RIGHT$(d2dividend$, 1) <> "0"
                d2dividend$ = MID$(d2dividend$, 1, LEN(d2dividend$) - 1) ' Strip off trailing zeros
            LOOP
            d2dividend$ = MID$(d2dividend$, 1, INSTR(d2dividend$, ".") - 1) + MID$(d2dividend$, INSTR(d2dividend$, ".") + 1) ' Strip off decimal point.
        ELSE
            d2dividend$ = d2dividend$ + STRING$(divplace%, "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
            divplace% = 0
        END IF
        DO
            DO
                ii = ii + 1
                divremainder% = divremainder% + 1: divremainder$ = divremainder$ + MID$(d2dividend$, divremainder%, 1)
                IF MID$(d2dividend$, divremainder%, 1) = "" THEN
                    IF divremainder$ = STRING$(LEN(divremainder$), "0") AND LEN(quotient$) > LEN(d2dividend$) THEN divflag% = -1: EXIT DO
                    divcarry% = divcarry% + 1
                    IF divcarry% = 1 THEN divplace3% = divremainder% - 1
                    IF divcarry% > divaccuracy% THEN divflag% = -2: EXIT DO
                    divremainder$ = divremainder$ + "0" ' No more digits to bring down.
                END IF
                IF LEN(divremainder$) > LEN(d1divisor$) OR LEN(divremainder$) = LEN(d1divisor$) AND divremainder$ >= d1divisor$ THEN EXIT DO
                quotient$ = quotient$ + "0"
            LOOP
            IF divflag% THEN divflag% = 0: EXIT DO
            FOR idiv% = 9 TO 1 STEP -1
                stringmatha$ = LTRIM$(STR$(idiv%)): stringmathb$ = d1divisor$
                product$ = "": GOSUB stringmultiply
                tempcutd$ = divremainder$ ' divremainder$ can be 00 or other leading zero values.
                DO
                    IF LEN(tempcutd$) = 1 THEN EXIT DO
                    IF LEFT$(tempcutd$, 1) = "0" THEN
                        tempcutd$ = MID$(tempcutd$, 2)
                    ELSE
                        EXIT DO
                    END IF
                LOOP
                IF LEN(tempcutd$) > LEN(product$) OR LEN(tempcutd$) = LEN(product$) AND product$ <= tempcutd$ THEN EXIT FOR
            NEXT
            quotient$ = quotient$ + LTRIM$(STR$(idiv%))
            stringmatha$ = LTRIM$(STR$(idiv%)): stringmathb$ = d1divisor$
            product$ = "": GOSUB stringmultiply
            operator$ = "-": stringmatha$ = divremainder$: stringmathb$ = product$: GOSUB stringcalc: divremainder$ = stringmatha$: operator$ = "/"
        LOOP
        IF divplace% = 0 AND divplace2% = 0 THEN divplace% = divplace3%
        IF divplace2% THEN divplace% = divplace% + divplace2% - 1
        IF quotient$ = "" THEN divplace% = 0 ' dividend is zero.
        IF divplace% OR divplace2% THEN
            tempq$ = MID$(quotient$, INSTR(quotient$, ".") + 1)
            IF LEN(tempq$) >= 3 THEN
                IF STRING$(LEN(divremainder$), "0") = divremainder$ AND divcarry% THEN
                ELSE
                    IF RIGHT$(tempq$, 3) <> STRING$(3, RIGHT$(tempq$, 1)) THEN
                        IF RIGHT$(quotient$, 1) < "5" THEN
                            quotient$ = MID$(quotient$, 1, LEN(quotient$) - 1)
                        ELSE
                            stringmatha$ = MID$(quotient$, 1, LEN(quotient$))
                            stringmathb$ = STRING$(LEN(stringmatha$) - 1, "0") + LTRIM$(STR$(10 - VAL(RIGHT$(quotient$, 1))))
                            operator$ = "+": GOSUB stringcalc:: operator$ = "/"
                            quotient$ = stringmatha$
                        END IF
                    END IF
                END IF
            END IF
            quotient$ = MID$(quotient$, 1, divplace%) + "." + MID$(quotient$, divplace% + 1, divaccuracy% + 1) ' One extra digit for rounding.
            DO UNTIL RIGHT$(quotient$, 1) <> "0"
                quotient$ = MID$(quotient$, 1, LEN(quotient$) - 1) ' Strip off trailing zeros
            LOOP
            IF RIGHT$(quotient$, 1) = "." THEN quotient$ = MID$(quotient$, 1, LEN(quotient$) - 1) ' Strip off abandoned decimal.
        END IF
        DO UNTIL LEFT$(quotient$, 1) <> "0"
            quotient$ = MID$(quotient$, 2) ' Strip off leading zeros
        LOOP
        IF quotient$ = "" THEN quotient$ = "0": divsign% = 0
        IF divsign% THEN quotient$ = "-" + quotient$
        runningtotal$ = quotient$
        operationdivision% = 0
        EXIT SUB
END SELECT
 
validatestringnumber:
valnum% = 0: negcnt% = 0: poscnt% = 0: nonzerospresent% = 0: zerospresent% = 0
IF RIGHT$(stringmathb$, 1) = "." THEN stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
FOR vii% = 1 TO LEN(stringmathb$)
    validatenum$ = MID$(stringmathb$, vii%, 1)
    SELECT CASE validatenum$
        CASE "."
            decimalcnt% = decimalcnt% + 1
        CASE "+"
            poscnt% = vii%
        CASE "-"
            negcnt% = vii%
        CASE "0"
            zerospresent% = -1
        CASE "1" TO "9"
            nonzerospresent% = -1
        CASE ELSE
            stringmathb$ = "invalid number": RETURN
    END SELECT
NEXT
IF decimalcnt% > 1 OR negcnt% > 1 OR poscnt% > 1 THEN
    stringmathb$ = "invalid number": RETURN
END IF
IF nonzerospresent% = 0 THEN
    IF zerospresent% THEN
        stringmathb$ = "0"
    ELSE
        stringmathb$ = "invalid number"
    END IF
END IF
RETURN
END SUB

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: codeguy on March 03, 2019, 04:22:38 am

Arbitrary precision factorial for QB64 posted at RosettaCode. Coded by yours truly

Code: QB64: [Select]

 
REDIM fac#(0)
Factorial fac#(), 655, 10, power#
PRINT power#
SUB Factorial (fac#(), n&, numdigits%, power#)
power# = 0
fac#(0) = 1
remain# = 0
stx& = 0
slog# = 0
NumDiv# = 10 ^ numdigits%
FOR fac# = 1 TO n&
    slog# = slog# + LOG(fac#) / LOG(10)
    FOR x& = 0 TO stx&
        fac#(x&) = fac#(x&) * fac# + remain#
        tx# = fac#(x&) MOD NumDiv#
        remain# = (fac#(x&) - tx#) / NumDiv#
        fac#(x&) = tx#
    NEXT
    IF remain# > 0 THEN
        stx& = UBOUND(fac#) + 1
        REDIM _PRESERVE fac#(stx&)
        fac#(stx&) = remain#
        remain# = 0
    END IF
NEXT
 
scanz& = LBOUND(fac#)
DO
    IF scanz& < UBOUND(fac#) THEN
        IF fac#(scanz&) THEN
            EXIT DO
        ELSE
            scanz& = scanz& + 1
        END IF
    ELSE
        EXIT DO
    END IF
LOOP
 
FOR x& = UBOUND(fac#) TO scanz& STEP -1
    m$ = LTRIM$(RTRIM$(STR$(fac#(x&))))
    IF x& < UBOUND(fac#) THEN
        WHILE LEN(m$) < numdigits%
            m$ = "0" + m$
        WEND
    END IF
    PRINT m$; " ";
    power# = power# + LEN(m$)
NEXT
power# = power# + (scanz& * numdigits%) - 1
PRINT slog#
END SUB
 

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on March 03, 2019, 11:17:19 pm

Well, here's something that isn't Greek to me...

Adding a way to calculate / convert to scientific notation. The variable limit% can be adjusted to the max. number of digits to be displayed. This routine is for positive numbers only. I didn't need to evaluate for negatives, because the routine I'm putting this in does that.

Code: QB64: [Select]

limit% = 5
LINE INPUT "Number: "; n$
IF LEFT$(n$, 1) = "-" THEN n$ = MID$(n$, 2): n2sign$ = "-"
ii% = INSTR(n$, ".") - 2: IF ii% = -2 THEN ii% = LEN(n$) - 1 ' No decimal.
n2$ = MID$(n$, 1, INSTR(n$, ".") - 1) + MID$(n$, INSTR(n$, ".") + 1)
IF LEFT$(n2$, 1) = "0" AND LEN(n2$) > 1 OR ii% = -1 THEN
    DO UNTIL LEFT$(n2$, 1) <> "0" ' Remove leading zeros to consider rounding.
        n2$ = MID$(n2$, 2)
        ii% = ii% - 1
    LOOP
    esign$ = "-"
ELSE
    esign$ = "+"
END IF
n2$ = MID$(n2$, 1, limit% + 1)
n% = LEN(n2$)
IF n% > limit% THEN
    IF RIGHT$(n2$, 1) > "4" THEN
        ' Substitute string math addition routine for line below.
        n2$ = LTRIM$(STR$(VAL(n2$) + 10 - VAL(RIGHT$(n2$, 1))))
    END IF
END IF
DO UNTIL RIGHT$(n2$, 1) <> "0" ' Remove trailing zeros.
    n2$ = MID$(n2$, 1, LEN(n2$) - 1)
LOOP
IF n2$ = "" THEN n2$ = "0": esign$ = "+": ii% = 1
n$ = n2sign$ + LEFT$(n2$, 1) + "." + MID$(n2$, 2, limit% - 1) + "e" + esign$ + LTRIM$(STR$(ABS(ii%)))
PRINT n$
RUN
 

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on March 04, 2019, 06:08:19 pm

Well, since the function posted in the Wiki by Clippy can't handle exponents over 308, I decided to make my own, but to get it working faster, I did fudge it a bit on the exponents, which are limited by passing with the VAL statement to an _INTEGER64 variable. Going much beyond that would take some pretty funky counting routine, but it could be done. So it looks like string math can go to memory capacity in decimals, but if converting back and forth in scientific notation will be limited.

Code: QB64: [Select]

' Good up to exponents of 9,223,372,036,854,775,807 (Limited by _integer64 in VAL statement).
LINE INPUT "Number in scientific notation: "; n$
IF LEFT$(n$, 1) = "-" THEN n2sign$ = "-"
IF VAL(LEFT$(n$, 1)) = 0 AND LEFT$(n$, 1) <> "0" THEN n2$ = MID$(n$, 2, 1) + UCASE$(MID$(n$, 4)) ELSE n2$ = MID$(n$, 1, 1) + UCASE$(MID$(n$, 3)) ' Strip of + or - sign and remove decimal.
FOR ii% = LEN(n2$) TO 1 STEP -1
    ii$ = MID$(n2$, ii%, 1)
    iiconcat$ = ii$ + iiconcat$
    IF ii$ = "E" OR ii$ = "D" THEN n2$ = MID$(n2$, 1, ii% - 1): EXIT FOR
NEXT
IF VAL(MID$(iiconcat$, 2)) < LEN(n2$) - 1 THEN n2point$ = "."
n2zeros$ = STRING$(VAL(MID$(iiconcat$, 3)) - LEN(n2$) + 1, "0")
jj&& = VAL(MID$(iiconcat$, 2)) + 1
IF jj&& < 0 THEN
    lzeros$ = STRING$(ABS(jj&&), "0")
    jj&& = 0
ELSE
    IF jj&& > LEN(n2$) AND n2$ <> "0" THEN
        tzeros$ = STRING$(jj&& - LEN(n2$), "0")
        jj&& = LEN(n2$)
    END IF
END IF
PRINT n2sign$ + MID$(n2$, 1, jj&&) + n2point$ + lzeros$ + MID$(n2$, jj&& + 1) + tzeros$
RUN
 

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on March 05, 2019, 02:32:59 pm

So I put together a routine to validate numeric and scientific notation input, and then convert back ad forth. If there's a bug, the conversions won't match. I should be able to put together a unit checker, soon. The limit% variable limits the display to 15 digits for scientific notation. I'll work on changing some of the smaller variable names in due time.

Code: QB64: [Select]

limit% = 15
LINE INPUT "Number: "; n$
GOSUB validatestringnumber
PRINT "Validation Results: "; n$
PRINT "Limited to"; limit%; "digits..."
IF INSTR(UCASE$(n$), "D") OR INSTR(UCASE$(n$), "E") THEN
    GOSUB scientifictonumeric
    PRINT "Numeric Representation: "; n$
    GOSUB numerictoscientific
    PRINT "Scientific Notation: "; n$
ELSE
    GOSUB numerictoscientific
    PRINT "Scientific Notation: "; n$
    GOSUB scientifictonumeric
    PRINT "Numeric Representation: "; n$
END IF
RUN
 
numerictoscientific:
IF LEFT$(n$, 1) = "-" THEN n$ = MID$(n$, 2): n2sign$ = "-"
ii% = INSTR(n$, ".") - 2: IF ii% = -2 THEN ii% = LEN(n$) - 1 ' No decimal.
n2$ = MID$(n$, 1, INSTR(n$, ".") - 1) + MID$(n$, INSTR(n$, ".") + 1)
IF LEFT$(n2$, 1) = "0" AND LEN(n2$) > 1 OR ii% = -1 THEN
    DO UNTIL LEFT$(n2$, 1) <> "0" ' Remove leading zeros to consider rounding.
        n2$ = MID$(n2$, 2)
        ii% = ii% - 1
    LOOP
    esign$ = "-"
ELSE
    esign$ = "+"
END IF
n2$ = MID$(n2$, 1, limit% + 1)
n% = LEN(n2$)
IF n% > limit% THEN
    IF RIGHT$(n2$, 1) > "4" THEN
        ' Substitute string math addition routine for line below. Only good to limit% = 15 or less without string math routine.
        n2$ = LTRIM$(STR$(VAL(n2$) + 10 - VAL(RIGHT$(n2$, 1))))
    END IF
END IF
DO UNTIL RIGHT$(n2$, 1) <> "0" ' Remove trailing zeros.
    n2$ = MID$(n2$, 1, LEN(n2$) - 1)
LOOP
IF n2$ = "" THEN n2$ = "0": esign$ = "+": ii% = 0
n$ = n2sign$ + LEFT$(n2$, 1) + "." + MID$(n2$, 2, limit% - 1) + "e" + esign$ + LTRIM$(STR$(ABS(ii%)))
n2sign$ = "": esign$ = "": ii% = 0
RETURN
 
scientifictonumeric:
' Good to exponents of 9,223,372,036,854,775,807 (Limited by _integer64 in VAL statement).
IF LEFT$(n$, 1) = "-" THEN n2sign$ = "-"
IF VAL(LEFT$(n$, 1)) = 0 AND LEFT$(n$, 1) <> "0" THEN n2$ = MID$(n$, 2, 1) + UCASE$(MID$(n$, 4)) ELSE n2$ = MID$(n$, 1, 1) + UCASE$(MID$(n$, 3)) ' Strip of + or - sign and remove decimal.
FOR ii% = LEN(n2$) TO 1 STEP -1
    ii$ = MID$(n2$, ii%, 1)
    iiconcat$ = ii$ + iiconcat$
    IF ii$ = "E" OR ii$ = "D" THEN n2$ = MID$(n2$, 1, ii% - 1): EXIT FOR
NEXT
IF VAL(MID$(iiconcat$, 2)) < LEN(n2$) - 1 THEN n2point$ = "."
n2zeros$ = STRING$(VAL(MID$(iiconcat$, 3)) - LEN(n2$) + 1, "0")
jj&& = VAL(MID$(iiconcat$, 2)) + 1
IF jj&& < 0 THEN
    lzeros$ = STRING$(ABS(jj&&), "0")
    jj&& = 0
ELSE
    IF jj&& > LEN(n2$) AND n2$ <> "0" THEN
        tzeros$ = STRING$(jj&& - LEN(n2$), "0")
        jj&& = LEN(n2$)
    END IF
END IF
IF LEN(n2$ + lzeros$ + tzeros$) > limit% THEN ' Rounding routine.
    IF RIGHT$(n2$, 1) > "4" THEN
        ' Substitute string math addition routine for line below. Only good to limit% = 15 or less without string math routine.
        n2$ = LTRIM$(STR$(VAL(n2$) + 10 - VAL(RIGHT$(n2$, 1))))
    END IF
END IF
n$ = MID$(n2$, 1, jj&&) + n2point$ + lzeros$ + MID$(n2$, jj&& + 1) + tzeros$ ' Required with or without rounding routine lines.
n$ = n2sign$ + MID$(n$, 1, limit% + LEN(n2point$)) ' For rounding purposes.
IF lzeros$ <> "" THEN ' Decimal fraction. Only needed when rouning routine is used.
    DO UNTIL RIGHT$(n$, 1) <> "0"
        n$ = MID$(n$, 1, LEN(n$) - 1)
    LOOP
    IF RIGHT$(n$, 1) = "." THEN n$ = MID$(n$, 1, LEN(n$) - 1)
    IF n$ = "" THEN n$ = "0"
END IF
RETURN
 
validatestringnumber:
IF INSTR(UCASE$(n$), "D") OR INSTR(UCASE$(n$), "E") THEN ' Evaluate for Scientific Notation.
    ' Modify n$ to a standard.
    jjd% = INSTR(UCASE$(n$), "D")
    jje% = INSTR(UCASE$(n$), "E")
    IF jjd% THEN jjed% = jjd% ELSE jjed% = jje% ' Get position of notation.
    IF INSTR(n$, ".") = 0 THEN ' Add a decimal if not present to original number.
        n$ = MID$(n$, 1, 1) + "." + MID$(n$, 2)
        jjed% = 3
    END IF
    n2$ = MID$(n$, jjed%): n$ = MID$(n$, 1, jjed% - 1) ' n$ is +- single digit whole number, decimal point and decimal number. n2$ is notation, sign and exponent.
    DO UNTIL RIGHT$(n$, 1) <> "0" ' Remove any trailing zeros for number. Example 1.0d3 or 1.0000d3, etc.
        n$ = MID$(n$, 1, LEN(n$) - 1)
        jjed% = jjed% - 1
    LOOP
    IF VAL(MID$(n$, 1, INSTR(n$, ".") - 1)) = 0 THEN
        IF RIGHT$(n$, 1) = "." THEN
            n$ = "0.e+0" ' Handles all types of zero entries.
        ELSE
            n$ = "invalid number"
        END IF
        RETURN
    END IF
    n$ = n$ + n2$
    IF MID$(n$, jjed% + 1, 1) <> "-" THEN
        IF MID$(n$, jjed% + 1, 1) <> "+" THEN
            n$ = MID$(n$, 1, jjed%) + "+" + MID$(n$, jjed% + 1) ' Add a + sign.
        END IF
    END IF
    n2$ = MID$(n$, 1, jjed% - 1) ' Vailidate the number portion.
    IF LEFT$(n2$, 1) = "-" THEN n2$ = MID$(n2$, 2) ' Strip off any leading - sign.
    IF LEFT$(n2$, 1) = "+" THEN n2$ = MID$(n2$, 2): n$ = MID$(n$, 2) ' Strip off any leading + sign.
    IF MID$(n2$, 2, 1) <> "." THEN n$ = "invalid number": RETURN
    FOR ii% = 1 TO LEN(n2$)
        IF MID$(n2$, ii%, 1) <> "." THEN
            IF VAL(MID$(n2$, ii%, 1)) = 0 AND MID$(n2$, ii%, 1) <> "0" THEN n$ = "invalid number": RETURN
        END IF
    NEXT
    IF n2$ = "" THEN n$ = "invalid number": RETURN
    n2$ = MID$(n$, jjed% + 2) ' Validate exponent. Allows -0 exponent as in: 0.e-0
    IF n2$ = "" THEN n$ = "invalid number": RETURN ' Example: 1.3d
    IF MID$(n2$, 1, 1) = "0" AND LEN(n2$) > 1 THEN n$ = "invalid number": RETURN ' Example 1.3d+01
    FOR ii% = 1 TO LEN(n2$)
        IF VAL(MID$(n2$, ii%, 1)) = 0 AND MID$(n2$, ii%, 1) <> "0" THEN n$ = "invalid number": RETURN
    NEXT
    RETURN
ELSE
    ' Evaluate standard number.
    valnum% = 0: negcnt% = 0: poscnt% = 0: nonzerospresent% = 0: zerospresent% = 0
    IF RIGHT$(stringmathb$, 1) = "." THEN stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
    FOR vii% = 1 TO LEN(stringmathb$)
        validatenum$ = MID$(stringmathb$, vii%, 1)
        SELECT CASE validatenum$
            CASE "."
                decimalcnt% = decimalcnt% + 1
            CASE "+"
                poscnt% = vii%
            CASE "-"
                negcnt% = vii%
            CASE "0"
                zerospresent% = -1
            CASE "1" TO "9"
                nonzerospresent% = -1
            CASE ELSE
                stringmathb$ = "invalid number": RETURN
        END SELECT
    NEXT
    IF decimalcnt% > 1 OR negcnt% > 1 OR poscnt% > 1 THEN
        stringmathb$ = "invalid number": RETURN
    END IF
    IF nonzerospresent% = 0 THEN
        IF zerospresent% THEN
            stringmathb$ = "0"
        ELSE
            stringmathb$ = "invalid number"
        END IF
    END IF
END IF
RETURN
 

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: codeguy on March 07, 2019, 02:55:54 pm

Bad news: old hp laptop died. Good news: replaced with i7. Haven't contributed in a while but I hope others have stolen my code. Yes, it's not flashy, but I I'm glad if anyone has been able to use it.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Jack002 on March 14, 2019, 11:27:51 am

In reference to your 18/7 discussion:
1/7 is the repeating decimal 0.142857142857142857
Its a repeating pattern that goes on forever... type 142857, then do it again and again. Not unlike 1/3 is 0.33333333333

This thread is fascinating to me. These long string numbers can make some interesting patterns
Try 1/97 for as many possible digits you can. There are some neat patterns in some decimal fraction equivalants

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: bplus on March 14, 2019, 11:47:40 am

Quote from: Jack002 on March 14, 2019, 11:27:51 am

In reference to your 18/7 discussion:
1/7 is the repeating decimal 0.142857142857142857
Its a repeating pattern that goes on forever... type 142857, then do it again and again. Not unlike 1/3 is 0.33333333333

This thread is fascinating to me. These long string numbers can make some interesting patterns
Try 1/97 for as many possible digits you can. There are some neat patterns in some decimal fraction equivalants

If you convert the decimal to base 2, use a white rectangle for 1 and a black rectangle for 0 (or vice versa), so that you get a sort of bar code for the base 2 number.

Then stack all the bar codes from 1/n to (n-1)/n, I am pretty sure you will be astounded how fraction patterns that can be reduced to lower terms have same pattern as in the lower n stack for instance 3/15 = 1/5 and both have the same bar code pattern.
[ This attachment cannot be displayed inline in 'Print Page' view ]

Also notice how the stack is symmetric about n/2, black is mirror image of white, and how the pattern changes with each increase of 1 in numerator.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Jack002 on March 14, 2019, 12:11:34 pm

Very interesting. I can see the 1/n relationship to (n-1)/n. They are opposites, so XOR of each other. I doubt patterns seen in numbers like 1/7 will look too interesting in base 2.

I've never seen a program do things like this. Very cool

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: bplus on March 14, 2019, 10:37:36 pm

Here is some old code that captures the exact part that repeats:

Code: QB64: [Select]

_TITLE "Decimal Expansion of Division without Dividing  by bplus 2017-12-03"
' dove tailing Adrians and my recent dividing programs
 
RANDOMIZE TIMER
DEFLNG A-Z
WHILE 1
    PRINT: PRINT "Enter 2 integers < 3200, numerator / denominator, 0's quit, don't forget / "
    INPUT nd$
    slash = INSTR(nd$, "/")
    IF slash THEN
        dvsr = VAL(MID$(nd$, slash + 1))
        IF dvsr = 0 THEN PRINT "Divisor is 0, bye.": END
        numerator = VAL(MID$(nd$, 1, slash - 1))
        IF numerator = 0 THEN PRINT "Numerator is 0, bye.": END
    ELSE
        PRINT "No slash found, bye.": END
    END IF
    PRINT numerator; " / "; dvsr; " = "; divide$(numerator, dvsr)
WEND
 
FUNCTION divide$ (n, d)
    'n = original product or numerator (preserve value of n)
    'd = divisor  (also preserve value)
    c = n 'copy of n to be reduced until <= d, c will be the remainder part of division
    a = 0 'a is for answer or accumulate, the integer part of the division result
 
    'find lowest power of 10 such that: d * 10^p > n
    p = 0 'power of 10
    WHILE d * (10 ^ p) < n
        p = p + 1
    WEND
    WHILE c >= d
        IF c = d THEN a = a + 1: c = 0: EXIT WHILE
        p = p - 1
        IF p >= 0 THEN
            m = 0
            WHILE d * m * 10 ^ p < c
                m = m + 1
            WEND
            m = m - 1
            c = c - d * m * 10 ^ p
            a = a + m * 10 ^ p
        END IF
    WEND
 
    'Now for the decimal expansion isolating the repeating part if one
    IF c <> 0 THEN
        DIM b(d)
        b$ = "."
        WHILE c <> 0
 
            'emergency bug out!
            loopct = loopct + 1 'loop count should not exceed 1000 for numbers I am testing
            IF loopct > 1000 THEN PRINT "Error: loop too long, bugging out! ": GOTO skip
 
            'track repeats  b() tracks been here once, b2() tracks been here twice
            IF b(c) = 1 THEN 'been here!
                IF rFlag = 1 THEN 'been here twice!
                    IF b2(c) = 1 THEN EXIT WHILE 'strike 3, we're out of here
                    b2(c) = 1
                ELSE
                    rFlag = 1
                    DIM b2(d)
                    b$ = b$ + " repeat "
                    b2(c) = 1
                END IF
            ELSE
                b(c) = 1
            END IF
 
            'c was last remainder, mult by 10 and see if some m * d > can reduce it
            tc = 10 * c
            flag = 0
            FOR m = 0 TO 9
                IF ((tc - m * d) >= 0) AND ((tc - (m + 1) * d) < 0) THEN
                    flag = 1: b$ = b$ + LTRIM$(STR$(m))
                    EXIT FOR
                END IF
            NEXT
            IF flag = 0 THEN b$ = b$ + "0": m = 0
            c = tc - d * m
        WEND
    END IF
 
    'OK either d divided n eventually or there is a repeated pattern recorded in b$
    skip: '< needed for debugging
    r$ = STR$(a)
    IF b$ <> "" THEN r$ = r$ + b$
    divide$ = r$
END FUNCTION
 
 

The longest patterns usually come from biggest prime number denominators.

1 digit repeating pattern series 1/15, 1/30, 1/60, 1/120, 1/240,... alternate 3... and 6...
also with 1/3, 1/6, 1/12, 1/24, ...

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Jack002 on March 15, 2019, 08:42:58 am

Very cool, bplus. I like the large prime number recips. 1/97 was there as I remember. This is great. Thanks.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: MWheatley on March 20, 2019, 08:55:12 am

Quote from: SMcNeill on February 24, 2019, 03:36:12 pm

As a rule, I don’t like string math simply for the speed (sloooow), and I don’t have any real need for it usually. LONGs get the majority of my work done, with _FLOATS used only when necessary (and even less often, SINGLE or DOUBLE), and string math is just a novelty needed by others much more than by me. ;)

Out of interest, what sort of things do you use LONGs for?

Malcolm

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: bplus on March 20, 2019, 10:31:01 am

Quote from: MWheatley on March 20, 2019, 08:55:12 am

Quote from: SMcNeill on February 24, 2019, 03:36:12 pm
As a rule, I don’t like string math simply for the speed (sloooow), and I don’t have any real need for it usually. LONGs get the majority of my work done, with _FLOATS used only when necessary (and even less often, SINGLE or DOUBLE), and string math is just a novelty needed by others much more than by me. ;)

Out of interest, what sort of things do you use LONGs for?

Malcolm

Signed INTEGERs only have a range of -32,7678 to 32,767 whereas LONG has a range of about 10 digits.

If you just squared the width of a screen you are likely to exceed INTEGER range.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on March 27, 2019, 11:51:23 pm

I use LONG in my String Math routine, as LEN() is limited by the LONG variable type limits. Oh, speaking of which, I posted the latest version here: https://www.tapatalk.com/groups/qbasic/viewtopic.php?f=648955&t=39442&p=212636#p212636

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on April 06, 2019, 02:48:03 pm

Well, I'm a little bit excited about the first unit testing results in my string math routine. I've ran it a 10 times with all good results. It will pause when a potential problem arises, but, so far, all of those seem to be generated from the higher degree of accuracy with more digits used in many of the string math operations. The pause at least allows me to view and compare, and so far, so good. I'm only using 17+ digits for now. If the first 12 of the 16 digit QB numeric result matches the string math result, it counts it as accepted and moves on. If not, it pauses.

Here is a screen shot where it paused on a 17 digit limit, rounding enabled. I checked in on a calculator to see if it missed a rounding opportunity, and as you can see, it actually didn't!

[ This attachment cannot be displayed inline in 'Print Page' view ]

So far, I've only tested limits between 17 to 140 digits, rounding enabled, show rounding, and no to everything else. Here's the code I'm testing. Press any key, if it pauses, to keep testing. If anyone does test it and finds a fail, please take a screen shot and post it. Also, let me know the parameters you tested it with, especially the digit limit.

Code: QB64: [Select]

WIDTH 156, 43
_SCREENMOVE 0, 0
PRINT
INPUT "Limit Display: "; limit&&
LINE INPUT "Use Rounding? Y/N: "; ans$
IF UCASE$(ans$) = "Y" THEN
    round_total% = -1
    LINE INPUT "Show if Rounded? Y/N: "; ans$
    IF UCASE$(ans$) = "Y" THEN show_rounding% = -1 ELSE show_rounding% = 0
ELSE
    round_total% = 0
END IF
LINE INPUT "Display in Scientific Notation? Y/N: "; ans$
IF UCASE$(ans$) = "Y" THEN
    snconvert% = -1
ELSE
    snconvert% = 0
    LINE INPUT "Display in Dollars and Cents? Y/N: "; ans$
    IF UCASE$(ans$) = "Y" THEN currency_display% = -1 ELSE currency_display% = 0
    LINE INPUT "Display Results with Commas? Y/N: "; ans$
END IF
IF UCASE$(ans$) = "Y" THEN comma_display% = -1 ELSE comma_display% = 0
DO
    DO
        '''LINE INPUT "Number: "; stringmathb$
        ' UNIT TESTING============================
        stringmathb$ = LTRIM$(STR$(RND * 1000000))
        '=========================================
        IF UCASE$(stringmathb$) = "C" THEN RUN
        origb$ = stringmathb$
        CALL stringmath(stringmatha$, operator$, stringmathb$, runningtotal$, snconvert%, round_total%, show_rounding%, comma_display%, currency_display%, limit&&)
        IF stringmathb$ <> "invalid number" AND stringmathb$ <> "overflow" THEN
            EXIT DO
        ELSE
            ' UNIT TESTING============================
            IF stringmathb$ = "overflow" THEN
                operator% = RND * 3
                SELECT CASE operator%
                    CASE 0: operator$ = "+"
                    CASE 1: operator$ = "-"
                    CASE 2: operator$ = "*"
                    CASE 3: operator$ = "/"
                END SELECT
                PRINT stringmathb$
                PRINT "Change Operator: "; operator$: orig_operator$ = operator$
                ' UNIT TESTING============================
                ''' PRINT stringmathb$
            ELSE
                PRINT stringmathb$
                END
            END IF
        END IF
    LOOP
    IF operator$ <> "" THEN
        DO UNTIL INSTR(origa$, ",") = 0
            origa$ = MID$(origa$, 1, INSTR(origa$, ",") - 1) + MID$(origa$, INSTR(origa$, ",") + 1)
        LOOP
        DO UNTIL INSTR(origb$, ",") = 0
            origb$ = MID$(origb$, 1, INSTR(origb$, ",") - 1) + MID$(origb$, INSTR(origb$, ",") + 1)
        LOOP
        IF INSTR(origb$, "$") THEN origb$ = MID$(origb$, 1, INSTR(origb$, "$") - 1) + MID$(origb$, INSTR(origb$, "$") + 1)
        SELECT CASE orig_operator$
            CASE "+"
                runningtotal# = VAL(origa$) + VAL(origb$)
            CASE "-"
                runningtotal# = VAL(origa$) - VAL(origb$)
            CASE "*"
                runningtotal# = VAL(origa$) * VAL(origb$)
            CASE "/"
                runningtotal# = VAL(origa$) / VAL(origb$)
            CASE "C", "c"
                RUN
        END SELECT
        origa$ = LTRIM$(STR$(runningtotal#))
        COLOR 8, 0: PRINT "Numeric Total: "; origa$: COLOR 7, 0
        PRINT "String Total:  "; runningtotal$
        ' UNIT TESTING============================
        q1$ = LTRIM$(STR$(runningtotal#))
        q2$ = runningtotal$
        IF INSTR(q1$, ".") THEN q1$ = MID$(q1$, 1, INSTR(q1$, ".") - 1) + MID$(q1$, INSTR(q1$, ".") + 1)
        IF INSTR(q2$, ".") THEN q2$ = MID$(q2$, 1, INSTR(q2$, ".") - 1) + MID$(q2$, INSTR(q2$, ".") + 1)
        IF RIGHT$(UCASE$(q2$), 1) = "R" THEN q2$ = MID$(q2$, 1, LEN(q2$) - 1)
        FOR i% = 1 TO 12
            IF MID$(q1$, i%, 1) <> MID$(q2$, i%, 1) THEN
                 DO 
                     _LIMIT 10
                 LOOP UNTIL INKEY$ <> ""
            EXIT FOR
            END IF
        NEXT
        '===========================================
    ELSE
        origa$ = runningtotal$: IF INSTR(origa$, "$") THEN origa$ = MID$(origa$, 1, INSTR(origa$, "$") - 1) + MID$(origa$, INSTR(origa$, "$") + 1)
    END IF
    COLOR 2, 0: PRINT "Operator: +-/*: ";: COLOR 7, 0
    DO
        operator% = RND * 3
        SELECT CASE operator%
            CASE 0: operator$ = "+"
            CASE 1: operator$ = "-"
            CASE 2: operator$ = "*"
            CASE 3: operator$ = "/"
        END SELECT
        EXIT DO
 
        operator$ = INKEY$
        IF LEN(operator$) THEN
            IF operator$ = CHR$(27) THEN SYSTEM
            IF INSTR("-+/*=8cC", operator$) THEN EXIT DO
        END IF
    LOOP
    IF UCASE$(operator$) = "C" THEN RUN
    IF operator$ = "=" THEN operator$ = "+"
    IF operator$ = "8" THEN operator$ = "*"
    orig_operator$ = operator$
    PRINT operator$
LOOP
 
SUB stringmath (stringmatha$, operator$, stringmathb$, runningtotal$, snconvert%, round_total%, show_rounding%, comma_display%, currency_display%, limit&&)
stringmathround$ = ""
IF limit&& > 2147483640 THEN limit&& = 2147483640
IF limit&& = 0 THEN limit&& = 70 ' Default.
 
IF RIGHT$(UCASE$(runningtotal$), 1) = "R" THEN runningtotal$ = MID$(runningtotal$, 1, LEN(runningtotal$) - 1) 'Strip off rounding designation.
' Check running total. If S.N. convert to numeric for operations.
IF INSTR(runningtotal$, ",") <> 0 OR INSTR(runningtotal$, "e") <> 0 THEN
    holdstringmathb$ = stringmathb$
    stringmathb$ = runningtotal$
    IF INSTR(runningtotal$, ",") <> 0 THEN GOSUB comma_removal ELSE GOSUB scientific_to_numeric
    runningtotal$ = stringmathb$: stringmathb$ = holdstringmathb$: holdstringmathb$ = ""
END IF
' Check input number. If S.N. convert to numeric for operations.
IF INSTR(UCASE$(stringmathb$), "D") <> 0 OR INSTR(UCASE$(stringmathb$), "E") <> 0 THEN
    GOSUB validate_string_number
    IF stringmathb$ = "invalid number" THEN EXIT SUB
    GOSUB scientific_to_numeric
END IF
 
IF runningtotal$ = "" THEN
    GOSUB validate_string_number
    IF stringmathb$ = "invalid number" THEN EXIT SUB
 
    IF LEFT$(stringmathb$, 1) = "-" THEN
        stringmathb$ = MID$(stringmathb$, 2)
        n2sign$ = "-"
    ELSE
        n2sign$ = ""
    END IF
    GOSUB limit_round_convert
    IF stringmathb$ = "overflow" THEN
        n2sign$ = "": PRINT "Validated: "; stringmathb$: EXIT SUB
    END IF
    runningtotal$ = n2sign$ + stringmathb$: n2sign$ = ""
    IF stringmathround$ <> "" THEN runningtotal$ = runningtotal$ + stringmathround$
    PRINT "Validated: "; runningtotal$
    IF INSTR(LCASE$(stringmathb$), "e") <> 0 THEN BEEP: GOSUB scientific_to_numeric
ELSE
    GOSUB validate_string_number
    PRINT "Validated: "; stringmathb$
    IF stringmathb$ = "invalid number" THEN EXIT SUB
    IF INSTR(UCASE$(stringmathb$), "e") <> 0 THEN GOSUB scientific_to_numeric
END IF
IF runningtotal$ <> "" THEN stringmatha$ = runningtotal$
 
SELECT CASE operator$
    CASE "+", "-"
        string_add_subtract:
        IF INSTR(stringmatha$, ".") <> 0 THEN ' Evaluate sum for decimal fraction.
            sumplace& = LEN(stringmatha$) - INSTR(stringmatha$, ".")
            stringmatha$ = MID$(stringmatha$, 1, INSTR(stringmatha$, ".") - 1) + MID$(stringmatha$, INSTR(stringmatha$, ".") + 1) ' Strip out decimal
        END IF
        IF INSTR(stringmathb$, ".") <> 0 THEN ' Evaluate number for decimal fraction.
            numplace& = LEN(stringmathb$) - INSTR(stringmathb$, ".")
            stringmathb$ = MID$(stringmathb$, 1, INSTR(stringmathb$, ".") - 1) + MID$(stringmathb$, INSTR(stringmathb$, ".") + 1) ' Strip out decimal
        END IF
        IF sumplace& > numplace& THEN addsubplace& = sumplace& ELSE addsubplace& = numplace&
        IF sumplace& > addsubplace& THEN
            stringmatha$ = stringmatha$ + STRING$(sumplace& - addsubplace&, "0")
        ELSEIF addsubplace& > sumplace& THEN
            stringmatha$ = stringmatha$ + STRING$(addsubplace& - sumplace&, "0")
        END IF
        IF numplace& > addsubplace& THEN
            stringmathb$ = stringmathb$ + STRING$(numplace& - addsubplace&, "0")
        ELSEIF addsubplace& > numplace& THEN
            stringmathb$ = stringmathb$ + STRING$(addsubplace& - numplace&, "0")
        END IF ' END Decimal evaluations.
 
        IF LEFT$(stringmatha$, 1) = "-" THEN sign_input$ = "-" ELSE sign_input$ = "+"
        IF LEFT$(stringmathb$, 1) = "-" THEN sign_total$ = "-" ELSE sign_total$ = "+"
 
        addsubsign% = 0
        SELECT CASE sign_input$ + operator$ + sign_total$
            CASE "+++", "+--"
                operator$ = "+"
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
            CASE "++-", "+-+"
                operator$ = "-"
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
                IF VAL(stringmathb$) > VAL(stringmatha$) THEN SWAP stringmatha$, stringmathb$: addsubsign% = -1
            CASE "---", "-++"
                operator$ = "-"
                IF LEFT$(stringmatha$, 1) = "-" THEN stringmatha$ = MID$(stringmatha$, 2)
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
                IF VAL(stringmathb$) > VAL(stringmatha$) THEN SWAP stringmatha$, stringmathb$ ELSE addsubsign% = -1
            CASE "--+", "-+-"
                operator$ = "+"
                IF LEFT$(stringmatha$, 1) = "-" THEN stringmatha$ = MID$(stringmatha$, 2)
                IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
                addsubsign% = -1
        END SELECT
 
        IF LEN(stringmatha$) > LEN(stringmathb$) THEN
            stringmathb$ = STRING$(LEN(stringmatha$) - LEN(stringmathb$), "0") + stringmathb$
        ELSEIF LEN(stringmatha$) < LEN(stringmathb$) THEN
            stringmatha$ = STRING$(LEN(stringmathb$) - LEN(stringmatha$), "0") + stringmatha$
        END IF
        addsubx1$ = ""
 
        SELECT CASE operator$
            CASE "+", "="
                FOR addsubii& = LEN(stringmatha$) TO 1 STEP -1
                    addsubx1% = VAL(MID$(stringmatha$, addsubii&, 1)) + VAL(MID$(stringmathb$, addsubii&, 1)) + addsubcarry%
                    IF addsubx1% > 9 THEN addsubx1% = addsubx1% - 10: addsubcarry% = 1 ELSE addsubcarry% = 0
                    addsubx1$ = LTRIM$(STR$(addsubx1%)) + addsubx1$
                NEXT
                IF addsubcarry% THEN addsubx1$ = "1" + addsubx1$: addsubcarry% = 0
                GOSUB replace_decimal
            CASE "-"
                FOR addsubii& = LEN(stringmatha$) TO 1 STEP -1
                    addsubx1% = VAL(MID$(stringmatha$, addsubii&, 1)) - VAL(MID$(stringmathb$, addsubii&, 1)) + addsubcarry%
                    IF addsubx1% < 0 THEN addsubx1% = addsubx1% + 10: addsubcarry% = -1 ELSE addsubcarry% = 0
                    addsubx1$ = LTRIM$(STR$(addsubx1%)) + addsubx1$
                NEXT
                IF addsubx1$ <> "" AND addsubx1$ <> STRING$(LEN(addsubx1$), "0") THEN GOSUB replace_decimal
                DO UNTIL LEFT$(addsubx1$, 1) <> "0" ' Remove leading zeros.
                    addsubx1$ = MID$(addsubx1$, 2)
                LOOP
                IF addsubx1$ = "" THEN
                    addsubx1$ = "0": addsubsign% = 0
                ELSE
                    IF addsubcarry% THEN addsubx1$ = "-" + addsubx1$: addsubcarry% = 0
                END IF
        END SELECT
 
        IF addsubsign% THEN
            IF LEFT$(addsubx1$, 1) = "-" THEN addsubx1$ = MID$(addsubx1$, 2) ELSE addsubx1$ = "-" + addsubx1$
        END IF
        stringmatha$ = addsubx1$: addsubx1$ = ""
        IF operationdivision% THEN RETURN
        stringmathb$ = stringmatha$: stringmatha$ = ""
        IF LEFT$(stringmathb$, 1) = "-" THEN
            stringmathb$ = MID$(stringmathb$, 2)
            n2sign$ = "-"
        ELSE
            n2sign$ = ""
        END IF
        GOSUB limit_round_convert
        IF stringmathb$ = "overflow" THEN n2sign$ = "": EXIT SUB
        GOSUB sm_converter
        runningtotal$ = n2sign$ + stringmathb$: n2sign$ = ""
 
    CASE "*"
        string_multiply:
        fac1$ = stringmatha$: fac2$ = stringmathb$ ' Make numbers whole numbers and remove any - sign.
        IF LEFT$(fac1$, 1) = "-" THEN fac1$ = MID$(fac1$, 2): m_sign% = -1
        IF LEFT$(fac2$, 1) = "-" THEN fac2$ = MID$(fac2$, 2): IF m_sign% THEN m_sign% = 0 ELSE m_sign% = -1
        IF INSTR(fac1$, ".") <> 0 THEN m_decimal_places& = LEN(fac1$) - INSTR(fac1$, "."): fac1$ = MID$(fac1$, 1, INSTR(fac1$, ".") - 1) + MID$(fac1$, INSTR(fac1$, ".") + 1)
        IF INSTR(fac2$, ".") <> 0 THEN m_decimal_places& = m_decimal_places& + LEN(fac2$) - INSTR(fac2$, "."): fac2$ = MID$(fac2$, 1, INSTR(fac2$, ".") - 1) + MID$(fac2$, INSTR(fac2$, ".") + 1)
        FOR m_i& = LEN(fac2$) TO 1 STEP -1 ' Multiply each charter top and bottom.
            m_k& = m_l&
            m_x2$ = MID$(fac2$, m_i&, 1)
            FOR m_j& = LEN(fac1$) TO 1 STEP -1
                m_x1$ = MID$(fac1$, m_j&, 1)
                IF m_product$ <> "" THEN
                    m_add$ = LTRIM$(STR$(VAL(m_x1$) * VAL(m_x2$))) + STRING$(m_k&, "0")
                    m_t& = 0: m_xproduct$ = "": m_carry% = 0
                    DO ' Add multiplied characters together.
                        m_x3$ = MID$(m_add$, LEN(m_add$) - m_t&, 1)
                        m_x4$ = MID$(m_product$, LEN(m_product$) - m_t&, 1)
                        IF m_x3$ = "" AND m_x4$ = "" THEN
                            IF m_carry% THEN m_xproduct$ = "1" + m_xproduct$
                            EXIT DO
                        END IF
                        m_g% = VAL(m_x3$) + VAL(m_x4$) + m_carry%
                        IF m_g% >= 10 THEN m_g% = m_g% - 10: m_carry% = 1 ELSE m_carry% = 0
                        m_xproduct$ = LTRIM$(STR$(m_g%)) + m_xproduct$
                        m_t& = m_t& + 1
                    LOOP
                    m_product$ = m_xproduct$: m_xproduct$ = ""
                ELSE
                    m_product$ = LTRIM$(STR$(VAL(m_x1$) * VAL(m_x2$))) + STRING$(m_k&, "0") ' First loop makes variable here.
                END IF
                m_k& = m_k& + 1 ' Adds trailing zeros multiplication
            NEXT
            m_l& = m_l& + 1 ' Used to reset value for m_k& adding one trailing zer for each loop.
        NEXT
        fac1$ = "": fac2$ = "": m_l& = 0: m_k& = 0: m_t& = 0
        IF m_decimal_places& > LEN(m_product$) THEN m_product$ = STRING$(m_decimal_places& - LEN(m_product$), "0") + m_product$ ' Add any leading zeros to a decimal. Ex: .02 * .01 is factored as 002. It needs one leading zero before adding the decimal point, .0002.
        IF m_decimal_places& AND m_product$ <> "0" THEN ' Replace any decimal point.
            m_product$ = MID$(m_product$, 1, LEN(m_product$) - m_decimal_places&) + "." + MID$(m_product$, LEN(m_product$) - m_decimal_places& + 1)
        END IF
        DO UNTIL LEFT$(m_product$, 1) <> "0" ' Remove leading zeros.
            m_product$ = MID$(m_product$, 2)
        LOOP
        IF m_decimal_places& THEN
            DO UNTIL RIGHT$(m_product$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
                m_product$ = MID$(m_product$, 1, LEN(m_product$) - 1)
            LOOP
        END IF
        IF m_product$ = "" THEN m_product$ = "0": m_sign% = 0
        IF RIGHT$(m_product$, 1) = "." THEN m_product$ = MID$(m_product$, 1, LEN(m_product$) - 1) ' Remove decimal from the end of an integer total.
        IF operationdivision% THEN m_sign% = 0: RETURN
        stringmathb$ = m_product$: m_product$ = "": GOSUB limit_round_convert
        IF stringmathb$ = "overflow" THEN EXIT SUB
        GOSUB sm_converter
        runningtotal$ = stringmathb$: stringmathb$ = ""
        IF m_sign% THEN runningtotal$ = "-" + runningtotal$: m_sign% = 0
 
    CASE "/"
        operationdivision% = -1
        divbuffer& = LEN(stringmathb$) - LEN(stringmatha$)
        IF divbuffer& < 0 THEN divbuffer& = 0
        d2dividend$ = stringmatha$
        d1divisor$ = stringmathb$
        IF LEFT$(d1divisor$, 1) = "0" AND LEN(d1divisor$) = 1 THEN PRINT "Division by zero not allowed.": END
        IF LEFT$(d1divisor$, 1) = "-" THEN divsign% = -1: d1divisor$ = MID$(d1divisor$, 2)
        IF LEFT$(d2dividend$, 1) = "-" THEN
            IF divsign% THEN
                divsign% = 0
            ELSE
                divsign% = -1
            END IF
            d2dividend$ = MID$(d2dividend$, 2)
        END IF
        IF INSTR(d1divisor$, ".") <> 0 THEN
            DO UNTIL RIGHT$(d1divisor$, 1) <> "0"
                d1divisor$ = MID$(d1divisor$, 1, LEN(d1divisor$) - 1) ' Strip off trailing zeros
            LOOP
            divplace& = LEN(d1divisor$) - INSTR(d1divisor$, ".")
            d1divisor$ = MID$(d1divisor$, 1, INSTR(d1divisor$, ".") - 1) + MID$(d1divisor$, INSTR(d1divisor$, ".") + 1) ' Strip off decimal point.
            DO UNTIL LEFT$(d1divisor$, 1) <> "0"
                d1divisor$ = MID$(d1divisor$, 2) ' Strip off leading zeros for divisors smaller than .1
            LOOP
        END IF
 
        IF INSTR(d2dividend$, ".") <> 0 THEN
            d2dividend$ = d2dividend$ + STRING$(divplace& - LEN(d2dividend$) - INSTR(d2dividend$, "."), "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
            divplace2& = INSTR(d2dividend$, ".")
            DO UNTIL RIGHT$(d2dividend$, 1) <> "0"
                d2dividend$ = MID$(d2dividend$, 1, LEN(d2dividend$) - 1) ' Strip off trailing zeros
            LOOP
            d2dividend$ = MID$(d2dividend$, 1, INSTR(d2dividend$, ".") - 1) + MID$(d2dividend$, INSTR(d2dividend$, ".") + 1) ' Strip off decimal point.
        ELSE
            d2dividend$ = d2dividend$ + STRING$(divplace&, "0") ' Add any zeros based on the length of dividend at decimal - length of divisor at decimal. If less than zero, nothing added.
            divplace& = 0
        END IF
        DO
            DO
                divremainder& = divremainder& + 1: divremainder$ = divremainder$ + MID$(d2dividend$, divremainder&, 1)
                IF MID$(d2dividend$, divremainder&, 1) = "" THEN
                    IF divremainder$ = STRING$(LEN(divremainder$), "0") AND LEN(quotient$) > LEN(d2dividend$) THEN divflag% = -1: EXIT DO
                    divcarry& = divcarry& + 1
                    IF divcarry& = 1 THEN divplace3& = divremainder& - 1
                    IF divcarry& > limit&& + 1 + divbuffer& THEN
                        divflag% = -2: EXIT DO
                    END IF
                    divremainder$ = divremainder$ + "0" ' No more digits to bring down.
                END IF
                IF LEN(divremainder$) > LEN(d1divisor$) OR LEN(divremainder$) = LEN(d1divisor$) AND divremainder$ >= d1divisor$ THEN EXIT DO
                quotient$ = quotient$ + "0"
            LOOP
            IF divflag% THEN divflag% = 0: EXIT DO
            FOR div_i% = 9 TO 1 STEP -1
                stringmatha$ = LTRIM$(STR$(div_i%)): stringmathb$ = d1divisor$
                m_product$ = "": GOSUB string_multiply
                tempcutd$ = divremainder$ ' divremainder$ can be 00 or other leading zero values.
                DO
                    IF LEN(tempcutd$) = 1 THEN EXIT DO
                    IF LEFT$(tempcutd$, 1) = "0" THEN
                        tempcutd$ = MID$(tempcutd$, 2)
                    ELSE
                        EXIT DO
                    END IF
                LOOP
                IF LEN(tempcutd$) > LEN(m_product$) OR LEN(tempcutd$) = LEN(m_product$) AND m_product$ <= tempcutd$ THEN EXIT FOR
            NEXT
            quotient$ = quotient$ + LTRIM$(STR$(div_i%))
            stringmatha$ = LTRIM$(STR$(div_i%)): stringmathb$ = d1divisor$
            m_product$ = "": GOSUB string_multiply
            operator$ = "-"
            stringmatha$ = divremainder$
            stringmathb$ = m_product$
            GOSUB string_add_subtract
            divremainder$ = stringmatha$
            operator$ = "/"
        LOOP
        IF divplace& = 0 AND divplace2& = 0 THEN divplace& = divplace3&
        IF divplace2& THEN divplace& = divplace& + divplace2& - 1
        IF quotient$ = "" THEN divplace& = 0 ' dividend is zero.
        IF divplace& OR divplace2& THEN
            quotient$ = MID$(quotient$, 1, divplace&) + "." + MID$(quotient$, divplace& + 1)
            DO UNTIL RIGHT$(quotient$, 1) <> "0"
                quotient$ = MID$(quotient$, 1, LEN(quotient$) - 1) ' Strip off trailing zeros
            LOOP
            IF RIGHT$(quotient$, 1) = "." THEN quotient$ = MID$(quotient$, 1, LEN(quotient$) - 1) ' Strip off abandoned decimal.
        END IF
        DO UNTIL LEFT$(quotient$, 1) <> "0"
            quotient$ = MID$(quotient$, 2) ' Strip off leading zeros
        LOOP
        IF quotient$ = "" THEN quotient$ = "0": divsign% = 0
        operationdivision% = 0
        stringmathb$ = quotient$: quotient$ = "": GOSUB limit_round_convert
        IF stringmathb$ = "overflow" THEN divsign% = 0: EXIT SUB
        GOSUB sm_converter
        runningtotal$ = stringmathb$: stringmathb$ = ""
        IF divsign% THEN runningtotal$ = "-" + runningtotal$
END SELECT
IF stringmathround$ <> "" THEN runningtotal$ = runningtotal$ + stringmathround$
EXIT SUB
 
validate_string_number:
vsn_negcnt& = 0: vsn_poscnt& = 0: vsn_depresent& = 0: decimalcnt& = 0: vsn_numberpresent& = 0: vsn_zerospresent& = 0
IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2): sm_sign$ = "-" ELSE sm_sign$ = ""
IF LEFT$(stringmathb$, 1) = "+" THEN IF sm_sign$ <> "-" THEN stringmathb$ = MID$(stringmathb$, 2) ELSE stringmathb$ = "invalid number": RETURN
IF INSTR(UCASE$(stringmathb$), "D") OR INSTR(UCASE$(stringmathb$), "E") THEN ' Evaluate for Scientific Notation.
    FOR sm_i& = 1 TO LEN(stringmathb$)
        validatenum$ = MID$(UCASE$(stringmathb$), sm_i&, 1)
        SELECT CASE validatenum$
            CASE "+"
                IF vsn_depresent& THEN vsn_poscnt& = vsn_poscnt& + 1 ELSE stringmathb$ = "invalid number": RETURN
            CASE "-"
                IF vsn_depresent& THEN vsn_negcnt& = vsn_negcnt& + 1 ELSE stringmathb$ = "invalid number": RETURN
            CASE "0" TO "9"
                vsn_numberpresent& = -1
            CASE "D", "E"
                vsn_depresent& = vsn_depresent& + 1
                IF decimalcnt& = 0 AND sm_i& <> 2 OR vsn_depresent& > 1 OR vsn_numberpresent& = 0 OR vsn_negcnt& > 1 OR vsn_poscnt& > 1 OR vsn_negcnt& = 1 AND vsn_poscnt& >= 1 THEN vsn_numberpresent& = 0: EXIT FOR
                vsn_numberpresent& = 0
                MID$(stringmathb$, sm_i&, 1) = "e" ' Standardize
            CASE "."
                decimalcnt& = decimalcnt& + 1
                IF sm_i& <> 2 THEN vsn_numberpresent& = 0: EXIT FOR
            CASE ELSE
                vsn_numberpresent& = 0: EXIT FOR
        END SELECT
    NEXT
    IF decimalcnt& = 0 THEN stringmathb$ = MID$(stringmathb$, 1, 1) + "." + MID$(stringmathb$, 2) ' Standardize "."
    IF vsn_numberpresent& = 0 OR vsn_negcnt& = 1 AND vsn_poscnt& = 1 OR decimalcnt& > 1 OR INSTR(stringmathb$, ".") <> 2 THEN stringmathb$ = "invalid number": RETURN
    vsn_depresent& = INSTR(stringmathb$, "e")
    sm_x$ = MID$(stringmathb$, vsn_depresent& + 1, 1) ' Standardize exponent "+" these two lines.
    IF sm_x$ <> "+" AND sm_x$ <> "-" THEN stringmathb$ = MID$(stringmathb$, 1, vsn_depresent&) + "+" + MID$(stringmathb$, vsn_depresent& + 1)
    IF MID$(stringmathb$, vsn_depresent& + 2, 1) = "0" THEN
        IF MID$(stringmathb$, vsn_depresent& + 3, 1) <> "" THEN stringmathb$ = "invalid number": RETURN ' No leading zeros allowed in exponent notation.
    END IF
    jjed& = INSTR(stringmathb$, "e") ' Get position of notation.
    valexpside$ = MID$(stringmathb$, jjed&) ' These two lines break up into number and notation
    stringmathb$ = MID$(stringmathb$, 1, jjed& - 1) ' stringmathb$ is +- single digit whole number, decimal point and decimal number. valexpside$ is notation, sign and exponent.
    DO UNTIL RIGHT$(stringmathb$, 1) <> "0" ' Remove any trailing zeros for number. Example 1.0d3 or 1.0000d3, etc.
        stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
    LOOP
    IF VAL(MID$(stringmathb$, 1, INSTR(stringmathb$, ".") - 1)) = 0 THEN
        IF RIGHT$(stringmathb$, 1) = "." THEN
            stringmathb$ = "0.e+0" ' Handles all types of zero entries.
        ELSE
            stringmathb$ = "invalid number": RETURN
        END IF
        RETURN
    END IF
    stringmathb$ = sm_sign$ + stringmathb$ + valexpside$
    RETURN
ELSE
    FOR sm_i& = 1 TO LEN(stringmathb$)
        validatenum$ = MID$(stringmathb$, sm_i&, 1)
        SELECT CASE validatenum$
            CASE "."
                decimalcnt& = decimalcnt& + 1
            CASE "0"
                vsn_zerospresent& = -1
            CASE "1" TO "9"
                vsn_numberpresent& = -1
            CASE "$"
            CASE ELSE
                stringmathb$ = "invalid number": RETURN
        END SELECT
    NEXT
    IF decimalcnt& > 1 OR vsn_negcnt& > 1 OR vsn_poscnt& > 1 OR vsn_negcnt& >= 1 AND vsn_poscnt& >= 1 THEN
        stringmathb$ = "invalid number": RETURN
    END IF
    IF INSTR(stringmathb$, "$") THEN GOSUB currency_validate
    IF INSTR(stringmathb$, ",") THEN
        GOSUB comma_validation
        IF stringmathb$ = "invalid number" THEN RETURN
        GOSUB comma_removal
    END IF
    IF RIGHT$(stringmathb$, 1) = "." THEN stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
    DO UNTIL LEFT$(stringmathb$, 1) <> "0" ' Strip off any leading zeros.
        stringmathb$ = MID$(stringmathb$, 2)
    LOOP
    stringmathb$ = sm_sign$ + stringmathb$
    IF INSTR(stringmathb$, ".") THEN
        DO UNTIL RIGHT$(stringmathb$, 1) <> "0" ' Strip off any trailing zeros in a decimal.
            stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
        LOOP
    END IF
    IF RIGHT$(stringmathb$, 1) = "." THEN stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
    IF vsn_numberpresent& = 0 THEN
        IF vsn_zerospresent& THEN
            stringmathb$ = "0"
        ELSE
            stringmathb$ = "invalid number"
        END IF
    END IF
END IF
RETURN
 
' Convert to commas, currency, S.N., etc.
sm_converter:
IF comma_display% THEN GOSUB comma_placement
IF currency_display% THEN GOSUB currency_convert
IF snconvert% THEN GOSUB numeric_to_scientific
RETURN
 
' Add in commas.
comma_placement:
GOSUB comma_prep
sm_i& = 0: sm_j& = 0: sm_seed& = 0
sm_seed& = LEN(temp_stringmathb1$) MOD 3: IF sm_seed& = 0 THEN sm_seed& = 3
sm_m1& = LEN(temp_stringmathb1$)
sm_m2& = (LEN(temp_stringmathb1$) - 1) \ 3
sm_replace$ = SPACE$(sm_m1& + sm_m2&)
DO WHILE sm_i& < sm_m1&
    MID$(sm_replace$, sm_j& + 1, sm_seed& + 1) = MID$(temp_stringmathb1$, sm_i& + 1, sm_seed&) + ","
    sm_i& = sm_i& + sm_seed&: sm_j& = sm_j& + sm_seed& + 1: sm_seed& = 3
LOOP
sm_replace$ = RTRIM$(sm_replace$)
IF RIGHT$(sm_replace$, 1) = "," THEN
    stringmathb$ = MID$(sm_replace$, 1, LEN(sm_replace$) - 1)
ELSE
    stringmathb$ = sm_replace$
END IF
sm_replace$ = "": temp_stringmathb1$ = ""
RETURN
 
' Validate comma entry.
comma_validation:
GOSUB comma_prep
IF INSTR(temp_stringmathb2$, ",") <> 0 OR temp_stringmathb1$ = STRING$(LEN(temp_stringmathb1$), ",") THEN
    stringmathb$ = "invalid number" ' Decimal part has comma or entry is all commas.
ELSE
    FOR sm_i& = LEN(temp_stringmathb1$) TO 1 STEP -1
        sm_j% = sm_j% + 1
        IF sm_j% = 4 THEN
            IF MID$(temp_stringmathb1$, sm_i&, 1) <> "," THEN stringmathb$ = "invalid number": EXIT FOR
            sm_j% = 0
        END IF
    NEXT
    IF stringmathb$ <> "invalid number" THEN
        stringmathb$ = sm_sign$ + temp_stringmathb1$ + temp_stringmathb2$
    END IF
END IF
temp_stringmathb1$ = "": temp_stringmathb2$ = "": sm_i& = 0: sm_j% = 0: sm_sign$ = "": sm_dollar$ = ""
RETURN
 
comma_removal:
sm_i& = 0: sm_j& = 0: sm_seed& = 0
sm_replace$ = SPACE$(LEN(stringmathb$))
DO
    sm_i& = INSTR(sm_seed& + 1, stringmathb$, ",")
    IF sm_i& = 0 THEN EXIT DO
    MID$(sm_replace$, sm_j& + 1, sm_i& - sm_seed& + 1) = MID$(stringmathb$, sm_seed& + 1, sm_i& - sm_seed& - 1)
    sm_j& = sm_j& + sm_i& - sm_seed& - 1
    sm_seed& = sm_i&
LOOP
stringmathb$ = RTRIM$(sm_replace$) + MID$(stringmathb$, sm_seed& + 1): sm_replace$ = ""
RETURN
 
comma_prep:
IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2): sm_sign$ = "-"
temp_stringmathb1$ = stringmathb$: stringmathb$ = ""
IF INSTR(temp_stringmathb1$, ".") THEN
    temp_stringmathb2$ = MID$(temp_stringmathb1$, INSTR(temp_stringmathb1$, ".")) ' Decimal part
    temp_stringmathb1$ = MID$(temp_stringmathb1$, 1, INSTR(temp_stringmathb1$, ".") - 1) ' Non-decimal part
END IF
IF LEFT$(temp_stringmathb1$, 1) = "$" THEN temp_stringmathb1$ = MID$(temp_stringmathb1$, 2): sm_dollar$ = "$"
RETURN
 
currency_validate:
IF LEFT$(stringmathb$, 2) = "$-" OR LEFT$(stringmathb$, 2) = "$+" THEN stringmathb$ = "invalid number": RETURN
IF LEFT$(stringmathb$, 1) = "$" THEN stringmathb$ = MID$(stringmathb$, 2)
IF INSTR(stringmathb$, "$") THEN stringmathb$ = "invalid number": RETURN
sm_dollar$ = "$"
RETURN
 
currency_convert:
IF INSTR(UCASE$(stringmathb$), "D") <> 0 OR INSTR(UCASE$(stringmathb$), "E") <> 0 THEN GOSUB scientific_to_numeric
IF INSTR(stringmathb$, ",") = 0 THEN GOSUB comma_placement
IF INSTR(stringmathb$, ".") = 0 THEN stringmathb$ = stringmathb$ + ".00"
IF RIGHT$(stringmathb$, 1) = "." THEN stringmathb$ = stringmathb$ + "00"
IF MID$(stringmathb$, LEN(stringmathb$) - 2, 1) <> "." THEN stringmathb$ = stringmathb$ + "0"
IF MID$(stringmathb$, LEN(stringmathb$) - 2, 1) <> "." THEN stringmathb$ = "invalid number": RETURN
IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2)
stringmathb$ = sm_sign$ + "$" + stringmathb$
RETURN
 
numeric_to_scientific:
IF LEFT$(stringmathb$, 1) = "-" THEN stringmathb$ = MID$(stringmathb$, 2): n2sign$ = "-"
IF INSTR(stringmathb$, ".") = 0 THEN exponentvalue&& = LEN(stringmathb$) - 1 ELSE exponentvalue&& = INSTR(stringmathb$, ".") - 2 ' Exponent is one less than number of digits for whole number an two less than the placement of the decimal point for a fraction.
stringmathb$ = MID$(stringmathb$, 1, INSTR(stringmathb$, ".") - 1) + MID$(stringmathb$, INSTR(stringmathb$, ".") + 1)
IF LEFT$(stringmathb$, 1) = "0" AND LEN(stringmathb$) > 1 OR exponentvalue&& = -1 THEN
    DO UNTIL LEFT$(stringmathb$, 1) <> "0" ' Remove leading zeros to consider rounding.
        stringmathb$ = MID$(stringmathb$, 2)
        exponentvalue&& = exponentvalue&& - 1
    LOOP
    esign$ = "-"
ELSE
    esign$ = "+"
END IF
DO UNTIL RIGHT$(stringmathb$, 1) <> "0" ' Remove trailing zeros.
    stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
LOOP
IF stringmathb$ = "" THEN stringmathb$ = "0": esign$ = "+": exponentvalue&& = 0
stringmathb$ = LEFT$(stringmathb$, 1) + "." + MID$(stringmathb$, 2)
IF stringmathb$ = "0." THEN n2sign$ = "": esign$ = "+"
stringmathb$ = stringmathb$ + "e" + esign$ + LTRIM$(STR$(ABS(exponentvalue&&))) ' S.N formed here.
IF stringmathb$ <> "overflow" THEN
    stringmathb$ = n2sign$ + stringmathb$
END IF
n2sign$ = "": esign$ = "": exponentvalue&& = 0
RETURN
 
scientific_to_numeric:
IF INSTR(UCASE$(stringmathb$), "D") THEN MID$(stringmathb$, INSTR(UCASE$(stringmathb$), "D"), 1) = "e"
IF MID$(stringmathb$, INSTR(stringmathb$, "e") + 2) = "0" THEN ' The numeric value is the number without the zero exponent.
    stringmathb$ = MID$(stringmathb$, 1, INSTR(stringmathb$, "e") - 1)
    IF RIGHT$(stringmathb$, 1) = "." THEN stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
    RETURN
ELSE
    IF LEFT$(stringmathb$, 1) = "-" THEN stn_sign$ = "-": stringmathb$ = MID$(stringmathb$, 2)
    stringmathb$ = MID$(stringmathb$, 1, INSTR(stringmathb$, ".") - 1) + MID$(stringmathb$, INSTR(stringmathb$, ".") + 1) ' Remove decimal point.
    stn_i& = INSTR(stringmathb$, "e") - 1 ' Length of the numric part.
    IF MID$(stringmathb$, INSTR(stringmathb$, "e") + 1, 1) = "-" THEN
        stringmathb$ = "." + STRING$(VAL(MID$(stringmathb$, stn_i& + 3)) - 1, "0") + MID$(stringmathb$, 1, stn_i&) ' Decimal point followed by exponent value in zeros added in front of numeric part.
    ELSE
        IF stn_i& - 1 > VAL(MID$(stringmathb$, stn_i& + 3)) THEN stn_point$ = "." ' - 1 for decimal place. Ex 2.034d+2 is 2034 here where 3 places to the right . could be moved before . disappears. > so no trailing decimal results.
        stringmathb$ = MID$(MID$(stringmathb$, 1, stn_i&), 1, VAL(MID$(stringmathb$, stn_i& + 3)) + 1) + stn_point$ + MID$(MID$(stringmathb$, 1, stn_i&), VAL(MID$(stringmathb$, stn_i& + 3)) + 2, stn_i& - VAL(MID$(stringmathb$, stn_i& + 3)) - 1) + STRING$(VAL(MID$(stringmathb$, stn_i& + 2)) - (stn_i& - 1), "0")
    END IF
END IF
IF stringmathb$ = "0" THEN stn_sign$ = ""
stringmathb$ = stn_sign$ + stringmathb$
stn_sign$ = "": stn_point$ = ""
RETURN
 
limit_round_convert:
' Try SN if whole number is too large (as it may be trailing zeros) or decimal is beyond limit.
IF LEFT$(stringmathb$, 2) = ".0" AND LEN(stringmathb$) > limit&& + 1 OR INSTR(stringmathb$, ".") > limit&& + 1 OR INSTR(stringmathb$, ".") = 0 AND LEN(stringmathb$) > limit&& THEN
    IF limit&& > 1 THEN
        GOSUB numeric_to_scientific ' Retry as S.N.
        IF LEN(stringmathb$) > limit&& + 3 THEN ' Needs rounding.
            snotation$ = MID$(stringmathb$, INSTR(UCASE$(stringmathb$), "E"))
            exponentvalue&& = VAL(MID$(snotation$, 2)) ' Get positive or negative sign.
            snexponent$ = MID$(stringmathb$, INSTR(UCASE$(stringmathb$), "E") + 2)
            stringmathb$ = MID$(stringmathb$, 1, INSTR(UCASE$(stringmathb$), "E") - 1)
            '''IF LEN(stringmathb$) + LEN(snexponent$) > limit&& + 1 AND exponentvalue&& >= limit&& THEN BEEP
            IF exponentvalue&& >= limit&& THEN
                stringmathb$ = MID$(stringmathb$, 1, exponentvalue&& + 3)
            ELSE
                stringmathb$ = MID$(stringmathb$, 1, limit&& - LEN(snexponent$) + 2)
            END IF
            GOSUB string_rounding_method
            IF LEFT$(stringmathb$, 3) = "10." THEN
                stringmathb$ = "1." + MID$(stringmathb$, 4)
                ' Add one to the exponent.
                FOR round_i& = LEN(snexponent$) TO 1 STEP -1
                    round_x$ = CHR$(ASC(MID$(snexponent$, round_i&, 1)) + 1)
                    IF round_x$ <> CHR$(47) THEN ' Decimal point + 1. Ignore.
                        IF round_x$ = CHR$(58) THEN
                            MID$(snexponent$, round_i&, 1) = "0": carry$ = "1"
                        ELSE
                            MID$(snexponent$, round_i&, 1) = round_x$: carry$ = "": EXIT FOR
                        END IF
                    END IF
                NEXT
                snexponent$ = carry$ + snexponent$: carry$ = ""
            END IF
            stringmathb$ = stringmathb$ + MID$(snotation$, 1, 2) + snexponent$
            IF LEN(snexponent$) + LEN(MID$(stringmathb$, 1, INSTR(UCASE$(stringmathb$), "E") - 1)) > limit&& + 1 THEN
                stringmathb$ = "overflow"
            END IF
            exponentvalue&& = 0
        END IF
    ELSE
        IF INSTR(stringmathb$, ".") > 0 AND INSTR(stringmathb$, ".") <= limit&& THEN
            stringmathb$ = MID$(stringmathb$, 1, limit&& + 2)
            IF round_total% = -1 AND RIGHT$(stringmathb$, 1) > "4" THEN
                GOSUB string_rounding_method
            ELSE
                stringmathb$ = MID$(stringmathb$, 1, limit&& + 1)
                IF show_rounding% THEN stringmathround$ = "r"
            END IF
        ELSE
            stringmathb$ = "overflow"
        END IF
    END IF
    RETURN
END IF
IF LEN(stringmathb$) > limit&& AND INSTR(stringmathb$, ".") = 0 OR LEN(stringmathb$) > limit&& + 1 AND INSTR(stringmathb$, ".") <> 0 THEN
    IF INSTR(stringmathb$, ".") = 0 THEN
        stringmathb$ = MID$(stringmathb$, 1, limit&& + 1)
    ELSE
        stringmathb$ = MID$(stringmathb$, 1, limit&& + 2)
    END IF
    GOSUB string_rounding_method
    IF LEN(stringmathb$) > limit&& + lrc_decimalpoint& THEN ' Ex: limit&& = 4 9999.9 1.e+4
        GOSUB numeric_to_scientific
    ELSE
        IF LEN(stringmathb$) > limit&& + lrc_decimalpoint& THEN stringmathb$ = "overflow"
    END IF
END IF
RETURN
 
replace_decimal:
IF addsubplace& THEN
    addsubx1$ = STRING$(addsubplace& - LEN(addsubx1$), "0") + addsubx1$
    addsubx1$ = MID$(addsubx1$, 1, LEN(addsubx1$) - addsubplace&) + "." + MID$(addsubx1$, LEN(addsubx1$) - addsubplace& + 1)
    DO UNTIL RIGHT$(addsubx1$, 1) <> "0" ' Remove trailing zeros in a decimal sum.
        addsubx1$ = MID$(addsubx1$, 1, LEN(addsubx1$) - 1)
        addsubplace& = addsubplace& - 1
    LOOP
    IF RIGHT$(addsubx1$, 1) = "." THEN addsubx1$ = MID$(addsubx1$, 1, LEN(addsubx1$) - 1) ' Number is now an integer.
END IF
RETURN
 
string_rounding_method:
IF INSTR(stringmathb$, ".") THEN lrc_decimalpoint& = 1 ELSE lrc_decimalpoint& = 0
IF MID$(stringmathb$, LEN(stringmathb$), 1) > "4" THEN
    FOR round_i& = LEN(stringmathb$) - 1 TO 1 STEP -1
        round_x$ = CHR$(ASC(MID$(stringmathb$, round_i&, 1)) + 1)
        IF round_x$ <> CHR$(47) THEN ' Decimal point + 1. Ignore.
            IF round_x$ = CHR$(58) THEN
                MID$(stringmathb$, round_i&, 1) = "0": carry$ = "1"
            ELSE
                MID$(stringmathb$, round_i&, 1) = round_x$: carry$ = "": EXIT FOR
            END IF
        END IF
    NEXT
    stringmathb$ = carry$ + MID$(stringmathb$, 1, LEN(stringmathb$) - 1): carry$ = ""
    IF show_rounding% THEN stringmathround$ = "R"
ELSE
    stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
    IF show_rounding% THEN stringmathround$ = "r"
END IF
 
IF lrc_decimalpoint& THEN
    DO UNTIL RIGHT$(stringmathb$, 1) <> "0"
        stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1)
    LOOP
    IF stringmathb$ = "" OR stringmathb$ = "." THEN stringmathb$ = "0": lrc_decimalpoint& = 0
    IF RIGHT$(stringmathb$, 1) = "." AND exponentvalue&& = 0 THEN
        stringmathb$ = MID$(stringmathb$, 1, LEN(stringmathb$) - 1): lrc_decimalpoint& = 0
    END IF
END IF
RETURN
END SUB

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Raven_Singularity on April 10, 2019, 01:16:43 pm

Was the rounding oddity about "round to the nearest even number" functionality?

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on April 10, 2019, 02:11:43 pm

Do you mean in the screen shot I posted? If so, I was worried when my routine left the figure as all 9's. I thought the only way it wouldn't round up to 649146.5 is if the digit after that last 9 in 649146.49999999999 was an 8. So I checked it with a calculator, and it was an 8. That got rounded up as a nine, the last digit of the 17 digit limit I set for that operation. So it did round correctly. Also, I use a capital "R" at the end, to indicate it rounded up. A lowercase "r" would indicate it rounded down.

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Raven_Singularity on April 10, 2019, 04:37:58 pm

I only know that BASIC in some form rounds up or down based on even whole numbers:

... -6, -4, -2, 0, 2, 4, 6 ...

So 1.5 and 2.5 would both round to 2. I have never liked this style of rounding, I learned 0.5 rounds up, and -0.5 rounds up or down, depending on the type of rounding. I don't like even-number rounding, because it creates uneven data sets:

0, 0, 2, 2, 4, 4 ...

Anyhow, probably not related, but one more odd way BASIC can round things internally.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on April 10, 2019, 06:51:13 pm

I used round up for 5 and over, round down for 4 and under. That's a standard. The other way I think is called "Banker's Rounding." That's where if the rounding digit is 5, and there are no other non-zero digits trailing it, you look at the number immediately preceding the rounding number, and round up only if that preceding number is even.

I'm still on the fence if I would consider changing to that.

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Raven_Singularity on April 10, 2019, 06:58:23 pm

Quote from: Pete on April 10, 2019, 06:51:13 pm

I used round up for 5 and over, round down for 4 and under. That's a standard. The other way I think is called "Banker's Rounding." That's where if the rounding digit is 5, and there are no other non-zero digits trailing it, you look at the number immediately preceding the rounding number, and round up only if that preceding number is even.

I'm still on the fence if I would consider changing to that.

Pete

Banker's Rounding sounds like a more "fair" form of rounding. 0.5 is halfway, going up or down are both wrong, heh. Dividing whether it goes up or down half the time is fair, but I didn't understand what you meant about the other digits causing the rounding.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on April 10, 2019, 07:43:03 pm

Example: 2.315 and 2.325 round to hundredths.

In Banker's Rounding, we have both digits in the thousandth ending in a 5, so both numbers are eligible to be rounded.

Next we look at the digit in front of each 5.

2.315 (The digit in front of the 5 is a 1, and odd number.)

2.325 (The digit in front of the 5 is a 2, an even number.)

In Banker's Rounding, we round up the value of an odd number in front of the trailing "5" digit to an even number and we leave even numbers alone.

So, 2.315 gets changed to 2.325 and 2.125 stays as 2.325.

Now, to get to hundredths, we drop the 5 off of each, and end up with both being...

2.32

And I'm glad I did an example this time, because I just re-read my last post and I should have ended that last sentence with odd, not even, as in...

I used round up for 5 and over, round down for 4 and under. That's a standard. The other way I think is called "Banker's Rounding." That's where if the rounding digit is 5, and there are no other non-zero digits trailing it, you look at the number immediately preceding the rounding number, and round up only if that preceding number is odd.

So both round to 2.32—instead of 2.325 rounding up to 2.33—when rounded off to the nearest 100th. The rationale for the third rule is that approximately half of the time the number will be rounded up and the other half of the time it will be rounded down.

Sorry for messing that up in my previous post.

Pete

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Jack002 on April 11, 2019, 10:50:10 am

I don't like rounding. I say if you want to round to the 3rd digit past the decimal then show me the 4th digit. I thought that rounding affects the accuracy of calculations negatively, but I can't seem to find people saying that.

My rounding pun
Farmer Brown had 290 cows but it was 300 once he rounded up

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: jack on April 11, 2019, 11:53:16 am

maybe your pun should be "Farmer Brown thought he had 290 cows but it was 300 once he rounded up"

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Raven_Singularity on April 11, 2019, 12:31:11 pm

"After losing his 290 cows, Farmer Brown later that day rounded up his 300 cows."

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: SMcNeill on April 11, 2019, 02:42:27 pm

You guys should quit picking on us farmers, when it comes to math. We’re rather good at it. To illustrate the point, let me tell you a tale my Grandpa told.

Back in the early 1900’s, everyone’s child was in a rush to head off to the city and get “educated” proper. It turns out, Grandpa’s neighbor’s children all went off and headed to college. While the oldest was getting his PHD, and the youngest was just starting, their father passed away. All three children rushed home for the funeral and reading of the will.

In the will, their father divided up his herd of horses in the following manner. The first born was supposed to get one half of the herd, the second child was supposed to get one third, while the youngest boy should’ve gotten one ninth.

Now, since their father had seventeen horses, they had no idea of what to do. No mater how they proposed settling the issue, they just couldn’t make the numbers work to everyone’s satisfaction. Luckily, my grandfather stopped by around that time to offer his condolences on their loss. When presented with their quandary, he gave them his horse as a bereavement give.

With eighteen horses now, the oldest got nine, the second child got six, and the third child got two. Taking the one that was left over as payment for services rendered, Grandfather left later that evening on the same horse he rode in on...

Who says farmers don’t know math? ;D

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Jack002 on April 11, 2019, 04:19:57 pm

Well it looks like I drug this thread off topic. I'm denying all responsibility.

Rounding tho. Anyone else think its inaccurate? I think if you divide 1 by 3 and get 0.333333 report all your digits and don't hide or round anything. Calculators are now reporting in fractional mode and preserve value when its not a repeating integer.
We use numbers in base 10 (usually) to represent an idea. They are not the idea, they are the representation.

Title: Re: Yuck String Math or What's wrong with FOO?
Post by: Pete on April 11, 2019, 04:46:02 pm

Quote from: SMcNeill on April 11, 2019, 02:42:27 pm

You guys should quit picking on us farmers, when it comes to math. We’re rather good at it. To illustrate the point, let me tell you a tale my Grandpa told.

Back in the early 1900’s, everyone’s child was in a rush to head off to the city and get “educated” proper. It turns out, Grandpa’s neighbor’s children all went off and headed to college. While the oldest was getting his PHD, and the youngest was just starting, their father passed away. All three children rushed home for the funeral and reading of the will.

In the will, their father divided up his herd of horses in the following manner. The first born was supposed to get one half of the herd, the second child was supposed to get one third, while the youngest boy should’ve gotten one ninth.

Now, since their father had seventeen horses, they had no idea of what to do. No mater how they proposed settling the issue, they just couldn’t make the numbers work to everyone’s satisfaction. Luckily, my grandfather stopped by around that time to offer his condolences on their loss. When presented with their quandary, he gave them his horse as a bereavement give.

With eighteen horses now, the oldest got nine, the second child got six, and the third child got two. Taking the one that was left over as payment for services rendered, Grandfather left later that evening on the same horse he rode in on...

Who says farmers don’t know math? ;D

But what about that other family that had 17 donkeys, and only 2 kids? I heard the grandpa lost his ass in that deal. Too bad, he should have just told each to take 8 live ones, and sawed the one remaining down the middle. Oops, I forgot, farmers don't like half-assed solutions. :D

@Jack: I know. I used to have a repeating number output method in my code, but I took it out when I discovered calculators that don't support that these days. A lot will report 2 / 3 as: .6666666666666667

Text Only | Text with Attachments

QB64.org Forum

Active Forums => QB64 Discussion => Topic started by: Pete on February 23, 2019, 04:35:51 pm