QB64.org Forum

Samples Gallery & Reference => Utilities => Topic started by: The Librarian on March 05, 2020, 11:06:44 pm

Title: Circle Intersecting Circle by STxAxTIC
Post by: The Librarian on March 05, 2020, 11:06:44 pm

Circle Intersecting Circle

Author: @bplus @STxAxTIC
Source: qb64.org Forum
URL: https://www.qb64.org/forum/index.php?topic=1973.0 (https://www.qb64.org/forum/index.php?topic=1973.0)
Version: 2019
Tags: [2d], [geometry], [intersections]

Description:
Here we present two (equivalent) methods for calculating the intersection points between any two circles.

Source Code:

Code: QB64: [Select]

1. SCREEN 12
2.  
3. C1x = -100
4. C1y = 50
5. C2x = 100
6. C2y = 100
7. r1 = 150
8. r2 = 100
9.  
10. DO
11.     DO WHILE _MOUSEINPUT
12.         IF _MOUSEBUTTON(1) THEN
13.             C2x = _MOUSEX - 320
14.             C2y = 240 - _MOUSEY
15.         END IF
16.         IF _MOUSEBUTTON(2) THEN
17.             C1x = _MOUSEX - 320
18.             C1y = 240 - _MOUSEY
19.         END IF
20.     LOOP
21.  
22.     CLS
23.     CIRCLE (320 + C1x, C1y * -1 + 240), r1, 8
24.     CIRCLE (320 + C2x, C2y * -1 + 240), r2, 7
25.  
26.     ''' Toggle between the two functions here.
27.     'CALL CircleIntersectCircle(C1x, C1y, r1, C2x, C2y, r2, i1x, i1y, i2x, i2y)
28.     CALL CircleIntersectCircle2(C1x, C1y, r1, C2x, C2y, r2, i1x, i1y, i2x, i2y)
29.     '''
30.     LOCATE 1, 1: PRINT i1x, i1y, i2x, i2y
31.  
32.     IF (i1x OR i1y OR i2x OR i2y) THEN
33.         CIRCLE (320 + i1x, i1y * -1 + 240), 3, 14
34.         CIRCLE (320 + i2x, i2y * -1 + 240), 3, 15
35.     END IF
36.  
37.     _DISPLAY
38.     _LIMIT 30
39. LOOP
40.  
41. SUB CircleIntersectCircle (c1x, c1y, r1, c2x, c2y, r2, i1x, i1y, i2x, i2y)
42.     ' Returns i1x, i1y, i2x, i2y
43.     i1x = 0: i1y = 0: i2x = 0: i2y = 0
44.     Dx = c1x - c2x
45.     Dy = c1y - c2y
46.     D2 = Dx * Dx + Dy * Dy
47.     IF (D2 ^ .5 < (r1 + r2)) THEN
48.         F = (-D2 + r2 * r2 - r1 * r1) / (2 * r1)
49.         a = Dx / F
50.         b = Dy / F
51.         g = a * a + b * b
52.         IF (g > 1) THEN
53.             h = SQR(g - 1)
54.             i1x = c1x + r1 * (a + b * h) / g
55.             i1y = c1y + r1 * (b - a * h) / g
56.             i2x = c1x + r1 * (a - b * h) / g
57.             i2y = c1y + r1 * (b + a * h) / g
58.         END IF
59.     END IF
60. END SUB
61.  
62. SUB CircleIntersectCircle2 (c1x, c1y, r1, c2x, c2y, r2, i1x, i1y, i2x, i2y)
63.     ' Returns i1x, i1y, i2x, i2y
64.     d = ((c1x - c2x) ^ 2 + (c1y - c2y) ^ 2) ^ .5
65.     alpha = _ACOS((r1 ^ 2 + d ^ 2 - r2 ^ 2) / (2 * r1 * d))
66.     x1 = r1 * COS(alpha)
67.     l = r1 * SIN(alpha)
68.     angle = _ATAN2(c2y - c1y, c2x - c1x)
69.     p3x = c1x + x1 * COS(angle)
70.     p3y = c1y + x1 * SIN(angle)
71.     i1x = p3x + l * COS(angle - _PI / 2)
72.     i1y = p3y + l * SIN(angle - _PI / 2)
73.     i2x = p3x + l * COS(angle + _PI / 2)
74.     i2y = p3y + l * SIN(angle + _PI / 2)
75. END SUB

Text Only | Text with Attachments